include "Traces.ma".
include "basics/jmeq.ma".

discriminator option.

record relations (p : label_params) (S1,S2 : abstract_status p) : Type[0] ≝
 { Srel: S1 → S2 → Prop
 ; Crel: S1 → S2 → Prop
 }.

definition Rrel ≝ λp.λS1,S2 : abstract_status p.λrel : relations … S1 S2.λs,s'.
 ∀s1,s1'. as_syntactical_succ … S1 s1 s → Crel … rel s1 s1' → as_syntactical_succ … S2 s1' s'.

record simulation_conditions (p : label_params) (S1,S2 : abstract_status p) 
(rel : relations …S1 S2) : Prop ≝
 { initial_is_initial :
   ∀s1,s2.Srel … rel s1 s2 → (bool_to_Prop (as_initial … s1) →  bool_to_Prop (as_initial … s2))
 ; final_is_final :
   ∀s1,s2.Srel … rel s1 s2 → (bool_to_Prop(as_final … s1) → bool_to_Prop (as_final … s2))
 ; io_is_io :
   ∀s1,s2.Srel … rel s1 s2 → as_classify … s2 = cl_io → as_classify … s1 = cl_io
 ; simulate_tau:
     ∀s1:S1.∀s2:S2.∀s1':S1.
      as_execute … (cost_act … (None ?))  s1 s1'→
      Srel … rel s1 s2 → as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      ∃s2'. ∃t: raw_trace … S2 s2 s2'.
        Srel … rel s1' s2' ∧ silent_trace … t
 ; simulate_label:
     ∀s1:S1.∀s2:S2.∀l.∀s1':S1.
      as_execute … S1 (cost_act … (Some ? l)) s1 s1' →
      as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      Srel … rel s1 s2 →
      ∃s2',s2'',s2'''.
       ∃t1: raw_trace … S2 s2 s2'.
       as_execute … (cost_act … (Some ? l)) s2' s2'' ∧
       ∃t3: raw_trace … s2'' s2'''.
        Srel … rel  s1' s2''' ∧ silent_trace … t1 ∧ pre_silent_trace … t3
 ; simulate_call_pl:
     ∀s1:S1.∀s2:S2.∀s1':S1.∀f,l.
      is_call_post_label … s1 →
      as_execute … (call_act … f l) s1 s1' →
      as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      Srel … rel s1 s2 →
      ∃s2',s2'',s2'''.
       ∃t1: raw_trace … S2 s2 s2'.
       as_execute … (call_act … f l) s2' s2'' ∧
       bool_to_Prop(is_call_post_label … s2') ∧
       ∃t3: raw_trace … S2 s2'' s2'''.
        Srel … rel s1' s2''' ∧ silent_trace … t1 ∧ pre_silent_trace … t3
 ; simulate_ret_l:
     ∀s1:S1.∀s2:S2.∀s1':S1.∀l.
      as_execute … S1 (ret_act … (Some ? l)) s1 s1' →
      as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      Srel  … rel s1 s2 →
      ∃s2',s2'',s2'''.
       ∃t1: raw_trace … S2 s2 s2'.
       as_execute p S2 (ret_act p (Some ? l)) s2' s2'' ∧
       ∃t3: raw_trace … S2 s2'' s2'''.
        Srel … rel s1' s2''' ∧ silent_trace … t1 ∧ pre_silent_trace … t3
 ; simulate_call_n:
     ∀s1:S1.∀s2:S2.∀s1':S1.∀f,l.
      as_execute … (call_act … f l) s1 s1' →
      ¬ is_call_post_label … s1 →
      as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      Srel … rel s1 s2 →
      ∃s2',s2'',s2'''.
       ∃t1: raw_trace … S2 s2 s2'.
       bool_to_Prop (¬ is_call_post_label … s2') ∧
       as_execute … (call_act … f l) s2' s2'' ∧
       ∃t3: raw_trace … S2 s2'' s2'''.
        Srel … rel s1' s2''' ∧ silent_trace … t1 ∧ pre_silent_trace … t3 
        ∧ Crel … rel s1 s2'
 ; simulate_ret_n:
     ∀s1:S1.∀s2:S2.∀s1':S1.
      as_execute … (ret_act … (None ?)) s1 s1' →
      as_classify … s1 ≠ cl_io → as_classify … s1' ≠ cl_io → 
      Srel … rel s1 s2 →
      ∃s2',s2'',s2''': S2.
       ∃t1: raw_trace … S2 s2 s2'.
       as_execute … (ret_act … (None ?)) s2' s2''  ∧
       ∃t3: raw_trace … S2 s2'' s2'''.
        Srel … rel s1' s2''' ∧ pre_silent_trace … t1 ∧ pre_silent_trace … t3 
        ∧ Rrel … rel s1' s2''
 ; simulate_io_in :
   ∀s1:S1.∀s2:S2.∀s1':S1.∀l.
   as_execute … (cost_act … (Some ? l)) s1 s1' → 
   as_classify … s1 ≠ cl_io → as_classify … s1' = cl_io → 
   Srel … rel s1 s2 → 
   ∃s2',s2''.∃t: raw_trace … s2 s2'.
   pre_silent_trace … t ∧ as_execute … (cost_act … (Some ? l)) s2' s2'' ∧
   as_classify … s2'' = cl_io ∧ Srel … rel s1' s2''
; simulate_io_out : 
   ∀s1:S1.∀s2:S2.∀s1':S1.∀l.
   as_execute … (cost_act … (Some ? l)) s1 s1' → 
   as_classify … s1 = cl_io → as_classify … s1' ≠ cl_io → 
   Srel … rel s1 s2 → 
   ∃s2',s2''.∃t : raw_trace … s2' s2''.
   pre_silent_trace … t ∧ as_execute … (cost_act … (Some ? l)) s2 s2' ∧
   as_classify … s2 = cl_io ∧ Srel … rel s1' s2''
 }.
 
lemma io_state_case : ∀P : status_class → Prop.∀s.
(s = cl_io → P s) → (s ≠ cl_io → P s) → P s.
#P * #H1 #H2 [2: @H1 %] @H2 % #EQ destruct
qed.

lemma simulate_labelled_action : ∀p.∀S1,S2 : abstract_status p.
∀rel : relations … S1 S2.
∀s1,s2 : S1.∀s1' : S2.
∀l : ActionLabel p.
simulation_conditions … rel → 
is_costlabelled_act … l → 
(is_call_act … l → is_call_post_label … s1) → 
as_execute … l s1 s2 → 
Srel … rel s1 s1' → 
¬ (as_classify … s1 = cl_io ∧ as_classify … s2 = cl_io) → 
∃pre_em,post_em,s2' : S2.
∃t_pre : raw_trace … s1' pre_em.
∃t_post : raw_trace … post_em s2'.
silent_trace … t_pre ∧ silent_trace … t_post ∧
as_execute … l pre_em post_em ∧
(is_call_act … l → is_call_post_label … pre_em) ∧
Srel … rel s2 s2'.
#p #S1 #S2 #rel #s1 #s2 #s1' *
[ #f #c | * [|#lbl] | * [|#lbl]]
#sim * #Hcall #prf #REL * #Hio
[ cases(simulate_call_pl … sim … prf … REL)
  [2: @Hcall %{f} %{c} %
  |3: % #ABS lapply(io_exiting … S1 … ABS … prf) * #lbl #EQ destruct
  |4: % #ABS lapply(io_entering … S1 … ABS … prf) * #lbl #EQ destruct
  ]
  #pre_em * #post_em * #s2' * #t_pre ** #prf' #call * #t_post ** #REL' #sil_tpre #sil_tpost
  %{pre_em} %{post_em} %{s2'} %{t_pre} %{t_post} % // % // % // % // %1 //
| cases(simulate_ret_l … sim … prf … REL)
  [2: % #ABS lapply(io_exiting … S1 … ABS … prf) * #lbl #EQ destruct
  |3: % #ABS lapply(io_entering … S1 … ABS … prf) * #lbl #EQ destruct
  ]
  #pre_em * #post_em * #s2' * #t_pre * #prf' * #t_post ** #REL' #sil_tpre #sil_tpost
  %{pre_em} %{post_em} %{s2'} %{t_pre} %{t_post} % // % [2: * #f * #c #EQ destruct] 
  % // % // %1 //
| @(io_state_case … (as_classify … s1)) @(io_state_case … (as_classify … s2))
  #class_s2 #class_s1
  [ cases(Hio ?) /2/
  | cases(simulate_io_out … sim … prf … REL) //
    #post_em * #s2' * #t_post *** #sil_tpost #prf' #Hclass #REL' 
    %{s1'} %{post_em} %{s2'} %{(t_base …)} %{t_post} % // % [2: * #f * #c #EQ destruct] 
    % // % [%2 %*] % assumption
  | cases(simulate_io_in … sim … prf … REL) //
    #pre_em * #s2' * #t_pre *** #sil_tpre #prf' #Hclass #REL' 
    %{pre_em} %{s2'} %{s2'} %{t_pre} %{(t_base …)} % // % [2: * #f * #c #EQ destruct] 
    % // % [% assumption]  %2 % *
  | cases(simulate_label … sim … prf … REL) //
    #pre_em * #post_em * #s2' * #t_pre * #prf' * #t_post ** #REL' #sil_tpre #sil_tpost
    %{pre_em} %{post_em} %{s2'} %{t_pre} %{t_post} % // % [2: * #f * #c #EQ destruct] 
    % // % // %1 //
  ]
]
qed.  
    
  
  
(* silente simula in silente *)


theorem simulates_pre_mesurable: ∀p.
 ∀S1,S2 : abstract_status p.∀rel : relations … S1 S2.
 ∀s1,s1' : S1. ∀t1: raw_trace … S1 s1 s1'.
  simulation_conditions … rel → 
  pre_measurable_trace … t1 →
  ∀s2 : S2.
 as_classify … s2 ≠ cl_io →   Srel … rel s1 s2 →
  ∃s2'. ∃t2: raw_trace … s2 s2'.
    pre_measurable_trace … t2 ∧
    get_costlabels_of_trace … t1 = get_costlabels_of_trace … t2 ∧
    Srel … rel s1' s2' ∧ 
    (measurable_suffix … t1 → measurable_suffix … t2) ∧
    (silent_trace … t1 → silent_trace … t2).
#p #S1 #S2 #rel #s1 #s1' #t1 #sim #H elim H -t1 -s1 -s1'
[ #st #Hst #s2 #Hs2 #Rsts2 %{s2} %{(t_base …)} %
 [ % [ % // % // % //] * #s_em ** [ #sx | #x1 #x2 #x3 #l1 #prf1 #tl1] * #t_pre * #s_post * #t_post * #sil_tpost
  * #prf1 ** normalize #EQ  lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct
 | #_ %2 % *
 ]
| #st1 #st2 #st3 #l #prf #tl #Hclass **
  [ #EQ destruct #pre_tl #IH #s2 #Hclass2 #R_st1_s2
    cases(simulate_tau … sim … prf … R_st1_s2) [2,3: /2 by head_of_premeasurable_is_not_io/]
    #s2' * #t2_init * #R_st2_s2' #silent_t2_init cases(IH … R_st2_s2') 
    [2: cases silent_t2_init /2 by pre_silent_io/ cases t2_init in Hclass2; //  
        #H12 #H13 #H14 #H15 #H16 #H17 #H18 * #H19 cases(H19 I) ]
    #s2_fin * #t2_fin **** #pre_t2_fin #EQcost #R_st3_s2_fin #Hm #Hs %{s2_fin} %{(t2_init @ t2_fin)} 
    cut(? : Prop)
      [3: #Hpre % 
         [ % 
             [ % 
                 [ %{Hpre} >get_cost_label_invariant_for_append_silent_trace_l // assumption
                 | assumption
                 ]
             |  #meas_suff cases(Hm ?)
                [ #s_pre' * #t_pre' * #s_post' * #t_post' * #sil_tpost' * #l_em * #ex_em ** #EQ 
                  destruct #Hcall #lem_cost %{s_pre'} %{(t2_init @ t_pre')} %{s_post'} %{t_post'} 
                  %{sil_tpost'} %{l_em} %{ex_em} /4 by conj/
                | cases meas_suff -meas_suff #s_em * #t_pre inversion t_pre in ⊢ ?;
                  [ #st #EQ1 #EQ2 #EQ3 destruct * #s1_post * #t_post * #sil_tpost * #l_em * #ex_em 
                    ** #EQ normalize in EQ; lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct #_ *
                  | #st1' #st2' #st3' #lbl #prf' #tl' #_ #EQ1 #EQ2 #EQ3 destruct * #s_post * #t_post * #sil_tpost
                    * #l_em * #ex_em ** #EQ normalize in EQ; lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct #Hcall #cost_lem
                    %{st3'} %{tl'} %{s_post} %{t_post} %{sil_tpost} %{l_em} %{ex_em} /4 by conj/
                  ]
                ]
             ]
        | * [2: * #H cases(H I)] #H inversion H [ #H9 #H10 #H11 #H12 #H13 #H14 destruct]
          #x1 #x2 #x3 #prf3 #tl'' #Hclass' #pre_siltl'' #_ #EQ1 #EQ2 #EQ3 #EQ4 destruct 
          /4 by append_silent,or_introl/
        ]
     |
     ]
    @append_premeasurable_silent //
  | #lbl #EQ destruct #pre_tl #IH #s2 #Hs2 #REL
    cases(simulate_label … sim … prf … REL) 
    [2,3: /2/] 
    #s2'' * #s2''' * #s2'''' * #t_s2'' * #exe_s2''' * #t_s2'''' ** #RELst2_s2'''' 
    #sil_ts2'' #sil_t_s2'''' cases(IH … RELst2_s2'''')  /2 by pre_silent_io/
    #s3 * #t_s3 **** #pre_s3 #EQcost #RElst3s3 #Hm #Hs %{s3}
    %{(t_s2'' @ (t_ind … exe_s2''' …))}  [ @(t_s2'''' @ t_s3) ] % 
    [2: * [ #H inversion H 
            [ #H22 #H23 #H24 #H25 #H26 #H27 destruct 
            | #H29 #H30 #H31 #H32 #H33 #H34 #H35 #H36 #H37 #H38 #H39 #H40 destruct
            ]
          | * #H cases(H I)
          ]
     ]
    %
    [ % [2: assumption] % 
      [ @append_premeasurable_silent // %2 /2 by ex_intro/ 
       [ cases sil_ts2'' [/2 by pre_silent_io/ ] inversion t_s2''
         [ #H31 #H32 #H33 #H34 #H35 destruct assumption ]
         #H37 #H38 #H39 #H40 #H41 #H42 #H43 #H44 #H45 #H46 #H47 destruct
         cases H47 #ABS @⊥ @ABS % ] 
       @append_premeasurable_silent // % //
    | whd in ⊢ (??%?); >EQcost >get_cost_label_invariant_for_append_silent_trace_l
      [2: assumption] whd in ⊢ (???%); 
      >get_cost_label_invariant_for_append_silent_trace_l //
    ] % assumption
    | #Hsuff cases(measurable_suffix_tind … Hsuff)
      [ * #_ #sil_tl lapply(Hs sil_tl) #sil_ts3 %{s2''} %{t_s2''} %{s2'''} %{(t_s2'''' @ t_s3)}
      % [ /3 by or_introl, append_silent/ ] %{(cost_act … (Some ? lbl))} %{(exe_s2''')} % // % // * #f * #c #EQ destruct
      | #H @measurable_suffix_append change with ((t_ind ??????? t_s2'''')@t_s3) in ⊢ (?????%);
        @measurable_suffix_append /2/
      ]
  ]
  ]
| #s2 #s2' #s2'' #l #class_s2 #exe_s2_s2' #tl whd in ⊢ (% → ?); * #ret_lab #EQ destruct(EQ)
  #pre_meas_tl #IH #s1 #class_s2 #RELst1s2
  cases(simulate_ret_l … sim … exe_s2_s2' … RELst1s2) [2,3: /2/ ]
  #st1 * #st2 * #st3 * #t1 * #exe_s2'' * #t2 ** #rel_s2_s2''' 
  #sil_t1 #sil_t2 cases(IH … rel_s2_s2''')
  [2: @(pre_silent_io … sil_t2) assumption]
  #s2_fin * #t_fin **** #pre_t_fin #EQcost #REL #Hm #Hs
  %{s2_fin} %{(t1 @ (t_ind … exe_s2'' … t2) @ t_fin)} % 
  [2: * [ #H inversion H 
            [ #H22 #H23 #H24 #H25 #H26 #H27 destruct 
            | #H29 #H30 #H31 #H32 #H33 #H34 #H35 #H36 #H37 #H38 #H39 #H40 destruct
            ]
          | * #H cases(H I)
          ]
  ]
  % 
    [ % [2: assumption]
      % [2: whd in ⊢ (??%?); 
        >(get_cost_label_invariant_for_append_silent_trace_l … sil_t1)
        whd in ⊢ (???%);
        >(get_cost_label_invariant_for_append_silent_trace_l … (or_introl … sil_t2))
        @eq_f assumption ]
  @append_premeasurable_silent [2: //] %3 
  [2,3: /3 by append_premeasurable_silent, ex_intro, or_introl/ ] 
  cases sil_t1 [ /2 by pre_silent_io/ ] inversion t1 
  [ #H49 #H50 #H51 #H52 #H53 destruct //]
  #H55 #H56 #H57 #H58 #H59 #H60 #H61 #H62 #H63 #H64 #H65 destruct cases H65
  #ABS @⊥ @ABS %
 |  #Hsuff cases(measurable_suffix_tind … Hsuff)
      [ * #_ #sil_tl lapply(Hs sil_tl) #sil_ts3 %{st1} %{t1} %{st2} %{(t2 @ t_fin)}
      % [ /3 by or_introl, append_silent/ ] %{(ret_act … (Some ? ret_lab))} %{(exe_s2'')} % // % // * #f * #c #EQ destruct
      | #H @measurable_suffix_append change with ((t_ind ??????? t2)@t_fin) in ⊢ (?????%);
        @measurable_suffix_append /2/
      ]
  ]
| #s1 #s2 #s3 #l #exe_s1_s2 #tl #class_s1 * #f * #lab #EQ destruct
  #post #pre_tl #IH #s2' #io_s2' #REL_s1_s2'
   cases(simulate_call_pl … sim … post … exe_s1_s2 … REL_s1_s2') 
   [2,3: /2 by head_of_premeasurable_is_not_io/ ]
   #s' * #s2'' * #s2''' * #t1 ** #exe_s2'' #post' * #t2 ** #REL #sil_t1 #sil_t2
   cases(IH  … REL)
   [2: /2 by pre_silent_io/ ]
   #s2_fin * #t_fin **** #pre_t_fin #EQcost #REL1 #Hm #Hs %{s2_fin}
   %{(t1 @ (t_ind … exe_s2'' … t2) @ t_fin)} %
   [2: * [ #H inversion H 
            [ #H22 #H23 #H24 #H25 #H26 #H27 destruct 
            | #H29 #H30 #H31 #H32 #H33 #H34 #H35 #H36 #H37 #H38 #H39 #H40 destruct
            ]
          | * #H cases(H I)
          ]
  ]
  % 
   [ % [2: assumption] %
   [2: whd in ⊢ (??%?); 
        >(get_cost_label_invariant_for_append_silent_trace_l … sil_t1)
        whd in ⊢ (???%);
        >(get_cost_label_invariant_for_append_silent_trace_l …  (or_introl … sil_t2))
        @eq_f assumption ]
   @append_premeasurable_silent try assumption
     %4 try assumption
     [ cases sil_t1 [/2 by pre_silent_io/ ] inversion t1 [#H67 #H68 #H69 #H70 #H71 destruct //]
       #H73 #H74 #H75 #H76 #H77 #H78 #H79 #H80 #H81 #H82 #H83 destruct cases H83
       #ABS @⊥ @ABS %
     | whd %{f} %{lab} %
     | @append_premeasurable_silent // % assumption
     ]
   | #Hsuff cases(measurable_suffix_tind … Hsuff)
      [ * #_ #sil_tl lapply(Hs sil_tl) #sil_ts3 %{s'} %{t1} %{s2''} %{(t2 @ t_fin)}
      % [ /3 by or_introl, append_silent/ ] %{(call_act … f lab)} %{(exe_s2'')} % // % //
      | #H @measurable_suffix_append change with ((t_ind ??????? t2)@t_fin) in ⊢ (?????%);
        @measurable_suffix_append /2/
      ]
  ]
|  #st1 #st2 #st3 #st4 #st5 #l1 #l2 #exe_12 #t1 #t2 #exe_34 #class_1 #class_3 *
  #f * #l #EQ destruct #Hst1 #pre_t1 #pre_t2 #succ_14 whd in ⊢ (% → ?); #EQ destruct
  #IH1 #IH2 #st1' #Hst1' #REL cases(simulate_call_n … sim … exe_12 … Hst1 … REL) [2,3: /2/ ]
  #st1'' * #st1''' * #st2' * #tr1 ** #nps_st1'' #exe_12' * #tr2 *** #REL1 #sil_tr1 
  #sil_tr2 #call_rel cases(IH1 … REL1)
  [2: /2 by pre_silent_io/ ] 
  #st3' * #tr3 **** #pre_tr3 #EQcost_tr3 #REL2 #Hm1 #Hs1
  cases(simulate_ret_n … sim … exe_34 … REL2) [2,3: /2 by head_of_premeasurable_is_not_io/ ] 
  #st3'' * #st4' * #st4'' *
  #tr4 * #exe_34' * #tr5 *** #REL3 #sil_tr4 #sil_tr5 #RET_REL cases(IH2 … REL3) [2: /2 by pre_silent_io/ ]
  #st5' * #tr6 **** #pre_tr6 #EQcost_tr6 #REL4 #Hm2 #Hs2 %{st5'} 
  %{(tr1 @ (t_ind … exe_12' …  ((tr2 @ tr3 @ tr4) @ (t_ind … exe_34' … (tr5 @tr6)))))}
  % 
  [2: * [ #H inversion H 
            [ #H22 #H23 #H24 #H25 #H26 #H27 destruct 
            | #H29 #H30 #H31 #H32 #H33 #H34 #H35 #H36 #H37 #H38 #H39 #H40 destruct
            ]
          | * #H cases(H I)
          ]
  ]
  % 
  [ % [2: assumption] %
  [ @append_premeasurable_silent try assumption %5 
       [1,2: /2 by pre_silent_io/
             cases sil_tr1 /2 by pre_silent_io/ inversion tr1
             [ #H85 #H86 #H87 #H88 #H89 destruct // ]
             #H97 #H98 #H99 #H100 #H101 #H102 #H103 #H104 #H105 #H106 #H107 destruct
             cases H107 #ABS @⊥ @ABS %
       | whd %{f} %{l} %
       | assumption 
       | @append_premeasurable_silent try assumption [2: % //]
         @append_silent_premeasurable // % //
       | @append_premeasurable_silent try assumption
       | @(RET_REL … call_rel) assumption
       | %
       ]
  | >get_cost_label_invariant_for_append_silent_trace_l [2: // ]
    whd in ⊢ (??%%); @eq_f >append_associative 
    >get_cost_label_invariant_for_append_silent_trace_l in ⊢ (???%);
    [2: % // ] >append_associative 
    >get_cost_label_append in ⊢ (???%);
    >get_cost_label_invariant_for_append_silent_trace_l in ⊢ (???%);
    [2: % //] normalize
    >get_cost_label_invariant_for_append_silent_trace_l in ⊢ (???%);
    [2: % // ] >get_cost_label_append in ⊢ (??%?); @eq_f2
    assumption
  ]
  % //
 | #Hsuff cases(measurable_suffix_tind … Hsuff)
   [ * #_ #ABS @⊥ cases Hsuff #s_em * #t_pre * #s_post * #t_post * #sil_tpost * #l_em
     * #ex_em ** inversion t_pre in ⊢ ?;
     [2: #z1 #z2 #z3 #lb #exec #tail #_ #EQ1 #EQ2 #EQ3 destruct #EQ normalize in EQ; lapply(eq_to_jmeq ??? EQ) -EQ
         #EQ destruct >e0 in ABS; #ABS lapply(silent_append_l2 … ABS) -ABS * [2: * #H cases(H I)] -IH1 -IH2
         -Hsuff -e0 -EQ #H inversion H
         [ #H101 #H102 #H103 #H104 #H105 #H106 #H107 #H108 destruct]
         #y1 #y2 #y3 #exec #tail1 #Hclass1 #sil_tail #_ #EQ1 #EQ2 #EQ3 #EQ4 destruct #_ *
     ]
     #st #EQ1 #EQ2 #EQ3 destruct normalize in ⊢ (% → ?); #EQ lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct
     #ABS1 >ABS1 in Hst1; [2: /3 by ex_intro/] *
   | #Hsuff @measurable_suffix_append change with (t_ind ???????? @ ?) in ⊢ (?????%); @measurable_suffix_append
     change with (t_ind ???????? @ ?) in ⊢ (?????%); @measurable_suffix_append @Hm2
     cases(measurable_suffix_append_case … Hsuff)
     [ * #_ * [2: * #H cases(H I)] #H inversion H in ⊢ ?; 
       [ #H137 #H138 #H139 #H140 #H141 #H142 @⊥
         -H142 lapply H141 -H141 lapply H138 -H138 lapply H140 -H140 <H139 #EQ lapply t2 -t2 >EQ -EQ
         #st2 #_ #EQ destruct(EQ)
       | #H144 #H145 #H146 #H147 #H148 #H149 #H150 #H151 #H152 #H153 #H154 #H155 @⊥ -Hsuff destruct
       ]
     | -Hsuff * #s_em * #t_pre inversion t_pre in ⊢ ?;
       [ #st #EQ1 #EQ2 #EQ3 destruct * #s_post * #t_post * #sil_tpost * #l_em * #ex_em ** #EQ normalize in EQ;
         lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct #_ *
       | #a1 #a2#a3 #lbl #exe #tl1 #_ #EQ1 #EQ2 #EQ3 destruct * #s1_post * #t_post * #sil_tpost * #l_em
         * #ex_em ** #EQ normalize in EQ; lapply(eq_to_jmeq ??? EQ) -EQ #EQ destruct #Hcall #Hcost
         %{a3} %{tl1} %{s1_post} %{t_post} %{sil_tpost} %{l_em} %{ex_em} /5 by conj/
       ]
     ]
   ]
 ]
]
qed.

lemma silent_in_silent : ∀p.∀S1,S2 : abstract_status p.∀rel : relations … S1 S2.
 ∀s1,s1' : S1. ∀t1: raw_trace … S1 s1 s1'.
  simulation_conditions … rel →
  ∀s2 : S2.Srel … rel s1 s2 → 
  silent_trace … t1 →
  ∃s2'. ∃t2: raw_trace … s2 s2'.
    silent_trace … t2 ∧
    Srel … rel s1' s2'.
    #p
#S1 #S2 #rel #s1 #s1' #t1 #sim #s2 #REL *
[ #pre_sil_ti0 cases(simulates_pre_mesurable … sim … (pre_silent_is_premeasurable … pre_sil_ti0) … REL) 
  [2: % #H 
      lapply(head_of_premeasurable_is_not_io … (pre_silent_is_premeasurable … pre_sil_ti0)) 
      >(io_is_io … sim … H) // * /2/
  ]
  #s2' * #t2 *** * #H1 #H2 #H3 #H4 #H5 %{s2'} %{t2} % /3 by or_introl/
| cases t1 in REL; [ #st #H #_ %{s2} %{(t_base …)} % [%2 % * ] // ]
  #H7 #H8 #H9 #H10 #H11 #H12 #H13 #H14 cases H14 #H cases(H I)
]
qed.

lemma tail_of_premeasurable_is_not_io : ∀p.∀S : abstract_status p.
∀s1,s2 : S.∀t : raw_trace … s1 s2.
pre_measurable_trace … t → 
as_classify … s2 ≠ cl_io. #p
#S #s1 #s2 #t #H elim H //
qed.

theorem simulates_measurable:
 ∀p.
 ∀S1,S2: abstract_status p.
 
 ∀rel: relations … S1 S2. simulation_conditions … rel →
 
 ∀si,sn: S1. ∀t: raw_trace … si sn.
 
 ∀s1,s2. measurable … s1 s2 … t →
 
 ∀si': S2. 
 (as_classify … si' = cl_io →  as_classify … si = cl_io) →  
 
 Srel … rel si si' →
 
 ∃sn'. ∃t': raw_trace … si' sn'.

 Srel … rel sn sn' ∧

 get_costlabels_of_trace … t = get_costlabels_of_trace … t' ∧
 
 ∃s1',s2'. measurable … s1' s2' … t'.
#p #S1 #S2 #rel #sim_rel #si #sn #t #s1 #s3 #Hmeas #s1' #Hclass #Rsi_si'
cases Hmeas -Hmeas #s0 * #s2 * #ti0 * #t12 * #t3n * #l1 * #l2 * #prf1 * #prf2 *******
#pre_t12 #EQ destruct #Hl1 #Hl2 #Hcall_fin #sil_ti0 #sil_t3n #Hcall_init
cases(silent_in_silent … sim_rel … Rsi_si' sil_ti0)
#s0' * #ti0' * #sil_ti0' #Rs0_s0'
cases(simulate_labelled_action … prf1 … Rs0_s0') /2/ 
     [2: % * #H1 #H2 lapply(head_of_premeasurable_is_not_io … pre_t12) >H2 * /2/ ]
#s0'' * #s1'' * #s1' * #t_s0'' * #t_s1'' **** #sil_ts0'' #sil_ts1'' #prf1' #Hcall_init'
#Rs1_s1'
cases(simulates_pre_mesurable … sim_rel … pre_t12 … Rs1_s1')
[2: % #H lapply(head_of_premeasurable_is_not_io … pre_t12) >(io_is_io … sim_rel … H) // * /2/ ]
#s2' * #t12' **** #pre_t12' #EQcost #Rs2_s2' #_ #_
cases(simulate_labelled_action … prf2 … Rs2_s2') /2/ 
  [2: % * #H1 #H2 lapply(tail_of_premeasurable_is_not_io … pre_t12) >H1 * /2/]
#s2'' * #s3'' * #s3' * #t_s2'' * #t_s3'' **** #sil_ts2'' #sil_ts3'' #prf2' #Hcall_fin' #Rs3_s3'
cases(silent_in_silent … sim_rel … Rs3_s3' sil_t3n) 
#sn' * #t_3n' * #sil_t3n' #Rsn_sn' %{sn'} 
%{(ti0'@ t_s0'' @ (t_ind … prf1' (t_s1''@t12' @ t_s2'' @ (t_ind … prf2' (t_s3'' @ t_3n')))))}
% [ % // >(get_cost_label_invariant_for_append_silent_trace_l … sil_ti0)
    >(get_cost_label_invariant_for_append_silent_trace_l … sil_ti0')
    >(get_cost_label_invariant_for_append_silent_trace_l … sil_ts0'')
    whd in ⊢ (??%%); @eq_f2 //
    >(get_cost_label_invariant_for_append_silent_trace_l … sil_ts1'')
    >get_cost_label_append >get_cost_label_append in ⊢ (???%); @eq_f2 //
    >(get_cost_label_invariant_for_append_silent_trace_l … sil_ts2'')
    whd in ⊢ (??%%); @eq_f2 //
    >(get_cost_label_invariant_for_append_silent_trace_l … sil_ts3'')
    >(get_cost_label_silent_is_empty … sil_t3n') >(get_cost_label_silent_is_empty … sil_t3n) % ]
%{s1''} %{s3''} whd %{s0''} %{s2''} %{(ti0' @t_s0'')} %{(t_s1'' @ t12' @ t_s2'')}
%{(t_s3'' @ t_3n')} %{l1} %{l2} %{prf1'} %{prf2'} % [2: /2/]
% [2: /2 by append_silent/] % [2: /2 by append_silent/] % [2: /2/] % // % // % //
@append_premeasurable_silent /2/
qed.