include "ASM/AssemblyProofSplit.ma".
include "common/LabelledObjects.ma".

lemma short_jump_cond_ok:
  ∀v1, v2: Word.
  ∀is_possible, offset.
    〈is_possible, offset〉 = short_jump_cond v1 v2 →
      is_possible → v2 = add 16 v1 (sign_extension offset).
  #v1 #v2 #is_possible #offset
  whd in match short_jump_cond; normalize nodelta
  @pair_elim #result #flags #sub16_refl
  @pair_elim #upper #lower #vsplit_refl
  inversion (get_index' bool ???) #get_index_refl normalize nodelta
  #relevant destruct(relevant) #relevant
  [1:
    @(sub_16_to_add_16_8_1 … flags)
  |2:
    @(sub_16_to_add_16_8_0 … flags)
  ]
  try assumption >sub16_refl
  <(eq_bv_eq … relevant)
  >(vsplit_ok … (sym_eq … vsplit_refl)) %
qed.

lemma absolute_jump_cond_ok:
  ∀v1, v2: Word.
  ∀is_possible, offset, v1_upper, v1_lower.
    〈is_possible, offset〉 = absolute_jump_cond v1 v2 →
      〈v1_upper, v1_lower〉 = vsplit ? 5 11 v1 →
        is_possible → v2 = v1_upper @@ offset.
  #v1 #v2 #is_possible #offset #v1_upper #v1_lower
  whd in match absolute_jump_cond; normalize nodelta
  @pair_elim #fst_5_addr #rest_addr #vsplit_v2_refl
  @pair_elim #fst_5_pc #rest_pc #vsplit_v1_refl
  #relevant destruct(relevant) normalize nodelta #relevant
  destruct(relevant) #relevant
  <(vsplit_ok … (sym_eq … vsplit_v2_refl))
  >(eq_bv_eq … relevant) %
qed. 

lemma ticks_of_instruction_AJMP:
 ∀address. ticks_of_instruction (AJMP (ADDR11 address)) = 2.
try % #addr @(vsplit_elim … 3 8 addr) #vl #vm #EQ >EQ
@(bitvector_3_elim_prop … vl) %
qed.

lemma ticks_of_instruction_ACALL:
 ∀address. ticks_of_instruction (ACALL (ADDR11 address)) = 2.
try % #addr @(vsplit_elim … 3 8 addr) #vl #vm #EQ >EQ
@(bitvector_3_elim_prop … vl) %
qed.

(*CSC: move elsewhere*)
lemma bv_append_eq_to_eq:
 ∀A,n. ∀v1,v2: Vector A n. ∀m. ∀v3,v4: Vector A m.
  v1@@v3 = v2@@v4 → v1=v2 ∧ v3=v4.
 #A #n #v1 elim v1
 [ #v2 >(Vector_O … v2) #m #v3 #v4 normalize * %%
 | #n' #hd1 #tl1 #IH #v2 cases (Vector_Sn … v2) #hd2 * #tl2 #EQ2 >EQ2
   #m #v3 #v4 #EQ normalize in EQ; destruct(EQ) cases (IH … e0) * * %% ]
qed.
   
theorem main_thm:
  ∀M, M': internal_pseudo_address_map.
  ∀program: pseudo_assembly_program.
  ∀program_in_bounds: |\snd program| ≤ 2^16.
  let 〈labels, costs〉 ≝ create_label_cost_map (\snd program) in
  let addr_of ≝ λid.λ_.bitvector_of_nat 16 (lookup_def ASMTag ℕ labels id O) in
  ∀is_well_labelled: is_well_labelled_p (\snd program).
  ∀sigma: Word → Word.
  ∀policy: Word → bool.
  ∀sigma_policy_specification_witness: sigma_policy_specification program sigma policy.
  ∀ps: PseudoStatus program.
  ∀program_counter_in_bounds: nat_of_bitvector 16 (program_counter … ps) < |\snd program|.
    next_internal_pseudo_address_map M program addr_of ps program_counter_in_bounds = Some … M' →
      ∃n. execute n … (status_of_pseudo_status M … ps sigma policy) =
        status_of_pseudo_status M' … 
          (execute_1_pseudo_instruction program (ticks_of program (λid. addr_of id ps) sigma policy) ps program_counter_in_bounds) sigma policy.
    #M #M' * #preamble #instr_list #program_in_bounds
    @pair_elim #labels #cost #create_label_cost_refl
    #is_well_labelled_witness #sigma #policy #sigma_policy_witness #ps
    letin ppc ≝ (program_counter pseudo_assembly_program ? ps) #ppc_in_bounds
    change with (next_internal_pseudo_address_map0 ?????? = ? → ?)
    generalize in match (fetch_assembly_pseudo2 〈preamble,instr_list〉 program_in_bounds sigma policy sigma_policy_witness ppc ppc_in_bounds) in ⊢ ?;
    >create_label_cost_refl normalize nodelta
    @pair_elim #assembled #costs' #assembly_refl normalize nodelta
    lapply (pair_destruct_1 ????? (sym_eq ??? assembly_refl)) #EQassembled
    @pair_elim #pi #newppc #fetch_pseudo_refl normalize nodelta
    @(pose … (λx. bitvector_of_nat ? (lookup_def … labels x 0))) #lookup_labels #EQlookup_labels
    @(pose … (λx. lookup_def … (construct_datalabels preamble) x (zero 16))) #lookup_datalabels #EQlookup_datalabels
    whd in match execute_1_pseudo_instruction; normalize nodelta
    whd in match ticks_of; normalize nodelta >fetch_pseudo_refl normalize nodelta
    lapply (snd_fetch_pseudo_instruction instr_list ppc ppc_in_bounds) >fetch_pseudo_refl #EQnewppc >EQnewppc
    lapply (snd_assembly_1_pseudoinstruction_ok 〈preamble,instr_list〉 … sigma policy sigma_policy_witness … ppc … pi … lookup_labels lookup_datalabels)
    [1: assumption |2: assumption] >create_label_cost_refl
    #X lapply (X EQlookup_labels EQlookup_datalabels ?) -X
    [1: >fetch_pseudo_refl %]
    #assm1 #assm2 #assm3 generalize in match assm2; generalize in match assm3;
    generalize in match assm1; -assm1 -assm2 -assm3
    normalize nodelta
    inversion pi
    [2,3:
      #arg #_
      (* XXX: we first work on sigma_increment_commutation *)
      #sigma_increment_commutation
      normalize in match (assembly_1_pseudoinstruction ??????) in sigma_increment_commutation;
      (* XXX: we work on the maps *)
      whd in ⊢ (??%? → ?); @Some_Some_elim #map_refl_assm <map_refl_assm
      (* XXX: we assume the fetch_many hypothesis *)
      #fetch_many_assm
      (* XXX: we give the existential *)
      %{0}
      whd in match execute_1_pseudo_instruction0; normalize nodelta
      change with (status_of_pseudo_status ????? = ?)
      whd in ⊢ (??%%); @split_eq_status try %
      [ >set_clock_set_program_counter ]
      >program_counter_set_program_counter >sigma_increment_commutation @add_zero
    |6: (* Mov *)
      #arg1 #arg2 #_
      (* XXX: we first work on sigma_increment_commutation *)
      #sigma_increment_commutation
      normalize in match (assembly_1_pseudoinstruction ??????) in sigma_increment_commutation;
      (* XXX: we work on the maps *)
      whd in ⊢ (??%? → ?); @Some_Some_elim #map_refl_assm <map_refl_assm
      (* XXX: we assume the fetch_many hypothesis *)
      #fetch_many_assm
      (* XXX: we give the existential *)
      %{1}
      whd in match (execute_1_pseudo_instruction0 ?????);
      (* XXX: work on the left hand side of the equality *)
      whd in ⊢ (??%?); whd in match (program_counter ???);
      (* XXX: execute fetches some more *)
      whd in match code_memory_of_pseudo_assembly_program; normalize nodelta
      whd in fetch_many_assm;
      >EQassembled in fetch_many_assm;
      cases (fetch ??) * #instr #newpc #ticks normalize nodelta *
      #eq_instr
      #fetch_many_assm whd in fetch_many_assm;
      lapply (eq_bv_eq … fetch_many_assm) -fetch_many_assm #EQnewpc
      destruct
      (* XXX: now we start to work on the mk_PreStatus equality *)
      (* XXX: lhs *)
      change with (set_arg_16 ????? = ?)
      @set_arg_16_status_of_pseudo_status
      [3: @(subaddressing_mode_elim … arg1) %
      |2: %
      | @sym_eq @set_clock_status_of_pseudo_status
        [ @sym_eq @set_program_counter_status_of_pseudo_status [<EQnewpc % | %]
        | % ]]
    |1: (* Instruction *)
      #instr #pi_refl
      change with (execute_1_preinstruction ???????) in match (execute_1_pseudo_instruction0 ?????);
      >EQassembled whd in match address_of_word_labels; normalize nodelta
        >create_label_cost_refl in ⊢ (? → ? → ? → %);
       @(main_lemma_preinstruction M M' preamble instr_list 〈preamble, instr_list〉 (refl …) ? sigma policy sigma_policy_witness
        ps ppc ? ? labels cost create_label_cost_refl newppc lookup_labels EQlookup_labels lookup_datalabels EQlookup_datalabels
        EQnewppc instr ? ? (refl …) ? (refl …)
        (set_program_counter pseudo_assembly_program 〈preamble, instr_list〉 ps (add 16 ppc (bitvector_of_nat 16 1)))
        (refl …) ? (refl …)) 
        try % try assumption >fetch_pseudo_refl assumption
    |4: (* Jmp *)
      #arg1 #pi_refl
      (* XXX: we first work on sigma_increment_commutation *)
      whd in match (assembly_1_pseudoinstruction ??????) in ⊢ (% → ?);
      whd in match (expand_pseudo_instruction ??????);
      whd in match (ticks_of0 ??????);
      inversion (short_jump_cond ??) #sj_possible #offset #sjc_refl normalize nodelta
      inversion (sj_possible ∧ ¬ policy ?) #sj_possible_refl normalize nodelta
      [2:
        inversion (absolute_jump_cond ??) #mj_possible #address #mjc_refl normalize nodelta
        inversion (mj_possible ∧ ¬ policy ?) #mj_possible_refl normalize nodelta
      ]
      #sigma_increment_commutation
      normalize in sigma_increment_commutation:(???(???(??%)));
      (* XXX: we work on the maps *)
      whd in ⊢ (??%? → ?); @Some_Some_elim #map_refl_assm <map_refl_assm
      (* XXX: we assume the fetch_many hypothesis *)
      * #fetch_refl #fetch_many_assm
      (* XXX: we give the existential *)
      %{1}
      (* XXX: work on the left hand side of the equality *)
      whd in ⊢ (??%?); whd in match (program_counter ???);
      (* XXX: execute fetches some more *)
      whd in match code_memory_of_pseudo_assembly_program; normalize nodelta
      whd in fetch_many_assm;
      >EQassembled in fetch_refl; #fetch_refl <fetch_refl
      lapply (eq_bv_eq … fetch_many_assm) -fetch_many_assm #EQnewpc
      change with (set_program_counter ???? =
       status_of_pseudo_status ?? (set_program_counter ????) ??)
       @set_program_counter_status_of_pseudo_status
       [2,4,6: @sym_eq @set_clock_status_of_pseudo_status try %
         [1,3,4: @sym_eq @set_program_counter_status_of_pseudo_status try %
                 @sigma_increment_commutation
         | @eq_f2 try % @ticks_of_instruction_AJMP ]]
       whd in ⊢ (??%%); normalize nodelta whd in match address_of_word_labels;
       normalize nodelta
       [ inversion (vsplit bool ???) #pc_bu #pc_bl #vsplit_refl normalize nodelta
         >EQlookup_labels in mjc_refl; >create_label_cost_refl #mjc_refl
         @(absolute_jump_cond_ok ????? pc_bl (sym_eq … mjc_refl))
         [2: >(andb_true_l … mj_possible_refl) %
         | <vsplit_refl @eq_f <EQnewpc % ]
       | >EQlookup_labels >create_label_cost_refl %
       |  inversion (half_add ???) #carry #new_pc #half_add_refl normalize nodelta
          >create_label_cost_refl
          >EQlookup_labels in sjc_refl; #sjc_refl
          >(pair_destruct_2 ????? (sym_eq … half_add_refl))
          >(short_jump_cond_ok ???? (sym_eq … sjc_refl))
          [2: >(andb_true_l … sj_possible_refl) %
          | >EQnewpc % ]]
    |5: (* Call *)
      #arg1 #pi_refl
      (* XXX: we first work on sigma_increment_commutation *)
      whd in match (assembly_1_pseudoinstruction ??????) in ⊢ (% → ?);
      whd in match (expand_pseudo_instruction ??????);
      whd in match (execute_1_pseudo_instruction0 ?????);
      whd in match (ticks_of0 ??????);
      inversion (absolute_jump_cond ??) #aj_possible #offset #ajc_refl normalize nodelta
      inversion (aj_possible ∧ ¬ policy ?) #aj_possible_refl normalize nodelta
      @pair_elim #carry #new_sp #carry_new_sp_refl lapply (refl_to_jmrefl ??? carry_new_sp_refl) -carry_new_sp_refl #carry_new_sp_refl
      @pair_elim #pc_bu #pc_bl #pc_bu_bl_refl lapply (refl_to_jmrefl ??? pc_bu_bl_refl) -pc_bu_bl_refl #pc_bu_bl_refl
      @pair_elim #carry' #new_sp' #carry_new_sp_refl' lapply (refl_to_jmrefl ??? carry_new_sp_refl') -carry_new_sp_refl' #carry_new_sp_refl'
      #sigma_increment_commutation
      normalize in sigma_increment_commutation:(???(???(??%)));
      (* XXX: we work on the maps *)
      whd in ⊢ (??%? → ?);
      @pair_elim #callM #accM #Mrefl
      @Some_Some_elim #map_refl_assm <map_refl_assm
      (* XXX: we assume the fetch_many hypothesis *)
      * #fetch_refl #fetch_many_assm
      (* XXX: we give the existential *)
      %{1}
      (* XXX: work on the left hand side of the equality *)
      whd in ⊢ (??%?); whd in match (program_counter ???);
      (* XXX: execute fetches some more *)
      whd in match code_memory_of_pseudo_assembly_program; normalize nodelta
      whd in fetch_many_assm;
      >EQassembled in fetch_refl; #fetch_refl <fetch_refl
      lapply (eq_bv_eq … fetch_many_assm) -fetch_many_assm #EQnewpc
      whd in ⊢ (??%?);
      [1:
        @(pair_replace ????? carry new_sp ??? carry_new_sp_refl)
        [ @eq_f2 try % @sym_eq
          @(pose … (set_clock ????)) #status #status_refl @sym_eq >status_refl
          /demod nohyps/
          (*CSC: mess with get_8051_sfr_set_program_counter + missing high level lemmas*)
          cut (∀A,B:Type[0]. ∀f,g:A → B. ∀a:A. f=g → f a = g a) [#A #B #f #f #a * %] #eq_fun
          >(eq_fun ???? ? (get_8051_sfr_set_program_counter (BitVectorTrie Byte 16) … SFR_SP …))
          >(eq_fun ???? ? (get_8051_sfr_set_program_counter pseudo_assembly_program … SFR_SP …))
          whd in match get_8051_sfr; normalize nodelta whd in match status_of_pseudo_status;
          normalize nodelta whd in match sfr_8051_of_pseudo_sfr_8051; normalize nodelta
          cases accM try % normalize nodelta #ul #addr cases (vsplit bool ???)
          normalize nodelta #v1 #v2 cases (eq_upper_lower ul upper) normalize nodelta
          >get_index_v_set_index_miss try % #abs normalize in abs; destruct(abs)
        ] whd in ⊢ (??%?);
        @pair_elim #pc_bu' #pc_bl' #pc_bu_bl_refl'
        @(pair_replace ????? ?? ??? carry_new_sp_refl')
        [ @eq_f2 try % @sym_eq
          @(pose … (write_at_stack_pointer ????)) #status #status_refl @sym_eq
          @(get_8051_sfr_status_of_pseudo_status … 〈callM,accM〉 … status) >status_refl -status_refl try %
          @sym_eq cases daemon (*CSC: write_at_stack_pointer_status_of_pseudo_status*)
        ]
        whd in ⊢ (??%?);
        @pair_elim #fiv #thr' #fiv_thr_refl'
        change with (set_program_counter ???? = ?)
        @set_program_counter_status_of_pseudo_status
        [2: @sym_eq cases daemon (*CSC: missing @write_at_stack_pointer_status_of_pseudo_status try %
          [1,3,4: @sym_eq @set_program_counter_status_of_pseudo_status try %
                  @sigma_increment_commutation
          | @eq_f2 try % @ticks_of_instruction_AJMP ]*)]
        whd in ajc_refl:(??%?); lapply ajc_refl -ajc_refl -map_refl_assm -Mrefl
        >EQlookup_labels normalize nodelta
        @vsplit_elim #fst_5_addr #rest_addr #fst_5_rest_refl
        >fst_5_rest_refl normalize nodelta
        @vsplit_elim #fst_5_pc #rest_pc #fst_5_rest_pc_refl normalize nodelta
        #pair_true_refl destruct(pair_true_refl)
        <EQnewpc in fst_5_rest_pc_refl;
        lapply pc_bu_bl_refl' -pc_bu_bl_refl'
        >program_counter_set_8051_sfr >set_clock_set_program_counter
        >program_counter_set_program_counter #relevant2
        <(vsplit_ok ?????? (sym_eq … relevant2))
        <(vsplit_ok ?????? (sym_eq … fiv_thr_refl'))
        >(vector_associative_append bool 5 3 8) #relevant3
        >(? : fiv = fst_5_addr)
        [1: <fst_5_rest_refl whd in match address_of_word_labels; normalize nodelta
            >create_label_cost_refl %
        |2: cases (bv_append_eq_to_eq … relevant3) #H #_ >H
            cases (conjunction_true … aj_possible_refl) #K #_ @sym_eq
            @eq_bv_eq assumption ]
      | @(pair_replace ????? carry new_sp ??? carry_new_sp_refl)
        [ @eq_f2 try %
          @sym_eq @(pose … (set_clock ????)) #status #status_refl @sym_eq
          @(get_8051_sfr_status_of_pseudo_status … 〈callM,accM〉 … status)
          >status_refl -status_refl try %
          @sym_eq @set_clock_status_of_pseudo_status try %
          @sym_eq @set_program_counter_status_of_pseudo_status try % assumption ]
        @pair_elim #pc_bu' #pc_bl' #pc_bu_bl_refl'
        @(pair_replace ????? carry' new_sp' ??? carry_new_sp_refl')
        [ @eq_f2 try % @sym_eq
          @(pose … (write_at_stack_pointer ????)) #status #status_refl @sym_eq
          @(get_8051_sfr_status_of_pseudo_status … 〈callM,accM〉 … status) >status_refl -status_refl try %
          @sym_eq cases daemon (*CSC: write_at_stack_pointer_status_of_pseudo_status*) ]
        change with (set_program_counter ???? = ?)
        @set_program_counter_status_of_pseudo_status
        [ >EQlookup_labels whd in match address_of_word_labels; normalize nodelta
          >create_label_cost_refl % ]
        cut(pc_bu' @@ pc_bl' = sigma (pc_bu @@ pc_bl))
        [1:
          >(vsplit_ok ?????? (sym_eq … pc_bu_bl_refl'))
          >(vsplit_ok ?????? (sym_eq … pc_bu_bl_refl))
          >add_commutative
          >program_counter_set_8051_sfr >set_clock_set_program_counter
          >program_counter_set_program_counter >add_commutative
          >program_counter_set_8051_sfr >set_clock_set_program_counter
          >program_counter_set_program_counter assumption ] #sigma_pc_bu_pc_bl_refl
        @sym_eq (*CSC: write_at_stack_pointer_status_of_pseudo_status*)
        cases daemon
      ]
    ]
qed.