include "basics/logic.ma".

include "common/AST.ma".
include "common/CostLabel.ma".
include "common/FrontEndOps.ma".
include "common/Registers.ma".

include "ASM/Vector.ma".
include "common/Graphs.ma".

inductive statement : Type[0] ≝
| St_skip : label → statement
| St_cost : costlabel → label → statement
| St_const : register → constant → label → statement
| St_op1 : unary_operation → register → register → label → statement (* destination source *)
| St_op2 : binary_operation → register → register → register → label → statement (* destination source1 source2 *)
| St_load : memory_chunk → register → register → label → statement
| St_store : memory_chunk → register → register → label → statement
| St_call_id : ident → list register → option register → label → statement
| St_call_ptr : register → list register → option register → label → statement
| St_tailcall_id : ident → list register → statement
| St_tailcall_ptr : register → list register → statement
| St_cond : register → label → label → statement
| St_jumptable : register → list label → statement
| St_return : statement
.

definition labels_P : (label → Prop) → statement → Prop ≝
λP,s. match s with
[ St_skip l ⇒ P l
| St_cost _ l ⇒ P l
| St_const _ _ l ⇒ P l
| St_op1 _ _ _ l ⇒ P l
| St_op2 _ _ _ _ l ⇒ P l
| St_load _ _ _ l ⇒ P l
| St_store _ _ _ l ⇒ P l
| St_call_id _ _ _ l ⇒ P l
| St_call_ptr _ _ _ l ⇒ P l
| St_tailcall_id _ _ ⇒ True
| St_tailcall_ptr _ _ ⇒ True
| St_cond _ l1 l2 ⇒ P l1 ∧ P l2
| St_jumptable _ ls ⇒ All ? P ls
| St_return ⇒ True
].

lemma labels_P_mp : ∀P,Q. (∀l. P l → Q l) → ∀s.labels_P P s → labels_P Q s.
#P #Q #H * /3/
#r #l #l' * /3/
qed.

definition labels_present : graph statement → statement → Prop ≝
λg,s. labels_P (present ?? g) s.

definition graph_closed : graph statement → Prop ≝
λg. ∀l,s. lookup ?? g l = Some ? s → labels_present g s.

record internal_function : Type[0] ≝
{ f_labgen    : universe LabelTag
; f_reggen    : universe RegisterTag
; f_result    : option (register × typ)
; f_params    : list (register × typ)
; f_locals    : list (register × typ)
; f_stacksize : nat
; f_graph     : graph statement
; f_closed    : graph_closed f_graph
; f_entry     : Σl:label. present ?? f_graph l
; f_exit      : Σl:label. present ?? f_graph l
}.

(* Note that the global variables will be initialised by the code in main
   by this stage, so the only initialisation data is the amount of space to
   allocate. *)

definition RTLabs_program ≝ program (λ_.fundef internal_function) nat.