source: src/utilities/monad.ma

Last change on this file was 2529, checked in by tranquil, 7 years ago

rewritten function handling in joint
swapped call_rel with ret_rel in the definition of status_rel, and parameterised status_simulation on status_rel
renamed SemanticUtils?

File size: 12.1 KB
Line 
1include "basics/types.ma".
2include "basics/relations.ma".
3include "utilities/setoids.ma".
4
5definition pred_transformer ≝ λA,B : Type[0].(A → Prop) → B → Prop.
6
7definition modus_ponens ≝ λA,B.λPT : pred_transformer A B.
8  ∀P,Q.(∀x.P x → Q x) → ∀y.PT P y → PT Q y.
9 
10lemma mp_transitive :
11  ∀A,B,C,PT1,PT2.modus_ponens A B PT1 → modus_ponens B C PT2 →
12    modus_ponens A C (PT2 ∘ PT1). /4/ qed.
13
14definition rel_transformer ≝ λA,B,C,D : Type[0].
15  (A → B → Prop) → C → D → Prop.
16 
17definition rel_modus_ponens ≝ λA,B,C,D.λRT : rel_transformer A B C D.
18  ∀P,Q.(∀x,y.P x y → Q x y) → ∀z,w.RT P z w → RT Q z w.
19 
20lemma rel_mp_transitive :
21  ∀A,B,C,D,E,F,RT1,RT2.rel_modus_ponens A B C D RT1 → rel_modus_ponens C D E F RT2 →
22    rel_modus_ponens … (RT2 ∘ RT1). /4/ qed.
23 
24record Monad : Type[1] ≝ {
25  monad :1> Type[0] → Type[0] ;
26  m_return : ∀X. X → monad X ;
27  m_bind : ∀X,Y. monad X → (X → monad Y) → monad Y
28}.
29
30(* notation "m »= f" with precedence 49
31  for @{'m_bind $m $f }. *)
32
33notation > "!_ e; e'"
34  with precedence 48 for @{'m_bind ${e} (λ_. ${e'})}.
35notation > "! ident v ← e; e'"
36  with precedence 48 for @{'m_bind ${e} (λ${ident v}. ${e'})}.
37notation > "! ident v : ty ← e; e'"
38  with precedence 48 for @{'m_bind ${e} (λ${ident v} : ${ty}. ${e'})}.
39notation > "! ident v ← e : ty ; e'"
40  with precedence 48 for @{'m_bind (${e} : ${ty}) (λ${ident v}.${e'})}.
41notation < "vbox(! \nbsp hvbox( ident v : ty \nbsp break ← \nbsp e ;) break e')"
42  with precedence 48 for @{'m_bind ${e} (λ${ident v} : ${ty}. ${e'})}.
43notation > "! ident v : ty ← e : ty' ; e'"
44  with precedence 48 for @{'m_bind (${e} : ${ty'}) (λ${ident v} : ${ty}. ${e'})}.
45notation > "! 〈ident v1, ident v2〉 ← e ; e'"
46  with precedence 48 for @{'m_bind2 ${e} (λ${ident v1}. λ${ident v2}. ${e'})}.
47notation > "! 〈ident v1, ident v2〉 ← e : ty ; e'"
48  with precedence 48 for @{'m_bind2 (${e} : $ty) (λ${ident v1}. λ${ident v2}. ${e'})}.
49notation > "! 〈ident v1 : ty1, ident v2 : ty2〉 ← e ; e'"
50  with precedence 48 for @{'m_bind2 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. ${e'})}.
51notation < "vbox(! \nbsp hvbox( 〈ident v1 : ty1, break ident v2 : ty2〉 \nbsp break ← \nbsp e ; ) break e')"
52  with precedence 48 for @{'m_bind2 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. ${e'})}.
53notation > "! 〈ident v1, ident v2, ident v3〉 ← e ; e'"
54  with precedence 48 for @{'m_bind3 ${e} (λ${ident v1}. λ${ident v2}. λ${ident v3}. ${e'})}.
55notation > "! 〈ident v1, ident v2, ident v3〉 ← e : ty ; e'"
56  with precedence 48 for @{'m_bind3 (${e} : ${ty}) (λ${ident v1}. λ${ident v2}. λ${ident v3}. ${e'})}.
57notation > "! 〈ident v1 : ty1, ident v2 : ty2, ident v3 : ty3〉 ← e ; e'"
58  with precedence 48 for @{'m_bind3 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. λ${ident v3} : ${ty3}. ${e'})}.
59notation < "vbox(! \nbsp hvbox( 〈ident v1 : ty1, break ident v2 : ty2, break ident v3 : ty3〉 \nbsp break ← e \nbsp ; ) break e')"
60  with precedence 48 for @{'m_bind3 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. λ${ident v3} : ${ty3}. ${e'})}.
61
62(* dependent pair versions *)
63notation > "! «ident v1, ident v2» ← e ; e'"
64  with precedence 48 for
65  @{'m_bind ${e} (λ${fresh p_sig}.
66    match ${fresh p_sig} with [mk_Sig ${ident v1} ${ident v2} ⇒ ${e'}])}.
67notation < "vbox(! \nbsp hvbox( «ident v1, break ident v2» \nbsp break ← \nbsp e ; ) break e')"
68  with precedence 48 for
69  @{'m_bind ${e} (λ${fresh p_sig}.
70    match ${fresh p_sig} with [mk_Sig ${ident v1} ${ident v2} ⇒ ${e'}])}.
71   
72notation > "! «ident v1, ident v2, ident H» ← e ; e'"
73  with precedence 48 for
74  @{'m_sigbind2 ${e} (λ${ident v1},${ident v2},${ident H}. ${e'})}.
75notation < "vbox(! \nbsp hvbox( «ident v1, break ident v2, break ident H» \nbsp break ← \nbsp e ; ) e')"
76  with precedence 48 for
77  @{'m_sigbind2 ${e} (λ${ident v1} : ${ty1}.λ${ident v2} : ${ty2}.
78    λ${ident H} : ${ty3}. ${e'})}.
79   
80 
81(*alternative do notation for backward compatibility *)
82notation > "'do'_ e; e'"
83  with precedence 48 for @{'m_bind ${e} (λ_. ${e'})}.
84notation > "'do' ident v ← e; e'"
85  with precedence 48 for @{'m_bind ${e} (λ${ident v}. ${e'})}.
86notation > "'do' ident v : ty ← e; e'"
87  with precedence 48 for @{'m_bind ${e} (λ${ident v} : ${ty}. ${e'})}.
88notation > "'do' ident v ← e : ty ; e'"
89  with precedence 48 for @{'m_bind (${e} : ${ty}) (λ${ident v}.${e'})}.
90notation > "'do' ident v : ty ← e : ty' ; e'"
91  with precedence 48 for @{'m_bind (${e} : ${ty'}) (λ${ident v} : ${ty}. ${e'})}.
92notation > "'do' 〈ident v1, ident v2〉 ← e ; e'"
93  with precedence 48 for @{'m_bind2 ${e} (λ${ident v1}. λ${ident v2}. ${e'})}.
94notation > "'do' 〈ident v1 : ty1, ident v2 : ty2〉 ← e ; e'"
95  with precedence 48 for @{'m_bind2 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. ${e'})}.
96notation > "'do' 〈ident v1, ident v2, ident v3〉 ← e ; e'"
97  with precedence 48 for @{'m_bind3 ${e} (λ${ident v1}. λ${ident v2}. λ${ident v3}. ${e'})}.
98notation > "'do' 〈ident v1 : ty1, ident v2 : ty2, ident v3 : ty3〉 ← e ; e'"
99  with precedence 48 for @{'m_bind3 ${e} (λ${ident v1} : ${ty1}. λ${ident v2} : ${ty2}. λ${ident v3} : ${ty3}. ${e'})}.
100
101(* dependent pair versions *)
102notation > "'do' «ident v1, ident v2» ← e ; e'"
103  with precedence 48 for
104  @{'m_bind ${e} (λ${fresh p_sig}.
105    match ${fresh p_sig} with [mk_Sig ${ident v1} ${ident v2} ⇒ ${e'}])}.
106
107notation > "'do' «ident v1, ident v2, ident H» ← e ; e'"
108  with precedence 48 for
109  @{'m_sigbind2 ${e} (λ${ident v1},${ident v2},${ident H}. ${e'})}.
110
111notation > "'do' ❬ident v1, ident v2❭ ← e ; e'"
112  with precedence 48 for
113  @{'m_bind ${e} (λ${fresh p_sig}.
114    match ${fresh p_sig} with [mk_DPair ${ident v1} ${ident v2} ⇒ ${e'}])}.
115
116notation > "'return' t" with precedence 49 for @{'m_return $t}.
117notation < "'return' \nbsp t" with precedence 49 for @{'m_return $t}.
118
119interpretation "monad bind" 'm_bind m f = (m_bind ? ? ? m f).
120interpretation "monad return" 'm_return x = (m_return ? ? x).
121
122
123record MonadProps : Type[1] ≝
124  { max_def :> Monad
125  ; m_return_bind : ∀X,Y.∀x : X.∀f : X → max_def Y. ! y ← return x ; f y = f x
126  ; m_bind_return : ∀X.∀m : max_def X.! x ← m ; return x = m
127  ; m_bind_bind : ∀X,Y,Z. ∀m : max_def X.∀f : X → max_def Y.
128      ∀g : Y → max_def Z.! y ← (! x ← m ; f x) ; g y = ! x ← m; ! y ← f x ; g y
129  ; m_bind_ext_eq : ∀X,Y.∀m : max_def X.∀f,g : X → max_def Y.
130      (∀x.f x = g x) → ! x ← m ; f x = ! x ← m ; g x
131  }.
132
133record SetoidMonadProps : Type[1] ≝
134  { smax_def :> Monad
135  ; sm_eq : ∀X.relation (smax_def X)
136  ; sm_eq_refl : ∀X.reflexive ? (sm_eq X)
137  ; sm_eq_trans : ∀X.transitive ? (sm_eq X)
138  ; sm_eq_sym : ∀X.symmetric ? (sm_eq X)
139  ; sm_return_proper : ∀X,x.sm_eq X (return x) (return x)
140  ; sm_bind_proper : ∀X,Y,x,y,f,g.sm_eq X x y → (∀x.sm_eq Y (f x) (g x)) → sm_eq Y (m_bind … x f) (m_bind … y g)
141  ; sm_return_bind : ∀X,Y.∀x : X.∀f : X → smax_def Y.
142      sm_eq Y (! y ← return x ; f y) (f x)
143  ; sm_bind_return : ∀X.∀m : smax_def X.sm_eq X (! x ← m ; return x) m
144  ; sm_bind_bind : ∀X,Y,Z. ∀m : smax_def X.∀f : X → smax_def Y.
145      ∀g : Y → smax_def Z.sm_eq Z (! y ← (! x ← m ; f x) ; g y) (! x ← m; ! y ← f x ; g y)
146  }.
147
148definition setoid_of_monad : ∀M : SetoidMonadProps.∀X : Type[0].
149  Setoid ≝
150  λM,X.mk_Setoid (M X) (sm_eq M X) (sm_eq_refl M X) (sm_eq_trans M X) (sm_eq_sym M X).
151
152include "hints_declaration.ma".
153alias symbol "hint_decl" (instance 1) = "hint_decl_Type1".
154unification hint 0 ≔ M, X;
155M' ≟ smax_def M, S ≟ setoid_of_monad M X
156(*-----------------------------*)⊢
157monad M' X ≡ std_supp S.
158
159include "basics/lists/list.ma".
160
161definition m_map ≝ λM : Monad.λX,Y.λf : X → Y.λm : M X.
162  ! x ← m ; return f x.
163
164definition m_map2 ≝ λM : Monad.λX,Y,Z.λf : X → Y → Z.λm : M X.λn : M Y.
165  ! x ← m ; ! y ← n ; return f x y.
166 
167definition m_bind2 ≝ λM : Monad.λX,Y,Z.λm : M (X × Y).λf : X → Y → M Z.
168  ! p ← m ; f (\fst p) (\snd p).
169
170interpretation "monad bind2" 'm_bind2 m f = (m_bind2 ? ? ? ? m f).
171
172definition m_bind3 :
173  ∀M : Monad.∀X,Y,Z,W.M (X×Y×Z) → (X → Y → Z → M W) → M W ≝
174  λM,X,Y,Z,W,m,f.
175  ! p ← m ; f (\fst (\fst p)) (\snd (\fst p)) (\snd p).
176
177interpretation "monad bind3" 'm_bind3 m f = (m_bind3 ? ? ? ? ? m f).
178
179definition m_join : ∀M : Monad.∀X.M (M X) → M X ≝
180  λM,X,m.! x ← m ; x.
181
182definition m_sigbind2 :
183  ∀M : Monad.∀A,B,C.∀P:A×B → Prop. M (Σx:A×B.P x) →
184      (∀a,b. P 〈a,b〉 → M C) → M C ≝
185λM,A,B,C,P,e,f.
186    ! e_sig ← e ;
187    match e_sig with
188    [ mk_Sig p p_prf ⇒
189      match p return λx.x = p → ? with
190      [ mk_Prod a b ⇒
191      λeq_p.  f a b (eq_ind_r ?? (λx.λ_.P x) p_prf ? eq_p)
192      ](refl …)
193    ].
194
195interpretation "monad sigbind2" 'm_sigbind2 m f = (m_sigbind2 ????? m f).
196
197definition m_list_map :
198  ∀M : Monad.∀X,Y.(X → M Y) → list X → M (list Y) ≝
199  λM,X,Y,f,l.foldr … (λel,macc.! r ← f el; !acc ← macc; return (r :: acc)) (return [ ]) l.
200
201definition m_list_map_sigma :
202  ∀M : Monad.∀X,Y,P.(X → M (Σy : Y.P y)) → list X → M (Σl : list Y.All ? P l) ≝
203  λM,X,Y,P,f,l.foldr … (λel,macc.
204    ! «r, r_prf» ← f el ;
205    ! «acc, acc_prf» ← macc ;
206    return (mk_Sig ?? (r :: acc) ?))
207    (return (mk_Sig … [ ] ?)) l. % assumption qed.
208
209definition m_bin_op :
210  ∀M : Monad.∀X,Y,Z.(X → Y → Z) → M X → M Y → M Z ≝
211  λM,X,Y,Z,op,m,n. ! x ← m ; ! y ← n ; return op x y.
212
213let rec m_fold (M : Monad)
214  X Y (f : X → Y → M Y) (l : list X) (init : Y) on l : M Y ≝
215match l with
216[ nil ⇒ return init
217| cons hd tl ⇒
218  ! y ← f hd init ;
219  m_fold M X Y f tl y
220].
221
222lemma m_fold_append : ∀M : MonadProps.∀X,Y,f,l1,l2,init.
223  m_fold M X Y f (l1@l2) init =
224  ! y ← m_fold … f l1 init ;
225  m_fold … f l2 y.
226#M #X #Y #f #l1 elim l1 -l1
227[ #l2 #init >m_return_bind %
228| #hd #tl #IH #l2 #init >m_bind_bind @m_bind_ext_eq #y @IH
229]
230qed.
231
232unification hint 0 ≔ M, X, Y, Z, m, f ;
233  P ≟ Prod X Y, F ≟ λp.f (\fst p) (\snd p) ⊢
234m_bind M P Z m F ≡ m_bind2 M X Y Z m f.
235
236unification hint 0 ≔ M, X, Y, Z, W, m, f ;
237  P' ≟ Prod X Y, P ≟ Prod P' Z, F ≟ λp.f (\fst (\fst p)) (\snd (\fst p)) (\snd p) ⊢
238m_bind M P W m F ≡ m_bind3 M X Y Z W m f.
239
240definition MakeMonadProps : ?→?→?→?→?→?→?→MonadProps ≝ λmonad,m_return,m_bind.
241mk_MonadProps (mk_Monad monad m_return m_bind).
242
243definition MakeSetoidMonadProps : ?→?→?→?→?→?→?→?→?→?→?→?→SetoidMonadProps ≝
244  λmonad,m_return,m_bind.
245  mk_SetoidMonadProps (mk_Monad monad m_return m_bind).
246 
247include "basics/russell.ma".
248 
249record MonadPred (M : Monad) : Type[1] ≝
250  { m_pred :2> ∀X.(X → Prop) → (M X → Prop)
251  ; mp_return : ∀X,P,x.P x → m_pred X P (return x)
252  ; mp_bind : ∀X,Y,Pin,Pout,m.m_pred X Pin m →
253      ∀f.(∀x.Pin x → m_pred Y Pout (f x)) →
254                  m_pred ? Pout (m_bind … m f)
255  ; m_pred_mp : ∀X.modus_ponens ?? (m_pred X)
256  }.
257
258record InjMonadPred (M : Monad) : Type[1] ≝
259  { im_pred :> MonadPred M
260  ; mp_inject : ∀X.∀P : X → Prop.(Σm.im_pred P m) → M (Σx.P x)
261  ; mp_inject_eq : ∀X,P,m.pi1 ?? m = ! x ← mp_inject X P m ; return pi1 … x
262  }.
263
264coercion coerc_mp_inject : ∀M.∀MP:InjMonadPred M.
265  ∀X.∀P : X → Prop.∀m : Σm.MP P m.M (Σx.P x) ≝
266  mp_inject on _m : Sig (monad ??) (λm.im_pred ??? m) to monad ? (Sig ? (λx.? x)).
267
268lemma mp_inject_bind : ∀M : MonadProps.∀MP,X,P,Y.∀m.∀f : X → M Y.
269  ! x ← mp_inject M MP X P m ; f (pi1 … x) = ! x ← pi1 … m ; f x.
270#M#MP#X#P#Y#m#f >mp_inject_eq >m_bind_bind @m_bind_ext_eq #x >m_return_bind % qed.
271
272record MonadRel (M1 : Monad) (M2 : Monad) : Type[1] ≝
273  { m_rel :3> ∀X,Y.(X → Y → Prop) → (M1 X → M2 Y → Prop)
274  ; mr_return : ∀X,Y,rel,x,y.rel x y → m_rel X Y rel (return x) (return y)
275  ; mr_bind : ∀X,Y,Z,W,relin,relout,m,n.m_rel X Y relin m n → ∀f,g.(∀x,y.relin x y → m_rel Z W relout (f x) (g y)) →
276                  m_rel ?? relout (m_bind … m f) (m_bind … n g)
277  ; m_rel_mp : ∀X,Y.rel_modus_ponens ???? (m_rel X Y)
278  }.
Note: See TracBrowser for help on using the repository browser.