source: src/utilities/extralib.ma @ 1948

(**************************************************************************)
(*       ___                                                              *)
(*      ||M||                                                             *)
(*      ||A||       A project by Andrea Asperti                           *)
(*      ||T||                                                             *)
(*      ||I||       Developers:                                           *)
(*      ||T||         The HELM team.                                      *)
(*      ||A||         http://helm.cs.unibo.it                             *)
(*      \   /                                                             *)
(*       \ /        This file is distributed under the terms of the       *)
(*        v         GNU General Public License Version 2                  *)
(*                                                                        *)
(**************************************************************************)

include "basics/types.ma".
include "basics/lists/list.ma".
include "basics/logic.ma".
include "ASM/Util.ma".

lemma eq_rect_Type0_r:
 ∀A.∀a.∀P: ∀x:A. eq ? x a → Type[0]. P a (refl A a) → ∀x.∀p:eq ? x a.P x p.
 #A #a #P #p #x0 #p0 @(eq_rect_r ??? p0) assumption.
qed.

lemma eq_rect_r2:
 ∀A.∀a,x.∀p:eq ? x a.∀P: ∀x:A. eq ? x a → Type[2]. P a (refl A a) → P x p.
 #A #a #x #p cases p; #P #H assumption.
qed.

lemma eq_rect_Type2_r:
 ∀A.∀a.∀P: ∀x:A. eq ? x a → Type[2]. P a (refl A a) → ∀x.∀p:eq ? x a.P x p.
 #A #a #P #p #x0 #p0 @(eq_rect_r2 ??? p0) assumption.
qed.

lemma eq_rect_CProp0_r:
 ∀A.∀a.∀P: ∀x:A. eq ? x a → CProp[0]. P a (refl A a) → ∀x.∀p:eq ? x a.P x p.
 #A #a #P #p #x0 #p0 @(eq_rect_r2 ??? p0) assumption.
qed.

lemma sym_neq : ∀A.∀x,y:A. x ≠ y → y ≠ x.
#A #x #y *;#H @nmk #H' /2/;
qed.

interpretation "logical iff" 'iff x y = (iff x y).

(* bool *)

definition xorb : bool → bool → bool ≝
  λx,y. match x with [ false ⇒ y | true ⇒ notb y ].
  
  
  

(* should be proved in nat.ma, but it's not! *)
(* Paolo: there is eqb_elim which does something very similar *)
lemma eqb_to_Prop : ∀n,m:nat.match eqb n m with [ true ⇒ n = m | false ⇒ n ≠ m ].
#n elim n;
[ #m cases m; //;
| #n' #IH #m cases m; [ /2/; | #m' whd in match (eqb (S n') (S m')) in ⊢ %;
  lapply (IH m'); cases (eqb n' m'); /2/; ]
] qed.

(* datatypes/list.ma *)

theorem nil_append_nil_both:
  ∀A:Type[0]. ∀l1,l2:list A.
    l1 @ l2 = [] → l1 = [] ∧ l2 = [].
#A #l1 #l2 cases l1
[ cases l2
  [ /2/
  | normalize #h #t #H destruct
  ]
| cases l2
  [ normalize #h #t #H destruct
  | normalize #h1 #t1 #h2 #h3 #H destruct
  ]
] qed. 

(* some useful stuff for quantifiers *)

lemma dec_bounded_forall:
  ∀P:ℕ → Prop.(∀n.(P n) + (¬P n)) → ∀k.(∀n.n < k → P n) + ¬(∀n.n < k → P n).
 #P #HP_dec #k elim k -k
 [ %1 #n #Hn @⊥ @(absurd (n < 0) Hn) @not_le_Sn_O
 | #k #Hind cases Hind
   [ #Hk cases (HP_dec k)
     [ #HPk %1 #n #Hn cases (le_to_or_lt_eq … Hn)
       [ #H @(Hk … (le_S_S_to_le … H))
       | #H >(injective_S … H) @HPk
       ]
     | #HPk %2 @nmk #Habs @(absurd (P k)) [ @(Habs … (le_n (S k))) | @HPk ]
     ]
   | #Hk %2 @nmk #Habs @(absurd (∀n.n<k→P n)) [ #n' #Hn' @(Habs … (le_S … Hn')) | @Hk ]
   ]
 ]
qed.

lemma dec_bounded_exists:
  ∀P:ℕ→Prop.(∀n.(P n) + (¬P n)) → ∀k.(∃n.n < k ∧ P n) + ¬(∃n.n < k ∧ P n).
 #P #HP_dec #k elim k -k
 [ %2 @nmk #Habs elim Habs #n #Hn @(absurd (n < 0) (proj1 … Hn)) @not_le_Sn_O
 | #k #Hind cases Hind
   [ #Hk %1 elim Hk #n #Hn @(ex_intro … n) @conj [ @le_S @(proj1 … Hn) | @(proj2 … Hn) ]
   | #Hk cases (HP_dec k)
     [ #HPk %1 @(ex_intro … k) @conj [ @le_n | @HPk ]
     | #HPk %2 @nmk #Habs elim Habs #n #Hn cases (le_to_or_lt_eq … (proj1 … Hn))
       [ #H @(absurd (∃n.n < k ∧ P n)) [ @(ex_intro … n) @conj
         [ @(le_S_S_to_le … H) | @(proj2 … Hn) ] | @Hk ]
       | #H @(absurd (P k)) [ <(injective_S … H) @(proj2 … Hn) | @HPk ]
       ]  
     ]
   ]
 ]
qed.

(* Replace decision functions by result. *)

lemma dec_true: ∀P:Prop.∀f:P + ¬P.∀p:P.∀Q:(P + ¬P) → Type[0]. (∀p'.Q (inl ?? p')) → Q f.
#P #f #p #Q #H cases f;
[ @H 
| #np cut False [ @(absurd ? p np) | * ]
] qed.

lemma dec_false: ∀P:Prop.∀f:P + ¬P.∀p:¬P.∀Q:(P + ¬P) → Type[0]. (∀p'.Q (inr ?? p')) → Q f.
#P #f #p #Q #H cases f;
[ #np cut False [ @(absurd ? np p) | * ]
| @H
] qed.


lemma not_exists_forall:
  ∀k:ℕ.∀P:ℕ → Prop.¬(∃x.x < k ∧ P x) → ∀x.x < k → ¬P x.
 #k #P #Hex #x #Hx @nmk #Habs @(absurd ? ? Hex) @(ex_intro … x)
 @conj [ @Hx | @Habs ]
qed.

lemma not_forall_exists:
  ∀k:ℕ.∀P:ℕ → Prop.(∀n.(P n) + (¬P n)) → ¬(∀x.x < k → P x) → ∃x.x < k ∧ ¬P x.
 #k #P #Hdec elim k
 [ #Hfa @⊥ @(absurd ?? Hfa) #z #Hz @⊥ @(absurd ? Hz) @not_le_Sn_O
 | -k #k #Hind #Hfa cases (Hdec k)
   [ #HP elim (Hind ?)
     [ -Hind; #x #Hx @(ex_intro ?? x) @conj [ @le_S @(proj1 ?? Hx) | @(proj2 ?? Hx) ]
     | @nmk #H @(absurd ?? Hfa) #x #Hx cases (le_to_or_lt_eq ?? Hx)
       [ #H2 @H @(le_S_S_to_le … H2)
       | #H2 >(injective_S … H2) @HP
       ]
     ]
   | #HP @(ex_intro … k) @conj [ @le_n | @HP ]
   ]
 ]
qed.

lemma associative_orb : associative ? orb.
*** // qed.

lemma commutative_orb : commutative ? orb.
** // qed.

lemma associative_andb : associative ? andb.
*** // qed.

lemma commutative_andb : commutative ? andb.
** // qed.


lemma notb_false : ∀b.(¬b) = false → b = true.
* [#_ % | normalize #EQ destruct]
qed.

lemma notb_true : ∀b.(¬b) = true → b = false.
* [normalize #EQ destruct | #_ %]
qed.



notation > "Σ 〈 ident x : tyx, ident y : tyy 〉 . P" with precedence 20 for
  @{'sigma (λ${fresh p}.
    match ${fresh p} with [mk_Prod (${ident x} : $tyx) (${ident y} : $tyy) ⇒ $P])}.
notation > "Σ 〈 ident x, ident y 〉 . P" with precedence 20 for
  @{'sigma (λ${fresh p}.
    match ${fresh p} with [mk_Prod ${ident x} ${ident y} ⇒ $P])}.
notation > "Σ 〈 ident x : tyx, ident y : tyy, ident z : tyz 〉 . P" with precedence 20 for
  @{'sigma (λ${fresh p1}.
    match ${fresh p1} with [mk_Prod ${fresh p2} (${ident z} : $tyz) ⇒
      match ${fresh p2} with [mk_Prod (${ident x} : $tyx) (${ident y} : $tyy) ⇒ $P]])}.
notation > "Σ 〈 ident x , ident y , ident z 〉 . P" with precedence 20 for
  @{'sigma (λ${fresh p1}.
    match ${fresh p1} with [mk_Prod ${fresh p2} ${ident z} ⇒
      match ${fresh p2} with [mk_Prod ${ident x} ${ident y} ⇒ $P]])}.