source: src/joint/semantics_blocks.ma @ 2557

include "joint/blocks.ma".
include "joint/Traces.ma".
include "joint/semanticsUtils.ma".

(* let rec seq_list_labels p g (b : list (joint_step p g)) on b : list label ≝
  match b with
  [ nil ⇒ [ ]
  | cons hd tl ⇒ step_labels … hd @ seq_list_labels … tl
  ].*)

definition repeat_eval_seq_no_pc ≝
  λp : evaluation_params.λcurr_id,curr_fn.
  m_fold … (eval_seq_no_pc … (ev_genv … p) curr_id curr_fn).

definition list_not_empty ≝ λA.λl : list A.match l with [ nil ⇒ false | _ ⇒ true ].

let rec produce_trace_any_any
  (p : evaluation_params)
  (st : state_pc p)
  curr_id curr_fn
  (b : list (joint_seq p (globals p))) on b :
  ∀l : list (code_point p).
  ∀dst : code_point p.
  ∀st' : state p.
  fetch_internal_function … (ev_genv p) (pc_block (pc … st)) =
    return 〈curr_id, curr_fn〉 →
  let src ≝ point_of_pc p (pc … st) in
  if list_not_empty ? b then
    ! x ← stmt_at ?? (joint_if_code … curr_fn) dst ; cost_label_of_stmt … x = None ?
  else
    True →
  src ~❨b, l❩~> dst in joint_if_code … curr_fn →
  All ? (λx.And (no_call … x) (no_cost_label … x)) b →
  repeat_eval_seq_no_pc p curr_id curr_fn b st = return st' →
  trace_any_any (joint_abstract_status p) st
    (mk_state_pc ? st' (pc_of_point p (pc_block (pc … st)) dst)) ≝  match b
  return λb.∀l,dst.?→?→?→?→?→?→?
  with
  [ nil ⇒
    λl,dst,st',fd_prf,dst_prf,in_code,all_other,EQ1.
    (taa_base (joint_abstract_status p) st)
    ⌈trace_any_any ??? ↦ ?⌉
  | cons hd tl ⇒
    λl.
    match l return λx.∀dst,st'.?→?→?→?→?→? with
    [ nil ⇒ λdst,st',fd_prf,dst_prf,in_code.⊥
    | cons mid rest ⇒
      λdst,st',fd_prf,dst_prf,in_code,all_other,EQ1.
      let mid_pc ≝ pc_of_point p (pc_block (pc … st)) mid in
      match eval_seq_no_pc … (ev_genv p) curr_id curr_fn hd st
      return λx.eval_seq_no_pc … (ev_genv p) curr_id curr_fn hd st = x →
      trace_any_any (joint_abstract_status p) st
        (mk_state_pc ? st' (pc_of_point p (pc_block (pc … st)) dst)) with
      [ Value st_mid ⇒ λEQ2.
        let tr_tl ≝ produce_trace_any_any ?
            (mk_state_pc ? st_mid mid_pc)
            curr_id curr_fn tl rest dst ?????? in
        taa_step … tr_tl
      | _ ⇒ λEQ2.⊥
      ] (refl …)
    ]
  ].
[ whd in EQ1 : (??%%);
  cases l in in_code; whd in ⊢ (%→?); [2: #hd #tl * ] #EQ destruct
  >pc_of_point_of_pc cases st //
| @in_code
|3,12: whd in EQ1 : (??%%); >EQ2 in EQ1; whd in ⊢ (??%?→?); #EQ1 destruct(EQ1)
]
change with (! y ← ? ; repeat_eval_seq_no_pc ????? = ?) in EQ1;
>EQ2 in EQ1; >m_return_bind
cases in_code -in_code * #nxt * #EQ_stmt_at #EQ_mid #rest_in_code
cases all_other -all_other * #hd_no_call #hd_no_cost #tl_other
#EQ1
try assumption
[ whd whd in match eval_state; normalize nodelta
  >(fetch_statement_eq … fd_prf EQ_stmt_at)
  >m_return_bind
  whd in match eval_statement_no_pc; normalize nodelta
  >EQ2 >m_return_bind
  whd in match eval_statement_advance; normalize nodelta
  >(no_call_advance … hd_no_call)
  whd in match next; normalize nodelta 
  whd in match succ_pc; normalize nodelta
  >EQ_mid %
| whd whd in ⊢ (??%?);
  >(fetch_statement_eq … fd_prf EQ_stmt_at) normalize nodelta
  @(no_call_other … hd_no_call)
| whd in ⊢ (?%);
  whd in match as_label; normalize nodelta
  %* #H @H -H whd in ⊢ (??%?);
  whd in match (as_pc_of ??);
  inversion (fetch_statement ????) normalize nodelta
  [2: // ]
  ** #i' #f' #stmt' #EQ
  elim (fetch_statement_inv … EQ)
  >fd_prf
  whd in ⊢ (??%?→?); #EQ destruct(EQ)
  whd in ⊢ (%→?);
  whd in match (point_of_pc ??); >point_of_offset_of_point
  #EQ'
  cases tl in tl_other rest_in_code;
  [ * cases rest [2: #hd' #tl' * ] whd in ⊢ (%→?); #EQ destruct(EQ)
    >EQ' in dst_prf; >m_return_bind #H @H
  | #hd' #tl' ** #_ #hd_no_cost' #_
    cases rest [ * ] #mid' #rest' * * #nxt' * #EQ_stmt_at' #EQ_mid' #_
    >EQ_stmt_at' in EQ'; #EQ' destruct(EQ')
    @(no_label_uncosted … hd_no_cost')
  ]
| >dst_prf cases (list_not_empty ??) %
| normalize nodelta >point_of_pc_of_point assumption
]
qed.