source: src/joint/semanticsUtils.ma @ 3261

include "joint/joint_semantics.ma".
include alias "common/Identifiers.ma".
include "utilities/hide.ma".
include "ASM/BitVectorTrie.ma".
include "joint/TranslateUtils.ma".
include "common/ExtraMonads.ma".
include "common/extraGlobalenvs.ma".

definition reg_store ≝ λreg,v,locals.add RegisterTag beval locals reg v.

definition reg_retrieve : register_env beval → register → res beval ≝
 λlocals,reg. opt_to_res … [MSG BadRegister; CTX ? reg] (lookup … locals reg).

record hw_register_env : Type[0] ≝
  { reg_env : BitVectorTrie beval 6
  ; other_bit : bebit
  }.

include alias "ASM/BitVectorTrie.ma".

definition hwreg_retrieve: hw_register_env → Register → beval ≝
 λenv,r. lookup … (bitvector_of_register r) (reg_env env) BVundef.

definition hwreg_store: Register → beval → hw_register_env → hw_register_env ≝
 λr,v,env.mk_hw_register_env (insert … (bitvector_of_register r) v (reg_env env))
  (other_bit env).

definition hwreg_set_other : bebit → hw_register_env → hw_register_env ≝
λv,env.mk_hw_register_env (reg_env env) v.

definition hwreg_retrieve_sp : hw_register_env → res xpointer ≝
λenv.
let spl ≝ hwreg_retrieve env RegisterSPL in
let sph ≝ hwreg_retrieve env RegisterSPH in
! ptr ← pointer_of_address 〈spl, sph〉 ;
match ptype ptr return λx.ptype ptr = x → res xpointer with
[ XData ⇒ λprf.return «ptr, prf»
| _ ⇒ λ_.Error … [MSG BadPointer]
] (refl …).

definition hwreg_store_sp : hw_register_env → xpointer → hw_register_env ≝
λenv,sp.
let 〈spl, sph〉 ≝ beval_pair_of_pointer sp in
hwreg_store RegisterSPH sph (hwreg_store RegisterSPL spl env).

definition init_hw_register_env: xpointer → hw_register_env ≝
 hwreg_store_sp (mk_hw_register_env (Stub …) BBundef).

(*** Store/retrieve on pseudo-registers ***)
include alias "common/Identifiers.ma".

unification hint 0 ≔ X ⊢ register_env X ≡ identifier_map RegisterTag X.

(******************************** GRAPHS **************************************)

record sem_graph_params : Type[1] ≝
{ sgp_pars : uns_params
; sgp_sup : ∀F.sem_unserialized_params sgp_pars F
; graph_pre_main_generator :
  ∀p : joint_program (mk_graph_params sgp_pars).
  joint_closed_internal_function (mk_graph_params sgp_pars) (prog_names … p)
}.


definition sem_graph_params_to_graph_params :
  ∀pars : sem_graph_params.graph_params ≝
  λpars.mk_graph_params (sgp_pars pars).

coercion graph_params_from_sem_graph_params nocomposites :
  ∀pars : sem_graph_params.
  graph_params ≝ sem_graph_params_to_graph_params
  on _pars : sem_graph_params to graph_params.

definition sem_graph_params_to_sem_params :
  ∀pars : sem_graph_params.
  sem_params ≝
  λpars.
  mk_sem_params
    (mk_serialized_params
      (pars : graph_params)
      (sgp_sup pars ?)
      (word_of_identifier ?)
      (an_identifier ?)
      ? (refl …))
    (graph_pre_main_generator pars).
* #p % qed.

coercion sem_params_from_sem_graph_params :
  ∀pars : sem_graph_params.
  sem_params ≝ sem_graph_params_to_sem_params
  on _pars : sem_graph_params to sem_params.


(******************************** LINEAR **************************************)

lemma succ_pos_of_nat_of_pos : ∀p.succ_pos_of_nat (nat_of_pos p) = succ p.
@pos_elim [%]
#p #IH >nat_possucc whd in ⊢ (??%?); >IH % qed.

record sem_lin_params : Type[1] ≝
{ slp_pars : uns_params
; slp_sup : ∀F.sem_unserialized_params slp_pars F
; lin_pre_main_generator :
  ∀p : joint_program (mk_lin_params slp_pars).
  joint_closed_internal_function (mk_lin_params slp_pars) (prog_names … p)
}.

definition sem_lin_params_to_lin_params :
  ∀pars : sem_lin_params.lin_params ≝
  λpars.mk_lin_params (slp_pars pars).

coercion lin_params_from_sem_lin_params nocomposites :
  ∀pars : sem_lin_params.
  lin_params ≝ sem_lin_params_to_lin_params
  on _pars : sem_lin_params to lin_params.

definition sem_lin_params_to_sem_params :
  ∀pars : sem_lin_params.
  sem_params ≝
  λpars.
  mk_sem_params
    (mk_serialized_params
      (pars : lin_params)
      (slp_sup pars ?)
      succ_pos_of_nat
      (λp.pred (nat_of_pos p))
      ??)
    (lin_pre_main_generator pars).
[ @pos_cases [%] #p >nat_possucc @succ_pos_of_nat_of_pos
| #n >nat_succ_pos %
] qed.

coercion sem_params_from_sem_lin_params :
  ∀pars : sem_lin_params.
  sem_params ≝ sem_lin_params_to_sem_params
  on _pars : sem_lin_params to sem_params.

(* TODO move elsewhere *)
lemma lookup_opt_pm_set_elim : ∀A.∀P : option A → Prop.∀p,q,o,m.
  (p = q → P o) →
  (p ≠ q → P (lookup_opt A p m)) →
  P (lookup_opt A p (pm_set A q o m)).
#A #P #p #q
@(eqb_elim p q) #H #o #m #H1 #H2
[ >H >lookup_opt_pm_set_hit @H1 @H
| >lookup_opt_pm_set_miss [ @H2 ] @H
]
qed.

lemma lookup_add_elim : ∀tag,A.∀P : option A → Prop.∀m,i,j,x.
  (i = j → P (Some ? x)) →
  (i ≠ j → P (lookup tag A m j)) →
  P (lookup tag A (add tag A m i x) j).
#tag #A #P * #m * #p * #q #x
#H1 #H2 whd in ⊢ (?%); normalize nodelta whd in match insert; normalize nodelta
@lookup_opt_pm_set_elim #H destruct
[ @H1 % | @H2 % #EQ destruct cases H #H @H % ]
qed.

lemma fetch_statement_eq : ∀p:sem_params.∀g.
  ∀ge : genv p g.∀ptr : program_counter.
  ∀i,fn,s.
  fetch_internal_function … ge (pc_block ptr) = OK … 〈i, fn〉 →
  let pt ≝ point_of_pc … ptr in
  stmt_at … (joint_if_code … fn) pt = Some ? s →
  fetch_statement … ge ptr = OK … 〈i, fn, s〉.
#p #g #ge #ptr #i #f #s #EQ1 #EQ2
whd in match fetch_statement; normalize nodelta >EQ1 >m_return_bind
>EQ2 %
qed.

lemma fetch_statement_inv : ∀p:sem_params.∀g.
  ∀ge : genv p g.∀ptr : program_counter.
  ∀i,fn,s.
  fetch_statement … ge ptr = OK … 〈i, fn, s〉 →
  fetch_internal_function … ge (pc_block ptr) = OK … 〈i, fn〉 ∧
  let pt ≝ point_of_pc p ptr in
  stmt_at … (joint_if_code … fn) pt = Some ? s.
#p #g #ge #ptr #i #fn #s #H
elim (bind_inversion ????? H) * #i #f' * #EQ1 -H #H
elim (bind_inversion ????? H) #s' * -H #H
lapply (opt_eq_from_res ???? H) -H #EQ2
whd in ⊢ (??%%→?); #EQ destruct(EQ) %{EQ1 EQ2}
qed.

definition pm_P : ∀A,B.∀P : A → B → Prop.positive_map A → positive_map B → Prop ≝
λA,B,P,mA,mB.
∀p.
match lookup_opt … p mA with
[ Some a ⇒
  match lookup_opt … p mB with
  [ Some b ⇒ P a b
  | _ ⇒ False
  ]
| _ ⇒ match lookup_opt … p mB with
  [ Some _ ⇒ False
  | _ ⇒ True
  ]
].

definition match_funct_map :
  ∀M : matching.
  ∀vars.positive_map (m_A M vars) → positive_map (m_B M vars) → Prop ≝
  λM,vars.pm_P … (match_fundef M ?).

lemma pm_P_insert :
  ∀A,B,P.
  ∀p,a1,a2,m1,m2.P a1 a2 → pm_P A B P m1 m2 →
  pm_P … P (insert … p a1 m1) (insert … p a2 m2).
#A #B #P #p #a1 #a2 #m1 #m2 #Pa1a2 #Pm1m2
#p'
@(eqb_elim p' p) #H destruct
[ >lookup_opt_insert_hit >lookup_opt_insert_hit @Pa1a2
| >(lookup_opt_insert_miss … a1 … H) >(lookup_opt_insert_miss … a2 … H)
  @Pm1m2
]
qed.

lemma pm_P_set_None :
  ∀A,B,P.
  ∀p,m1,m2.pm_P A B P m1 m2 →
  pm_P … P (pm_set … p (None ?) m1) (pm_set … p (None ?) m2).
#A #B #P #p #m1 #m2 #Pm1m2
#p'
@(eqb_elim p' p) #H destruct
[ >lookup_opt_pm_set_hit >lookup_opt_pm_set_hit %
| >(lookup_opt_pm_set_miss … H) >(lookup_opt_pm_set_miss … H)
  @Pm1m2
]
qed.

record match_genv_t (M : matching)
  (vars : list ident)
  (ge1 : genv_t (m_A M vars)) (ge2 : genv_t (m_B M vars)) : Prop ≝
{ symbols_eq : symbols … ge1 = symbols … ge2
; nextfunction_eq : nextfunction … ge1 = nextfunction … ge2
; functions_match : pm_P ?? (match_fundef M ?) (functions … ge1) (functions … ge2)
}.

lemma add_globals_match :
  ∀M : matching.∀initV,initW.
  ∀vars1,vars2.
  ∀vars.
(*  let vars1' ≝ map … (λx.\fst (\fst x)) vars1 in
  let vars2' ≝ map … (λx.\fst (\fst x)) vars2 in *)
  ∀env_mem1 : genv_t (m_A M vars) × mem.
  ∀env_mem2 : genv_t (m_B M vars) × mem.
  All2 (ident×region×(m_V M)) (ident×region×(m_W M))
      (match_var_entry M) vars1 vars2 →
  nextblock … (\snd env_mem1) = nextblock … (\snd env_mem2) →
  match_genv_t M vars
    (\fst env_mem1) (\fst env_mem2) →
  match_genv_t M vars
    (\fst (add_globals … initV env_mem1 vars1))
    (\fst (add_globals … initW env_mem2 vars2)).
#M #init1 #init2 #vars1
elim vars1 -vars1 [2: ** #id1 #r1 #v1 #tl1 #IH ]
* [2,4: ** #id2 #r2 #v2 #tl2 ]
#vars * #env1 #mem1 * #env2 #mem2 *
[2: #_ #H @H ]
#H inversion H #id' #r' #v1' #v2' #P #EQ1 #EQ2 #_ destruct -H #H
#EQnxtbl #G @(IH tl2 … H)
cases mem1 in EQnxtbl; -mem1 #mem1 #nbl1 #prf1
cases mem2 -mem2 #mem2 #nbl2 #prf2 #EQ destruct
[ % ]
normalize nodelta %
whd in match add_symbol;
whd in match drop_fn; normalize nodelta
[ >(symbols_eq … G) %
| @(nextfunction_eq … G)
| >(symbols_eq … G) cases (lookup ? block ??) normalize nodelta
  [2: ** [2,3: #p] normalize nodelta ]
  try @pm_P_set_None 
  @(functions_match … G)
]
qed.

lemma add_functs_match :
  ∀M : matching.
  ∀vars.
  ∀functs1,functs2.
(*  let vars1' ≝ map … (λx.\fst (\fst x)) vars1 in
  let vars2' ≝ map … (λx.\fst (\fst x)) vars2 in *)
  ∀env1 : genv_t (m_A M vars).
  ∀env2 : genv_t (m_B M vars).
  All2 …
    (match_funct_entry M vars vars) functs1 functs2 →
  match_genv_t M vars env1 env2 →
  match_genv_t M vars
    (add_functs … env1 functs1)
    (add_functs … env2 functs2).
#M #vars #functs1 elim functs1 -functs1 [2: * #id1 #f1 #tl1 #IH ]
* [2,4: * #id2 #f2 #tl2 ]
#env1 #env2 *
[2: #H @H ]
#H
cut (id1 = id2 ∧ match_fundef M … f1 f2)
[ @(match_funct_entry_inv M ??????? H) #v #i #f1 #f2 #H %{H} % ]
* #EQ destruct #Pf1f2 #Ptl1tl2 #G
lapply (IH … Ptl1tl2 G) -G #G
%
whd in 
  match (add_functs ?? (? :: tl1));
whd in 
  match (add_functs ?? (? :: tl2));
change with (add_functs ?? tl1) in match (foldr ???? tl1);
change with (add_functs ?? tl2) in match (foldr ???? tl2);
whd in match drop_fn; normalize nodelta
[ >(nextfunction_eq … G)  >(symbols_eq … G) %
| >(nextfunction_eq … G) %
| >(symbols_eq … G) cases (lookup ? block ??) normalize nodelta
  [2: ** [2,3: #p] normalize nodelta ]
  >(nextfunction_eq … G)
  @(pm_P_insert … Pf1f2)
  try @pm_P_set_None @(functions_match … G)
]
qed.

lemma globalenv_match:
    ∀M:matching.∀initV,initW.
     (∀v,w. match_var_entry M v w →
      size_init_data_list (initV (\snd v)) = size_init_data_list (initW (\snd w))) →
    ∀p: program (m_A M) (m_V M). ∀p': program (m_B M) (m_W M).
    ∀MATCH:match_program … M p p'.
    match_genv_t M ? (globalenv … initV p)
      (globalenv … initW p' ⌈prog_var_names … p' ↦ prog_var_names … p⌉).
[2: @sym_eq @(matching_vars … (mp_vars … MATCH)) ]
* #A #B #V #W #Pf #Pv #iV #iW #init_eq
* #vars1 #functs1 #main1
* #vars2 #functs2 #main2
*
whd in match prog_var_names;
normalize nodelta;
#Mvars #Mfns #EQmain destruct
lapply (sym_eq ????)
#E
lapply Mfns lapply functs2 -functs2
whd in match globalenv; whd in match globalenv_allocmem;
whd in match prog_var_names in E ⊢ %;
normalize nodelta in E ⊢ %;
>E normalize nodelta #functs2 #Mfns
@add_globals_match [ assumption | % ]
@add_functs_match [ assumption ]
% try % #p %
qed.

lemma symbols_transf:
 ∀A,B,V,init.∀prog_in : program A V.
 ∀trans : ∀vars.A vars → B vars.
 let prog_out ≝ transform_program … prog_in trans in
 symbols … (globalenv … init prog_out) = symbols … (globalenv … init prog_in).
#A #B #V #iV #p #tf whd
lapply (transform_program_match … tf p)
#MATCH
>(symbols_eq … (globalenv_match … MATCH))
[2: @iV |3: #v #w * // ]
lapply (sym_eq ????)
whd in match (prog_var_names ???); whd in match (prog_vars B ??);
#E >(K ?? E) normalize nodelta %
qed.

lemma functions_transf:
 ∀A,B,V,init.∀prog_in : program A V.
 ∀trans : ∀vars.A vars → B vars.
 let prog_out ≝ transform_program … prog_in trans in
 ∀p.lookup_opt … p (functions … (globalenv … init prog_out)) =
 option_map ?? (trans ?) (lookup_opt … p (functions … (globalenv … init prog_in))).
#A #B #V #iV #p #tf #n
lapply (transform_program_match … tf p)
#MATCH
whd in match globalenv; whd in match globalenv_allocmem;
normalize nodelta
lapply (functions_match … (globalenv_match … MATCH) n)
[ @iV | @iV | #v #w * // ]
lapply (sym_eq ????)
whd in match (prog_var_names ???); whd in match (prog_vars B ??);
#E >(K ?? E) normalize nodelta
cases (lookup_opt ???) [2: #x ] normalize nodelta
cases (lookup_opt ???) [2,4: #y ] normalize nodelta
[ #EQ <EQ % |*: * % ]
qed.

lemma symbol_for_block_transf :
 ∀A,B,V,init.∀prog_in : program A V.
 ∀trans : ∀vars.A vars → B vars.
 let prog_out ≝ transform_program … prog_in trans in
 ∀bl.
 symbol_for_block … (globalenv … init prog_out) bl =
 symbol_for_block … (globalenv … init prog_in) bl.
#A #B #V #iV #p #tf whd
#bl 
whd in match symbol_for_block; normalize nodelta
>(symbols_transf … tf) %
qed.

include alias "common/Pointers.ma".

(* TODO move *)
lemma Exists_mp : ∀A,P,Q,l.(∀x.P x → Q x) → Exists A P l → Exists A Q l.
#A #P #Q #l #H elim l -l [2: #hd #tl #IH] * #G whd /3 by or_introl, or_intror/ qed.

definition joint_globalenv :
  ∀p : sem_params.∀pr:joint_program p.
    (ident → option ℕ) → genv p (prog_names … pr) ≝
λp,prog,stacksizes.
let genv ≝ globalenv … (λx.x) prog in
let pc_from_lbl ≝ λbl.λfn : joint_closed_internal_function p ?.λlbl.
  ! pt ← point_of_label … (joint_if_code … fn) lbl ;
  return mk_program_counter bl (offset_of_point … p pt) in
mk_genv_gen ?? genv ? stacksizes (pre_main_generator … p prog) pc_from_lbl.
#s #H
cases (find_symbol_exists ?? (λx.x) … prog s ?)
[ #bl #EQ >EQ % #ABS destruct ]
cases (Exists_append … H) -H #H
[ @Exists_append_r | @Exists_append_l ]
[ @(Exists_mp … H) @sym_eq ]
cases prog in H; #functs * #vars #functs' #main #init_cost
whd in match prog_funct_names; normalize nodelta #EQ
>map_ext_eq [ >EQ @Exists_mp @sym_eq | // ] skip 
qed.

lemma opt_to_res_bind : ∀X,Y,m,f,e.opt_to_res Y e (! x ← m ; f x) =
  ! x ← opt_to_res X e m ; opt_to_res Y e (f x).
#X #Y * [2: #x] #f #e % qed.

lemma fetch_function_transf:
 ∀src,dst : sem_params.∀prog_in : joint_program src.
 ∀stacksizes,trans.
 let prog_out ≝ transform_joint_program src dst trans prog_in in
 ∀bl.
 fetch_function … (joint_globalenv … prog_out stacksizes) bl =
 if eqZb (block_id bl) (-1) then
   return 〈pre_main_id, Internal ? (pre_main_generator … dst prog_out)〉
 else
   ! 〈id, f〉 ← fetch_function … (joint_globalenv … prog_in stacksizes) bl ;
   return 〈id, transf_fundef ?? (trans ?) f〉.
#src #dst #p #sizes #tf whd
lapply (transform_program_match … (λvars.transf_fundef … (tf ?)) p)
#MATCH
whd in match fetch_function;
whd in match joint_globalenv; normalize nodelta
#bl @eqZb_elim #Hbl normalize nodelta [ % ]
whd in match transform_joint_program;
whd in match prog_names; normalize nodelta
>symbol_for_block_transf
>opt_to_res_bind >opt_to_res_bind in ⊢ (???%); >m_bind_bind
@m_bind_ext_eq #id
whd in match find_funct_ptr; normalize nodelta
cases bl -bl ** [2,3: #p] normalize nodelta #_ try %
lapply (functions_match … (globalenv_match … MATCH) p) try @(λx.x)
[#v #w * //]
lapply (sym_eq ????)
whd in match prog_var_names; normalize nodelta
#E >(K ?? E) -E normalize nodelta
cases (lookup_opt ???) [2: #x ] normalize nodelta
cases (lookup_opt ???) [2,4: #y ] normalize nodelta
* %
qed.

lemma fetch_internal_function_transf :
 ∀src,dst : sem_params.∀prog_in : joint_program src.
 ∀stacksizes,trans.
 let prog_out ≝ transform_joint_program src dst trans prog_in in
 ∀bl.
 fetch_internal_function … (joint_globalenv … prog_out stacksizes) bl =
 if eqZb (block_id bl) (-1) then
   return 〈pre_main_id, pre_main_generator … dst prog_out〉
 else
   ! 〈i, f〉 ← fetch_internal_function … (joint_globalenv … prog_in stacksizes) bl ;
   return 〈i, trans … f〉.
#src #dst #p #sizes #tf whd
#bl whd in match fetch_internal_function; normalize nodelta
>(fetch_function_transf … p)
@eqZb_elim #Hbl [%] normalize nodelta >m_bind_bind >m_bind_bind
@m_bind_ext_eq * #id * #f %
qed.

include alias "utilities/binary/positive.ma".

lemma pm_map_add_ind : ∀A.∀P : positive_map A → Prop.
(∀m.(∀p.lookup_opt A p m = None ?) → P m) →
(∀m,p,v.P m → lookup_opt A p m = None ? → P (insert A p v m)) →
∀m.P m.
#A #P #H1 #H2 #m lapply H2 lapply H1 lapply P -P elim m -m
[ #P #H1 #_ @H1 #p % ]
#o #l #r #IHl #IHr #P #H1 #H2
@IHl #l'
[ #empty_l' @IHr #r'
  [ #empty_r' cases o [ @H1 * try #p normalize // ]
    #v change with (P (insert ? one v (pm_node ? (None ?) ??)))
    @H2 [ @H1 * try #p normalize // | % ]
  ]
]
#p #v #H #G
[ change with (P (insert ? (p1 p) v (pm_node ? ???)))
| change with (P (insert ? (p0 p) v (pm_node ? ???)))
] @H2 assumption
qed.

include alias "basics/logic.ma".
include alias "common/PositiveMap.ma".

lemma swap_neg : ∀A,B : Prop.(A → B) → ¬B → ¬A.
#A #B #impl * #Bf % #At @Bf @impl @At qed-.

definition b_graph_transform_program_props ≝
  λsrc,dst : sem_graph_params.
  λstacksizes.
  λdata,prog_in.
  λinit_regs : block → list register.
  λf_lbls : block → label → list label.
  λf_regs : block → label → list register.
   let prog_out ≝ b_graph_transform_program src dst data prog_in in
   let src_genv ≝ joint_globalenv src prog_in stacksizes in
   let dst_genv ≝ joint_globalenv dst prog_out stacksizes in
  ∀bl,def_in.
  find_funct_ptr … src_genv bl = return (Internal ? def_in) →
  ∃init_data,def_out.
  find_funct_ptr … dst_genv bl = return (Internal ? def_out) ∧
  bind_new_instantiates … init_data (data … def_in) (init_regs bl) ∧
  b_graph_translate_props src dst ? init_data
    def_in def_out (f_lbls bl) (f_regs bl).

lemma make_b_graph_transform_program_props :
 ∀src,dst:sem_graph_params.
 ∀stacksizes.
 ∀data : ∀globals.joint_closed_internal_function src globals →
  bound_b_graph_translate_data src dst globals.
 ∀prog_in : joint_program src.
 let prog_out ≝ b_graph_transform_program … data prog_in in
 let src_genv ≝ joint_globalenv src prog_in stacksizes in
 let dst_genv ≝ joint_globalenv dst prog_out stacksizes in
 ∃init_regs : block → list register.
 ∃f_lbls : block → label → list label.
 ∃f_regs : block → label → list register.
 b_graph_transform_program_props src dst stacksizes data prog_in init_regs f_lbls f_regs.
cases daemon (* TOREDO
#src #dst #data #prog_in
whd in match b_graph_transform_program_props; normalize nodelta
whd in match joint_globalenv; normalize nodelta
letin prog_out ≝ (b_graph_transform_program … data prog_in)
letin src_genv ≝ (globalenv … (λx.x) prog_in)
letin dst_genv ≝ (globalenv … (λx.x) prog_out)
cut (∀p.lookup_opt ? p (functions ? dst_genv) =
     option_map ?? (transf_fundef … (λf.b_graph_translate … (data … f) f))
      (lookup_opt ? p (functions ? src_genv)))
[ @functions_transf ]
cut (symbols ? dst_genv = symbols ? src_genv)
[ @symbols_transf ]
cases dst_genv #functs2 #nextf2 #symbols2 #H2
cases src_genv #functs1 #nextf1 #symbols1 #H1 #EQ destruct
lapply H2 lapply H1 lapply functs2
@(pm_map_add_ind … functs1) -functs1 -functs2 #functs1
[ #functs1_empty | #p #f #IH #p_not_in ]
#functs2 #H1 #H2 #transf
[ %{(λ_.[ ])} %{(λ_.λ_.[])} %{(λ_.λ_.[])}
  #bl #def_in #ABS1 #ABS2 @⊥ lapply ABS2 -ABS2 lapply ABS1 -ABS1
  whd in match find_funct_ptr;
  whd in match find_symbol;
  normalize nodelta
  cases bl; * normalize nodelta
  [2,3: #p ]
  [1,3: #_ whd in ⊢ (???%→?); #EQ destruct ]
  >lookup_add_hit
  #H >lookup_opt_insert_miss
  [2: @(swap_neg … H) #EQ >EQ % ]
  whd in match drop_fn; normalize nodelta
  cases (lookup … symbols1 pre_main_id)
  normalize nodelta
  [ >functs1_empty | ** [2,3: #p' ] normalize nodelta
    [1,3: >functs1_empty
    | @lookup_opt_pm_set_elim #H destruct
      [2: >functs1_empty ]
    ]
  ] whd in ⊢ (???%→?); #EQ destruct
]
cases (IH (pm_set … p (None ?) functs2) ???)
[|*: @hide_prf
  [ #b #G @(H1 b ?) @(swap_neg … G) -G
    whd in match insert; normalize nodelta
    @lookup_opt_pm_set_elim
    [ #EQ #ABS destruct ]
    #NEQ #H @H
  | #b #G @(H2 b ?) @(swap_neg … G) -G
    @lookup_opt_pm_set_elim
    [ #_ #_ % ]
    #_ #H @H
  | #b @lookup_opt_pm_set_elim
    [ #EQ destruct >p_not_in % ]
    #NEQ >transf
    >(lookup_opt_insert_miss ? f b p … NEQ) %
  ]
]
#init_regs * #f_lbls * #f_regs #props
-IH cases f in H1 transf; -f #f #H1 #transf
[ (* internal *)
  letin upd ≝ (λA : Type[0].λf : block → A.
    λid.λv,id'.
    if eq_block id id' then v else f id')
  cases (pi2 ?? (b_graph_translate … (data … f) f))
  #loc_data * #loc_init_regs * #loc_f_lbls * #loc_f_regs *
  #inst_loc_data #loc_props
  letin bl ≝ (mk_block (neg p))
  %{(upd … init_regs bl loc_init_regs)}
  %{(upd … f_lbls bl loc_f_lbls)}
  %{(upd … f_regs bl loc_f_regs)}
| (* external, nothing changes *)
  %{init_regs}
  %{f_lbls}
  %{f_regs}
]
* #p' #def_in
whd in match find_funct_ptr; normalize nodelta
whd in match (block_region (mk_block p'));
cases p' -p' [2,3,5,6: #p' ] normalize nodelta
[1,3,5,6: #_ #ABS normalize in ABS; destruct]
whd in match find_symbol;
whd in match insert; normalize nodelta
#bl_prf
@lookup_opt_pm_set_elim #pp' destruct
[1,3: whd in ⊢ (??%%→?); #EQ destruct(EQ)
  [ %{loc_data} %
    [2: % [ % ]
      [ >lookup_opt_insert_hit %
      |*: >eq_block_b_b assumption
      ]
    |]
|*: >(lookup_opt_insert_miss ???? functs1 … pp')
  [ @eq_block_elim [ #EQ destruct cases (absurd ?? pp') % ] #_ normalize nodelta]
  #EQ lapply (props (mk_block (neg p')) def_in EQ)
  whd in match find_funct_ptr; normalize nodelta
  >(lookup_opt_pm_set_miss … functs2 … pp') #H @H
] *)
qed.

lemma if_elim' : ∀A : Type[0].∀P : A → Prop.∀b : bool.∀c1,c2 : A.
  (b → P c1) → (¬(bool_to_Prop b) → P c2) → P (if b then c1 else c2).
#A #P * /3 by Prop_notb/ qed.

lemma b_graph_transform_program_fetch_internal_function :
 ∀src,dst:sem_graph_params.
 ∀stacksizes.
 ∀data : ∀globals.joint_closed_internal_function src globals →
  bound_b_graph_translate_data src dst globals.
 ∀prog_in : joint_program src.
 ∀init_regs : block → list register.
 ∀f_lbls : block → label → list label.
 ∀f_regs : block → label → list register.
 b_graph_transform_program_props … stacksizes data prog_in init_regs f_lbls f_regs →
 let prog_out ≝ b_graph_transform_program … data prog_in in
 let src_genv ≝ joint_globalenv src prog_in stacksizes in
 let dst_genv ≝ joint_globalenv dst prog_out stacksizes in
 ∀bl : Σbl.block_region … bl = Code.∀id,def_in.
 if eqZb (block_id … bl) (-1) then
   (fetch_internal_function … dst_genv bl =
     return 〈pre_main_id, pre_main_generator … dst prog_out〉)
 else
   (fetch_internal_function … src_genv bl = return 〈id, def_in〉 →
   ∃init_data,def_out.
   fetch_internal_function … dst_genv bl = return 〈id, def_out〉 ∧
   bind_new_instantiates … init_data (data … def_in) (init_regs bl) ∧
   b_graph_translate_props src dst ? init_data
      def_in def_out (f_lbls bl) (f_regs bl)).
#src #dst #stacksizes #data #prog_in
#init_regs #f_lbls #f_regs #props
#bl #id #def_in
@if_elim' #Hbl
[ whd in match fetch_internal_function; whd in match fetch_function;
  normalize nodelta >Hbl % ]
#H @('bind_inversion H) * #id' * #def_in' -H
normalize nodelta [2: #_ whd in ⊢ (??%%→?); #ABS destruct ]
whd in match fetch_function; normalize nodelta
>Hbl normalize nodelta
#H @('bind_inversion (opt_eq_from_res … H)) -H #id'' #EQ1
#H @('bind_inversion H) -H #def_in'' #H
whd in ⊢ (??%%→??%%→?); #EQ2 #EQ3 destruct
cases (props … H)
#loc_data * #def_out ** #H1 #H2 #H3
%{loc_data} %{def_out}
%{H3} %{H2}
whd in match fetch_internal_function;
whd in match fetch_function; normalize nodelta
>Hbl normalize nodelta
whd in match joint_globalenv; normalize nodelta
whd in match prog_names; normalize nodelta
>symbol_for_block_transf >EQ1 >m_return_bind
>H1 %
qed.

lemma b_graph_transform_program_fetch_statement :
 ∀src,dst:sem_graph_params.∀stacksizes.
 ∀data : ∀globals.joint_closed_internal_function src globals →
  bound_b_graph_translate_data src dst globals.
 ∀prog_in : joint_program src.
 ∀init_regs : block → list register.
 ∀f_lbls : block → label → list label.
 ∀f_regs : block → label → list register.
 b_graph_transform_program_props … stacksizes data prog_in init_regs f_lbls f_regs →
 let prog_out ≝ b_graph_transform_program … data prog_in in
 let src_genv ≝ joint_globalenv src prog_in stacksizes in
 let dst_genv ≝ joint_globalenv dst prog_out stacksizes in
 ∀pc,id,def_in,s.
 if eqZb (block_id … (pc_block … pc)) (-1) then
   (fetch_internal_function … dst_genv (pc_block … pc) =
     return 〈pre_main_id, pre_main_generator … dst prog_out〉)
 else
   (fetch_statement … src_genv pc = return 〈id, def_in, s〉 →
   ∃init_data,def_out.
   let bl ≝ pc_block pc in
   fetch_internal_function … dst_genv bl = return 〈id, def_out〉 ∧
   bind_new_instantiates … init_data (data … def_in) (init_regs bl) ∧
   let l ≝ point_of_pc dst pc in
    let lbls ≝ f_lbls bl l in let regs ≝ f_regs bl l in
    match s with
    [ sequential s' nxt ⇒
      let block ≝
        if not_emptyb … (added_prologue … init_data) ∧
           eq_identifier … (joint_if_entry … def_in) l then
          bret … [ ]
        else
          f_step … init_data l s' in
      l ~❨block, l::lbls, regs❩~> nxt in joint_if_code … def_out
    | final s' ⇒
      l ~❨f_fin … init_data l s', l::lbls, regs❩~> it in joint_if_code … def_out
    | FCOND abs _ _ _ ⇒ Ⓧabs
    ]).
#src #dst #stacksizes #data #prog_in
#init_regs #f_lbls #f_regs #props
#pc #id #def_in #s
lapply (b_graph_transform_program_fetch_internal_function … props
  (pc_block … pc) id def_in)
@if_elim' #Hbl >Hbl normalize nodelta [ #H @H ] #G
#H @('bind_inversion H) * #id' #def_in' -H
#EQfif
#H @('bind_inversion H) -H #s
#H lapply (opt_eq_from_res ???? H) -H
#EQstmt_at whd in ⊢ (??%%→?); #EQ destruct
cases (G … EQfif)
#a * #b ** #H1 #H2 #H3 %{a} %{b} %
[ %{H1 H2}
| @(multi_fetch_ok … H3 … EQstmt_at)
]
qed.

lemma b_graph_transform_program_fetch_statement_plus :
 ∀src,dst:sem_graph_params.∀stacksizes.
 ∀data : ∀globals.joint_closed_internal_function src globals →
  bound_b_graph_translate_data src dst globals.
 ∀prog_in : joint_program src.
 ∀init_regs : block → list register.
 ∀f_lbls : block → label → list label.
 ∀f_regs : block → label → list register.
 b_graph_transform_program_props … stacksizes data prog_in init_regs f_lbls f_regs →
 let prog_out ≝ b_graph_transform_program … data prog_in in
 let src_genv ≝ joint_globalenv src prog_in stacksizes in
 let dst_genv ≝ joint_globalenv dst prog_out stacksizes in
 ∀pc,id,def_in,s.
 if eqZb (block_id … (pc_block … pc)) (-1) then
   (fetch_internal_function … dst_genv (pc_block … pc) =
     return 〈pre_main_id, pre_main_generator … dst prog_out〉)
 else
   (fetch_statement … src_genv pc = return 〈id, def_in, s〉 →
   ∃init_data,def_out.
   let bl ≝ pc_block pc in
   fetch_internal_function … dst_genv bl = return 〈id, def_out〉 ∧
   bind_new_instantiates … init_data (data … def_in) (init_regs bl) ∧
   let l ≝ point_of_pc dst pc in
   let lbls ≝ f_lbls bl l in
   let regs ≝ f_regs bl l in
   partial_partition … (f_lbls bl) ∧
   partial_partition … (f_regs bl) ∧
   (∀l.All …
      (λlbl.¬fresh_for_univ … lbl (joint_if_luniverse … def_in) ∧
             fresh_for_univ … lbl (joint_if_luniverse … def_out)) (f_lbls bl l)) ∧
    (∀l.All …
      (λreg.¬fresh_for_univ … reg (joint_if_runiverse … def_in) ∧
             fresh_for_univ … reg (joint_if_runiverse … def_out)) (f_regs bl l)) ∧
   match s with
    [ sequential s' nxt ⇒
      let block ≝
        if not_emptyb … (added_prologue … init_data) ∧
           eq_identifier … (joint_if_entry … def_in) l then
          bret … [ ]
        else
          f_step … init_data l s' in
      l ~❨block, l::lbls, regs❩~> nxt in joint_if_code … def_out
    | final s' ⇒
      l ~❨f_fin … init_data l s', l::lbls, regs❩~> it in joint_if_code … def_out
    | FCOND abs _ _ _ ⇒ Ⓧabs
    ]).
#src #dst #stacksizes #data #prog_in
#init_regs #f_lbls #f_regs #props
#pc #id #def_in #s
lapply (b_graph_transform_program_fetch_internal_function … props … (pc_block … pc) id def_in)
@if_elim' #Hbl >Hbl normalize nodelta
[ #H @H ] #G
#H @('bind_inversion H) * #id' #def_in' -H
#EQfif
#H @('bind_inversion H) -H #s
#H lapply (opt_eq_from_res ???? H) -H
#EQstmt_at whd in ⊢ (??%%→?); #EQ destruct
cases (G … EQfif)
#a * #b ** #H1 #H2 #H3 %{a} %{b} %
[ %{H1 H2}
| %{(multi_fetch_ok … H3 … EQstmt_at)}
  %{(freshness_regs … H3)}
  %{(freshness_lbls … H3)}
  %{(partition_regs … H3)}
  @(partition_lbls … H3)
]         
qed.