source: src/joint/semantics.ma @ 1377

Last change on this file since 1377 was 1377, checked in by sacerdot, 8 years ago

pop_frame now incorporates the fetch_result (that made sense only for RTL).
pop_frame and save_frame are now also more symmetric

File size: 15.9 KB
Line 
1include "utilities/lists.ma".
2include "common/Globalenvs.ma".
3include "common/IO.ma".
4include "common/SmallstepExec.ma".
5include "joint/Joint.ma".
6include "joint/BEMem.ma".
7
8(* CSC: external functions never fail (??) and always return something of the
9   size of one register, both in the frontend and in the backend.
10   Is this reasonable??? In OCaml it always return a list, but in the frontend
11   only the head is kept (or Undef if the list is empty) ??? *)
12
13record more_sem_params (p:params_): Type[1] ≝
14 { framesT: Type[0]
15 ; regsT: Type[0]
16
17 ; succ_pc: succ p → address → address
18 ; greg_store_: generic_reg p → beval → regsT → res regsT
19 ; greg_retrieve_: regsT → generic_reg p → res beval
20 ; acca_store_: acc_a_reg p → beval → regsT → res regsT
21 ; acca_retrieve_: regsT → acc_a_reg p → res beval
22 ; accb_store_: acc_b_reg p → beval → regsT → res regsT
23 ; accb_retrieve_: regsT → acc_b_reg p → res beval
24 ; dpl_store_: dpl_reg p → beval → regsT → res regsT
25 ; dpl_retrieve_: regsT → dpl_reg p → res beval
26 ; dph_store_: dph_reg p → beval → regsT → res regsT
27 ; dph_retrieve_: regsT → dph_reg p → res beval
28 ; pair_reg_move_: regsT → pair_reg p → res regsT
29 
30 ; pointer_of_label: label → Σp:pointer. ptype p = Code
31 }.
32
33record sem_params: Type[1] ≝
34 { spp :> params_
35 ; more_sem_pars :> more_sem_params spp
36 }.
37
38record state (p: sem_params): Type[0] ≝
39 { st_frms: framesT ? p
40 ; pc: address
41 ; sp: pointer
42 ; carry: beval
43 ; regs: regsT ? p
44 ; m: bemem
45 }.
46
47record more_sem_params1 (succT: Type[0]) (p:params1): Type[1] ≝
48 { more_sparams :> more_sem_params (mk_params_ p succT)
49
50 ; init_locals : localsT p → regsT … more_sparams → regsT … more_sparams
51 ; pop_frame: state (mk_sem_params … more_sparams) → res ((state (mk_sem_params … more_sparams)) × address)
52   (*CSC: save_frame returns a res only because we can call a function with the wrong number and
53     type of arguments. To be fixed using a dependent type *)
54 ; save_frame: address → nat → paramsT … p → call_args p → call_dest p → state (mk_sem_params … more_sparams) → res (state (mk_sem_params … more_sparams))
55 }.
56
57record sem_params1: Type[1] ≝
58 { spp1 :> params1
59 ; ssucc_ : Type[0]
60 ; more_sem_params1 :> more_sem_params1 ssucc_ spp1
61 }.
62
63definition sem_params_of_sem_params1 ≝ λsp1: sem_params1. mk_sem_params … sp1.
64coercion sem_params_of_sem_params1 : ∀_x:sem_params1. sem_params
65 ≝ sem_params_of_sem_params1 on _x: sem_params1 to sem_params.
66
67definition genv ≝ λglobals.λp:params globals. (genv_t Genv) (joint_function globals p).
68
69record more_sem_params2 (globals: list ident) (p: params globals) : Type[1] ≝
70 { more_sparams1 :> more_sem_params1 (succ p) p
71
72 ; fetch_statement: genv … p → state (mk_sem_params … more_sparams1) → res (joint_statement (mk_sem_params … more_sparams1) globals)
73 ; fetch_result: state (mk_sem_params … more_sparams1) → res (list beval)
74
75 ; fetch_external_args: external_function → state (mk_sem_params … more_sparams1) → res (list val)
76 ; set_result: list val → state (mk_sem_params … more_sparams1) → res (state (mk_sem_params … more_sparams1))
77
78 ; exec_extended: genv globals p → extend_statements (mk_sem_params … more_sparams1) → succ p → state (mk_sem_params … more_sparams1) → IO io_out io_in (trace × (state (mk_sem_params … more_sparams1)))
79 }.
80
81record sem_params2 (globals: list ident): Type[1] ≝
82 { p2:> params globals
83 ; more_sparams2:> more_sem_params2 globals p2
84 }.
85
86definition sem_params_of_sem_params2 ≝ λglobals. λsp2: sem_params2 globals. mk_sem_params sp2 sp2.
87coercion sem_params_of_sem_params2 : ∀globals. ∀_x:sem_params2 globals. sem_params
88 ≝ sem_params_of_sem_params2 on _x: sem_params2 ? to sem_params.
89(*
90unification hint  0 ≔ globals: (list ident), p: sem_params2 globals;
91   S ≟ sem_params_of_sem_params2 globals p
92(* ---------------------------------------- *) ⊢
93   pars_ (spp (mk_sem_params (p2 globals p)
94    (more_sparams (p2 globals p) globals
95    (more_sparams2 globals p)))) ≡ spp__o__pars_ S.
96*)
97definition sem_params1_of_sem_params2 ≝ λglobals. λsp2: sem_params2 globals. mk_sem_params1 sp2 (succ sp2) sp2.
98coercion sem_params1_of_sem_params2 : ∀globals. ∀_x:sem_params2 globals. sem_params1
99 ≝ sem_params1_of_sem_params2 on _x: sem_params2 ? to sem_params1.
100
101definition address_of_label: sem_params → label → address.
102 #p #l generalize in match (refl … (address_of_pointer (pointer_of_label … p l)))
103 cases (address_of_pointer (pointer_of_label … p l)) in ⊢ (???% → ?)
104  [ #res #_ @res
105  | #msg cases (pointer_of_label … p l) * * #q #com #off #E1 #E2 try destruct
106    normalize in E2; destruct ]
107qed.
108
109definition set_m: ∀p. bemem → state p → state p ≝
110 λp,m,st. mk_state p (st_frms … st) (pc … st) (sp … st) (carry … st) (regs … st) m.
111
112definition set_regs: ∀p:sem_params. regsT ? p → state p → state p ≝
113 λp,regs,st. mk_state p (st_frms … st) (pc … st) (sp … st) (carry … st) regs (m … st).
114
115definition set_sp: ∀p. pointer → state p → state p ≝
116 λp,sp,st. mk_state … (st_frms … st) (pc … st) sp (carry … st) (regs … st) (m … st).
117
118definition set_carry: ∀p. beval → state p → state p ≝
119 λp,carry,st. mk_state … (st_frms … st) (pc … st) (sp … st) carry (regs … st) (m … st).
120
121definition set_pc: ∀p. address → state p → state p ≝
122 λp,pc,st. mk_state … (st_frms … st) pc (sp … st) (carry … st) (regs … st) (m … st).
123
124definition set_frms: ∀p:sem_params. framesT ? p → state p → state p ≝
125 λp,frms,st. mk_state … frms (pc … st) (sp … st) (carry … st) (regs … st) (m … st).
126
127definition goto: ∀p:sem_params. label → state p → state p ≝
128 λp,l,st. set_pc … (address_of_label p l) st.
129
130definition next: ∀p:sem_params. succ … p → state p → state p ≝
131 λp,l,st. set_pc … (succ_pc … (more_sem_pars p) l (pc … st)) st.
132
133definition greg_store: ∀p:sem_params. generic_reg p → beval → state p → res (state p) ≝
134 λp,dst,v,st.
135  do regs  ← greg_store_ … dst v (regs … st);
136  OK ? (set_regs … regs st).
137
138definition greg_retrieve: ∀p:sem_params. state p → generic_reg p → res beval ≝
139 λp,st,dst.greg_retrieve_ … (regs … st) dst.
140
141definition acca_store: ∀p:sem_params. acc_a_reg p → beval → state p → res (state p) ≝
142 λp,dst,v,st.
143  do regs ← acca_store_ … dst v (regs … st);
144  OK ? (set_regs … regs st).
145
146definition acca_retrieve: ∀p:sem_params. state p → acc_a_reg p → res beval ≝
147 λp,st,dst.acca_retrieve_ … (regs … st) dst.
148
149definition accb_store: ∀p:sem_params. acc_b_reg p → beval → state p → res (state p) ≝
150 λp,dst,v,st.
151  do regs ← accb_store_ … dst v (regs … st);
152  OK ? (set_regs … regs st).
153
154definition accb_retrieve: ∀p:sem_params. state p → acc_b_reg p → res beval ≝
155 λp,st,dst.accb_retrieve_ … (regs … st) dst.
156
157definition dpl_store: ∀p:sem_params. dpl_reg p → beval → state p → res (state p) ≝
158 λp,dst,v,st.
159  do regs ← dpl_store_ … dst v (regs … st);
160  OK ? (set_regs … regs st).
161
162definition dpl_retrieve: ∀p:sem_params. state p → dpl_reg p → res beval ≝
163 λp,st,dst.dpl_retrieve_ … (regs … st) dst.
164
165definition dph_store: ∀p:sem_params. dph_reg p → beval → state p → res (state p) ≝
166 λp,dst,v,st.
167  do regs ← dph_store_ … dst v (regs … st);
168  OK ? (set_regs … regs st).
169
170definition dph_retrieve: ∀p:sem_params. state p → dph_reg p → res beval ≝
171 λp,st,dst.dph_retrieve_ … (regs … st) dst.
172
173definition pair_reg_move: ∀p:sem_params. state p → pair_reg p → res (state p) ≝
174 λp,st,rs.
175  do regs ← pair_reg_move_ … (regs … st) rs;
176  OK … (set_regs … regs st).
177
178axiom FailedStore: String.
179
180definition push: ∀p. state p → beval → res (state p) ≝
181 λp,st,v.
182  let sp ≝ sp … st in
183  do m ← opt_to_res … (msg FailedStore) (bestorev (m … st) sp v);
184  let sp ≝ shift_pointer … sp [[false;false;false;false;false;false;false;true]] in
185  OK … (set_m … m (set_sp … sp st)).
186
187definition pop: ∀p. state p → res (state p × beval) ≝
188 λp,st.
189  let sp ≝ sp ? st in
190  let sp ≝ neg_shift_pointer ? sp [[false;false;false;false;false;false;false;true]] in
191  let st ≝ set_sp … sp st in
192  do v ← opt_to_res ? (msg FailedStore) (beloadv (m ? st) sp);
193  OK ? 〈st,v〉.
194
195definition save_ra : ∀p. state p → address → res (state p) ≝
196 λp,st,l.
197  let 〈addrl,addrh〉 ≝ l in
198  do st ← push … st addrl;
199  push … st addrh.
200
201definition fetch_ra : ∀p.state p → res (state p × address) ≝
202 λp,st.
203  do 〈st,addrh〉 ← pop … st;
204  do 〈st,addrl〉 ← pop … st;
205  OK ? 〈st, 〈addrl,addrh〉〉.
206
207axiom MissingSymbol : String.
208axiom FailedLoad : String.
209axiom BadFunction : String.
210
211definition eval_statement : ∀globals: list ident.∀p:sem_params2 globals. genv globals p → state p → IO io_out io_in (trace × (state p)) ≝
212 λglobals,p,ge,st.
213  ! s ← fetch_statement … ge st;
214  match s with
215    [ GOTO l ⇒ ret ? 〈E0, goto … l st〉
216    | sequential seq l ⇒
217      match seq with
218      [ extension c ⇒ exec_extended … p ge c l st
219      | COST_LABEL cl ⇒ ret ? 〈Echarge cl, next … l st〉
220      | COMMENT c ⇒ ret ? 〈E0, next … l st〉
221      | INT dest v ⇒
222        ! st ← greg_store p dest (BVByte v) st;
223          ret ? 〈E0, next … l st〉
224      | LOAD dst addrl addrh ⇒
225        ! vaddrh ← dph_retrieve … st addrh;
226        ! vaddrl ← dpl_retrieve … st addrl;
227        ! vaddr ← pointer_of_address 〈vaddrl,vaddrh〉;
228        ! v ← opt_to_res … (msg FailedLoad) (beloadv (m … st) vaddr);
229        ! st ← acca_store p … dst v st;
230          ret ? 〈E0, next … l st〉
231      | STORE addrl addrh src ⇒
232        ! vaddrh ← dph_retrieve … st addrh;
233        ! vaddrl ← dpl_retrieve … st addrl;
234        ! vaddr ← pointer_of_address 〈vaddrl,vaddrh〉;
235        ! v ← acca_retrieve … st src;
236        ! m' ← opt_to_res … (msg FailedStore) (bestorev (m … st) vaddr v);
237          ret ? 〈E0, next … l (set_m … m' st)〉
238      | COND src ltrue ⇒
239        ! v ← acca_retrieve … st src;
240        ! b ← bool_of_beval v;
241          ret ? 〈E0, (if b then goto … ltrue else next … l) st〉
242      | ADDRESS ident prf ldest hdest ⇒
243        ! addr ← opt_to_res ? [MSG MissingSymbol; CTX … ident] (find_symbol ?? ge ident);
244        ! 〈laddr,haddr〉 ← address_of_pointer (mk_pointer (block_region addr) addr ? zero_offset);
245        ! st ← dpl_store p ldest laddr st;
246        ! st ← dph_store p hdest haddr st;
247          ret ? 〈E0, next … l st〉
248      | OP1 op dacc_a sacc_a ⇒
249        ! v ← acca_retrieve … st sacc_a;
250        ! v ← Byte_of_val v;
251          let v' ≝ BVByte (op1 eval op v) in
252        ! st ← acca_store p dacc_a v' st;
253          ret ? 〈E0, next … l st〉
254      | OP2 op dacc_a sacc_a src ⇒
255        ! v1 ← acca_retrieve … st sacc_a;
256        ! v1 ← Byte_of_val v1;
257        ! v2 ← greg_retrieve … st src;
258        ! v2 ← Byte_of_val v2;
259        ! carry ← bool_of_beval (carry … st);
260          let 〈v',carry〉 ≝ op2 eval carry op v1 v2 in
261          let v' ≝ BVByte v' in
262          let carry ≝ beval_of_bool carry in
263        ! st ← acca_store p dacc_a v' st;
264          ret ? 〈E0, next … l (set_carry … carry st)〉
265      | CLEAR_CARRY ⇒ ret ? 〈E0, next … l (set_carry … BVfalse st)〉
266      | SET_CARRY ⇒ ret ? 〈E0, next … l (set_carry … BVtrue st)〉
267      | OPACCS op dacc_a_reg dacc_b_reg sacc_a_reg sacc_b_reg ⇒
268        ! v1 ← acca_retrieve … st sacc_a_reg;
269        ! v1 ← Byte_of_val v1;
270        ! v2 ← accb_retrieve … st sacc_b_reg;
271        ! v2 ← Byte_of_val v2;
272          let 〈v1',v2'〉 ≝ opaccs eval op v1 v2 in
273          let v1' ≝ BVByte v1' in
274          let v2' ≝ BVByte v2' in
275        ! st ← acca_store p dacc_a_reg v1' st;
276        ! st ← accb_store p dacc_b_reg v2' st;
277          ret ? 〈E0, next … l st〉
278      | POP dst ⇒
279        ! 〈st,v〉 ← pop … st;
280        ! st ← acca_store p dst v st;
281          ret ? 〈E0, next … l st〉
282      | PUSH src ⇒
283        ! v ← acca_retrieve … st src;
284        ! st ← push … st v;
285          ret ? 〈E0, next … l st〉
286      | MOVE dst_src ⇒
287        ! st ← pair_reg_move … st dst_src ;
288          ret ? 〈E0, next … l st〉
289      | CALL_ID id args dest ⇒
290        ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol ?? ge id);
291        ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr ?? ge b);
292          match fd with
293          [ Internal fn ⇒
294            let l ≝ succ_pc … (more_sem_pars p) l (pc … st) in
295            ! st ← save_frame … l (joint_if_stacksize … fn) (joint_if_params … fn) args dest st ;
296            let regs ≝ init_locals … (joint_if_locals … fn) (regs … st) in
297            let l' ≝ joint_if_entry … fn in
298             ret ? 〈 E0, goto … l' (set_regs p regs st)〉
299          | External fn ⇒
300            ! params ← fetch_external_args … fn st;
301            ! evargs ← check_eventval_list params (sig_args (ef_sig fn));
302            ! evres ← do_io (ef_id fn) evargs (proj_sig_res (ef_sig fn));
303            (* CSC: XXX bug here; I think I should split it into Byte-long
304               components; instead I am making a singleton out of it *)
305              let vs ≝ [mk_val ? evres] in
306            ! st ← set_result … vs st;
307              ret ? 〈Eextcall (ef_id fn) evargs (mk_eventval ? evres), next … l st〉
308          ]]
309    | RETURN ⇒
310      ! 〈st,ra〉 ← pop_frame … st;
311        ret ? 〈E0,set_pc … ra st〉].
312cases addr //
313qed.
314
315definition is_final: ∀globals:list ident. ∀p: sem_params2 globals. genv … p → address → state p → option int ≝
316 λglobals,p,ge,exit,st.res_to_opt ? (
317  do s ← fetch_statement … ge st;
318  match s with
319   [ RETURN ⇒
320      do 〈st,l〉 ← fetch_ra … st;
321      if eq_address l exit then
322       do vals ← fetch_result … st ;
323       Word_of_list_beval vals
324      else
325       Error ? []
326   | _ ⇒ Error ? []]).
327
328record evaluation_parameters : Type[1] ≝
329 { globals: list ident
330 ; sparams2: sem_params2 globals
331 ; exit: address
332 ; genv2: genv globals sparams2
333 }.
334
335definition joint_exec: trans_system io_out io_in ≝
336  mk_trans_system … evaluation_parameters (λG. state (sparams2 G))
337   (λG.is_final (globals G) (sparams2 G) (genv2 G) (exit G))
338   (λG.eval_statement (globals G) (sparams2 G) (genv2 G)).
339
340definition make_global :
341 ∀pars:∀globals.params globals. ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
342  joint_program pars → evaluation_parameters
343
344 λpars,sparams.
345  (λp. mk_evaluation_parameters (prog_var_names … p) (mk_sem_params2 … (sparams p)) ? (globalenv Genv … (λx.[Init_space x]) p)).
346cases daemon (*CSC: XXXXXXXXXXXXX*)
347qed.
348
349definition make_initial_state :
350 ∀pars:∀globals.params globals. ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
351 ∀p: joint_program … pars. res (state (mk_sem_params (pars (prog_var_names … p)) (sparams p))) ≝
352λpars,sparams,p.
353  let ge ≝ genv2 (make_global pars sparams p) in
354  do m ← init_mem Genv … (λx.[Init_space x]) p;
355  let main ≝ prog_main … p in
356  do b ← opt_to_res ? [MSG MissingSymbol; CTX ? main] (find_symbol ? ? ge main);
357  do f ← opt_to_res ? [MSG BadFunction; CTX ? main] (find_funct_ptr ? ? ge b);
358  ?.(* OK ? 〈ge,Callstate f (nil ?) [ ] (nil ?) m〉.*)
359cases daemon qed.
360(*
361RTL:
362 init_prog == init_mem
363 init_sp: inizializzare lo stack pointer
364 init_isp: inizializzare l'altro stack pointer
365 init_renv: inizializzare i registri fisici
366 init_main_call: chiamata di funzione
367   --- init_fun_call: cambia fra ERTL e LTL
368 change_carry: a 0
369*)
370
371definition joint_fullexec :
372 ∀pars:∀globals.params globals.
373 ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
374 fullexec io_out io_in ≝
375 λpars,sparams.
376  mk_fullexec ??? joint_exec (make_global pars sparams) (make_initial_state pars sparams).
Note: See TracBrowser for help on using the repository browser.