source: src/joint/semantics.ma @ 1376

Last change on this file since 1376 was 1376, checked in by sacerdot, 9 years ago

Stack deallocation for RTL implemented in pop_frame.

File size: 16.1 KB
Line 
1include "utilities/lists.ma".
2include "common/Globalenvs.ma".
3include "common/IO.ma".
4include "common/SmallstepExec.ma".
5include "joint/Joint.ma".
6include "joint/BEMem.ma".
7
8(* CSC: external functions never fail (??) and always return something of the
9   size of one register, both in the frontend and in the backend.
10   Is this reasonable??? In OCaml it always return a list, but in the frontend
11   only the head is kept (or Undef if the list is empty) ??? *)
12
13record more_sem_params (p:params_): Type[1] ≝
14 { framesT: Type[0]
15 ; regsT: Type[0]
16
17 ; succ_pc: succ p → address → address
18 ; greg_store_: generic_reg p → beval → regsT → res regsT
19 ; greg_retrieve_: regsT → generic_reg p → res beval
20 ; acca_store_: acc_a_reg p → beval → regsT → res regsT
21 ; acca_retrieve_: regsT → acc_a_reg p → res beval
22 ; accb_store_: acc_b_reg p → beval → regsT → res regsT
23 ; accb_retrieve_: regsT → acc_b_reg p → res beval
24 ; dpl_store_: dpl_reg p → beval → regsT → res regsT
25 ; dpl_retrieve_: regsT → dpl_reg p → res beval
26 ; dph_store_: dph_reg p → beval → regsT → res regsT
27 ; dph_retrieve_: regsT → dph_reg p → res beval
28 ; pair_reg_move_: regsT → pair_reg p → res regsT
29 
30 ; pointer_of_label: label → Σp:pointer. ptype p = Code
31 }.
32
33record sem_params: Type[1] ≝
34 { spp :> params_
35 ; more_sem_pars :> more_sem_params spp
36 }.
37
38record state (p: sem_params): Type[0] ≝
39 { st_frms: framesT ? p
40 ; pc: address
41 ; sp: pointer
42 ; carry: beval
43 ; regs: regsT ? p
44 ; m: bemem
45 }.
46
47record more_sem_params1 (succT: Type[0]) (p:params1): Type[1] ≝
48 { more_sparams :> more_sem_params (mk_params_ p succT)
49
50   (* Functions that manipulate the st_frms component of the state *)
51 ; init_locals : localsT p → regsT … more_sparams → regsT … more_sparams
52 ; pop_frame: list beval → state (mk_sem_params … more_sparams) → res (state (mk_sem_params … more_sparams))
53   (*CSC: save_frame returns a res only because we can call a function with the wrong number and
54     type of arguments. To be fixed using a dependent type *)
55 ; save_frame: nat → paramsT … p → call_args p → call_dest p → state (mk_sem_params … more_sparams) → res (state (mk_sem_params … more_sparams))
56 }.
57
58record sem_params1: Type[1] ≝
59 { spp1 :> params1
60 ; ssucc_ : Type[0]
61 ; more_sem_params1 :> more_sem_params1 ssucc_ spp1
62 }.
63
64definition sem_params_of_sem_params1 ≝ λsp1: sem_params1. mk_sem_params … sp1.
65coercion sem_params_of_sem_params1 : ∀_x:sem_params1. sem_params
66 ≝ sem_params_of_sem_params1 on _x: sem_params1 to sem_params.
67
68definition genv ≝ λglobals.λp:params globals. (genv_t Genv) (joint_function globals p).
69
70record more_sem_params2 (globals: list ident) (p: params globals) : Type[1] ≝
71 { more_sparams1 :> more_sem_params1 (succ p) p
72
73 ; fetch_statement: genv … p → state (mk_sem_params … more_sparams1) → res (joint_statement (mk_sem_params … more_sparams1) globals)
74 ; fetch_result: state (mk_sem_params … more_sparams1) → res (list beval)
75
76 ; fetch_external_args: external_function → state (mk_sem_params … more_sparams1) → res (list val)
77 ; set_result: list val → state (mk_sem_params … more_sparams1) → res (state (mk_sem_params … more_sparams1))
78
79 ; exec_extended: genv globals p → extend_statements (mk_sem_params … more_sparams1) → succ p → state (mk_sem_params … more_sparams1) → IO io_out io_in (trace × (state (mk_sem_params … more_sparams1)))
80 }.
81
82record sem_params2 (globals: list ident): Type[1] ≝
83 { p2:> params globals
84 ; more_sparams2:> more_sem_params2 globals p2
85 }.
86
87definition sem_params_of_sem_params2 ≝ λglobals. λsp2: sem_params2 globals. mk_sem_params sp2 sp2.
88coercion sem_params_of_sem_params2 : ∀globals. ∀_x:sem_params2 globals. sem_params
89 ≝ sem_params_of_sem_params2 on _x: sem_params2 ? to sem_params.
90(*
91unification hint  0 ≔ globals: (list ident), p: sem_params2 globals;
92   S ≟ sem_params_of_sem_params2 globals p
93(* ---------------------------------------- *) ⊢
94   pars_ (spp (mk_sem_params (p2 globals p)
95    (more_sparams (p2 globals p) globals
96    (more_sparams2 globals p)))) ≡ spp__o__pars_ S.
97*)
98definition sem_params1_of_sem_params2 ≝ λglobals. λsp2: sem_params2 globals. mk_sem_params1 sp2 (succ sp2) sp2.
99coercion sem_params1_of_sem_params2 : ∀globals. ∀_x:sem_params2 globals. sem_params1
100 ≝ sem_params1_of_sem_params2 on _x: sem_params2 ? to sem_params1.
101
102definition address_of_label: sem_params → label → address.
103 #p #l generalize in match (refl … (address_of_pointer (pointer_of_label … p l)))
104 cases (address_of_pointer (pointer_of_label … p l)) in ⊢ (???% → ?)
105  [ #res #_ @res
106  | #msg cases (pointer_of_label … p l) * * #q #com #off #E1 #E2 try destruct
107    normalize in E2; destruct ]
108qed.
109
110definition set_m: ∀p. bemem → state p → state p ≝
111 λp,m,st. mk_state p (st_frms … st) (pc … st) (sp … st) (carry … st) (regs … st) m.
112
113definition set_regs: ∀p:sem_params. regsT ? p → state p → state p ≝
114 λp,regs,st. mk_state p (st_frms … st) (pc … st) (sp … st) (carry … st) regs (m … st).
115
116definition set_sp: ∀p. pointer → state p → state p ≝
117 λp,sp,st. mk_state … (st_frms … st) (pc … st) sp (carry … st) (regs … st) (m … st).
118
119definition set_carry: ∀p. beval → state p → state p ≝
120 λp,carry,st. mk_state … (st_frms … st) (pc … st) (sp … st) carry (regs … st) (m … st).
121
122definition set_pc: ∀p. address → state p → state p ≝
123 λp,pc,st. mk_state … (st_frms … st) pc (sp … st) (carry … st) (regs … st) (m … st).
124
125definition set_frms: ∀p:sem_params. framesT ? p → state p → state p ≝
126 λp,frms,st. mk_state … frms (pc … st) (sp … st) (carry … st) (regs … st) (m … st).
127
128definition goto: ∀p:sem_params. label → state p → state p ≝
129 λp,l,st. set_pc … (address_of_label p l) st.
130
131definition next: ∀p:sem_params. succ … p → state p → state p ≝
132 λp,l,st. set_pc … (succ_pc … (more_sem_pars p) l (pc … st)) st.
133
134definition greg_store: ∀p:sem_params. generic_reg p → beval → state p → res (state p) ≝
135 λp,dst,v,st.
136  do regs  ← greg_store_ … dst v (regs … st);
137  OK ? (set_regs … regs st).
138
139definition greg_retrieve: ∀p:sem_params. state p → generic_reg p → res beval ≝
140 λp,st,dst.greg_retrieve_ … (regs … st) dst.
141
142definition acca_store: ∀p:sem_params. acc_a_reg p → beval → state p → res (state p) ≝
143 λp,dst,v,st.
144  do regs ← acca_store_ … dst v (regs … st);
145  OK ? (set_regs … regs st).
146
147definition acca_retrieve: ∀p:sem_params. state p → acc_a_reg p → res beval ≝
148 λp,st,dst.acca_retrieve_ … (regs … st) dst.
149
150definition accb_store: ∀p:sem_params. acc_b_reg p → beval → state p → res (state p) ≝
151 λp,dst,v,st.
152  do regs ← accb_store_ … dst v (regs … st);
153  OK ? (set_regs … regs st).
154
155definition accb_retrieve: ∀p:sem_params. state p → acc_b_reg p → res beval ≝
156 λp,st,dst.accb_retrieve_ … (regs … st) dst.
157
158definition dpl_store: ∀p:sem_params. dpl_reg p → beval → state p → res (state p) ≝
159 λp,dst,v,st.
160  do regs ← dpl_store_ … dst v (regs … st);
161  OK ? (set_regs … regs st).
162
163definition dpl_retrieve: ∀p:sem_params. state p → dpl_reg p → res beval ≝
164 λp,st,dst.dpl_retrieve_ … (regs … st) dst.
165
166definition dph_store: ∀p:sem_params. dph_reg p → beval → state p → res (state p) ≝
167 λp,dst,v,st.
168  do regs ← dph_store_ … dst v (regs … st);
169  OK ? (set_regs … regs st).
170
171definition dph_retrieve: ∀p:sem_params. state p → dph_reg p → res beval ≝
172 λp,st,dst.dph_retrieve_ … (regs … st) dst.
173
174definition pair_reg_move: ∀p:sem_params. state p → pair_reg p → res (state p) ≝
175 λp,st,rs.
176  do regs ← pair_reg_move_ … (regs … st) rs;
177  OK … (set_regs … regs st).
178
179axiom FailedStore: String.
180
181definition push: ∀p. state p → beval → res (state p) ≝
182 λp,st,v.
183  let sp ≝ sp … st in
184  do m ← opt_to_res … (msg FailedStore) (bestorev (m … st) sp v);
185  let sp ≝ shift_pointer … sp [[false;false;false;false;false;false;false;true]] in
186  OK … (set_m … m (set_sp … sp st)).
187
188definition pop: ∀p. state p → res (state p × beval) ≝
189 λp,st.
190  let sp ≝ sp ? st in
191  let sp ≝ neg_shift_pointer ? sp [[false;false;false;false;false;false;false;true]] in
192  let st ≝ set_sp … sp st in
193  do v ← opt_to_res ? (msg FailedStore) (beloadv (m ? st) sp);
194  OK ? 〈st,v〉.
195
196definition save_ra : ∀p. state p → succ p → res (state p) ≝
197 λp,st,l.
198  let 〈addrl,addrh〉 ≝ succ_pc … (more_sem_pars p) l (pc … st) in
199  do st ← push … st addrl;
200  push … st addrh.
201
202definition fetch_ra : ∀p.state p → res (state p × address) ≝
203 λp,st.
204  do 〈st,addrh〉 ← pop … st;
205  do 〈st,addrl〉 ← pop … st;
206  OK ? 〈st, 〈addrl,addrh〉〉.
207
208axiom MissingSymbol : String.
209axiom FailedLoad : String.
210axiom BadFunction : String.
211
212definition eval_statement : ∀globals: list ident.∀p:sem_params2 globals. genv globals p → state p → IO io_out io_in (trace × (state p)) ≝
213 λglobals,p,ge,st.
214  ! s ← fetch_statement … ge st;
215  match s with
216    [ GOTO l ⇒ ret ? 〈E0, goto … l st〉
217    | sequential seq l ⇒
218      match seq with
219      [ extension c ⇒ exec_extended … p ge c l st
220      | COST_LABEL cl ⇒ ret ? 〈Echarge cl, next … l st〉
221      | COMMENT c ⇒ ret ? 〈E0, next … l st〉
222      | INT dest v ⇒
223        ! st ← greg_store p dest (BVByte v) st;
224          ret ? 〈E0, next … l st〉
225      | LOAD dst addrl addrh ⇒
226        ! vaddrh ← dph_retrieve … st addrh;
227        ! vaddrl ← dpl_retrieve … st addrl;
228        ! vaddr ← pointer_of_address 〈vaddrl,vaddrh〉;
229        ! v ← opt_to_res … (msg FailedLoad) (beloadv (m … st) vaddr);
230        ! st ← acca_store p … dst v st;
231          ret ? 〈E0, next … l st〉
232      | STORE addrl addrh src ⇒
233        ! vaddrh ← dph_retrieve … st addrh;
234        ! vaddrl ← dpl_retrieve … st addrl;
235        ! vaddr ← pointer_of_address 〈vaddrl,vaddrh〉;
236        ! v ← acca_retrieve … st src;
237        ! m' ← opt_to_res … (msg FailedStore) (bestorev (m … st) vaddr v);
238          ret ? 〈E0, next … l (set_m … m' st)〉
239      | COND src ltrue ⇒
240        ! v ← acca_retrieve … st src;
241        ! b ← bool_of_beval v;
242          ret ? 〈E0, (if b then goto … ltrue else next … l) st〉
243      | ADDRESS ident prf ldest hdest ⇒
244        ! addr ← opt_to_res ? [MSG MissingSymbol; CTX … ident] (find_symbol ?? ge ident);
245        ! 〈laddr,haddr〉 ← address_of_pointer (mk_pointer (block_region addr) addr ? zero_offset);
246        ! st ← dpl_store p ldest laddr st;
247        ! st ← dph_store p hdest haddr st;
248          ret ? 〈E0, next … l st〉
249      | OP1 op dacc_a sacc_a ⇒
250        ! v ← acca_retrieve … st sacc_a;
251        ! v ← Byte_of_val v;
252          let v' ≝ BVByte (op1 eval op v) in
253        ! st ← acca_store p dacc_a v' st;
254          ret ? 〈E0, next … l st〉
255      | OP2 op dacc_a sacc_a src ⇒
256        ! v1 ← acca_retrieve … st sacc_a;
257        ! v1 ← Byte_of_val v1;
258        ! v2 ← greg_retrieve … st src;
259        ! v2 ← Byte_of_val v2;
260        ! carry ← bool_of_beval (carry … st);
261          let 〈v',carry〉 ≝ op2 eval carry op v1 v2 in
262          let v' ≝ BVByte v' in
263          let carry ≝ beval_of_bool carry in
264        ! st ← acca_store p dacc_a v' st;
265          ret ? 〈E0, next … l (set_carry … carry st)〉
266      | CLEAR_CARRY ⇒ ret ? 〈E0, next … l (set_carry … BVfalse st)〉
267      | SET_CARRY ⇒ ret ? 〈E0, next … l (set_carry … BVtrue st)〉
268      | OPACCS op dacc_a_reg dacc_b_reg sacc_a_reg sacc_b_reg ⇒
269        ! v1 ← acca_retrieve … st sacc_a_reg;
270        ! v1 ← Byte_of_val v1;
271        ! v2 ← accb_retrieve … st sacc_b_reg;
272        ! v2 ← Byte_of_val v2;
273          let 〈v1',v2'〉 ≝ opaccs eval op v1 v2 in
274          let v1' ≝ BVByte v1' in
275          let v2' ≝ BVByte v2' in
276        ! st ← acca_store p dacc_a_reg v1' st;
277        ! st ← accb_store p dacc_b_reg v2' st;
278          ret ? 〈E0, next … l st〉
279      | POP dst ⇒
280        ! 〈st,v〉 ← pop … st;
281        ! st ← acca_store p dst v st;
282          ret ? 〈E0, next … l st〉
283      | PUSH src ⇒
284        ! v ← acca_retrieve … st src;
285        ! st ← push … st v;
286          ret ? 〈E0, next … l st〉
287      | MOVE dst_src ⇒
288        ! st ← pair_reg_move … st dst_src ;
289          ret ? 〈E0, next … l st〉
290      | CALL_ID id args dest ⇒
291        ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol ?? ge id);
292        ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr ?? ge b);
293          match fd with
294          [ Internal fn ⇒
295            ! st ← save_ra … st l;
296            ! st ← save_frame … (joint_if_stacksize … fn) (joint_if_params … fn) args dest st ;
297            let regs ≝ init_locals … (joint_if_locals … fn) (regs … st) in
298            let l' ≝ joint_if_entry … fn in
299             ret ? 〈 E0, goto … l' (set_regs p regs st)〉
300          | External fn ⇒
301            ! params ← fetch_external_args … fn st;
302            ! evargs ← check_eventval_list params (sig_args (ef_sig fn));
303            ! evres ← do_io (ef_id fn) evargs (proj_sig_res (ef_sig fn));
304            (* CSC: XXX bug here; I think I should split it into Byte-long
305               components; instead I am making a singleton out of it *)
306              let vs ≝ [mk_val ? evres] in
307            ! st ← set_result … vs st;
308              ret ? 〈Eextcall (ef_id fn) evargs (mk_eventval ? evres), next … l st〉
309          ]]
310    | RETURN ⇒
311      ! res ← fetch_result … st;
312      ! st ← pop_frame … res st;
313      ! 〈st,pch〉 ← pop … st;
314      ! 〈st,pcl〉 ← pop … st;
315        ret ? 〈E0,set_pc … 〈pcl,pch〉 st〉].
316cases addr //
317qed.
318
319definition is_final: ∀globals:list ident. ∀p: sem_params2 globals. genv … p → address → state p → option int ≝
320 λglobals,p,ge,exit,st.res_to_opt ? (
321  do s ← fetch_statement … ge st;
322  match s with
323   [ RETURN ⇒
324      do 〈st,l〉 ← fetch_ra … st;
325      if eq_address l exit then
326       do vals ← fetch_result … st ;
327       Word_of_list_beval vals
328      else
329       Error ? []
330   | _ ⇒ Error ? []]).
331
332record evaluation_parameters : Type[1] ≝
333 { globals: list ident
334 ; sparams2: sem_params2 globals
335 ; exit: address
336 ; genv2: genv globals sparams2
337 }.
338
339definition joint_exec: trans_system io_out io_in ≝
340  mk_trans_system … evaluation_parameters (λG. state (sparams2 G))
341   (λG.is_final (globals G) (sparams2 G) (genv2 G) (exit G))
342   (λG.eval_statement (globals G) (sparams2 G) (genv2 G)).
343
344definition make_global :
345 ∀pars:∀globals.params globals. ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
346  joint_program pars → evaluation_parameters
347
348 λpars,sparams.
349  (λp. mk_evaluation_parameters (prog_var_names … p) (mk_sem_params2 … (sparams p)) ? (globalenv Genv … (λx.[Init_space x]) p)).
350cases daemon (*CSC: XXXXXXXXXXXXX*)
351qed.
352
353definition make_initial_state :
354 ∀pars:∀globals.params globals. ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
355 ∀p: joint_program … pars. res (state (mk_sem_params (pars (prog_var_names … p)) (sparams p))) ≝
356λpars,sparams,p.
357  let ge ≝ genv2 (make_global pars sparams p) in
358  do m ← init_mem Genv … (λx.[Init_space x]) p;
359  let main ≝ prog_main … p in
360  do b ← opt_to_res ? [MSG MissingSymbol; CTX ? main] (find_symbol ? ? ge main);
361  do f ← opt_to_res ? [MSG BadFunction; CTX ? main] (find_funct_ptr ? ? ge b);
362  ?.(* OK ? 〈ge,Callstate f (nil ?) [ ] (nil ?) m〉.*)
363cases daemon qed.
364(*
365RTL:
366 init_prog == init_mem
367 init_sp: inizializzare lo stack pointer
368 init_isp: inizializzare l'altro stack pointer
369 init_renv: inizializzare i registri fisici
370 init_main_call: chiamata di funzione
371   --- init_fun_call: cambia fra ERTL e LTL
372 change_carry: a 0
373*)
374
375definition joint_fullexec :
376 ∀pars:∀globals.params globals.
377 ∀sparams:∀p: joint_program pars. more_sem_params2 … (pars (prog_var_names … p)).
378 fullexec io_out io_in ≝
379 λpars,sparams.
380  mk_fullexec ??? joint_exec (make_global pars sparams) (make_initial_state pars sparams).
Note: See TracBrowser for help on using the repository browser.