source: src/joint/joint_printer.ma @ 2853

Last change on this file since 2853 was 2853, checked in by sacerdot, 7 years ago

Pretty printing of line/label numbers.

File size: 9.0 KB
Line 
1(**************************************************************************)
2(*       ___                                                              *)
3(*      ||M||                                                             *)
4(*      ||A||       A project by Andrea Asperti                           *)
5(*      ||T||                                                             *)
6(*      ||I||       Developers:                                           *)
7(*      ||T||         The HELM team.                                      *)
8(*      ||A||         http://helm.cs.unibo.it                             *)
9(*      \   /                                                             *)
10(*       \ /        This file is distributed under the terms of the       *)
11(*        v         GNU General Public License Version 2                  *)
12(*                                                                        *)
13(**************************************************************************)
14
15include "joint/Joint.ma".
16
17inductive keyword : Type[0] ≝
18  | kwCOMMENT: keyword
19  | kwMOVE: keyword
20  | kwPOP: keyword
21  | kwPUSH: keyword
22  | kwADDRESS: keyword
23  | kwOPACCS: keyword
24  | kwOP1: keyword
25  | kwOP2: keyword
26  | kwCLEAR_CARRY: keyword
27  | kwSET_CARRY: keyword
28  | kwLOAD: keyword
29  | kwSTORE: keyword
30  | kwCOST_LABEL: keyword
31  | kwCOND: keyword
32  | kwCALL: keyword
33  | kwGOTO: keyword
34  | kwRETURN: keyword
35  | kwTAILCALL: keyword
36  | kwFCOND: keyword.
37
38record printing_pass_independent_params (string: Type[0]) : Type[0] ≝
39 { print_String: String → string
40 ; print_keyword: keyword → string
41 ; print_concat: string → string → string
42 ; print_newline: string
43 ; print_empty: string
44 ; print_ident: ident → string
45 ; print_costlabel: costlabel → string
46 ; print_label: label → string
47 ; print_OpAccs: OpAccs → string
48 ; print_Op1: Op1 → string
49 ; print_Op2: Op2 → string }.
50
51record printing_params (string: Type[0]) (P: unserialized_params) : Type[0] ≝
52 { print_pass_ind:> printing_pass_independent_params string
53 ; print_acc_a_reg: acc_a_reg P → string
54 ; print_acc_b_reg: acc_b_reg P → string
55 ; print_acc_a_arg: acc_a_arg P → string
56 ; print_acc_b_arg: acc_b_arg P → string
57 ; print_dpl_reg: dpl_reg P → string   (* low address registers *)
58 ; print_dph_reg: dph_reg P → string   (* high address registers *)
59 ; print_dpl_arg: dpl_arg P → string   (* low address registers *)
60 ; print_dph_arg: dph_arg P → string   (* high address registers *)
61 ; print_snd_arg : snd_arg P → string  (* second argument of binary op *)
62 ; print_pair_move: pair_move P → string (* argument of move instructions *)
63 ; print_call_args: call_args P → string (* arguments of function calls *)
64 ; print_call_dest: call_dest P → string (* possible destination of function computation *)
65 (* other instructions not fitting in the general framework *)
66 ; print_ext_seq : ext_seq P → string
67 }.
68
69record code_iteration_params (string: Type[0]) (p:params) (globals) : Type[1] ≝
70 { fold_code:
71    ∀A:Type[0].
72     (code_point p → joint_statement p globals → A → A) →
73      codeT p globals → A → A
74 ; print_succ: succ … p → string
75 ; print_code_point: code_point p → string
76 }.
77
78definition graph_code_iteration_params:
79 ∀string,graph_params,globals.
80  printing_params string (graph_params_to_params graph_params) →
81   code_iteration_params string (graph_params_to_params graph_params) globals ≝
82 λstring,gp,globals,pp.
83  mk_code_iteration_params ???
84   (λA.λf:code_point (graph_params_to_params …) → ?.
85     graph_fold … (λn. f (an_identifier … n)) …)
86   (print_label … pp) (print_label … pp).
87
88definition print_list:
89 ∀string. printing_pass_independent_params string → list string → string ≝
90 λstring,pp.
91  foldr ?? (print_concat … pp) (print_empty … pp). 
92
93definition print_joint_seq :
94 ∀p. ∀globals. ∀string. printing_params string p → joint_seq p globals → string ≝
95 λp,globals,string,pp,seq.
96  match seq with
97  [ COMMENT str ⇒
98     print_list … pp [print_keyword … pp kwCOMMENT; print_String … pp str]
99  | MOVE pm ⇒
100     print_list … pp [print_keyword … pp kwMOVE; print_pair_move … pp pm]
101  | POP arg ⇒
102     print_list … pp [print_keyword … pp kwPOP; print_acc_a_reg … pp arg]
103  | PUSH arg ⇒
104     print_list … pp [print_keyword … pp kwPUSH; print_acc_a_arg … pp arg]
105  | ADDRESS i Hi arg1 arg2 ⇒
106     print_list … pp
107      [print_keyword … pp kwADDRESS;
108       print_ident … pp i;
109       print_dpl_reg … pp arg1;
110       print_dph_reg … pp arg2]
111  | OPACCS opa arg1 arg2 arg3 arg4 ⇒
112     print_list … pp
113      [print_keyword … pp kwOPACCS;
114       print_OpAccs … pp opa;
115       print_acc_a_reg … pp arg1;
116       print_acc_b_reg … pp arg2;
117       print_acc_a_arg … pp arg3;
118       print_acc_b_arg … pp arg4]
119  | OP1 op1 arg1 arg2 ⇒
120     print_list … pp
121      [print_keyword … pp kwOP1;
122       print_Op1 … pp op1;
123       print_acc_a_reg … pp arg1;
124       print_acc_a_reg … pp arg2]
125  | OP2 op2 arg1 arg2 arg3 ⇒
126     print_list … pp
127      [print_keyword … pp kwOP2;
128       print_Op2 … pp op2;
129       print_acc_a_reg … pp arg1;
130       print_acc_a_arg … pp arg2;
131       print_snd_arg … pp arg3]
132  (* int done with generic move *)
133  | CLEAR_CARRY ⇒ print_keyword … pp kwCLEAR_CARRY
134  | SET_CARRY ⇒ print_keyword … pp kwSET_CARRY
135  | LOAD arg1 arg2 arg3 ⇒
136     print_list … pp
137      [print_keyword … pp kwLOAD;
138       print_acc_a_reg … pp arg1;
139       print_dpl_arg … pp arg2;
140       print_dph_arg … pp arg3]
141  | STORE arg1 arg2 arg3 ⇒
142     print_list … pp
143      [print_keyword … pp kwSTORE;
144       print_dpl_arg … pp arg1;
145       print_dph_arg … pp arg2;
146       print_acc_a_arg … pp arg3]
147  | extension_seq ext ⇒ print_ext_seq … pp ext].
148
149definition print_joint_step:
150 ∀p,globals. ∀string. printing_params string p → joint_step p globals → string ≝
151 λp,globals,string,pp,step.
152  match step with
153   [ COST_LABEL arg ⇒
154      print_list ? pp
155       [print_keyword … pp kwCOST_LABEL;
156        print_costlabel … pp arg]
157   | CALL arg1 arg2 arg3 ⇒
158      print_list … pp
159       [print_keyword … pp kwCALL;
160        match arg1 with
161        [ inl id ⇒ print_ident … pp id
162        | inr arg11_arg12 ⇒
163           print_concat … pp
164            (print_dpl_arg … pp (\fst arg11_arg12))
165            (print_dph_arg … pp (\snd arg11_arg12))];
166        print_call_args … pp arg2;
167        print_call_dest … pp arg3]
168   | COND arg1 arg2 ⇒
169      print_list … pp
170       [print_keyword … pp kwCOND;
171        print_acc_a_reg … pp arg1;
172        print_label … pp arg2]
173   | step_seq seq ⇒ print_joint_seq … pp seq ].
174
175definition print_joint_fin_step:
176 ∀p. ∀string. printing_params string p → joint_fin_step p → string ≝
177 λp,string,pp,fin.
178  match fin with
179   [ GOTO l ⇒
180      print_list ? pp
181       [ print_keyword … pp kwGOTO;
182         print_label … pp l]
183   | RETURN ⇒ print_keyword … pp kwRETURN
184   | TAILCALL has arg1 arg2 ⇒
185      print_list … pp
186       [print_keyword … pp kwTAILCALL;
187        match arg1 with
188        [ inl id ⇒ print_ident … pp id
189        | inr arg11_arg12 ⇒
190           print_concat … pp
191            (print_dpl_arg … pp (\fst arg11_arg12))
192            (print_dph_arg … pp (\snd arg11_arg12))];
193        print_call_args … pp arg2]].
194
195definition print_joint_statement:
196 ∀p:params.∀globals. ∀string. printing_params string p →
197  code_iteration_params string p globals → joint_statement p globals → string ≝
198 λp,globals,string,pp,cip,stmt.
199  match stmt with
200  [ sequential js arg1 ⇒
201     print_concat … pp (print_joint_step … pp js) (print_succ … cip arg1)
202  | final fin ⇒ print_joint_fin_step … pp fin
203  | FCOND has arg1 arg2 arg3 ⇒
204     print_list ? pp
205      [ print_keyword … pp kwFCOND;
206        print_acc_a_reg … pp arg1;
207        print_label … pp arg2;
208        print_label … pp arg3 ]].
209
210definition print_joint_internal_function:
211 ∀p:params. ∀globals. ∀string. code_iteration_params string p globals →
212  printing_params string p → joint_internal_function p globals → string
213≝ λp,globals,string,cip,pp,f.
214   fold_code … cip …
215    (λcp.λstmt.λacc.
216      print_list … pp
217       [ print_code_point … cip cp;
218         print_joint_statement … pp cip stmt;
219         print_newline … pp;
220         acc])
221    (joint_if_code … f) (print_empty … pp).
222
223definition print_joint_function:
224 ∀p:params. ∀globals. ∀string. code_iteration_params string p globals → printing_params string p →
225  joint_function p globals → string ≝
226 λp,globals,string,cip,pp,f.
227  match f with
228  [ Internal f ⇒ print_joint_internal_function … cip … pp f
229  | External f ⇒ print_empty … pp ].
230
231definition print_joint_program:
232 ∀p:params. ∀string.
233  printing_params string p →
234  ∀prog:joint_program p.
235   code_iteration_params string p (map … (λx. \fst (\fst x)) (prog_vars ?? prog)) → string ≝
236 λp,string,pp,prog,cip.
237  foldr ?? (λf. print_concat … pp (print_joint_function … cip … pp (\snd f)))
238   (print_empty … pp) (prog_funct … prog).
Note: See TracBrowser for help on using the repository browser.