source: src/joint/Traces.ma @ 2601

include "joint/joint_semantics.ma".
include "common/StructuredTraces.ma".

record evaluation_params : Type[1] ≝
 { globals: list ident
 ; sparams:> sem_params
 ; ev_genv: genv sparams globals
(* ; io_env : state sparams → ∀o:io_out.res (io_in o) *)
 }.
 


record prog_params : Type[1] ≝
 { prog_spars : sem_params
 ; prog : joint_program prog_spars
 ; stack_sizes : ident → option ℕ
(* ; prog_io : state prog_spars → ∀o.res (io_in o) *)
 }.

lemma map_Exists : ∀A,B,f,P,l.Exists B P (map A B f l) → Exists ? (λx.P (f x)) l.
#A #B #f #P #l elim l -l [*]
#hd #tl #IH *
[ #Phd %1{Phd}
| #Ptl %2{(IH Ptl)}
]
qed.

lemma Exists_In : ∀A,P,l.Exists A P l → ∃x.In A l x ∧ P x.
#A #P #l elim l -l [*] #hd #tl #IH *
[ #Phd %{hd} %{Phd} %1 %
| #Ptl elim (IH Ptl) #x * #H1 #H2 %{x} %{H2} %2{H1}
]
qed.

lemma In_Exists : ∀A,P,l,x.In A l x → P x → Exists A P l.
#A #P #l elim l -l [ #x *] #hd #tl #IH #x *
[ #EQ >EQ #H %1{H}
| #Intl #Px %2{(IH … Intl Px)}
]
qed.

lemma Exists_mp : ∀A,P,Q,l.(∀x.P x → Q x) → Exists A P l → Exists A Q l.
#A #P #Q #l #H elim l -l [*] #hd #tl #IH * #G [ %1 | %2 ] /2/ qed. 

definition make_global : prog_params → evaluation_params
≝
λpars.
let p ≝ prog pars in
let spars ≝ prog_spars pars in
let genv ≝ globalenv_noinit ? p in
let get_pc_lbl ≝ λid,lbl.
  ! bl ← block_of_funct_id … spars genv id ;
  pc_of_label … genv bl lbl in
mk_evaluation_params
  (prog_var_names … p)
  spars
  (mk_genv_gen ?? genv ? (stack_sizes pars) get_pc_lbl)
 (* (prog_io pars) *).
#s #H
elim (find_symbol_exists … p s ?)
[ #bl #EQ >EQ % #ABS destruct(ABS)|*:]
@Exists_append_r
@(Exists_mp … H) //
qed.

coercion prog_params_to_ev_params : ∀p : prog_params.evaluation_params
≝ make_global on _p : prog_params to evaluation_params.

axiom BadMain : String.

definition make_initial_state :
 ∀pars: prog_params.res (state_pc pars) ≝
λpars.let p ≝ prog pars in
  let sem_globals : evaluation_params ≝ pars in
  let ge ≝ ev_genv sem_globals in
  let m ≝ alloc_mem … p in
  let 〈m,spb〉 ≝ alloc … m 0 external_ram_size XData in
  let spp : xpointer ≝
    «mk_pointer spb (mk_offset (bitvector_of_Z ? external_ram_size)),
     pi2 … spb» in
(*  let ispp : xpointer ≝ mk_pointer ispb (mk_offset (bitvector_of_nat ? 47)) in *)
  let main ≝ prog_main … p in
  let st0 ≝ mk_state pars (empty_framesT …) empty_is (BBbit false) (empty_regsT … spp) m in
  (* use exit_pc as ra and call_dest_for_main as dest *)
  let st0' ≝ mk_state_pc … (set_sp … spp st0) exit_pc exit_pc in
  ! st0_no_pc ← save_frame ?? sem_globals ID (call_dest_for_main … pars) (prog_main … p) st0' ;
  let st0'' ≝ set_no_pc … st0_no_pc st0' in
  ! bl ← block_of_call … ge (inl … main) st0'';
  ! 〈i, fn〉 ← fetch_function … ge bl ;
  match fn with
  [ Internal ifn ⇒
    ! st' ← eval_internal_call … ge i ifn (call_args_for_main … pars) st0'' ;
    let pc' ≝ pc_of_point … bl (joint_if_entry … ifn) in
    return mk_state_pc … st' pc' exit_pc
  | External _ ⇒ Error … [MSG BadMain; CTX ? main] (* External main not supported: why? *)
  ].

definition joint_classify_step :
  ∀p : evaluation_params.state p → joint_step p (globals … p) → status_class ≝
  λp,st,stmt.
  match stmt with
  [ step_seq _ ⇒ cl_other
  | CALL f args dest ⇒
    match (! bl ← block_of_call … (ev_genv p) f st ;
            fetch_function … (ev_genv p) bl) with
    [ OK id_fn ⇒
      match \snd id_fn with
      [ Internal _ ⇒ cl_call
      | External _ ⇒ cl_other
      ]
    | Error _ ⇒ cl_other
    ]
  | COND _ _ ⇒ cl_jump
  ].

definition joint_classify_final :
  ∀p : evaluation_params.state p → joint_fin_step p → status_class ≝
  λp,st,stmt.
  match stmt with
  [ GOTO _ ⇒ cl_other
  | RETURN ⇒ cl_return
  | TAILCALL _ f args ⇒
    match (! bl ← block_of_call … (ev_genv p) f st ;
            fetch_function … (ev_genv p) bl) with
    [ OK id_fn ⇒
      match \snd id_fn with
      [ Internal _ ⇒ cl_tailcall
      | External _ ⇒ cl_return
      ]
    | Error _ ⇒ cl_other
    ]
  ].

definition joint_classify :
  ∀p : evaluation_params.state_pc p → option status_class ≝
  λp,st.
  ! 〈i,f,s〉 ← res_to_opt … (fetch_statement … (ev_genv p) (pc … st)) ;
  match s with
  [ sequential s _ ⇒ Some ? (joint_classify_step p st s)
  | final s ⇒ Some ? (joint_classify_final p st s)
  | FCOND _ _ _ _ ⇒ Some ? cl_jump
  ].

definition no_cost_label : ∀p,g.joint_seq p g → Prop ≝
  λp,g,s.match s with
  [ COST_LABEL _ ⇒ False
  | _ ⇒ True
  ].

lemma joint_classify_call : ∀p : evaluation_params.∀st.
  joint_classify p st = Some ? cl_call →
  ∃i_f,f',args,dest,next,bl,i',fd'.
  fetch_statement … (ev_genv p) (pc … st) =
    OK ? 〈i_f, sequential … (CALL … f' args dest) next〉 ∧
  block_of_call … (ev_genv p) f' st = OK ? bl ∧
  fetch_internal_function … (ev_genv p) bl = OK ? 〈i', fd'〉.
#p #st
whd in match joint_classify; normalize nodelta
inversion (fetch_statement … (ev_genv p) (pc … st))
[2: #e #_ whd in ⊢ (??%?→?); #ABS destruct(ABS) ]
* #i_f * [2,3: [ * [ #lbl | | #fl #f #args ] | #fl #a #ltrue #lfalse ] #_
>m_return_bind normalize nodelta
  [3: whd in match joint_classify_final; normalize nodelta
    generalize in ⊢ (??(?? (match % with [ _ ⇒ ? | _ ⇒ ?]))?→?); * [* #i' * #fd | #e ]
    normalize nodelta ]
  #ABS destruct(ABS) ]
* [ #f' #args #dest | #a #lbl | #s ] #nxt #fetch >m_return_bind
normalize nodelta
[2,3: normalize in ⊢ (%→?); #ABS destruct(ABS) ]
whd in match joint_classify_step;
normalize nodelta
inversion (block_of_call ?????)
[ #bl #block_of_c  >m_return_bind
  inversion (fetch_function ???)
  [ * #i' *
    [ #fd' #fetch' #_
      %{i_f} %{f'} %{args} %{dest} %{nxt} %{bl} %{i'} %{fd'}
      % [ %{block_of_c} % ]
      whd in match fetch_internal_function; normalize nodelta
      >fetch' %
    ]
  ]
]
#x #_ normalize in ⊢ (%→?); #ABS destruct(ABS)
qed.

definition joint_after_ret : ∀p:evaluation_params.
  (Σs : state_pc p.joint_classify p s = Some ? cl_call) → state_pc p → Prop ≝
λp,s1,s2.
match fetch_statement … (ev_genv p) (pc … s1) with
[ OK x ⇒
  match \snd x with
  [ sequential s next ⇒
    last_pop … s2 = pc … s1 ∧
    pc … s2 = succ_pc p (pc … s1) next
  | _ ⇒ False (* never happens *)
  ]
| _ ⇒ False (* never happens *)
].

definition joint_call_ident : ∀p:evaluation_params.
  (Σs : state_pc p.joint_classify p s = Some ? cl_call) → ident ≝
(* this is a definition without a dummy ident :
λp,st.
match ?
return λx.
  !〈f, s〉 ← fetch_statement ? p … (ev_genv p) (pc … st) ;
  match s with
  [ sequential s next ⇒
    match s with
    [ step_seq s ⇒
      match s with
      [ CALL f' args dest ⇒
        function_of_call … (ev_genv p) st f'
      | _ ⇒ Error … [ ]
      ]
    | _ ⇒ Error … [ ]
    ]
  | _ ⇒ Error … [ ]
  ] = x → ? with
[ OK v ⇒ λ_.v
| Error e ⇒ λABS.⊥
] (refl …).
@hide_prf
elim (joint_classify_call … (pi2 … st))
#f *#f' *#args *#dest *#next *#fn *#fd ** #EQ1 #EQ2 #EQ3
lapply ABS -ABS
>EQ1 >m_return_bind normalize nodelta >EQ2 #ABS destruct(ABS)
qed. *)
(* with a dummy ident (which is never used as seen above in the commented script)
   I think handling of the function is easier *)
λp,st.
let dummy : ident ≝ an_identifier ? one in (* used where it cannot ever happen *)
match fetch_statement … (ev_genv p) (pc … st) with
[ OK x ⇒
  match \snd x with
  [ sequential s next ⇒
    match s with
    [ step_seq s ⇒
      match s with
      [ CALL f' args dest ⇒
        match
          (! bl ← block_of_call … (ev_genv p) f' st;
           fetch_internal_function … (ev_genv p) bl) with
        [ OK i_f ⇒ \fst i_f
        | _ ⇒ dummy
        ]
      | _ ⇒ dummy
      ]
    | _ ⇒ dummy
    ]
  | _ ⇒ dummy
  ]
| _ ⇒ dummy
].

definition joint_tailcall_ident : ∀p:evaluation_params.
  (Σs : state_pc p.joint_classify p s = Some ? cl_tailcall) → ident ≝
λp,st.
let dummy : ident ≝ an_identifier ? one in (* used where it cannot ever happen *)
match fetch_statement … (ev_genv p) (pc … st) with
[ OK x ⇒
  match \snd x with
  [ final s ⇒
    match s with
    [ TAILCALL _ f' args ⇒
      match
        (! bl ← block_of_call … (ev_genv p) f' st;
         fetch_internal_function … (ev_genv p) bl) with
      [ OK i_f ⇒ \fst i_f
      | _ ⇒ dummy
      ]
    | _ ⇒ dummy
    ]
  | _ ⇒ dummy
  ]
| _ ⇒ dummy
].

definition pcDeq ≝ mk_DeqSet program_counter eq_program_counter ?.
*#p1 #EQ1 * #p2 #EQ2 @eq_program_counter_elim
[ #EQ destruct % #H %
| * #NEQ % #ABS destruct elim (NEQ ?) %
]
qed.

(*
let rec io_evaluate O I X (env : ∀o.res (I o)) (c : IO O I X) on c : res X ≝
  match c with
  [ Value x ⇒ OK … x
  | Interact o f ⇒
    ! i ← env o ;
    io_evaluate O I X env (f i)
  | Wrong e ⇒ Error … e
  ].
*)

definition cost_label_of_stmt :
  ∀p : evaluation_params.joint_statement p (globals p) → option costlabel ≝
  λp,s.match s with
  [ sequential s _ ⇒
    match s with
    [ step_seq s ⇒
      match s with
      [ COST_LABEL lbl ⇒ Some ? lbl
      | _ ⇒ None ?
      ]
    | _ ⇒ None ?
    ]
  | _ ⇒ None ?
  ].


lemma no_label_uncosted : ∀p : evaluation_params.∀s,nxt.
no_cost_label p (globals p) s →
cost_label_of_stmt … (sequential … s nxt) = None ?.
#p * // #lbl #next *
qed.

definition joint_abstract_status :
 ∀p : evaluation_params.
 abstract_status ≝
 λp.
 mk_abstract_status
   (* as_status ≝ *) (state_pc p)
   (* as_execute ≝ *)
    (λs1,s2.(* io_evaluate … (io_env p s1) *) (eval_state … (ev_genv p) s1) = return s2)
   (* as_pc ≝ *) pcDeq
   (* as_pc_of ≝ *) (pc …)
   (* as_classify ≝ *) (joint_classify p)
   (* as_label_of_pc ≝ *)
    (λpc.
      match fetch_statement … (ev_genv p) pc with
      [ OK fn_stmt ⇒ cost_label_of_stmt … (\snd fn_stmt)
      | _ ⇒ None ?
      ])
   (* as_after_return ≝ *) (joint_after_ret p)
   (* as_final ≝ *) (λs.is_final p  (globals ?) (ev_genv p) exit_pc s ≠ None ?)
   (* as_call_ident ≝ *) (joint_call_ident p)
   (* as_tailcall_ident ≝ *) (joint_tailcall_ident p).