source: src/joint/StatusSimulationHelper.ma @ 3003

(**************************************************************************)
(*       ___                                                              *)
(*      ||M||                                                             *)
(*      ||A||       A project by Andrea Asperti                           *)
(*      ||T||                                                             *)
(*      ||I||       Developers:                                           *)
(*      ||T||         The HELM team.                                      *)
(*      ||A||         http://helm.cs.unibo.it                             *)
(*      \   /                                                             *)
(*       \ /        This file is distributed under the terms of the       *)
(*        v         GNU General Public License Version 2                  *)
(*                                                                        *)
(**************************************************************************)

include "joint/semanticsUtils.ma".
include "joint/Traces.ma".
include "common/StatusSimulation.ma".
include "joint/semantics_blocks.ma".

lemma set_no_pc_eta:
 ∀P.∀st1: state_pc P. set_no_pc P st1 st1 = st1.
#P * //
qed.

lemma pc_of_label_eq :
  ∀pars: sem_graph_params.
  ∀globals,ge,bl,i_fn,lbl.
  fetch_internal_function ? globals ge bl = return i_fn →
  pc_of_label pars globals ge bl lbl =
    OK ? (pc_of_point pars bl lbl). 
#p #globals #ge #bl #i_fn #lbl #EQf 
whd in match pc_of_label;
normalize nodelta >EQf >m_return_bind %
qed.


lemma bind_new_bind_new_instantiates : 
∀B,X : Type[0]. ∀ m : bind_new B X. ∀ x : X. ∀l : list B.∀P.
bind_new_instantiates B X x m l → bind_new_P' ?? P m → 
P l x.
#B #X #m elim m normalize nodelta
[#x #y * normalize // #B #l' #P *
| #f #IH #x #l elim l normalize [#P *] #hd #tl normalize #_ #P #H #Hr @(IH … H)
 @Hr
]
qed.

let rec bind_instantiates B X (b : bind_new B X) (l : list B) on b : (option X) ≝
  match b with
  [ bret B ⇒
    match l with
    [ nil ⇒ Some ? B
    | _ ⇒ None ?
    ]
  | bnew f ⇒
    match l with
    [ nil ⇒ None ?
    | cons r l' ⇒
      bind_instantiates B X (f r) l'
    ]
  ].
  
lemma bind_instantiates_bind_new_instantiates : ∀B,X.∀b : bind_new B X.
∀l : list B.∀x : X.
bind_instantiates B X b l = Some ? x → 
bind_new_instantiates B X x b l. 
#B #X #b elim b 
[#x1 * [2: #hd #tl] #x whd in ⊢ (??%? → ?); #EQ destruct(EQ) %
|#f #IH * [2: #hd #tl] #x whd in ⊢ (??%? → ?); [2: #EQ destruct(EQ)] #H
 whd @IH assumption
]
qed.

lemma bind_new_instantiates_bind_instantiates : ∀B,X.∀b : bind_new B X.
∀l : list B.∀x : X.
bind_new_instantiates B X x b l → 
bind_instantiates B X b l = Some ? x.
#B #X #b elim b
[ #x1 * [2: #hd #tl] #x whd in ⊢ (% → ?); [*] #EQ destruct(EQ) %
| #f #IH * [2: #hd #tl] #x whd in ⊢ (% → ?); [2: *] #H whd in ⊢ (??%?); @IH @H
]
qed.


definition joint_state_relation ≝ 
λP_in,P_out.program_counter → state P_in → state P_out → Prop.

definition joint_state_pc_relation ≝ λP_in,P_out.state_pc P_in → state_pc P_out → Prop.

definition lbl_funct_type ≝  block → label → (list label).
definition regs_funct_type ≝ block → label → (list register).

definition preamble_length ≝ 
λP_in : sem_graph_params.λP_out : sem_graph_params.λprog : joint_program P_in.
λstack_size : (ident → option ℕ).
λinit : ∀globals.joint_closed_internal_function P_in globals
         →bound_b_graph_translate_data P_in P_out globals.
λinit_regs : block → list register.
λf_regs : regs_funct_type.λbl : block.λlbl : label.
! bl ← code_block_of_block bl ;
! 〈id,fn〉 ← res_to_opt … (fetch_internal_function … (prog_var_names … prog) 
                           (joint_globalenv P_in prog stack_size) bl);
! stmt ← stmt_at P_in (prog_var_names … prog) (joint_if_code … fn) lbl;
! data ← bind_instantiates ?? (init … fn) (init_regs bl);
match stmt with
[ sequential step nxt ⇒ 
    ! step_block ← bind_instantiates ?? (f_step … data lbl step) (f_regs bl lbl);
    return |\fst (\fst step_block)|
| final fin ⇒ 
    ! fin_block ← bind_instantiates ?? (f_fin … data lbl fin) (f_regs bl lbl);
    return |\fst fin_block|
| FCOND abs _ _ _ ⇒ Ⓧabs
]. 


definition sigma_label : ∀p_in,p_out : sem_graph_params.
joint_program p_in → (ident → option ℕ) → 
(∀globals.joint_closed_internal_function p_in globals
         →bound_b_graph_translate_data p_in p_out globals) → 
(block → list register) → lbl_funct_type → regs_funct_type → 
block → label → option label ≝ 
λp_in,p_out,prog,stack_size,init,init_regs,f_lbls,f_regs,bl,searched.
! bl ← code_block_of_block bl ;
! 〈id,fn〉 ← res_to_opt … (fetch_internal_function … (prog_var_names … prog) 
                           (joint_globalenv p_in prog stack_size) bl);
! 〈res,s〉 ← 
 find ?? (joint_if_code ?? fn)
  (λlbl.λ_.match preamble_length … prog stack_size init init_regs f_regs bl lbl with
             [ None ⇒ false
             | Some n ⇒ match nth_opt ? n (lbl::(f_lbls bl lbl)) with
                         [ None ⇒ false
                         | Some x ⇒ eq_identifier … searched x
                         ]
             ]);
return res.

lemma partial_inj_sigma : 
∀p_in,p_out,prog,stack_size,init,init_regs.
∀f_lbls : lbl_funct_type.∀f_regs,bl,lbl1,lbl2. 
sigma_label p_in p_out prog stack_size init init_regs f_lbls f_regs bl lbl1 ≠ None ?→ 
sigma_label p_in p_out prog stack_size init init_regs f_lbls f_regs bl lbl1 = 
sigma_label p_in p_out prog stack_size init init_regs f_lbls f_regs bl lbl2 → 
lbl1 = lbl2.
#p_in #p_out #prog #stack_size #init #init_regs #f_lbls #f_regs #bl #lbl1 #lbl2 
inversion(sigma_label ????????? lbl1)
[ #_ * #H @⊥ @H %]
#lbl1' #H @('bind_inversion H) -H #bl' #EQbl'
#H @('bind_inversion H) -H * #f #fn #H lapply(res_eq_from_opt ??? H) -H
#EQfn #H @('bind_inversion H) -H * #res #stmt #H1 whd in ⊢ (??%? → ?);
#EQ destruct(EQ) #_ #H lapply(sym_eq ??? H) -H #H @('bind_inversion H) -H
#bl'' >EQbl' #EQ destruct(EQ) >EQfn >m_return_bind #H @('bind_inversion H) -H
* #lbl2' #stmt' #H2 whd in ⊢ (??%? → ?); #EQ destruct(EQ)
lapply(find_predicate ?????? H1) lapply(find_predicate ?????? H2)
cases (preamble_length ?????????) normalize nodelta [*] #n cases(nth_opt ???) 
normalize nodelta
[*] #lbl @eq_identifier_elim [2: #_ *] #EQ destruct(EQ) #_ @eq_identifier_elim
[2: #_ *] #EQ destruct(EQ) #_ %
qed.

definition sigma_pc_opt :  
∀p_in,p_out : sem_graph_params.
joint_program p_in → (ident → option ℕ) → 
(∀globals.joint_closed_internal_function p_in globals
         →bound_b_graph_translate_data p_in p_out globals) → 
(block → list register) → lbl_funct_type → regs_funct_type → 
program_counter → option program_counter ≝
λp_in,p_out,prog,stack_size,init,init_regs,f_lbls,f_regs,pc.
let target_point ≝ point_of_pc p_out pc in
if eqZb (block_id (pc_block pc)) (-1) then
 return pc
else 
 ! source_point ← sigma_label p_in p_out prog stack_size init init_regs 
                   f_lbls f_regs (pc_block pc) target_point;
 return pc_of_point p_in (pc_block pc) source_point.

lemma sigma_stored_pc_inj :
∀p_in,p_out,prog,stack_size,init,init_regs,f_lbls,f_regs,pc,pc'. 
sigma_pc_opt p_in p_out prog stack_size init init_regs f_lbls f_regs pc ≠ None ? →
sigma_pc_opt p_in p_out prog stack_size init init_regs f_lbls f_regs pc = 
sigma_pc_opt p_in p_out prog stack_size init init_regs f_lbls f_regs pc' → 
pc = pc'.
#p_in #p_out #prog #stack_size #init #init_regs #f_lbls #f_regs 
* #bl1 #p1 * #bl2 #p2
inversion(sigma_pc_opt ??????) [#_ * #H @⊥ @H %] #pc1
whd in match sigma_pc_opt in ⊢ (% → ?); normalize nodelta 
@eqZb_elim [2: *] normalize nodelta #Hbl 
[ #H @('bind_inversion H) -H * #pt1 #EQpt1] 
whd in ⊢ (??%? → ?); #EQ destruct(EQ)
#_ #H lapply(sym_eq ??? H) -H whd in match sigma_pc_opt; 
normalize nodelta @eqZb_elim [2,4: *] #Hbl1 normalize nodelta
[1,2: #H @('bind_inversion H) -H * #pt2 #EQpt2] whd in match pc_of_point;
normalize nodelta whd in match (offset_of_point ??);
whd in ⊢ (??%% → ?); #EQ destruct(EQ)
[2,3: @⊥ [ >Hbl in Hbl1; | >Hbl1 in Hbl;] #H @H % |4: %]
whd in match (offset_of_point ??) in EQpt2;
<EQpt1 in EQpt2; #H lapply(partial_inj_sigma … (sym_eq ??? H))
[ >EQpt1 % #EQ -prog destruct(EQ)] whd in match point_of_pc; normalize nodelta
whd in match (point_of_offset ??); whd in match (point_of_offset ??); 
#EQ -prog destruct(EQ) %
qed.

definition sigma_stored_pc ≝ 
λp_in,p_out,prog,stack_size,init,init_regs,f_lbls,f_regs,pc.
match sigma_pc_opt p_in p_out prog stack_size init init_regs f_lbls f_regs pc with
      [None ⇒ null_pc (pc_offset … pc) | Some x ⇒ x].


record good_state_relation (P_in : sem_graph_params) 
   (P_out : sem_graph_params) (prog : joint_program P_in)
   (stack_sizes : ident → option ℕ)
   (init : ∀globals.joint_closed_internal_function P_in globals
         →bound_b_graph_translate_data P_in P_out globals)
   (init_regs : block → list register) (f_lbls : lbl_funct_type) 
   (f_regs : regs_funct_type)
   (st_no_pc_rel : joint_state_relation P_in P_out)
   (st_rel : joint_state_pc_relation P_in P_out) : Prop ≝ 
{ good_translation :> b_graph_transform_program_props P_in P_out stack_sizes init 
                     prog init_regs f_lbls f_regs
; fetch_ok_sigma_state_ok : 
   ∀st1,st2,f,fn. st_rel st1 st2 → 
    fetch_internal_function … (prog_var_names … prog) 
     (joint_globalenv P_in prog stack_sizes) (pc_block (pc … st1))  
     = return 〈f,fn〉 →
     st_no_pc_rel (pc … st1) (st_no_pc … st1) (st_no_pc … st2)
; fetch_ok_pc_ok : 
  ∀st1,st2,f,fn.st_rel st1 st2 → 
   fetch_internal_function … (prog_var_names … prog) 
     (joint_globalenv P_in prog stack_sizes) (pc_block (pc … st1))  
     = return 〈f,fn〉 → 
   pc … st1 = pc … st2
; fetch_ok_sigma_last_pop_ok : 
  ∀st1,st2,f,fn.st_rel st1 st2 → 
   fetch_internal_function … (prog_var_names … prog) 
     (joint_globalenv P_in prog stack_sizes) (pc_block (pc … st1))  
     = return 〈f,fn〉 → 
   (last_pop … st1) = sigma_stored_pc P_in P_out prog stack_sizes init init_regs 
                       f_lbls f_regs (last_pop … st2)
; st_rel_def : 
  ∀st1,st2,pc,lp1,lp2,f,fn.
  fetch_internal_function … (prog_var_names … prog) 
     (joint_globalenv P_in prog stack_sizes) (pc_block pc) = return 〈f,fn〉 →
   st_no_pc_rel pc st1 st2 →
   lp1 = sigma_stored_pc P_in P_out prog stack_sizes init init_regs 
          f_lbls f_regs lp2 → 
  st_rel (mk_state_pc ? st1 pc lp1) (mk_state_pc ? st2 pc lp2)
; as_label_ok_non_entry :
  let trans_prog ≝ b_graph_transform_program P_in P_out init prog in 
  ∀st1,st2,f,fn,stmt. 
  fetch_statement … (prog_var_names … prog)
  (joint_globalenv P_in prog stack_sizes) (pc … st1) = return〈f,fn,stmt〉 → 
  st_rel st1 st2 → point_of_pc P_in (pc … st1) ≠ joint_if_entry … fn → 
  as_label (joint_status P_in prog stack_sizes) st1 = 
  as_label (joint_status P_out trans_prog stack_sizes) st2
; pre_main_ok :
  let trans_prog ≝ b_graph_transform_program P_in P_out init prog in 
    ∀st1,st1' : joint_abstract_status (mk_prog_params P_in prog stack_sizes) .
    ∀st2 : joint_abstract_status (mk_prog_params P_out trans_prog stack_sizes).
    block_id … (pc_block (pc … st1)) = -1 → 
    st_rel st1 st2 → 
    as_label (joint_status P_in prog stack_sizes) st1 =
    as_label (joint_status P_out trans_prog stack_sizes) st2 ∧
    joint_classify … (mk_prog_params P_in prog stack_sizes) st1 =
    joint_classify … (mk_prog_params P_out trans_prog stack_sizes) st2 ∧
    (eval_state P_in (prog_var_names … prog) (joint_globalenv P_in prog stack_sizes)
      st1 = return st1' → 
    ∃st2'. st_rel st1' st2' ∧ 
    eval_state P_out (prog_var_names … trans_prog) 
     (joint_globalenv P_out trans_prog stack_sizes) st2 = return st2')
; cond_commutation :
    let trans_prog ≝ b_graph_transform_program P_in P_out init prog in 
    ∀st1,st1' : joint_abstract_status (mk_prog_params P_in prog stack_sizes) .
    ∀st2 : joint_abstract_status (mk_prog_params P_out trans_prog stack_sizes).
    ∀f,fn,a,ltrue,lfalse.
    block_id … (pc_block (pc … st1)) ≠ -1 → 
    let cond ≝ (COND P_in ? a ltrue) in
    fetch_statement P_in … (joint_globalenv P_in prog stack_sizes) (pc … st1) = 
    return 〈f, fn,  sequential … cond lfalse〉 →  
    eval_state P_in (prog_var_names … prog) 
    (joint_globalenv P_in prog stack_sizes) st1 = return st1' → 
    st_rel st1 st2 → 
    ∀t_fn.
    fetch_internal_function … (prog_var_names … trans_prog)
     (joint_globalenv P_out trans_prog stack_sizes) (pc_block (pc … st2)) =
     return 〈f,t_fn〉 → 
    bind_new_P' ??
     (λregs1.λdata.bind_new_P' ?? 
     (λregs2.λblp.(\snd blp) = [ ] ∧
        ∀mid.
          stmt_at ? (prog_var_names … trans_prog) (joint_if_code ?? t_fn) mid
          = return sequential P_out ? ((\snd (\fst blp)) mid) lfalse→ 
         ∃st2_pre_mid_no_pc. 
            repeat_eval_seq_no_pc … (mk_prog_params P_out trans_prog stack_sizes) f 
             (map_eval ?? (\fst (\fst blp)) mid) (st_no_pc ? st2) 
            = return st2_pre_mid_no_pc ∧
            st_no_pc_rel (pc … st1') (st_no_pc … st1') (st2_pre_mid_no_pc) ∧
            joint_classify_step … ((\snd (\fst blp)) mid)  = cl_jump ∧
            cost_label_of_stmt P_out (prog_var_names … trans_prog)
                               (sequential P_out ? ((\snd (\fst blp)) mid) lfalse) = None ? ∧
            let st2_pre_mid ≝  mk_state_pc P_out st2_pre_mid_no_pc 
                               (pc_of_point P_out (pc_block (pc … st2)) mid) (last_pop … st2) in
            let st2' ≝ mk_state_pc P_out st2_pre_mid_no_pc (pc … st1') (last_pop … st2) in
            eval_statement_advance P_out (prog_var_names … trans_prog)
             (joint_globalenv P_out trans_prog stack_sizes) f t_fn
             (sequential P_out ? ((\snd (\fst blp)) mid) lfalse) st2_pre_mid = return st2'
   )  (f_step … data (point_of_pc P_in (pc … st1)) cond)   
  ) (init ? fn) 
; seq_commutation :
  let trans_prog ≝ b_graph_transform_program P_in P_out init prog in 
  ∀st1,st1' : joint_abstract_status (mk_prog_params P_in prog stack_sizes) .
  ∀st2 : joint_abstract_status (mk_prog_params P_out trans_prog stack_sizes).
  ∀f,fn,stmt,nxt.
  block_id … (pc_block (pc … st1)) ≠ -1 → 
  let seq ≝ (step_seq P_in ? stmt) in
  fetch_statement P_in … (joint_globalenv P_in prog stack_sizes) (pc … st1) = 
  return 〈f, fn,  sequential … seq nxt〉 →  
  eval_state P_in (prog_var_names … prog) (joint_globalenv P_in prog stack_sizes) 
  st1 = return st1' → 
  st_rel st1 st2 → 
  ∀t_fn.
  fetch_internal_function … (prog_var_names … trans_prog)
     (joint_globalenv P_out trans_prog stack_sizes) (pc_block (pc … st2)) =
  return 〈f,t_fn〉 → 
  bind_new_P' ??
     (λregs1.λdata.bind_new_P' ?? 
      (λregs2.λblp.
       ∃l : list (joint_seq P_out (prog_var_names … trans_prog)).
                            blp = (ensure_step_block ?? l) ∧
       ∃st2_fin_no_pc.
           repeat_eval_seq_no_pc … (mk_prog_params P_out trans_prog stack_sizes) f 
              l  (st_no_pc … st2)= return st2_fin_no_pc ∧
           st_no_pc_rel (pc … st1') (st_no_pc … st1') st2_fin_no_pc
      ) (f_step … data (point_of_pc P_in (pc … st1)) seq)
     ) (init ? fn)
; cost_commutation : 
  let trans_prog ≝ b_graph_transform_program P_in P_out init prog in
  ∀st1,st2,pc.∀f,fn,c,nxt.
  block_id … (pc_block pc) ≠ -1 → 
  st_no_pc_rel pc st1 st2 → 
  fetch_statement P_in … (joint_globalenv P_in prog stack_sizes) pc = 
  return 〈f, fn,  sequential ?? (COST_LABEL ?? c) nxt〉 →  
  st_no_pc_rel (pc_of_point P_in (pc_block pc) nxt) st1 st2 
}.

(*TO BE MOVED*)
lemma decidable_In : ∀A.∀l : list A. ∀a : A. (∀a'.decidable (a = a')) →  
decidable (In A l a).
#A #l elim l [ #a #_ %2 % *] #hd #tl #IH #a #DEC cases(IH a DEC)
[ #H % %2 assumption | * #H cases (DEC hd) 
[ #H1 %1 %1 assumption | * #H1 %2 % * [ #H2 @H1 assumption | #H2 @H assumption]]
qed.

lemma In_all : ∀A.∀l : list A. ∀ a : A.¬In A l a → All A (λx.x≠a) l.
#A #l elim l [ #a #_ @I] #hd #tl #IH #a * #H % [2: @IH % #H1 @H %2 assumption]
% #H1 @H % >H1 %
qed.

lemma All_In : ∀A.∀l : list A. ∀ a : A.All A (λx.x≠a) l → ¬In A l a.
#A #l elim l [#a #_ % *] #hd #tl #IH #a ** #H1 #H2 % *
[ #H3 @H1 >H3 % | cases(IH a H2) #H3 #H4 @H3 assumption]
qed.

lemma fetch_stmt_ok_succ_ok : ∀p : sem_graph_params.
∀prog : joint_program p.∀stack_size,f,fn,stmt,pc,pc',lbl.
In ? (stmt_labels p ? stmt) lbl→ 
fetch_statement p … (joint_globalenv p prog stack_size) pc = return 〈f,fn,stmt〉 →
pc' = pc_of_point p (pc_block pc) lbl → 
∃stmt'.fetch_statement p … (joint_globalenv p prog stack_size) pc' = return 〈f,fn,stmt'〉.
#p #prog #stack_size #f #fn #stmt #pc #pc' #lbl #Hlbl #EQfetch
cases(fetch_statement_inv … EQfetch) #EQfn normalize nodelta #EQstmt
#EQ destruct(EQ) lapply(code_is_closed … (pi2 ?? fn) … EQstmt) *
cases(decidable_In ? (stmt_explicit_labels … stmt) lbl ?) 
[3: * cases lbl #x #y cases(decidable_eq_pos … x y) 
    [#EQ destruct % % | * #H %2 % #H1 @H destruct %]
| whd in ⊢ (% → ?); #H1 #H2 cases(Exists_All … H1 H2) #lbl1 * #EQ destruct
  whd in match code_has_label; whd in match code_has_point; normalize nodelta
  inversion(stmt_at ????) [#_ *] #stmt' #EQstmt' #_ #_ %{stmt'}
  whd in match fetch_statement; normalize nodelta >EQfn >m_return_bind
  >point_of_pc_of_point >EQstmt' %
| #H lapply(In_all ??? H) -H cases(Exists_append … Hlbl)
  [ cases stmt [ #step #nxt | #fin | *] whd in match stmt_implicit_label;
    normalize nodelta [2: *] * [2: *] #EQ destruct(EQ) #_ #_ 
    whd in match stmt_forall_succ; whd in match code_has_point; normalize nodelta
    inversion(stmt_at ????) [#_ *] #stmt' #EQstmt' #_ %{stmt'}
    whd in match fetch_statement; normalize nodelta >EQfn >m_return_bind
    >point_of_pc_of_point >EQstmt' %
  | #H1 #H2 cases(Exists_All … H1 H2) #x * #EQ destruct * #H @⊥ @H %
  ]
]
qed. 



lemma fetch_stmt_ok_sigma_state_ok : ∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.∀st_no_pc_rel,st_rel.
∀f,fn,stmt,st1,st2.
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs 
                    st_no_pc_rel st_rel → 
st_rel st1 st2 → 
fetch_statement P_in … (joint_globalenv P_in prog stack_sizes) (pc … st1) =
 return 〈f,fn,stmt〉 → 
st_no_pc_rel (pc … st1) (st_no_pc … st1) (st_no_pc … st2).
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_lb_r #init #st_no_pc_rel
#st_rel #f #fn #stmt #st1 #st2 #goodR #Hst_rel #EQfetch
cases(fetch_statement_inv … EQfetch) #EQfn #EQstmt
@(fetch_ok_sigma_state_ok … goodR … EQfn) assumption
qed.

lemma fetch_stmt_ok_sigma_pc_ok : ∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀st_no_pc_rel,st_rel.
∀f,fn,stmt,st1,st2.
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs  
                    st_no_pc_rel st_rel → 
st_rel st1 st2 → 
fetch_statement P_in … (joint_globalenv P_in prog stack_sizes) (pc … st1) =
 return 〈f,fn,stmt〉 → 
pc … st1 = pc … st2.
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_lb_r #init #st_no_pc_rel
#st_rel #f #fn #stmt #st1 #st2 #goodR #Hst_rel #EQfetch
cases(fetch_statement_inv … EQfetch) #EQfn #EQstmt
@(fetch_ok_pc_ok … goodR … EQfn) assumption
qed.

lemma fetch_stmt_ok_sigma_last_pop_ok : ∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀st_no_pc_rel,st_rel.
∀f,fn,stmt,st1,st2.
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs 
                    st_no_pc_rel st_rel → 
st_rel st1 st2 → 
fetch_statement P_in … (ev_genv … (mk_prog_params P_in prog stack_sizes)) (pc … st1) =
 return 〈f,fn,stmt〉 → 
(last_pop … st1) = 
 sigma_stored_pc P_in P_out prog stack_sizes init f_bl_r f_lbls 
  f_regs (last_pop … st2).
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_lb_r #init #st_no_pc_rel
#st_rel #f #fn #stmt #st1 #st2 #goodR #Hst_rel #EQfetch
cases(fetch_statement_inv … EQfetch) #EQfn #EQstmt
@(fetch_ok_sigma_last_pop_ok … goodR … EQfn) assumption
qed.

(*
lemma fetch_stmt_ok_st_rel_def : ∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀good : b_graph_transform_program_props P_in P_out init prog f_bl_r f_lbls f_regs.
∀st_no_pc_rel,st_rel.
∀f,fn,stmt,st1,st2.
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs good 
                    st_no_pc_rel st_rel → 
st_no_pc_rel (st_no_pc … st1) (st_no_pc … st2) → (pc … st1) = (pc … st2) → 
(last_pop … st1) = sigma_stored_pc P_in P_out prog f_lbls (last_pop … st2) → 
fetch_statement P_in … (ev_genv … (mk_prog_params P_in prog stack_sizes)) (pc … st1) =
 return 〈f,fn,stmt〉 → st_rel st1 st2.
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_bl_r #init #good #st_no_pc_rel
#st_rel #f #fn #stmt * #st1 #pc1 #lp1 * #st2 #pc2 #lp2 #goodR #Hno_pc #EQ destruct(EQ) 
#EQlp1 #EQfetch cases(fetch_statement_inv … EQfetch) #EQfn #EQstmt
@(st_rel_def … goodR … EQfn) assumption
qed.
*)

(*
(*CSC: Isn't this already proved somewhere else??? *) 
lemma point_of_pc_pc_of_point:
 ∀P_in: sem_graph_params.∀l,st.
   point_of_pc P_in
    (pc_of_point (mk_sem_graph_params (sgp_pars P_in) (sgp_sup P_in))
     (pc_block (pc P_in st)) l) = l.
 #P * //
qed.*)

(*TO BE MOVED*)
lemma append_All : ∀A : Type[0]. ∀ P : A → Prop. ∀l1,l2 : list A.
All ? P (l1 @ l2) → All ? P l1 ∧ All ? P l2.
#A #P #l1 elim l1
[ #l2 change with l2 in ⊢ (???% → ?); #H % //]
#a #tl #IH #l2 change with (P a ∧ All A P (tl @ l2)) in ⊢ (% → ?);
* #H1 #H2 lapply(IH … H2) * #H3 #H4 % // whd % //
qed.

lemma general_eval_cond_ok : ∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀st_no_pc_rel,st_rel.
let prog_pars_in ≝ mk_prog_params P_in prog stack_sizes in
let trans_prog  ≝ b_graph_transform_program P_in P_out init prog in
let prog_pars_out ≝ mk_prog_params P_out trans_prog stack_sizes in
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs 
                    st_no_pc_rel st_rel→ 
∀st1,st1' : joint_abstract_status prog_pars_in.
∀st2 : joint_abstract_status prog_pars_out.
∀f.
∀fn : joint_closed_internal_function P_in (prog_var_names … prog).
∀a,ltrue,lfalse.
block_id … (pc_block (pc … st1)) ≠ -1 → 
st_rel st1 st2 → 
 let cond ≝ (COND P_in ? a ltrue) in
  fetch_statement P_in …
   (joint_globalenv P_in prog stack_sizes) (pc … st1) = 
     return 〈f, fn,  sequential … cond lfalse〉 → 
 eval_state P_in (prog_var_names … prog)
  (joint_globalenv P_in prog stack_sizes) st1 = return st1' → 
as_costed (joint_abstract_status prog_pars_in) st1' →
∃ st2'. st_rel st1' st2' ∧ 
∃taf : trace_any_any_free (joint_abstract_status prog_pars_out) st2 st2'.
bool_to_Prop (taaf_non_empty … taf).
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_bl_r #init #st_no_pc_rel 
#st_rel #goodR #st1 #st1' #st2 #f #fn #a #ltrue #lfalse * #Hbl #Rst1st2 #EQfetch 
#EQeval
@('bind_inversion EQeval) #x >EQfetch whd in ⊢ (??%% → ?); #EQ destruct(EQ)
whd in match eval_statement_no_pc; normalize nodelta >m_return_bind
#H lapply(err_eq_from_io ????? H) -H #H @('bind_inversion H) -H #bv #EQbv
#H @('bind_inversion H) -H * #EQbool normalize nodelta whd in ⊢ (??%% → ?);
cases(fetch_statement_inv … EQfetch) #EQfn normalize nodelta #EQstmt
[ >(pc_of_label_eq … EQfn)
  normalize nodelta whd in match set_pc; normalize nodelta whd in ⊢ (??%? → ?);
| whd in match next; whd in match set_pc; whd in match set_no_pc; normalize nodelta
] 
#EQ destruct(EQ) #n_costed
lapply(b_graph_transform_program_fetch_statement … goodR (pc … st1) f fn ?)
[2,4: @eqZb_elim [1,3: #ABS @⊥ >ABS in Hbl; #H @H %] #_ normalize nodelta 
      #H cases(H EQfetch) -H |*:]
#init_data * #t_fn1 **  >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch)
#EQt_fn1 whd in ⊢ (% → ?); #Hinit normalize nodelta 
*** #blp #blm #bls * whd in ⊢ (% → ?); @if_elim
[1,3: @eq_identifier_elim [2,4: #_ cases(not_emptyb ??) *] 
      whd in match point_of_pc; normalize nodelta whd in match (point_of_offset ??);
      #ABS #_ lapply(fetch_statement_inv … EQfetch) * #_ 
      >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) 
      whd in match point_of_pc; normalize nodelta whd in match (point_of_offset ??);
      <ABS cases(entry_is_cost … (pi2 ?? fn)) #nxt1 * #c #EQ >EQ #EQ1 destruct(EQ1)
]
#_ <(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) #EQbl whd in ⊢ (% → ?); * 
#l1 * #mid1 * #mid2 * #l2 *** #EQmid1 whd in ⊢ (% → ?); #seq_pre_l whd in ⊢ (% → ?); * #nxt1 
* #EQmid change with nxt1 in ⊢ (??%? → ?); #EQ destruct(EQ)
cases(bind_new_bind_new_instantiates … EQbl (bind_new_bind_new_instantiates … Hinit
               (cond_commutation … goodR … EQfetch EQeval Rst1st2 t_fn1 EQt_fn1)))
[2,4: % assumption]
#EQ destruct(EQ) #APP whd in ⊢ (% → ?); * #EQ1 #EQ2 destruct(EQ1 EQ2)
cases(APP … EQmid) -APP #st_pre_mid_no_pc **** whd in match set_no_pc; normalize nodelta
#EQst_pre_mid_no_pc #Hsem #CL_JUMP #COST #Hst2_mid 
[ %{(mk_state_pc ? st_pre_mid_no_pc (pc_of_point P_in (pc_block (pc … st1)) ltrue) 
     (last_pop … st2))}
| %{(mk_state_pc ? st_pre_mid_no_pc (pc_of_point P_in (pc_block (pc … st1)) lfalse)
     (last_pop … st2))}
]
letin st1' ≝ (mk_state_pc P_in ???)
letin st2' ≝ (mk_state_pc P_out ???)
cut(st_rel st1' st2')
[1,3: @(st_rel_def … goodR … f fn ?) 
      [1,4: change with (pc_block (pc … st1)) in match (pc_block ?); assumption
      |2,5: assumption
      |3,6: @(fetch_stmt_ok_sigma_last_pop_ok … goodR … EQfetch) assumption
      ]
]
#H_fin
%
[1,3: assumption]
>(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) in seq_pre_l; #seq_pre_l
lapply(taaf_to_taa ??? 
           (produce_trace_any_any_free ? st2 f t_fn1 ??? st_pre_mid_no_pc EQt_fn1
                                       seq_pre_l EQst_pre_mid_no_pc) ?)
[1,3: @if_elim #_ // % whd in ⊢ (% → ?); whd in match (as_label ??);
      whd in match fetch_statement; normalize nodelta >EQt_fn1 >m_return_bind
      whd in match (as_pc_of ??); whd in match point_of_pc; normalize nodelta
      >point_of_offset_of_point >EQmid >m_return_bind normalize nodelta >COST *
      #H @H %
] 
#taa_pre_mid %{(taaf_step_jump ? ??? taa_pre_mid ???) I}
[1,4: cases(fetch_stmt_ok_succ_ok … (pc … st1) (pc … st1') … EQfetch ?)
      [2: @ltrue|3: %2 % % |4: % |6: @lfalse |7: % % |8: %] #stmt' #EQstmt'
      whd <(as_label_ok_non_entry … goodR … EQstmt' H_fin) 
      [1,3: assumption 
      |2,4: cases(entry_unused … (pi2 ?? fn) … EQstmt)
            [ whd in match stmt_forall_labels; whd in match stmt_labels;
              normalize nodelta #H cases(append_All … H) #_
              whd in match stmt_explicit_labels; whd in match step_labels;
              normalize nodelta * whd in match (point_of_label ????); 
              * #H1 #_ #_ >point_of_pc_of_point % #H2 @H1 >H2 %
            | ** whd in match (point_of_label ????); #H1 #_ #_ % whd in match st1';
              #H2 @H1 <H2 whd in match succ_pc; whd in match point_of_pc; 
              normalize nodelta whd in match pc_of_point; normalize nodelta
              >point_of_offset_of_point %
            ]
      ]
|2,5: whd whd in match (as_classify ??); whd in match fetch_statement; normalize nodelta
      >EQt_fn1 >m_return_bind >point_of_pc_of_point >EQmid normalize nodelta
      assumption
|*: whd whd in match eval_state; whd in match fetch_statement; normalize nodelta
    >EQt_fn1 >m_return_bind >point_of_pc_of_point >EQmid >m_return_bind
    cases(blm mid1) in CL_JUMP COST Hst2_mid;
    [1,5: #c #_ whd in ⊢ (??%% → ?); #EQ destruct(EQ)
    |2,4,6,8: [1,3: #c_id #args #dest |*: #seq] whd in ⊢ (??%% → ?); #EQ destruct(EQ)
    ]
    #r #ltrue #_ #_ #Hst2_mid whd in match eval_statement_no_pc; normalize nodelta 
    >m_return_bind assumption
]
qed.


lemma general_eval_seq_no_call_ok :∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀st_no_pc_rel,st_rel.
let prog_pars_in ≝ mk_prog_params P_in prog stack_sizes in
let trans_prog  ≝ b_graph_transform_program P_in P_out init prog in
let prog_pars_out ≝ mk_prog_params P_out trans_prog stack_sizes in
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs 
                    st_no_pc_rel st_rel → 
∀st1,st1' : joint_abstract_status prog_pars_in.
∀st2 : joint_abstract_status prog_pars_out.
∀f.∀fn : joint_closed_internal_function P_in (prog_var_names … prog).
∀stmt,nxt.
block_id … (pc_block (pc … st1)) ≠ -1 → 
st_rel st1 st2 → 
 let seq ≝ (step_seq P_in ? stmt) in
  fetch_statement P_in …
   (joint_globalenv P_in prog stack_sizes) (pc … st1) = 
     return 〈f, fn,  sequential ?? seq nxt〉 → 
 eval_state P_in (prog_var_names … prog) (joint_globalenv P_in prog stack_sizes)
  st1 = return st1' → 
∃st2'. st_rel st1' st2' ∧            
∃taf : trace_any_any_free (joint_abstract_status prog_pars_out) st2 st2'.            
 if taaf_non_empty … taf then True else  (*IT CAN BE SIMPLIFIED *)
(¬as_costed (joint_abstract_status (mk_prog_params P_in prog stack_sizes)) st1 ∨ 
 ¬as_costed (joint_abstract_status (mk_prog_params P_in prog stack_sizes)) st1'). 
#P_in #P_out #prog #stack_sizes #f_lbls #f_regs #f_bl_r #init #st_no_pc_rel #st_rel 
#goodR #st1 #st1' #st2 #f #fn #stmt #nxt * #Hbl #Rst1st2 #EQfetch #EQeval
@('bind_inversion EQeval) #x >EQfetch whd in ⊢ (??%% → ?); #EQ destruct(EQ)
#H @('bind_inversion H) -H #st1_no_pc #H lapply(err_eq_from_io ????? H) -H
#EQst1_no_pc whd in ⊢ (??%% → ?); whd in match next; whd in match set_pc;
whd in match set_no_pc; normalize nodelta #EQ destruct(EQ)
lapply(b_graph_transform_program_fetch_statement … goodR (pc … st1) f fn ?)
[2: @eqZb_elim [ #ABS @⊥ >ABS in Hbl; #H @H %] #_ normalize nodelta 
      #H cases(H EQfetch) -H |*:]
#init_data * #t_fn ** >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) 
#EQt_fn #Hinit normalize nodelta * #bl * @if_elim
[ @eq_identifier_elim [2: #_ cases(not_emptyb ??) *] whd in match point_of_pc; 
  normalize nodelta whd in match (point_of_offset ??); #ABS #_ 
  lapply(fetch_statement_inv … EQfetch) * #_ 
  >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) whd in match point_of_pc; 
  normalize nodelta whd in match (point_of_offset ??); <ABS 
  cases(entry_is_cost … (pi2 ?? fn)) #nxt1 * #c #EQ >EQ #EQ1 destruct(EQ1)
]
#_ <(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) #EQbl 
>(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) #SBiC 
cases(bind_new_bind_new_instantiates … EQbl (bind_new_bind_new_instantiates … Hinit
               (seq_commutation … goodR … EQfetch EQeval Rst1st2 t_fn EQt_fn)))
               [2: % assumption]
#l * #EQ destruct(EQ) * #st2_fin_no_pc * #EQst2_fin_no_pc #Rsem
%{(mk_state_pc ? st2_fin_no_pc (pc_of_point P_out (pc_block (pc … st2)) nxt) (last_pop … st2))}
cases(fetch_statement_inv … EQfetch) >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) 
#EQfn #_
%
[ @(st_rel_def ?????????? goodR … f fn)
      [ change with (pc_block (pc … st2)) in match (pc_block ?); assumption
      | <(fetch_stmt_ok_sigma_pc_ok … goodR … EQfetch) assumption
      | @(fetch_stmt_ok_sigma_last_pop_ok … goodR … EQfetch) assumption
      ]
]
%{(produce_trace_any_any_free_coerced ? st2 f t_fn l ?? st2_fin_no_pc EQt_fn 
                                      SBiC EQst2_fin_no_pc)}
@if_elim #_ [@I] % % whd in ⊢ (% → ?); * #H @H -H whd in ⊢ (??%?); >EQfetch %
qed.


lemma general_eval_cost_ok :
∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀st_no_pc_rel,st_rel.
let prog_pars_in ≝ mk_prog_params P_in prog stack_sizes in
let trans_prog  ≝ b_graph_transform_program P_in P_out init prog in
let prog_pars_out ≝ mk_prog_params P_out trans_prog stack_sizes in
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs 
                    st_no_pc_rel st_rel → 
∀st1,st1' : joint_abstract_status prog_pars_in.
∀st2 : joint_abstract_status prog_pars_out.
∀f.
∀fn : joint_closed_internal_function P_in (prog_var_names … prog).∀c,nxt.
block_id … (pc_block (pc … st1)) ≠ -1 → 
st_rel st1 st2 → 
let cost ≝ COST_LABEL P_in ? c in
 fetch_statement P_in …
  (joint_globalenv P_in prog stack_sizes) (pc … st1) = 
    return 〈f, fn,  sequential ?? cost nxt〉 → 
 eval_state P_in (prog_var_names … prog) (ev_genv … prog_pars_in) 
            st1 = return st1' → 
∃ st2'. st_rel st1' st2' ∧
∃taf : trace_any_any_free 
        (joint_abstract_status (mk_prog_params P_out trans_prog stack_sizes))
        st2 st2'.
bool_to_Prop (taaf_non_empty … taf).
#P_in #P_out #prog #stack_size #f_lbls #f_regs #f_bl_r #init #st_no_pc_rel
#st_rel #goodR #st1 #st1' #st2 #f #fn #c #nxt * #Hbl #Rst1st2 normalize nodelta 
#EQfetch 
whd in match eval_state; whd in match eval_statement_no_pc; normalize nodelta 
>EQfetch >m_return_bind normalize nodelta >m_return_bind whd in ⊢ (??%% → ?); 
#EQ destruct(EQ) 
%{(mk_state_pc ? (st_no_pc … st2) (pc_of_point P_out (pc_block (pc … st2)) nxt)
                 (last_pop … st2))} %
[ cases(fetch_statement_inv … EQfetch) #EQfn #_ 
  <(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch)
  whd in match (succ_pc ???); whd in match (point_of_succ ???);
  >set_no_pc_eta
  @(st_rel_def … prog … stack_size … goodR 
          (st_no_pc … st1) (st_no_pc … st2)) [3: >EQfn in ⊢ (??%?); %|1,2:]
  [ @(cost_commutation … prog … stack_size … goodR … EQfetch) [ % assumption]
    @(fetch_stmt_ok_sigma_state_ok … goodR … Rst1st2 EQfetch)
  | @(fetch_stmt_ok_sigma_last_pop_ok … goodR … Rst1st2 EQfetch)
  ]
| lapply(b_graph_transform_program_fetch_statement … goodR (pc … st1) f fn ?)
  [2: @eqZb_elim [ #ABS @⊥ >ABS in Hbl; #H @H %] #_ normalize nodelta 
      #H cases(H EQfetch) -H |*:]
  #init_data * #t_fn ** >(fetch_stmt_ok_sigma_pc_ok … goodR … Rst1st2 EQfetch) 
  #EQt_fn #Hinit normalize nodelta * #bl * 
  @if_elim @eq_identifier_elim [2: #_ cases(not_emptyb ??) *]
  [ #EQentry inversion(not_emptyb ??) [2: #_ *] #non_empty_pre #_ whd in ⊢ (% → ?);
    inversion (f_regs ??) [2: #x #y #_ #_ *] #EQregs normalize nodelta #EQ destruct(EQ)
    whd in ⊢ (% → ?); * #pre * #mid1 * #mid2 * #post *** #EQmid1 whd in ⊢ (% → ?);
    * #EQ1 #EQ2 destruct(EQ1 EQ2) whd in ⊢ (% → ?); * #nxt1 * #EQt_stmt
    change with nxt1 in ⊢ (??%? → ?); #EQ destruct(EQ) whd in ⊢ (% → ?);
    * #EQ1 #EQ2 destruct(EQ1 EQ2)
  | #EQentry inversion(not_emptyb ??) [ #_ *] #empty_pre #_
    >(f_step_on_cost … init_data) whd in ⊢ (% → ?); inversion(f_regs ??) [2: #x #y #_ #_ *]
   #EQregs normalize nodelta #EQ destruct(EQ) whd in ⊢ (% → ?); * #pre * #mid1 * 
   #mid2 * #post *** #EQmid1 * #EQ1 #EQ2 destruct(EQ1 EQ2) * #nxt1 * #EQt_stmt
   change with nxt1 in ⊢ (??%? → ?); #EQ destruct(EQ) * #EQ1 #EQ2 destruct(EQ1 EQ2)
  | #EQentry #_  >(f_step_on_cost … init_data) whd in ⊢ (% → ?);
    inversion(f_regs ??) [2: #x #y #_ #_ *] #EQregs normalize nodelta #EQ destruct(EQ)
    * #pre * #mid1 * #mid2 * #post *** #EQmid1 * #EQ1 #EQ2 destruct(EQ1 EQ2) *
    #nxt1 * #EQt_stmt change with nxt1 in ⊢ (??%? → ?); #EQ destruct(EQ)
    * #EQ1 #EQ2 destruct(EQ1 EQ2)
  ]  
  %{(taaf_step … (taa_base …) …)} 
  [3,6,9: @I
  |*: whd whd in ⊢ (??%?); whd in match fetch_statement; normalize nodelta
     >EQt_fn >m_return_bind >EQt_stmt >m_return_bind %
  ]
]
qed.

(*
lemma eval_return_ok : 
∀ P_in , P_out: sem_graph_params.
∀prog : joint_program P_in.
∀stack_sizes.
∀ f_lbls,f_regs.∀f_bl_r.∀init.
∀good : b_graph_transform_program_props P_in P_out init prog f_bl_r f_lbls f_regs.
∀st_no_pc_rel,st_rel.
let prog_pars_in ≝ mk_prog_params P_in prog stack_sizes in
let trans_prog  ≝ b_graph_transform_program P_in P_out init prog in
let prog_pars_out ≝ mk_prog_params P_out trans_prog stack_sizes in
good_state_relation P_in P_out prog stack_sizes init f_bl_r f_lbls f_regs good 
                    st_no_pc_rel st_rel → 
∀st1,st1' :  joint_abstract_status prog_pars_in.
∀st2 : joint_abstract_status prog_pars_out.
∀f.
∀fn : joint_closed_internal_function P_in (prog_var_names … prog).
*)