source: src/joint/SemanticUtils.ma @ 1416

include "joint/semantics.ma".
include alias "common/Identifiers.ma".

(*** Store/retrieve on pseudo-registers ***)

axiom BadRegister : String.

definition reg_store ≝ λreg,v,locals. update RegisterTag beval locals reg v.

definition reg_retrieve : register_env beval → register → res beval ≝
 λlocals,reg. opt_to_res … [MSG BadRegister; CTX ? reg] (lookup … locals reg).

(*** Store/retrieve on hardware registers ***)

definition init_hw_register_env: address → hw_register_env ≝
 λaddr.
  let 〈dpl,dph〉 ≝ addr in
  let env ≝ hwreg_store RegisterDPH dph empty_hw_register_env in
   hwreg_store RegisterDPL dpl env.

(****************************************************************************)

(*CSC: XXXXXXXXXXXXXXXXX bug here; we need to change the encoding so that
  the block is the one of the function and the offset corresponds to the
  label. Code pointer arithmetics must be prevented in another way, i.e.
  by not allowing any increment/decrement on Code regions (with the
  exception of LIN's succ_pc function). If we don't do that, then the
  find_funct_ptr (e.g. in graph_fetch_statement) are not correct! *)
(*CSC: XXXX; do we need to create a brand new chunk per label, so that
  pointer operations on labels are not semantically valid?
  ATM, the pointers are not valid (they do not point to allocated regions)
  and, moreover, they conflict with function blocks and with other pointers
  in other functions. However, there could be simpler ways to invalidate
  pointer arithmetics on Code pointers.
*)
definition pointer_of_label: label → Σp:pointer. ptype p = Code ≝
 λl.
  mk_pointer Code
   (mk_block Code (Zopp (nat_of_bitvector ? (word_of_identifier … l))))
   ? (mk_offset OZ). 
// qed.

(*CSC: XXXX; inverse of the previous function, but it does not check that
  the offset is zero and thus it never fails. *)
definition label_of_pointer: pointer → res label ≝
 λp. OK … (an_identifier ? (bitvector_of_nat … (abs (block_id (pblock p))))).

(*CSC: XXX This code is cut&paste from joint/semantics.ma, address_of_label.
 But I can't use it directly because this one uses a concrete definition of
 pointer_of_label and it is used to istantiate the more_sem_params record
 where the abstract version is declared as a field. Is there a better way
 to organize the code? *)
definition graph_succ_p: label → address → res address ≝
 λl.λ_.address_of_pointer (pointer_of_label l).

axiom BadProgramCounter: String.

definition graph_fetch_function:
 ∀params1,sem_params,globals.
  genv … (graph_params params1 globals) →
   state sem_params → res (joint_internal_function … (graph_params params1 globals)) ≝
 λparams1,sem_params,globals,ge,st.
  do p ← code_pointer_of_address (pc … st) ;
  let b ≝ pblock p in
  do def ← opt_to_res ? [MSG BadProgramCounter] (find_funct_ptr … ge b) ;
  match def with
  [ Internal def' ⇒ OK … def'
  | External _ ⇒ Error … [MSG BadProgramCounter]].

definition graph_fetch_statement:
 ∀params1,sem_params,globals.
  genv … (graph_params params1 globals) →
   state sem_params → res (joint_statement (graph_params_ params1) globals) ≝
 λparams1,sem_params,globals,ge,st.
  do p ← code_pointer_of_address (pc … st) ;
  do f ← graph_fetch_function … ge st ;
  do l ← label_of_pointer p;
  opt_to_res ? [MSG BadProgramCounter] (lookup ?? (joint_if_code … f) l).