source: src/compiler.ma @ 2835

Last change on this file since 2835 was 2835, checked in by sacerdot, 7 years ago

Included Uses.ma which is required by the untrusted code.
The inclusion in the .ma file forces compilation and code extraction.

File size: 4.5 KB
Line 
1(* Front-end related includes *)
2include "Clight/label.ma".
3include "Clight/SimplifyCasts.ma".
4include "Clight/switchRemoval.ma".
5include "Clight/toCminor.ma".
6include "Cminor/toRTLabs.ma".
7include "RTLabs/CostCheck.ma".
8include "RTLabs/CostInj.ma".
9
10(* Back-end related includes *)
11include "RTLabs/RTLabsToRTL.ma".
12include "RTL/RTLToERTL.ma".
13include "ERTL/ERTLToERTLptr.ma".
14include "ERTLptr/ERTLptrToLTL.ma".
15include "LTL/LTLToLIN.ma".
16include "LIN/LINToASM.ma".
17
18(* List of all passes whose outputs can be observed *)
19inductive pass : Type[0] ≝
20   clight_pass: pass
21 | clight_switch_removed_pass: pass
22 | clight_label_pass: pass
23 | clight_simplified_pass: pass
24 | cminor_pass: pass
25 | rtlabs_pass: pass
26 | rtl_separate_pass: pass
27 | rtl_uniq_pass: pass
28 | ertl_pass: pass
29 | ertlptr_pass: pass
30 | ltl_pass: pass
31 | lin_pass: pass.
32
33definition syntax_of_pass : pass → Type[0] ≝
34 λpass.
35  match pass with
36  [ clight_pass ⇒ clight_program
37  | clight_switch_removed_pass ⇒ clight_program
38  | clight_label_pass ⇒ clight_program
39  | clight_simplified_pass ⇒ clight_program
40  | cminor_pass ⇒ Cminor_program
41  | rtlabs_pass ⇒ RTLabs_program
42  | rtl_separate_pass ⇒ rtl_program
43  | rtl_uniq_pass ⇒ rtl_program
44  | ertl_pass ⇒ ertl_program
45  | ertlptr_pass ⇒ ertlptr_program
46  | ltl_pass ⇒ ltl_program
47  | lin_pass ⇒ lin_program ].
48
49definition observe_pass ≝ ∀pass. syntax_of_pass pass → unit.
50
51(* The compiler front-end *)
52definition front_end :
53 observe_pass → clight_program → res (costlabel × clight_program × RTLabs_program) ≝
54λobserve,p.
55  let i ≝ observe clight_pass p in
56  let p ≝ program_switch_removal p in
57  let i ≝ observe clight_switch_removed_pass p in
58  let 〈p',init_cost〉 ≝ clight_label p in
59  let i ≝ observe clight_label_pass p' in
60  let p ≝ simplify_program p' in
61  let i ≝ observe clight_simplified_pass p in
62  ! p ← clight_to_cminor p;
63  let i ≝ observe cminor_pass p in
64  let p ≝ cminor_to_rtlabs init_cost p in
65  let i ≝ observe rtlabs_pass p in
66  if check_cost_program p then
67    if check_program_cost_injectivity p then
68      (return 〈init_cost,p',p〉)
69    else
70      (Error ? (msg RepeatedCostLabel))
71  else
72    (Error ? (msg BadCostLabelling)).
73
74(* The compiler back-end *)
75include "ERTLptr/Uses.ma".  (* Included by the untrusted code *)
76axiom compute_fixpoint : fixpoint_computer.
77axiom colour_graph : coloured_graph_computer.
78
79definition back_end :
80 observe_pass → RTLabs_program →
81  res (pseudo_assembly_program × stack_cost_model × nat) ≝
82λobserve,p.
83  let p ≝ rtlabs_to_rtl p in
84  let i ≝ observe rtl_separate_pass p in
85  let i ≝ observe rtl_uniq_pass p in
86  let p ≝ rtl_to_ertl p in
87  let i ≝ observe ertl_pass p in
88  let p ≝ ertl_to_ertlptr p in
89  let i ≝ observe ertlptr_pass p in
90  let 〈p,stack_cost,max_stack〉 ≝ ertlptr_to_ltl compute_fixpoint colour_graph p in (* TODO: abstract over colouring *)
91  let i ≝ observe ltl_pass p in
92  let p ≝ ltl_to_lin p in
93  let i ≝ observe lin_pass p in
94   ! p ← opt_to_res ? (msg AssemblyTooLarge) (lin_to_asm p) ;
95   return 〈p,stack_cost,max_stack〉.
96
97(* The assembler *)
98include "ASM/Policy.ma".
99
100definition assembler : pseudo_assembly_program → res labelled_object_code ≝
101λp.
102  ! sigma_pol ← opt_to_res ? (msg Jump_expansion_failed) (jump_expansion' p);
103  let sigma ≝ λppc. \fst sigma_pol ppc in
104  let pol ≝ λppc. \snd sigma_pol ppc in
105  OK ? (assembly p sigma pol).
106
107(* Cost lifting *)
108include "ASM/ASMCosts.ma".
109
110definition lift_cost_map_back_to_front :
111  ∀clight, code_memory, lbls.
112    let abstat ≝ ASM_abstract_status code_memory lbls in
113  as_cost_map abstat → clight_cost_map clight ≝
114  λclight,code_memory,lbls,k,asm_cost_map.
115  lift_sigma_map_id … 0 (* labels not present in out code get 0 *)
116    (strong_decidable_in_codomain …) k asm_cost_map.
117
118(* Cost model computation *)
119include "ASM/ASMCostsSplit.ma".
120
121record compiler_output : Type[0] ≝
122 { c_labelled_object_code: labelled_object_code
123 ; c_stack_cost: stack_cost_model
124 ; c_max_stack: nat
125 ; c_labelled_clight: clight_program
126 ; c_clight_cost_map: clight_cost_map c_labelled_clight
127 }.
128
129definition compile : observe_pass → clight_program → res compiler_output ≝
130λobserve,p.
131  ! 〈init_cost,p',p〉 ← front_end observe p;
132  ! 〈p,stack_cost,max_stack〉 ← back_end observe p;
133  ! p ← assembler p;
134  let k ≝ ASM_cost_map p in
135  let k' ≝
136   lift_cost_map_back_to_front p' (load_code_memory (oc p)) (costlabels p) k in
137  return mk_compiler_output p stack_cost max_stack p' k'.
Note: See TracBrowser for help on using the repository browser.