source: src/compiler.ma @ 2828

(* Front-end related includes *)
include "Clight/label.ma".
include "Clight/SimplifyCasts.ma".
include "Clight/switchRemoval.ma".
include "Clight/toCminor.ma".
include "Cminor/toRTLabs.ma".
include "RTLabs/CostCheck.ma".
include "RTLabs/CostInj.ma".

(* Back-end related includes *)
include "RTLabs/RTLabsToRTL.ma". 
include "RTL/RTLToERTL.ma".
include "ERTL/ERTLToERTLptr.ma".
include "ERTLptr/ERTLptrToLTL.ma".
include "LTL/LTLToLIN.ma". 
include "LIN/LINToASM.ma".

(* List of all passes whose outputs can be observed *)
inductive pass : Type[0] ≝
   clight_pass: pass
 | clight_switch_removed_pass: pass
 | clight_label_pass: pass
 | clight_simplified_pass: pass
 | cminor_pass: pass
 | rtlabs_pass: pass
 | rtl_separate_pass: pass
 | rtl_uniq_pass: pass
 | ertl_pass: pass
 | ertlptr_pass: pass
 | ltl_pass: pass
 | lin_pass: pass.

definition syntax_of_pass : pass → Type[0] ≝
 λpass.
  match pass with
  [ clight_pass ⇒ clight_program
  | clight_switch_removed_pass ⇒ clight_program
  | clight_label_pass ⇒ clight_program
  | clight_simplified_pass ⇒ clight_program
  | cminor_pass ⇒ Cminor_program
  | rtlabs_pass ⇒ RTLabs_program
  | rtl_separate_pass ⇒ rtl_program
  | rtl_uniq_pass ⇒ rtl_program
  | ertl_pass ⇒ ertl_program
  | ertlptr_pass ⇒ ertlptr_program
  | ltl_pass ⇒ ltl_program
  | lin_pass ⇒ lin_program ].

definition observe_pass ≝ ∀pass. syntax_of_pass pass → unit.

(* The compiler front-end *)
definition front_end :
 observe_pass → clight_program → res (costlabel × clight_program × RTLabs_program) ≝
λobserve,p.
  let i ≝ observe clight_pass p in
  let p ≝ program_switch_removal p in
  let i ≝ observe clight_switch_removed_pass p in
  let 〈p',init_cost〉 ≝ clight_label p in
  let i ≝ observe clight_label_pass p' in
  let p ≝ simplify_program p' in
  let i ≝ observe clight_simplified_pass p in
  ! p ← clight_to_cminor p;
  let i ≝ observe cminor_pass p in
  let p ≝ cminor_to_rtlabs init_cost p in
  let i ≝ observe rtlabs_pass p in
  if check_cost_program p then
    if check_program_cost_injectivity p then
      (return 〈init_cost,p',p〉)
    else
      (Error ? (msg RepeatedCostLabel))
  else
    (Error ? (msg BadCostLabelling)).

(* The compiler back-end *)
axiom compute_fixpoint : fixpoint_computer.
axiom colour_graph : coloured_graph_computer.

definition back_end :
 observe_pass → RTLabs_program →
  res (pseudo_assembly_program × stack_cost_model × nat) ≝
λobserve,p.
  let p ≝ rtlabs_to_rtl p in
  let i ≝ observe rtl_separate_pass p in
  let i ≝ observe rtl_uniq_pass p in
  let p ≝ rtl_to_ertl p in
  let i ≝ observe ertl_pass p in
  let p ≝ ertl_to_ertlptr p in
  let i ≝ observe ertlptr_pass p in
  let 〈p,stack_cost,max_stack〉 ≝ ertlptr_to_ltl compute_fixpoint colour_graph p in (* TODO: abstract over colouring *)
  let i ≝ observe ltl_pass p in
  let p ≝ ltl_to_lin p in
  let i ≝ observe lin_pass p in
   ! p ← opt_to_res ? (msg AssemblyTooLarge) (lin_to_asm p) ; 
   return 〈p,stack_cost,max_stack〉.

(* The assembler *)
include "ASM/Policy.ma".

definition assembler : pseudo_assembly_program → res labelled_object_code ≝
λp.
  ! sigma_pol ← opt_to_res ? (msg Jump_expansion_failed) (jump_expansion' p);
  let sigma ≝ λppc. \fst sigma_pol ppc in
  let pol ≝ λppc. \snd sigma_pol ppc in
  OK ? (assembly p sigma pol).

(* Cost lifting *)
include "ASM/ASMCosts.ma". 

definition lift_cost_map_back_to_front :
  ∀clight, code_memory, lbls.
    let abstat ≝ ASM_abstract_status code_memory lbls in 
  as_cost_map abstat → clight_cost_map clight ≝ 
  λclight,code_memory,lbls,k,asm_cost_map.
  lift_sigma_map_id … 0 (* labels not present in out code get 0 *)
    (strong_decidable_in_codomain …) k asm_cost_map.

(* Cost model computation *)
include "ASM/ASMCostsSplit.ma".

record compiler_output : Type[0] ≝
 { c_labelled_object_code: labelled_object_code
 ; c_stack_cost: stack_cost_model
 ; c_max_stack: nat
 ; c_labelled_clight: clight_program
 ; c_clight_cost_map: clight_cost_map c_labelled_clight
 }.

definition compile : observe_pass → clight_program → res compiler_output ≝ 
λobserve,p.
  ! 〈init_cost,p',p〉 ← front_end observe p;
  ! 〈p,stack_cost,max_stack〉 ← back_end observe p;
  ! p ← assembler p;
  let k ≝ ASM_cost_map p in
  let k' ≝
   lift_cost_map_back_to_front p' (load_code_memory (oc p)) (costlabels p) k in
  return mk_compiler_output p stack_cost max_stack p' k'.