source: src/compiler.ma @ 2794

Last change on this file since 2794 was 2794, checked in by mckinna, 7 years ago

Minor tweaks/tidying up

File size: 2.7 KB
Line 
1include "Clight/label.ma".
2include "Clight/SimplifyCasts.ma".
3include "Clight/switchRemoval.ma".
4include "Clight/toCminor.ma".
5include "Cminor/toRTLabs.ma".
6include "RTLabs/CostCheck.ma".
7include "RTLabs/CostInj.ma".
8
9definition front_end : clight_program → res (costlabel × clight_program × RTLabs_program) ≝
10λp.
11  let p ≝ program_switch_removal p in
12  let 〈p',init_cost〉 ≝ clight_label p in
13  let p ≝ simplify_program p' in
14  ! p ← clight_to_cminor p;
15  let p ≝ cminor_to_rtlabs init_cost p in
16  if check_cost_program p then
17    if check_program_cost_injectivity p then
18      (return 〈init_cost,p',p〉)
19    else
20      (Error ? (msg RepeatedCostLabel))
21  else
22    (Error ? (msg BadCostLabelling)).
23
24include "RTLabs/RTLabsToRTL.ma".
25include "RTL/RTLToERTL.ma".
26include "ERTL/ERTLToERTLptr.ma".
27include "ERTLptr/ERTLptrToLTL.ma".
28include "LTL/LTLToLIN.ma".
29include "LIN/LINToASM.ma".
30
31axiom compute_fixpoint : fixpoint_computer.
32axiom colour_graph : coloured_graph_computer.
33
34definition back_end :
35 RTLabs_program →
36  res (pseudo_assembly_program × stack_cost_model × nat) ≝
37λp.
38  let p ≝ rtlabs_to_rtl p in
39  let p ≝ rtl_to_ertl p in
40  let p ≝ ertl_to_ertlptr p in
41  let 〈p,stack_cost,max_stack〉 ≝ ertlptr_to_ltl compute_fixpoint colour_graph p in (* TODO: abstract over colouring *)
42  let p ≝ ltl_to_lin p in
43   ! p ← opt_to_res ? (msg AssemblyTooLarge) (lin_to_asm p) ;
44   return 〈p,stack_cost,max_stack〉.
45
46include "ASM/Policy.ma".
47
48definition assembler : pseudo_assembly_program → res labelled_object_code ≝
49λp.
50  ! sigma_pol ← opt_to_res ? (msg Jump_expansion_failed) (jump_expansion' p);
51  let sigma ≝ λppc. \fst sigma_pol ppc in
52  let pol ≝ λppc. \snd sigma_pol ppc in
53  OK ? (assembly p sigma pol).
54
55include "ASM/ASMCosts.ma".
56
57definition lift_cost_map_back_to_front :
58  ∀clight, code_memory, lbls.
59    let abstat ≝ ASM_abstract_status code_memory lbls in
60  as_cost_map abstat → clight_cost_map clight ≝
61  λclight,code_memory,lbls,k,asm_cost_map.
62  lift_sigma_map_id … 0 (* labels not present in out code get 0 *)
63    (strong_decidable_in_codomain …) k asm_cost_map.
64
65include "ASM/ASMCostsSplit.ma".
66
67record compiler_output : Type[0] ≝
68 { c_labelled_object_code: labelled_object_code
69 ; c_stack_cost: stack_cost_model
70 ; c_max_stack: nat
71 ; c_labelled_clight: clight_program
72 ; c_clight_cost_map: clight_cost_map c_labelled_clight
73 }.
74
75definition compile : clight_program → res compiler_output ≝
76λp.
77  ! 〈init_cost,p',p〉 ← front_end p;
78  ! 〈p,stack_cost,max_stack〉 ← back_end p;
79  ! p ← assembler p;
80  let k ≝ ASM_cost_map p in
81  let k' ≝
82   lift_cost_map_back_to_front p' (load_code_memory (oc p)) (costlabels p) k in
83  return mk_compiler_output p stack_cost max_stack p' k'.
Note: See TracBrowser for help on using the repository browser.