source: src/compiler.ma @ 2766

Last change on this file since 2766 was 2763, checked in by sacerdot, 7 years ago

All daemons in compiler.ma closed (i.e. proof obligations added
to the sigma type of compiled programs).

File size: 3.8 KB
Line 
1include "Clight/label.ma".
2include "Clight/SimplifyCasts.ma".
3include "Clight/switchRemoval.ma".
4include "Clight/toCminor.ma".
5include "Cminor/toRTLabs.ma".
6include "RTLabs/CostCheck.ma".
7include "RTLabs/CostInj.ma".
8
9definition front_end : clight_program → res (costlabel × clight_program × RTLabs_program) ≝
10λp.
11  let p ≝ program_switch_removal p in
12  let 〈p',init_cost〉 ≝ clight_label p in
13  let p ≝ simplify_program p' in
14  ! p ← clight_to_cminor p;
15  let p ≝ cminor_to_rtlabs init_cost p in
16  if check_cost_program p then
17    if check_program_cost_injectivity p then
18      (return 〈init_cost,p',p〉)
19    else
20      (Error ? (msg RepeatedCostLabel))
21  else
22    (Error ? (msg BadCostLabelling)).
23
24include "RTLabs/RTLabsToRTL.ma".
25include "RTL/RTLToERTL.ma".
26include "ERTL/ERTLToERTLptr.ma".
27include "ERTLptr/ERTLptrToLTL.ma".
28include "LTL/LTLToLIN.ma".
29include "LIN/LINToASM.ma".
30
31axiom compute_fixpoint : fixpoint_computer.
32axiom colour_graph : coloured_graph_computer.
33
34definition back_end : RTLabs_program → pseudo_assembly_program ≝
35λp.
36  let p ≝ rtlabs_to_rtl p in
37  let p ≝ rtl_to_ertl p in
38  let p ≝ ertl_to_ertlptr p in
39  let p ≝ ertlptr_to_ltl compute_fixpoint colour_graph p in (* TODO: abstract over colouring *)
40  let p ≝ ltl_to_lin p in
41          lin_to_asm p.
42
43include "ASM/Policy.ma".
44(* Equivalent to the inclusion of ASM/Policy.ma, waiting for that slow
45   file to compile
46  include "ASM/PolicyStep.ma".
47  axiom jump_expansion': ∀program:preamble × (Σl:list labelled_instruction.lt (S (|l|)) 2^16 ∧ is_well_labelled_p l).
48 option (Σsigma_policy:(Word → Word) × (Word → bool).
49   let 〈sigma,policy〉≝ sigma_policy in
50   sigma_policy_specification 〈\fst program,\snd program〉 sigma policy). *)
51   
52definition assembler : pseudo_assembly_program → res labelled_object_code ≝
53λp.
54(*  ! list_instr_ok ← opt_to_res ? (msg AssemblyTooLarge) ?(*(program_ok_opt ? list_instr)*); *)
55  ! sigma_pol ← opt_to_res ? (msg Jump_expansion_failed) (jump_expansion' p);
56  let sigma ≝ λppc. \fst sigma_pol ppc in
57  let pol ≝ λppc. \snd sigma_pol ppc in
58  OK ? (assembly p sigma pol).
59
60include "ASM/ASMCosts.ma".
61
62(*CSC: move the next definitions, e.g. in BitVectorTrie *)
63definition in_codomain: ∀A:Type[0].∀n:nat. BitVectorTrie A n → A → Prop ≝
64 λA,n,m,a. ∃k:BitVector n. lookup_opt … k m = Some … a.
65
66definition strong_decidable: Prop → Type[0] ≝
67 λP:Prop. P + ¬ P.
68
69lemma strong_decidable_in_codomain:
70 ∀A:DeqSet.∀n:nat.∀m: BitVectorTrie A n.∀a:A.
71  strong_decidable (in_codomain A n m a).
72 #A #n #m elim m
73 [ normalize #a' #a inversion (a' == a) #H
74   [ %1 %{(VEmpty …)} >(\P H) %
75   | %2 % * #_ #EQ destruct lapply (\Pf H) /2/ ]
76 | -n #n #L #R #Hl #Hr #a
77   cases (Hl a) -Hl [#K %1 cases K #k #H %{(false:::k)} <H % ] #Hl
78   cases (Hr a) -Hr [#K %1 cases K #k #H %{(true:::k)}  <H % ] #Hr
79   %2 % * #k cases (BitVector_Sn … k) ** #tl #EQ >EQ whd in ⊢ (??%? → ?);
80   normalize nodelta whd in match (tail ???); #abs [ cases Hr | cases Hl ] /3/
81 | #n #A %2 % * #x normalize #abs destruct ]
82qed.
83
84(* can now move this defn to ASM/ASMCosts.ma *)
85definition lift_cost_map_back_to_front :
86  ∀clight, code_memory, lbls.
87    let abstat ≝ ASM_abstract_status code_memory lbls in
88  as_cost_map abstat → clight_cost_map clight ≝
89  λclight,code_memory,lbls,k,asm_cost_map.
90  lift_sigma_map_id … 0 (* labels not present in out code get 0 *)
91    (strong_decidable_in_codomain …) k asm_cost_map.
92
93include "ASM/ASMCostsSplit.ma".
94
95definition compile : clight_program →
96  res (labelled_object_code × (𝚺labelled:clight_program. clight_cost_map labelled)) ≝
97λp.
98  ! 〈init_cost,p',p〉 ← front_end p;
99  let p ≝ back_end p in
100    ! p ← assembler p;
101  let k ≝ ASM_cost_map p in
102  let k' ≝
103   lift_cost_map_back_to_front p' (load_code_memory (oc p)) (costlabels p) k in
104  return 〈p, ❬p', k'❭〉.
Note: See TracBrowser for help on using the repository browser.