source: src/common/Identifiers.ma @ 2428

Last change on this file since 2428 was 2420, checked in by campbell, 7 years ago

Tidy away generic results about folds on positive/identifier maps.

File size: 37.1 KB
Line 
1include "basics/types.ma".
2include "ASM/String.ma".
3include "utilities/binary/positive.ma".
4include "utilities/lists.ma".
5include "utilities/extralib.ma".
6include "common/Errors.ma".
7
8(* identifiers and their generators are tagged to differentiate them, and to
9   provide extra type checking. *)
10
11(* in common/PreIdentifiers.ma, via Errors.ma.
12inductive identifier (tag:String) : Type[0] ≝
13  an_identifier : Pos → identifier tag.
14*)
15
16record universe (tag:String) : Type[0] ≝
17{
18  next_identifier : Pos
19}.
20
21definition new_universe : ∀tag:String. universe tag ≝
22  λtag. mk_universe tag one.
23
24let rec fresh (tag:String) (u:universe tag) on u : identifier tag × (universe tag) ≝
25  let id ≝ next_identifier ? u in
26  〈an_identifier tag id, mk_universe tag (succ id)〉.
27
28
29let rec fresh_for_univ tag (id:identifier tag) (u:universe tag) on id : Prop ≝
30  match id with [ an_identifier p ⇒ p < next_identifier … u ].
31
32
33lemma fresh_is_fresh : ∀tag,id,u,u'.
34  〈id,u〉 = fresh tag u' →
35  fresh_for_univ tag id u.
36#tag * #id * #u * #u' #E whd in E:(???%); destruct //
37qed.
38
39lemma fresh_remains_fresh : ∀tag,id,id',u,u'.
40  fresh_for_univ tag id u →
41  〈id',u'〉 = fresh tag u →
42  fresh_for_univ tag id u'.
43#tag * #id * #id' * #u * #u' normalize #H #E destruct /2 by le_S/
44qed.
45
46lemma fresh_distinct : ∀tag,id,id',u,u'.
47  fresh_for_univ tag id u →
48  〈id',u'〉 = fresh tag u →
49  id ≠ id'.
50#tag * #id * #id' * #u * #u' normalize #H #E destruct % #E' destruct /2 by absurd/
51qed.
52
53
54let rec env_fresh_for_univ tag A (env:list (identifier tag × A)) (u:universe tag) on u : Prop ≝
55  All ? (λida. fresh_for_univ tag (\fst ida) u) env.
56
57lemma fresh_env_extend : ∀tag,A,env,u,u',id,a.
58  env_fresh_for_univ tag A env u →
59  〈id,u'〉 = fresh tag u →
60  env_fresh_for_univ tag A (〈id,a〉::env) u'.
61#tag #A #env * #u * #u' #id #a
62#H #E whd % [ @(fresh_is_fresh … E) | @(All_mp … H) * #id #a #H' /2 by fresh_remains_fresh/ ]
63qed.
64
65definition eq_identifier : ∀t. identifier t → identifier t → bool ≝
66  λt,l,r.
67  match l with
68  [ an_identifier l' ⇒
69    match r with
70    [ an_identifier r' ⇒
71      eqb l' r'
72    ]
73  ].
74
75lemma eq_identifier_elim : ∀P:bool → Type[0]. ∀t,x,y.
76  (x = y → P true) → (x ≠ y → P false) →
77  P (eq_identifier t x y).
78#P #t * #x * #y #T #F
79change with (P (eqb ??))
80@(eqb_elim x y P) [ /2 by / | * #H @F % #E destruct /2 by / ]
81qed.
82
83lemma eq_identifier_eq:
84  ∀tag: String.
85  ∀l.
86  ∀r.
87    eq_identifier tag l r = true → l = r.
88  #tag #l #r cases l cases r
89  #pos_l #pos_r
90  cases pos_l cases pos_r
91  [1:
92    #_ %
93  |2,3,4,7:
94    #p1_l normalize in ⊢ (% → ?);
95    #absurd destruct(absurd)
96  |5,9:
97    #p1_l #p1_r normalize in ⊢ (% → ?);
98    #relevant lapply (eqb_true_to_eq … relevant) #EQ >EQ %
99  |*:
100    #p_l #p_r normalize in ⊢ (% → ?);
101    #absurd destruct(absurd)
102  ]
103qed.
104
105axiom neq_identifier_neq:
106  ∀tag: String.
107  ∀l, r: identifier tag.
108    eq_identifier tag l r = false → (l = r → False).
109
110include "basics/deqsets.ma".
111definition Deq_identifier : String → DeqSet ≝ λtag.
112  mk_DeqSet (identifier tag) (eq_identifier tag) ?.
113#x#y @eq_identifier_elim /2 by conj/ * #H % [#ABS destruct(ABS) | #G elim (H G)]
114qed.
115
116unification hint 0 ≔ tag; D ≟ Deq_identifier tag
117(*-----------------------------------------------------*)⊢
118identifier tag ≡ carr D.
119
120definition word_of_identifier ≝
121  λt.
122  λl: identifier t.
123  match l with   
124  [ an_identifier l' ⇒ l'
125  ].
126
127lemma eq_identifier_refl : ∀tag,id. eq_identifier tag id id = true.
128#tag * #id whd in ⊢ (??%?); >eqb_n_n @refl
129qed.
130
131axiom eq_identifier_sym:
132  ∀tag: String.
133  ∀l  : identifier tag.
134  ∀r  : identifier tag.
135    eq_identifier tag l r = eq_identifier tag r l.
136
137lemma eq_identifier_false : ∀tag,x,y. x≠y → eq_identifier tag x y = false.
138#tag * #x * #y #NE normalize @not_eq_to_eqb_false /2 by not_to_not/
139qed.
140
141definition identifier_eq : ∀tag:String. ∀x,y:identifier tag. (x=y) + (x≠y).
142#tag * #x * #y lapply (refl ? (eqb x y)) cases (eqb x y) in ⊢ (???% → %);
143#E [ % | %2 ]
144lapply E @eqb_elim
145[ #H #_ >H @refl | 2,3: #_ #H destruct | #H #_ % #H' destruct /2 by absurd/ ]
146qed.
147
148definition identifier_of_nat : ∀tag:String. nat → identifier tag ≝
149  λtag,n. an_identifier tag (succ_pos_of_nat  n).
150
151
152(* States that all identifiers in an environment are distinct from one another. *)
153let rec distinct_env tag (A:Type[0]) (l:list (identifier tag × A)) on l : Prop ≝
154match l with
155[ nil ⇒ True
156| cons hd tl ⇒ All ? (λia. \fst hd ≠ \fst ia) tl ∧
157               distinct_env tag A tl
158].
159
160lemma distinct_env_append_l : ∀tag,A,l,r. distinct_env tag A (l@r) → distinct_env tag A l.
161#tag #A #l elim l
162[ //
163| * #id #a #tl #IH #r * #H1 #H2 % /2 by All_append_l/
164] qed.
165
166lemma distinct_env_append_r : ∀tag,A,l,r. distinct_env tag A (l@r) → distinct_env tag A r.
167#tag #A #l elim l
168[ //
169| * #id #a #tl #IH #r * #H1 #H2 /2 by /
170] qed.
171
172(* check_distinct_env is quadratic - we could pay more attention when building maps to make sure that
173   the original environment was distinct. *)
174
175axiom DuplicateVariable : String.
176
177let rec check_member_env tag (A:Type[0]) (id:identifier tag) (l:list (identifier tag × A)) on l : res (All ? (λia. id ≠ \fst ia) l) ≝
178match l return λl.res (All ?? l) with
179[ nil ⇒ OK ? I
180| cons hd tl ⇒
181    match identifier_eq tag id (\fst hd) with
182    [ inl _ ⇒ Error ? [MSG DuplicateVariable; CTX ? id]
183    | inr NE ⇒
184        do Htl ← check_member_env tag A id tl;
185        OK ? (conj ?? NE Htl)
186    ]
187].
188
189let rec check_distinct_env tag (A:Type[0]) (l:list (identifier tag × A)) on l : res (distinct_env tag A l) ≝
190match l return λl.res (distinct_env tag A l) with
191[ nil ⇒ OK ? I
192| cons hd tl ⇒
193    do Hhd ← check_member_env tag A (\fst hd) tl;
194    do Htl ← check_distinct_env tag A tl;
195    OK ? (conj ?? Hhd Htl)
196].
197
198
199
200
201(* Maps from identifiers to arbitrary types. *)
202
203include "common/PositiveMap.ma".
204
205inductive identifier_map (tag:String) (A:Type[0]) : Type[0] ≝
206  an_id_map : positive_map A → identifier_map tag A.
207 
208definition empty_map : ∀tag:String. ∀A. identifier_map tag A ≝
209  λtag,A. an_id_map tag A (pm_leaf A).
210
211let rec lookup tag A (m:identifier_map tag A) (l:identifier tag) on m : option A ≝
212  lookup_opt A (match l with [ an_identifier l' ⇒ l' ])
213               (match m with [ an_id_map m' ⇒ m' ]).
214
215definition lookup_def ≝
216λtag,A,m,l,d. match lookup tag A m l with [ None ⇒ d | Some x ⇒ x].
217
218definition member ≝
219  λtag,A.λm:identifier_map tag A.λl:identifier tag.
220  match lookup tag A m l with [ None ⇒ false | _ ⇒ true ].
221
222interpretation "identifier map membership" 'mem a b = (member ?? b a).
223
224definition lookup_safe : ∀tag,A.∀m : identifier_map tag A.∀i.i∈m → A ≝
225λtag,A,m,i.
226match lookup … m i return λx.match x in option return λ_.bool with [ _ ⇒ ?] → ? with
227[ Some x ⇒ λ_.x
228| None ⇒ λprf.⊥
229]. @prf qed.
230
231lemma lookup_eq_safe : ∀tag,A,m,i,prf.lookup tag A m i = Some ? (lookup_safe tag A m i prf).
232#tag #A #m #i whd in match (i∈m);
233whd in match lookup_safe; normalize nodelta
234cases (lookup ????) normalize nodelta [*] // qed.
235
236(* Always adds the identifier to the map. *)
237let rec add tag A (m:identifier_map tag A) (l:identifier tag) (a:A) on m : identifier_map tag A ≝
238  an_id_map tag A (insert A (match l with [ an_identifier l' ⇒ l' ]) a
239                            (match m with [ an_id_map m' ⇒ m' ])).
240
241lemma lookup_add_hit : ∀tag,A,m,i,a.
242  lookup tag A (add tag A m i a) i = Some ? a.
243#tag #A * #m * #i #a
244@lookup_opt_insert_hit
245qed.
246
247lemma lookup_def_add_hit : ∀tag,A,m,i,a,d.
248  lookup_def tag A (add tag A m i a) i d = a.
249#tag #A * #m * #i #a #d
250@lookup_insert_hit
251qed.
252
253lemma lookup_add_miss : ∀tag,A,m,i,j,a.
254  i ≠ j →
255  lookup tag A (add tag A m j a) i = lookup tag A m i.
256#tag #A * #m * #i * #j #a #H
257@lookup_opt_insert_miss /2 by not_to_not/
258qed.
259
260axiom lookup_def_add_miss : ∀tag,A,m,i,j,a,d.
261  i ≠ j →
262  lookup_def tag A (add tag A m j a) i d = lookup_def tag A m i d.
263
264lemma lookup_add_oblivious : ∀tag,A,m,i,j,a.
265  (lookup tag A m i ≠ None ?) →
266  lookup tag A (add tag A m j a) i ≠ None ?.
267#tag #A #m #i #j #a #H
268cases (identifier_eq ? i j)
269[ #E >E >lookup_add_hit % #N destruct
270| #NE >lookup_add_miss //
271] qed.
272
273lemma lookup_add_cases : ∀tag,A,m,i,j,a,v.
274  lookup tag A (add tag A m i a) j = Some ? v →
275  (i=j ∧ v = a) ∨ lookup tag A m j = Some ? v.
276#tag #A #m #i #j #a #v
277cases (identifier_eq ? i j)
278[ #E >E >lookup_add_hit #H %1 destruct % //
279| #NE >lookup_add_miss /2 by or_intror, sym_not_eq/
280] qed.
281
282(* Extract every identifier, value pair from the map. *)
283definition elements : ∀tag,A. identifier_map tag A → list (identifier tag × A) ≝
284λtag,A,m.
285  fold ?? (λl,a,el. 〈an_identifier tag l, a〉::el)
286          (match m with [ an_id_map m' ⇒ m' ]) [ ].
287
288(* Test a predicate on all of the entries in a map.  The predicate is given a
289   proof that the entry appears in the map. *)
290
291definition idmap_all : ∀tag,A. ∀m:identifier_map tag A. (∀id,a. lookup tag A m id = Some A a → bool) → bool ≝
292λtag,A,m,f. pm_all A (match m with [ an_id_map m' ⇒ m' ])
293                     (λp,a,H. f (an_identifier tag p) a ?).
294cases m in H ⊢ %; #m' normalize //
295qed.
296
297inductive idmap_pred_graph : ∀tag,A,m,id,a,L. ∀f:(∀id,a. lookup tag A m id = Some A a → bool). bool → Prop ≝
298| idmappg : ∀tag,A,m,id,a,L,f. idmap_pred_graph tag A m id a L f (f id a L).
299
300lemma idmap_pred_irr : ∀tag,A,m,id,a,L,L'. ∀f:(∀id,a. lookup tag A m id = Some A a → bool).
301  f id a L = f id a L'.
302#tag #A #m #id #a #L #L' #f
303cut (idmap_pred_graph tag A m id a L f (f id a L)) [ % ]
304cases (f id a L) #H
305cut (idmap_pred_graph tag A m id a L' f ?) [ 2,5: @H | 1,4: skip ] * //
306qed.
307
308lemma idmap_all_ok : ∀tag,A,m,f.
309  bool_to_Prop (idmap_all tag A m f) ↔ (∀id,a,H. f id a H).
310#tag #A * #m #f
311whd in match (idmap_all ????); @(iff_trans … (pm_all_ok …)) %
312[ #H * #id #a #PR lapply (H id a PR) #X @eq_true_to_b <X @idmap_pred_irr
313| #H #p #a #PR @H
314] qed.
315
316
317axiom MissingId : String.
318
319(* Only updates an existing entry; fails with an error otherwise. *)
320definition update : ∀tag,A. identifier_map tag A → identifier tag → A → res (identifier_map tag A) ≝
321λtag,A,m,l,a.
322  match update A (match l with [ an_identifier l' ⇒ l' ]) a
323                 (match m with [ an_id_map m' ⇒ m' ]) with
324  [ None ⇒ Error ? ([MSG MissingId; CTX tag l]) (* missing identifier *)
325  | Some m' ⇒ OK ? (an_id_map tag A m')
326  ].
327
328(* Fold over the entries in a map.  There are some lemmas to help reason about
329   this near the bottom of the file (they require sets). *)
330
331definition foldi:
332  ∀A, B: Type[0].
333  ∀tag: String.
334  (identifier tag -> A -> B -> B) -> identifier_map tag A -> B -> B ≝
335λA,B,tag,f,m,b.
336  match m with
337  [ an_id_map m' ⇒ fold A B (λbv. f (an_identifier ? bv)) m' b ].
338
339(* An informative, dependently-typed, fold. *)
340
341definition fold_inf:
342  ∀A, B: Type[0].
343  ∀tag: String.
344  ∀m:identifier_map tag A.
345  (∀id:identifier tag. ∀a:A. lookup … m id = Some A a → B → B) → B → B ≝
346λA,B,tag,m.
347  match m return λm. (∀id:identifier tag. ∀a:A. lookup … m id = Some A a → B → B) → B → B with
348  [ an_id_map m' ⇒ λf,b. pm_fold_inf A B m' (λbv,a,H. f (an_identifier ? bv) a H) b ].
349
350(* Find one element of a map that satisfies a predicate *)
351definition find : ∀tag,A. identifier_map tag A → (identifier tag → A → bool) →
352  option (identifier tag × A) ≝
353λtag,A,m,p.
354  match m with [ an_id_map m' ⇒
355    option_map … (λx. 〈an_identifier tag (\fst x), \snd x〉)
356      (pm_find … m' (λid. p (an_identifier tag id))) ].
357
358lemma find_lookup : ∀tag,A,m,p,id,a.
359  find tag A m p = Some ? 〈id,a〉 →
360  lookup … m id = Some ? a.
361#tag #A * #m #p * #id #a #FIND
362@(pm_find_lookup A (λid. p (an_identifier tag id)) id a m)
363whd in FIND:(??%?); cases (pm_find ???) in FIND ⊢ %;
364[ normalize #E destruct
365| * #id' #a' normalize #E destruct %
366] qed.
367
368lemma find_predicate : ∀tag,A,m,p,id,a.
369  find tag A m p = Some ? 〈id,a〉 →
370  p id a.
371#tag #A * #m #p * #id #a #FIND whd in FIND:(??%?);
372@(pm_find_predicate A m (λid. p (an_identifier tag id)) id a)
373cases (pm_find ???) in FIND ⊢ %;
374[ normalize #E destruct
375| * #id' #a' normalize #E destruct %
376] qed.
377
378(* A predicate that an identifier is in a map, and a failure-avoiding lookup
379   and update using it. *)
380
381definition present : ∀tag,A. identifier_map tag A → identifier tag → Prop ≝
382λtag,A,m,i. lookup … m i ≠ None ?.
383
384lemma member_present : ∀tag,A,m,id.
385  member tag A m id = true → present tag A m id.
386#tag #A * #m #id normalize cases (lookup_opt A ??) normalize
387[ #E destruct
388| #x #E % #E' destruct
389] qed.
390
391lemma present_member : ∀tag,A,m,id.
392  present tag A m id → member tag A m id.
393#tag #A #m #id whd in ⊢ (% → ?%); cases (lookup ????) // * #H cases (H (refl ??))
394qed.
395
396definition lookup_present : ∀tag,A. ∀m:identifier_map tag A. ∀id. present ?? m id → A ≝
397λtag,A,m,id. match lookup ?? m id return λx. x ≠ None ? → ? with [ Some a ⇒ λ_. a | None ⇒ λH.⊥ ].
398cases H #H'  cases (H' (refl ??)) qed.
399
400lemma lookup_lookup_present : ∀tag,A,m,id,p.
401  lookup tag A m id = Some ? (lookup_present tag A m id p).
402#tag #A #m #id #p
403whd in p ⊢ (???(??%));
404cases (lookup tag A m id) in p ⊢ %;
405[ * #H @⊥ @H @refl
406| #a #H @refl
407] qed.
408
409lemma lookup_is_present : ∀tag,T,m,id,t.
410  lookup tag T m id = Some T t →
411  present ?? m id.
412#tag #T #m #id #t #L normalize >L % #E destruct
413qed.
414
415lemma lookup_present_eq : ∀tag,T,m,id,t.
416  lookup tag T m id = Some T t →
417  ∀H. lookup_present tag T m id H = t.
418#tag #T #m #id #t #L #H
419lapply (lookup_lookup_present … H) >L #E destruct %
420qed.
421
422
423definition update_present : ∀tag,A. ∀m:identifier_map tag A. ∀id. present ?? m id → A → identifier_map tag A ≝
424λtag,A,m,l,p,a.
425  let l' ≝ match l with [ an_identifier l' ⇒ l' ] in
426  let m' ≝ match m with [ an_id_map m' ⇒ m' ] in
427  let u' ≝ update A l' a m' in
428  match u' return λx. update ???? = x → ? with
429  [ None ⇒ λE.⊥
430  | Some m' ⇒ λ_. an_id_map tag A m'
431  ] (refl ? u').
432cases l in p E; cases m; -l' -m' #m' #l'
433whd in ⊢ (% → ?);
434 whd in ⊢ (?(??(???%%)?) → ??(??%?%)? → ?);
435#NL #U cases NL #H @H @(update_fail … U)
436qed.
437
438lemma update_still_present : ∀tag,A,m,id,a,id'.
439  ∀H:present tag A m id.
440  ∀H':present tag A m id'.
441  present tag A (update_present tag A m id' H' a) id.
442#tag #A * #m * #id #a * #id' #H #H'
443whd whd in ⊢ (?(??(???(%??????)?)?)); normalize nodelta
444cases (identifier_eq ? (an_identifier tag id) (an_identifier tag id'))
445[ #E >E @refute_none_by_refl #m' #U whd in ⊢ (?(??%?)); >(update_lookup_opt_same ????? U)
446  % #E' destruct
447| #NE @refute_none_by_refl #m' #U whd in ⊢ (?(??%?)); whd in ⊢ (?(??(??%%)?));
448  <(update_lookup_opt_other ????? U id) [ @H | % #E cases NE >E #H @H @refl ]
449] qed.
450
451lemma lookup_present_add_hit:
452  ∀tag, A, map, k, v, k_pres.
453    lookup_present tag A (add … map k v) k k_pres = v.
454  #tag #a #map #k #v #k_pres
455  lapply (lookup_lookup_present … (add … map k v) … k_pres)
456  >lookup_add_hit #Some_assm destruct(Some_assm)
457  <e0 %
458qed.
459
460lemma lookup_present_add_miss:
461  ∀tag, A, map, k, k', v, k_pres', k_pres''.
462    k' ≠ k →
463      lookup_present tag A (add … map k v) k' k_pres' = lookup_present tag A map k' k_pres''.
464  #tag #A #map #k #k' #v #k_pres' #k_pres'' #neq_assm
465  lapply (lookup_lookup_present … (add … map k v) ? k_pres')
466  >lookup_add_miss try assumption
467  #Some_assm
468  lapply (lookup_lookup_present … map k') >Some_assm #Some_assm'
469  lapply (Some_assm' k_pres'') #Some_assm'' destruct assumption
470qed.
471
472lemma present_add_present:
473  ∀tag, a, map, k, k', v.
474    k' ≠ k →
475      present tag a (add tag a map k v) k' →
476        present tag a map k'.
477  #tag #a #map #k #k' #v #neq_hyp #present_hyp
478  whd in match present; normalize nodelta
479  whd in match present in present_hyp; normalize nodelta in present_hyp;
480  cases (not_None_to_Some a … present_hyp) #v' #Some_eq_hyp
481  lapply (lookup_add_cases tag ?????? Some_eq_hyp) *
482  [1:
483    * #k_eq_hyp @⊥ /2/
484  |2:
485    #Some_eq_hyp' /2/
486  ]
487qed.
488
489lemma present_add_hit:
490  ∀tag, a, map, k, v.
491    present tag a (add tag a map k v) k.
492  #tag #a #map #k #v
493  whd >lookup_add_hit
494  % #absurd destruct
495qed.
496
497lemma present_add_miss:
498  ∀tag, a, map, k, k', v.
499    present tag a map k' → present tag a (add tag a map k v) k'.
500  #tag #a #map #k #k' #v #present_assm
501  whd @lookup_add_oblivious assumption
502qed.
503
504lemma present_add_cases: ∀tag,A,map,k,v,k'.
505  present tag A (add tag A map k v) k' →
506  k = k' ∨ (k ≠ k' ∧ present tag A map k').
507#tag #A #map #k #v #k' normalize
508cases (identifier_eq ? k k')
509[ #E /2/
510| #NE >lookup_add_miss /3/
511] qed.
512
513
514let rec fresh_for_map tag A (id:identifier tag) (m:identifier_map tag A) on id : Prop ≝
515  lookup … m id = None A.
516
517lemma fresh_for_empty_map : ∀tag,A,id.
518  fresh_for_map tag A id (empty_map tag A).
519#tag #A * #id //
520qed.
521
522definition fresh_map_for_univ ≝
523λtag,A. λm:identifier_map tag A. λu:universe tag.
524  ∀id. present tag A m id → fresh_for_univ tag id u.
525
526lemma fresh_fresh_for_map : ∀tag,A,m,id,u,u'.
527  fresh_map_for_univ tag A m u →
528  〈id,u'〉 = fresh tag u →
529  fresh_for_map tag A id m.
530#tag #A * #m * #id * #u * #u' whd in ⊢ (% → ???% → %);
531#FMU #E destruct lapply (FMU (an_identifier tag u)) whd in ⊢ ((% → %) → ?);
532generalize in ⊢ ((?(??%?) → ?) → ??%?); *
533[ // | #a #H @False_ind lapply (H ?) /2 by absurd/ % #E destruct
534qed.
535
536lemma fresh_map_preserved : ∀tag,A,m,u,u',id.
537  fresh_map_for_univ tag A m u →
538  〈id,u'〉 = fresh tag u →
539  fresh_map_for_univ tag A m u'.
540#tag #A #m #u * #u' #id whd in ⊢ (% → ? → %); #H #E
541#id' #PR @(fresh_remains_fresh … E) @H //
542qed.
543
544lemma fresh_map_add : ∀tag,A,m,u,id,a.
545  fresh_map_for_univ tag A m u →
546  fresh_for_univ tag id u →
547  fresh_map_for_univ tag A (add tag A m id a) u.
548#tag #A * #m #u #id #a #Hm #Hi
549#id' #PR cases (identifier_eq tag id' id)
550[ #E >E @Hi
551| #NE @Hm whd in PR;
552  change with (add tag A (an_id_map tag A m) id a) in PR:(?(??(???%?)?));
553  >lookup_add_miss in PR; //
554] qed.
555
556lemma present_not_fresh : ∀tag,A,m,id,id'.
557  present tag A m id →
558  fresh_for_map tag A id' m →
559  id ≠ id'.
560#tag #A #m #id * #id' whd in ⊢ (% → % → ?);
561* #NE #E % #E' destruct @(NE E)
562qed.
563
564lemma fresh_for_map_add : ∀tag,A,id,m,id',a.
565  id ≠ id' →
566  fresh_for_map tag A id m →
567  fresh_for_map tag A id (add tag A m id' a).
568#tag #A * #id #m #id' #a #NE #F
569whd >lookup_add_miss //
570qed.
571
572(* Extending the domain of a map (without necessarily preserving contents). *)
573
574definition extends_domain : ∀tag,A. identifier_map tag A → identifier_map tag A → Prop ≝
575λtag,A,m1,m2. ∀l. present ?? m1 l → present ?? m2 l.
576
577lemma extends_dom_trans : ∀tag,A,m1,m2,m3.
578  extends_domain tag A m1 m2 → extends_domain tag A m2 m3 → extends_domain tag A m1 m3.
579#tag #A #m1 #m2 #m3 #H1 #H2 #l #P1 @H2 @H1 @P1 qed.
580
581
582(* Sets *)
583
584definition identifier_set ≝ λtag.identifier_map tag unit.
585
586definition empty_set : ∀tag.identifier_set tag ≝ λtag.empty_map ….
587
588
589definition add_set : ∀tag.identifier_set tag → identifier tag → identifier_set tag ≝
590  λtag,s,i.add … s i it.
591
592definition singleton_set : ∀tag:String. identifier tag → identifier_set tag ≝
593λtag,i. add_set tag (empty_set tag) i.
594
595let rec union_set (tag:String) A B (s:identifier_map tag A) (s':identifier_map tag B) on s : identifier_set tag ≝
596  an_id_map tag unit (merge … (λo,o'.match o with [Some _ ⇒ Some ? it | None ⇒ !_ o'; return it])
597    (match s with [ an_id_map s0 ⇒ s0 ])
598    (match s' with [ an_id_map s1 ⇒ s1 ])).
599
600
601(* set minus is generalised to maps *)
602let rec minus_set (tag:String) A B (s:identifier_map tag A) (s':identifier_map tag B) on s : identifier_map tag A ≝
603  an_id_map tag A (merge A B A (λo,o'.match o' with [None ⇒ o | Some _ ⇒ None ?])
604    (match s with [ an_id_map s0 ⇒ s0 ])
605    (match s' with [ an_id_map s1 ⇒ s1 ])).
606
607notation "a ∖ b" left associative with precedence 55 for @{'setminus $a $b}.
608
609interpretation "identifier set union" 'union a b = (union_set ??? a b).
610notation "∅" non associative with precedence 90 for @{ 'empty }.
611interpretation "empty identifier set" 'empty = (empty_set ?).
612interpretation "singleton identifier set" 'singl a = (add_set ? (empty_set ?) a).
613interpretation "identifier map difference" 'setminus a b = (minus_set ??? a b).
614
615definition IdentifierSet : String → Setoid ≝ λtag.
616  mk_Setoid (identifier_set tag) (λs,s'.∀i.i ∈ s = (i ∈ s')) ???.
617  // qed.
618
619unification hint 0 ≔ tag;
620S ≟ IdentifierSet tag
621(*-----------------------------*)⊢
622identifier_set tag ≡ std_supp S.
623unification hint 0 ≔ tag;
624S ≟ IdentifierSet tag
625(*-----------------------------*)⊢
626identifier_map tag unit ≡ std_supp S.
627
628lemma mem_set_add : ∀tag,A.∀i,j : identifier tag.∀s,x.
629  i ∈ add ? A s j x = (eq_identifier ? i j ∨ i ∈ s).
630#tag #A *#i *#j *#s #x normalize
631@(eqb_elim i j)
632[#EQ destruct
633  >(lookup_opt_insert_hit A x j)
634|#NEQ >(lookup_opt_insert_miss … s NEQ)
635] elim (lookup_opt  A j s) normalize // qed.
636
637lemma mem_set_add_id : ∀tag,A,i,s,x.bool_to_Prop (i ∈ add tag A s i x).
638#tag #A #i #s #x >mem_set_add
639@eq_identifier_elim [#_ %| #ABS elim (absurd … (refl ? i) ABS)] qed.
640
641lemma in_map_domain : ∀tag,A.∀m : identifier_map tag A.∀i.
642  if i ∈ m then (∃s.lookup … m i = Some ? s) else (lookup … m i = None ?).
643#tag #A * #m * #i normalize
644elim (lookup_opt A i m) normalize
645[ % | #x %{x} % ]
646qed.
647
648lemma union_empty_l : ∀tag.∀s:identifier_set tag. ∅ ∪ s = s.
649#tag * normalize #m >map_opt_id_eq_ext // * %
650qed.
651
652lemma union_empty_r : ∀tag.∀s:identifier_set tag. s ∪ ∅ = s.
653#tag * * [//] *[2: *] #l#r normalize
654>map_opt_id_eq_ext [1,3: >map_opt_id_eq_ext [2,4: *] |*: *] //
655qed.
656
657lemma minus_empty_l : ∀tag,A.∀s:identifier_map tag A. ∅ ∖ s ≅ ∅.
658#tag #A * * [//] *[2:#x]#l#r * * normalize [1,4://]
659#p >lookup_opt_map elim (lookup_opt ???) normalize //
660qed.
661
662lemma minus_empty_r : ∀tag,A.∀s:identifier_map tag A. s ∖ ∅ = s.
663#tag #A * * [//] *[2:#x]#l#r normalize
664>map_opt_id >map_opt_id //
665qed.
666
667lemma mem_set_union : ∀tag.∀i : identifier tag.∀s,s' : identifier_set tag.
668  i ∈ (s ∪ s') = (i ∈ s ∨ i ∈ s').
669#tag * #i * #s * #s' normalize
670>lookup_opt_merge [2: @refl]
671elim (lookup_opt ???)
672elim (lookup_opt ???)
673normalize // qed.
674
675lemma mem_set_minus : ∀tag,A,B.∀i : identifier tag.∀s : identifier_map tag A.
676  ∀s' : identifier_map tag B.
677  i ∈ (s ∖ s') = (i ∈ s ∧ ¬ i ∈ s').
678#tag #A #B * #i * #s * #s' normalize
679>lookup_opt_merge [2: @refl]
680elim (lookup_opt ???)
681elim (lookup_opt ???)
682normalize // qed.
683
684lemma set_eq_ext_node : ∀tag.∀o,o',l,l',r,r'.
685  an_id_map tag ? (pm_node ? o l r) ≅ an_id_map … (pm_node ? o' l' r') →
686    o = o' ∧ an_id_map tag ? l ≅ an_id_map … l' ∧ an_id_map tag ? r ≅ an_id_map … r'.
687#tag#o#o'#l#l'#r#r'#H
688%[
689%[ lapply (H (an_identifier ? one))
690   elim o [2: *] elim o' [2,4: *] normalize // #EQ destruct
691 | *#p lapply (H (an_identifier ? (p0 p))) normalize //
692]| *#p lapply (H (an_identifier ? (p1 p))) normalize //
693]
694qed.
695
696lemma set_eq_ext_leaf : ∀tag,A.∀o,l,r.
697  (∀i.i∈an_id_map tag A (pm_node ? o l r) = false) →
698    o = None ? ∧ (∀i.i∈an_id_map tag ? l = false) ∧ (∀i.i∈an_id_map tag ? r = false).
699#tag#A#o#l#r#H
700%[
701%[ lapply (H (an_identifier ? one))
702   elim o [2: #a] normalize // #EQ destruct
703 | *#p lapply (H (an_identifier ? (p0 p))) normalize //
704]| *#p lapply (H (an_identifier ? (p1 p))) normalize //
705]
706qed.
707
708
709definition id_map_size : ∀tag : String.∀A. identifier_map tag A → ℕ ≝
710  λtag,A,s.match s with [an_id_map p ⇒ |p|].
711
712interpretation "identifier map domain size" 'norm s = (id_map_size ?? s).
713
714lemma set_eq_ext_empty_to_card : ∀tag,A.∀s : identifier_map tag A. (∀i.i∈s = false) → |s| = 0.
715#tag#A * #s elim s [//]
716#o#l#r normalize in ⊢((?→%)→(?→%)→?); #Hil #Hir #H
717elim (set_eq_ext_leaf … H) * #EQ destruct #Hl #Hr normalize
718>(Hil Hl) >(Hir Hr) // qed.
719
720lemma set_eq_ext_to_card : ∀tag.∀s,s' : identifier_set tag. s ≅ s' → |s| = |s'|.
721#tag *#s elim s
722[** [//] #o#l#r #H
723  >(set_eq_ext_empty_to_card … (std_symm … H)) //
724| #o#l#r normalize in ⊢((?→?→??%?)→(?→?→??%?)→?);
725  #Hil #Hir **
726  [#H @(set_eq_ext_empty_to_card … H)]
727  #o'#l'#r' #H elim (set_eq_ext_node … H) * #EQ destruct(EQ) #Hl #Hr
728  normalize >(Hil ? Hl) >(Hir ? Hr) //
729] qed.
730
731lemma add_size: ∀tag,A,s,i,x.
732  |add tag A s i x| = (if i ∈ s then 0 else 1) + |s|.
733#tag #A *#s *#i #x
734lapply (insert_size ? i x s)
735lapply (refl ? (lookup_opt ? i s))
736generalize in ⊢ (???%→?); * [2: #x']
737normalize #EQ >EQ normalize //
738qed.
739
740lemma mem_set_O_lt_card : ∀tag,A.∀i.∀s : identifier_map tag A. i ∈ s → |s| > 0.
741#tag #A * #i * #s normalize #H
742@(lookup_opt_O_lt_size … i)
743% #EQ >EQ in H; normalize *
744qed.
745
746(* NB: no control on values if applied to maps *)
747definition set_subset ≝ λtag,A,B.λs : identifier_map tag A.
748  λs' : identifier_map tag B. ∀i.i ∈ s → (bool_to_Prop (i ∈ s')).
749
750interpretation "identifier set subset" 'subseteq s s' = (set_subset ??? s s').
751
752lemma add_subset :
753  ∀tag,A,B.∀i : identifier tag.∀x.∀s : identifier_map ? A.∀s' : identifier_map ? B.
754    i ∈ s' → s ⊆ s' → add … s i x ⊆ s'.
755#tag#A#B#i#x#s#s' #H #G #j
756>mem_set_add
757@eq_identifier_elim #H' [* >H' @H | #js @(G ? js)]
758qed.
759
760definition set_forall : ∀tag,A.(identifier tag → Prop) →
761  identifier_map tag A → Prop ≝ λtag,A,P,m.∀i. i ∈ m → P i.
762 
763lemma set_forall_add : ∀tag,P,m,i.set_forall tag ? P m → P i →
764  set_forall tag ? P (add_set ? m i).
765#tag#P#m#i#Pm#Pi#j
766>mem_set_add
767@eq_identifier_elim
768[#EQ destruct(EQ) #_ @Pi
769|#_ @Pm
770]
771qed.
772
773include "utilities/proper.ma".
774
775lemma minus_subset : ∀tag,A,B.minus_set tag A B ⊨ set_subset … ++> set_subset … -+> set_subset ….
776#tag#A#B#s#s' #H #s'' #s''' #G #i
777>mem_set_minus >mem_set_minus
778#H' elim (andb_Prop_true … H') -H' #is #nis''
779>(H … is)
780elim (true_or_false_Prop (i∈s'''))
781[ #is''' >(G … is''') in nis''; *
782| #nis''' >nis''' %
783]
784qed.
785
786lemma subset_node : ∀tag,A,B.∀o,o',l,l',r,r'.
787  an_id_map tag A (pm_node ? o l r) ⊆ an_id_map tag B (pm_node ? o' l' r') →
788    opt_All ? (λ_.o' ≠ None ?) o ∧ an_id_map tag ? l ⊆ an_id_map tag  ? l' ∧
789      an_id_map tag ? r ⊆ an_id_map tag ? r'.
790#tag#A#B#o#o'#l#l'#r#r'#H
791%[%
792  [ lapply (H (an_identifier ? (one))) elim o [2: #a] elim o' [2:#b]
793    normalize // [#_ % #ABS destruct(ABS) | #G lapply (G I) *]
794  | *#p lapply (H (an_identifier ? (p0 p)))
795  ]
796 | *#p lapply (H (an_identifier ? (p1 p)))
797] #H @H
798qed.
799
800lemma subset_leaf : ∀tag,A.∀o,l,r.
801  an_id_map tag A (pm_node ? o l r) ⊆ ∅ →
802    o = None ? ∧ (∀i.i∈an_id_map tag ? l = false) ∧ (∀i.i∈an_id_map tag ? r = false).
803#tag#A#o#l#r#H
804%[
805%[ lapply (H (an_identifier ? one))
806   elim o [2: #a] normalize // #EQ lapply(EQ I) *
807 | *#p lapply (H (an_identifier ? (p0 p)))
808 ]
809|  *#p lapply (H (an_identifier ? (p1 p)))
810] normalize elim (lookup_opt ? p ?) normalize
811// #a #H lapply (H I) *
812qed.
813
814lemma subset_card : ∀tag,A,B.∀s : identifier_map tag A.∀s' : identifier_map tag B.
815  s ⊆ s' → |s| ≤ |s'|.
816#tag #A #B *#s elim s
817[ //
818| #o#l#r #Hil #Hir **
819  [ #H elim (subset_leaf … H) * #EQ >EQ #Hl #Hr
820    lapply (set_eq_ext_empty_to_card … Hl)
821    lapply (set_eq_ext_empty_to_card … Hr)
822    normalize //
823  | #o' #l' #r' #H elim (subset_node … H) *
824    elim o [2: #a] elim o' [2,4: #a']
825    [3: #G normalize in G; elim(absurd ? (refl ??) G)
826    |*: #_ #Hl #Hr lapply (Hil ? Hl) lapply (Hir ? Hr)
827      normalize #H1 #H2
828      [@le_S_S | @(transitive_le … (|l'|+|r'|)) [2: / by /]]
829      @le_plus assumption
830    ]
831  ]
832]
833qed.
834
835lemma mem_set_empty : ∀tag,A.∀i: identifier tag. i∈empty_map tag A = false.
836#tag #A * #i normalize %
837qed.
838
839lemma mem_set_singl_to_eq : ∀tag.∀i,j : identifier tag.i∈{(j)} → i = j.
840#tag
841#i #j >mem_set_add >mem_set_empty
842#H elim (orb_true_l … H) -H
843[@eq_identifier_elim [//] #_] #EQ destruct
844qed.
845
846lemma subset_add_set : ∀tag,i,s.s ⊆ add_set tag s i.
847#tag#i#s#j #H >mem_set_add >H
848>commutative_orb %
849qed.
850
851lemma add_set_monotonic : ∀tag,i,s,s'.s ⊆ s' → add_set tag s i ⊆ add_set tag s' i.
852#tag#i#s#s' #H #j >mem_set_add >mem_set_add
853@orb_elim elim (eq_identifier ???)
854whd lapply (H j) /2 by /
855qed.
856
857lemma transitive_subset : ∀tag,A.transitive ? (set_subset tag A A).
858#tag#A#s#s'#s''#H#G#i #is
859@(G … (H … is))
860qed.
861
862definition set_from_list : ∀tag.list (identifier tag) → identifier_map tag unit ≝
863  λtag.foldl … (add_set ?) ∅.
864
865coercion id_set_from_list : ∀tag.∀l : list (identifier tag).identifier_map tag unit ≝
866  set_from_list on _l : list (identifier ?) to identifier_map ? unit.
867
868lemma mem_map_domain : ∀tag,A.∀m : identifier_map tag A.∀i.
869i∈m → lookup … m i ≠ None ?.
870#tag#A * #m #i
871whd in match (i∈?);
872elim (lookup ????) normalize [2: #x]
873* % #EQ destruct(EQ)
874qed.
875
876
877
878lemma mem_list_as_set : ∀tag.∀l : list (identifier tag).
879  ∀i.i ∈ l → In ? l i.
880#tag #l @(list_elim_left … l)
881[ #i *
882| #t #h #Hi  #i
883  whd in ⊢ (?(???%?)→?);
884  >foldl_append
885  whd in ⊢ (?(???%?)→?);
886  >mem_set_add
887  @eq_identifier_elim
888  [ #EQi destruct(EQi)
889    #_ @Exists_append_r % %
890  | #_ #H @Exists_append_l @Hi assumption
891  ]
892]
893qed.
894
895lemma list_as_set_mem : ∀tag.∀l : list (identifier tag).
896  ∀i.In ? l i → i ∈ l.
897#tag #l @(list_elim_left … l)
898[ #i *
899| #t #h #Hi #i #H
900  whd in ⊢ (?(???%?));
901  >foldl_append
902  whd in ⊢ (?(???%?));
903  elim (Exists_append … H) -H
904  [ #H >mem_set_add
905    @eq_identifier_elim [//] #_ normalize
906    @Hi @H
907  | * [2: *] #EQi destruct(EQi) >mem_set_add_id %
908  ]
909]
910qed.
911
912lemma list_as_set_All : ∀tag,P.∀ l : list (identifier tag).
913  (∀i.i ∈ l → P i) → All ? P l.
914#tag #P #l @(list_elim_left … l)
915[ #_ %
916| #x #l' #Hi
917  whd in match (set_from_list … (l'@[x]));
918  >foldl_append
919  #H @All_append
920  [ @Hi #i #G @H
921    whd in ⊢ (?(???%?));
922    >mem_set_add @orb_Prop_r @G
923  | % [2: %]
924    @H
925    whd in ⊢ (?(???%?));
926    @mem_set_add_id
927  ]
928]
929qed.
930
931lemma All_list_as_set : ∀tag,P.∀ l : list (identifier tag).
932  All ? P l → ∀i.i ∈ l → P i.
933#tag #P #l @(list_elim_left … l)
934[ * #i *
935| #x #l' #Hi #H
936  lapply (All_append_l … H)
937  lapply (All_append_r … H)
938  * #Px * #Pl' #i
939  whd in match (set_from_list … (l'@[x]));
940  >foldl_append
941  >mem_set_add
942  @eq_identifier_elim
943  [ #EQx >EQx #_ @Px
944  | #_ whd in match (?∨?); @Hi @Pl'
945  ]
946]
947qed. 
948
949lemma map_mem_prop :
950  ∀tag,A.∀m : identifier_map tag A.∀i.
951  lookup ?? m i ≠ None ? → i ∈ m.
952#p #globals #m #i
953lapply (in_map_domain … m i)
954cases (i∈m)
955[ * #x #_ #_ %
956| #EQ >EQ * #ABS @ABS %
957] qed.
958
959
960(* Attempt to choose an entry in the map/set, and if successful return the entry
961   and the map/set without it. *)
962
963definition choose : ∀tag,A. identifier_map tag A → option (identifier tag × A × (identifier_map tag A)) ≝
964λtag,A,m.
965  match pm_choose A (match m with [ an_id_map m' ⇒ m' ]) with
966  [ None ⇒ None ?
967  | Some x ⇒ Some ? 〈〈an_identifier tag (\fst (\fst x)), \snd (\fst x)〉, an_id_map tag A (\snd x)〉
968  ].
969
970lemma choose_empty : ∀tag,A,m.
971  choose tag A m = None ? ↔ ∀id. lookup tag A m id = None ?.
972#tag #A * #m lapply (pm_choose_empty A m) * #H1 #H2 %
973[ normalize #C * @H1 cases (pm_choose A m) in C ⊢ %; [ // | normalize #x #E destruct ]
974| normalize #L lapply (pm_choose_empty A m) cases (pm_choose A m)
975  [ * #H1 #H2 normalize // | #x * #_ #H lapply (H ?) [ #p @(L (an_identifier ? p)) | #E destruct ] ]
976] qed.
977
978lemma choose_some : ∀tag,A,m,id,a,m'.
979  choose tag A m = Some ? 〈〈id,a〉,m'〉 →
980  lookup tag A m id = Some A a ∧
981  lookup tag A m' id = None A ∧
982  (∀id'. id = id' ∨ lookup tag A m id' = lookup tag A m' id').
983#tag #A * #m * #id #a * #m' #C
984lapply (pm_choose_some A m id a m' ?)
985[ whd in C:(??%?); cases (pm_choose A m) in C ⊢ %; normalize [ #E destruct | * * #x #y #z #E destruct % ] ]
986* * * #L1 #L2 #L3 #_
987% [ % [ @L1 | @L2 ] | * #id' cases (L3 id') [ /2/ | #L4 %2 @L4 ] ]
988qed.
989
990lemma choose_some_subset : ∀tag,A,m,id,a,m'.
991  choose tag A m = Some ? 〈〈id,a〉,m'〉 →
992  m' ⊆ m.
993#tag #A #m #id #a #m' #C
994cases (choose_some … m' C) * #L1 #L2 #L3
995#id' whd in ⊢ (?% → ?%);
996cases (L3 id')
997[ #E destruct >L2 *
998| #L4 >L4 //
999] qed.
1000
1001lemma choose_some_card : ∀tag,A,m,id,a,m'.
1002  choose tag A m = Some ? 〈〈id,a〉,m'〉 →
1003  |m| = S (|m'|).
1004#tag #A * #m * #id #a * #m' #C
1005lapply (pm_choose_some A m id a m' ?)
1006[ whd in C:(??%?); cases (pm_choose A m) in C ⊢ %; normalize [ #E destruct | * * #x #y #z #E destruct % ] ]
1007* #_ #H @H
1008qed.
1009
1010(* Remove an element from a map/set, returning the element and a new map/set. *)
1011
1012definition try_remove : ∀tag,A. identifier_map tag A → identifier tag → option (A × (identifier_map tag A)) ≝
1013λtag,A,m,id.
1014  match pm_try_remove A (match id with [ an_identifier id' ⇒ id']) (match m with [ an_id_map m' ⇒ m' ]) with
1015  [ None ⇒ None ?
1016  | Some x ⇒ Some ? 〈\fst x, an_id_map tag A (\snd x)〉
1017  ].
1018
1019lemma try_remove_empty : ∀tag,A,m,id.
1020  try_remove tag A m id = None ? ↔ lookup tag A m id = None ?.
1021#tag #A * #m * #id lapply (pm_try_remove_none A id m) * #H1 #H2 %
1022[ normalize #C @H1 cases (pm_try_remove A id m) in C ⊢ %; [ // | normalize #x #E destruct ]
1023| normalize #L >H2 //
1024] qed.
1025
1026lemma try_remove_some : ∀tag,A,m,id,a,m'.
1027  try_remove tag A m id = Some ? 〈a,m'〉 →
1028  lookup tag A m id = Some A a ∧
1029  lookup tag A m' id = None A ∧
1030  (∀id'. id = id' ∨ lookup tag A m id' = lookup tag A m' id').
1031#tag #A * #m * #id #a * #m' #C
1032lapply (pm_try_remove_some A id m a m' ?)
1033[ whd in C:(??%?); cases (pm_try_remove A id m) in C ⊢ %; normalize [ #E destruct | * #x #y #E destruct % ] ]
1034* * * #L1 #L2 #L3 #_
1035% [ % [ @L1 | @L2 ] | * #id' cases (L3 id') [ /2/ | #L4 %2 @L4 ] ]
1036qed.
1037
1038lemma try_remove_some_card : ∀tag,A,m,id,a,m'.
1039  try_remove tag A m id = Some ? 〈a,m'〉 →
1040  |m| = S (|m'|).
1041#tag #A * #m * #id #a * #m' #C
1042lapply (pm_try_remove_some A id m a m' ?)
1043[ whd in C:(??%?); cases (pm_try_remove A id m) in C ⊢ %; normalize [ #E destruct | * #x #y #E destruct % ] ]
1044* #_ #H @H
1045qed.
1046
1047lemma try_remove_this : ∀tag,A,m,id,a.
1048  lookup tag A m id = Some A a →
1049  ∃m'. try_remove tag A m id = Some ? 〈a,m'〉.
1050#tag #A * #m * #id #a #L
1051cases (pm_try_remove_some' A id m a L)
1052#m' #R %{(an_id_map tag A m')} whd in ⊢ (??%?); >R %
1053qed.
1054 
1055(* Link a map with the set consisting of its domain. *)
1056
1057definition id_set_of_map : ∀tag,A. identifier_map tag A → identifier_set tag ≝
1058λtag,A,m. an_id_map tag unit (map … (λ_. it) (match m with [ an_id_map m' ⇒ m'])).
1059
1060lemma id_set_of_map_subset : ∀tag,A,m.
1061  id_set_of_map tag A m ⊆ m.
1062#tag #A * #m * #id normalize
1063>lookup_opt_map normalize cases (lookup_opt ???) //
1064qed.
1065
1066lemma id_set_of_map_present : ∀tag,A,m,id.
1067  present tag A m id ↔ present tag unit (id_set_of_map … m) id.
1068#tag #A * #m * #id %
1069normalize @not_to_not
1070>lookup_opt_map cases (lookup_opt ???) normalize //
1071#a #E destruct
1072qed.
1073
1074lemma id_set_of_map_card : ∀tag,A,m.
1075  |m| = |id_set_of_map tag A m|.
1076#tag #A * #m whd in ⊢ (??%%); >map_size //
1077qed.
1078
1079
1080(* Transforming a list into a set. *)
1081
1082definition set_of_list : ∀tag. list (identifier tag) → identifier_set tag ≝
1083λtag,l. foldl ?? (λs,id. add_set tag s id) ∅ l.
1084
1085lemma fold_add_set_monotone : ∀tag,l,s,id.
1086  present tag unit s id →
1087  present tag unit (foldl ?? (λs,id. add_set tag s id) s l) id.
1088#tag #l elim l
1089[ //
1090| #h #t #IH #s #id #PR
1091  whd in ⊢ (???%?); @IH
1092  @lookup_add_oblivious
1093  @PR
1094] qed.
1095
1096lemma in_set_of_list : ∀tag,l,id.
1097  Exists ? (λid'. id' = id) l →
1098  present ?? (set_of_list tag l) id.
1099#tag #l #id whd in match (set_of_list ??); generalize in match ∅; elim l
1100[ #s *
1101| #id' #tl #IH #s *
1102  [ #E whd in ⊢ (???%?); destruct
1103    @fold_add_set_monotone //
1104  | @IH
1105  ]
1106] qed.
1107
1108lemma in_set_of_list' : ∀tag,l,id.
1109  present ?? (set_of_list tag l) id →
1110  Exists ? (λid'. id = id') l.
1111#tag #l #id whd in match (set_of_list ??);
1112cut (¬present ?? ∅ id) [ /3/ ]
1113generalize in match ∅;
1114elim l
1115[ #s #F #T @⊥ @(absurd … T F)
1116| #id' #tl #IH #s #F #PR whd in PR:(???%?);
1117  cases (identifier_eq … id id')
1118  [ #E destruct /2/
1119  | #NE %2 @(IH … PR)
1120    @(not_to_not … F) /2/
1121  ]
1122] qed.
1123
1124
1125(* Returns the domain of a map as the canonical set (one made only from the
1126   empty set and addition. *)
1127definition domain_of_map : ∀tag,A. identifier_map tag A → identifier_set tag ≝
1128λtag,A,m. an_id_map tag unit (domain_of_pm A (match m with [ an_id_map m ⇒ m ])).
1129lemma domain_of_map_present : ∀tag,A,m,id.
1130  present tag A m id ↔ present tag unit (domain_of_map … m) id.
1131#tag #A * #m * #p @domain_of_pm_present
1132qed.
1133
1134(* Some lemmas for reasoning about folds. *)
1135
1136lemma foldi_ind : ∀A,B,tag,f,m,b. ∀P:B → identifier_set tag → Prop.
1137  P b (empty_set …) →
1138  (∀k,ks,a,b. ¬present ?? ks k → lookup ?? m k = Some ? a → P b ks → P (f k a b) (add_set tag ks k)) →
1139  P (foldi A B tag f m b) (domain_of_map … m).
1140#A #B #tag #f * #m #b #P #P0 #STEP
1141whd in match (foldi ??????); change with (an_id_map ?? (domain_of_pm A m)) in match (domain_of_map ???);
1142@pm_fold_ind
1143[ @P0
1144| #p #ps #a #b0 #FR #L #pre @(STEP (an_identifier tag p) (an_id_map tag unit ps))
1145  [ normalize >FR /3/
1146  | @L
1147  | @pre
1148  ]
1149] qed.
1150
1151lemma foldi_ind' : ∀A,B,tag,f,m,b,b'. ∀P:B → identifier_set tag → Prop.
1152  P b (empty_set …) →
1153  (∀k,ks,a,b. ¬present ?? ks k → lookup ?? m k = Some ? a → P b ks → P (f k a b) (add_set tag ks k)) →
1154  foldi A B tag f m b = b' →
1155  P b' (domain_of_map … m).
1156#H1 #H2 #H3 #H4 #H5 #H6 #H7 #H8 #H9 #H10 #H11  destruct @foldi_ind /2/
1157qed.
1158
Note: See TracBrowser for help on using the repository browser.