source: src/common/Animation.ma @ 950

include "common/IO.ma".
include "common/SmallstepExec.ma".

(* Functions to allow programs to be executed up to some number of steps, given
   a predetermined set of input values.  Note that we throw away the state if
   we stop at a continuation - it can be too large to work with. *)

definition get_input : ∀o:io_out. eventval → res (io_in o) ≝
λo,ev.
match io_in_typ o return λt. res (eventval_type t) with
[ ASTint _ _ ⇒ match ev with [ EVint i ⇒ OK ? i | _ ⇒ Error ? (msg IllTypedEvent) ]
| ASTfloat _ ⇒ match ev with [ EVfloat f ⇒ OK ? f | _ ⇒ Error ? (msg IllTypedEvent) ]
| ASTptr _ ⇒ Error ? (msg IllTypedEvent)
].

inductive snapshot (state:Type[0]) : Type[0] ≝
| running : trace → state → snapshot state
| finished : trace → int → mem → snapshot state
| input_exhausted : trace → snapshot state.

axiom StoppedMidIO : String.

let rec up_to_nth_step (n:nat) (ex:execstep io_out io_in) (input:list eventval) (e:execution (state ?? ex) io_out io_in) (t:trace) : res (snapshot (state ?? ex)) ≝
match n with
[ O ⇒ match e with [ e_step tr s _ ⇒ OK ? (running ? (t⧺tr) s)
                   | e_stop tr r m ⇒ OK ? (finished ? (t⧺tr) r m)
                   | e_interact o k ⇒ Error ? (msg StoppedMidIO)
                   | e_wrong m ⇒ Error ? m ]
| S m ⇒ match e with [ e_step tr s e' ⇒ up_to_nth_step m ex input e' (t⧺tr)
                     | e_stop tr r m ⇒ OK ? (finished ? (t⧺tr) r m)
                     | e_interact o k ⇒ 
                         match input with
                         [ nil ⇒ OK ? (input_exhausted ? t)
                         | cons h tl ⇒ do i ← get_input o h;
                                       up_to_nth_step m ex tl (k i) t
                         ]
                     | e_wrong m ⇒ Error ? m
                     ]
].

definition exec_up_to : ∀fx:fullexec io_out io_in. program ?? fx → nat → list eventval → res (snapshot (state ?? fx)) ≝
λfx,p,n,i. up_to_nth_step n fx i (exec_inf ?? fx p) E0.

(* Provide an easy way to get a term in proof mode for reduction.
   For example,
   
   example exec: result ? (exec_up_to myprog 20 [EVint (repr 12)]).
   normalize  (* you can examine the result here *)
   % qed.
   
 *)

inductive result (A:Type[0]) : A → Type[0] ≝
| witness : ∀a:A. result A a.

definition finishes_with : int → ∀S.res (snapshot S) → Prop ≝
λr,S,s. match s with [ OK s' ⇒ match s' with [ finished t r' _ ⇒ r = r' | _ ⇒ False ] | _ ⇒ False ].

(* Hide the representation of memory to make displaying the results easier. *)

notation < "'MEM'" with precedence 1 for @{ 'mem }.
interpretation "hide memory" 'mem = (mk_mem ???).