source: src/RTLabs/syntax.ma @ 878

include "basics/logic.ma".

include "common/AST.ma".
include "common/CostLabel.ma".
include "common/FrontEndOps.ma".
include "common/Registers.ma".

include "ASM/Vector.ma".
include "common/Graphs.ma".

(* XXX: ASTish stuff *)

definition immediate : Type[0] ≝ int.

(* Addressing modes *)

inductive addressing : Type[0] ≝
| Aindexed  : immediate → addressing         (* r1 + offset *)
| Aindexed2 : addressing                     (* r1 + r2 *)
| Aglobal   : ident → immediate → addressing (* global + offset *)
| Abased    : ident → immediate → addressing (* global + offset + r1 *)
| Ainstack  : immediate → addressing         (* stack + offset *)
.

definition addr_mode_args : addressing → nat ≝
λa. match a with
[ Aindexed _  ⇒ 1
| Aindexed2   ⇒ 2
| Aglobal _ _ ⇒ 0
| Abased _ _  ⇒ 1
| Ainstack _  ⇒ 0
].

definition addr ≝ λm.Vector register (addr_mode_args m).

(* Statements, including the label of successor(s). *)

inductive statement : Type[0] ≝
| St_skip : label → statement
| St_cost : costlabel → label → statement
| St_const : register → constant → label → statement
| St_op1 : unary_operation → register → register → label → statement
| St_op2 : binary_operation → register → register → register → label → statement
| St_load : memory_chunk → ∀m:addressing. addr m → register → label → statement
| St_store : memory_chunk → ∀m:addressing. addr m → register → label → statement
| St_call_id : ident → list register → option register → label → statement
| St_call_ptr : register → list register → option register → label → statement
| St_tailcall_id : ident → list register → statement
| St_tailcall_ptr : register → list register → statement
(* Um, what? *)
| St_condcst : constant → label → label → statement
| St_cond1 : unary_operation → register → label → label → statement
| St_cond2 : binary_operation → register → register → label → label → statement
| St_jumptable : register → list label → statement
| St_return : statement
.

record internal_function : Type[0] ≝
{ f_labgen    : universe LabelTag
; f_reggen    : universe RegisterTag
; f_sig       : signature
; f_result    : option register
; f_params    : list register
; f_locals    : list register
; f_ptrs      : list register
; f_stacksize : nat
; f_graph     : graph statement
; f_entry     : label
; f_exit      : label
}.

(* Note that the global variables will be initialised by the code in main
   by this stage.  All initialisation data should only reserve space. *)

definition RTLabs_program ≝ program (fundef internal_function) unit.

(* TO CONSIDER:

   - removing most successor labels from the statements (bit icky, what about
     return and jump tables?)
   - seems like load and store ought to have types that control the size of the
     register list based on the addressing mode; similarly, memory_chunk and
     register are probably related.
   - label and register generation really tell us something about the sets of
     labels and register that may appear, perhaps it should be renamed, or the
     graph made dependent on them to make it obvious, etc.
 *)