source: src/RTLabs/semantics.ma @ 2296

Last change on this file since 2296 was 2296, checked in by campbell, 7 years ago

Tidy up some ill-placed definitions.

File size: 17.7 KB
Line 
1
2include "basics/lists/list.ma".
3
4include "common/Errors.ma".
5include "common/Globalenvs.ma".
6include "common/IO.ma".
7include "common/SmallstepExec.ma".
8
9include "RTLabs/syntax.ma".
10
11definition genv ≝ genv_t (fundef internal_function).
12
13record frame : Type[0] ≝
14{ func   : internal_function
15; locals : register_env val
16; next   : label
17; next_ok: present ?? (f_graph func) next
18; sp     : block
19; retdst : option register
20}.
21
22definition adv : ∀l:label. ∀f:frame. present ?? (f_graph (func f)) l → frame ≝
23λl,f,p. mk_frame (func f) (locals f) l p (sp f) (retdst f).
24
25inductive state : Type[0] ≝
26| State :
27   ∀   f : frame.
28   ∀  fs : list frame.
29   ∀   m : mem.
30   state
31| Callstate :
32   ∀  fd : fundef internal_function.
33   ∀args : list val.
34   ∀ dst : option register.
35   ∀ stk : list frame.
36   ∀   m : mem.
37   state
38| Returnstate :
39   ∀ rtv : option val.
40   ∀ dst : option register.
41   ∀ stk : list frame.
42   ∀   m : mem.
43   state
44| Finalstate :
45   ∀   r : int.
46   state
47.
48
49definition build_state ≝ λf.λfs.λm.λn.λp. State (adv n f p) fs m.
50
51definition init_locals : list (register × typ) → register_env val ≝
52foldr ?? (λidt,en. let 〈id,ty〉 ≝ idt in add RegisterTag val en id Vundef) (empty_map ??).
53
54definition reg_store ≝
55λreg,v,locals.
56  update RegisterTag val locals reg v.
57
58axiom WrongNumberOfParameters : String.
59
60let rec params_store (rs:list (register × typ)) (vs:list val) (locals : register_env val) : res (register_env val) ≝
61match rs with
62[ nil ⇒ match vs with [ nil ⇒ OK ? locals | _ ⇒ Error ? (msg WrongNumberOfParameters)]
63| cons rt rst ⇒ match vs with [ nil ⇒ Error ? (msg WrongNumberOfParameters) | cons v vst ⇒
64  let 〈r,ty〉 ≝ rt in
65  let locals' ≝ add RegisterTag val locals r v in
66  params_store rst vst locals'
67] ].
68
69axiom BadRegister : String.
70
71definition reg_retrieve : register_env ? → register → res val ≝
72λlocals,reg. opt_to_res … [MSG BadRegister; CTX ? reg] (lookup ?? locals reg).
73
74axiom FailedOp : String.
75axiom MissingSymbol : String.
76
77axiom MissingStatement : String.
78axiom FailedConstant : String.
79axiom FailedLoad : String.
80axiom FailedStore : String.
81axiom BadFunction : String.
82axiom BadJumpTable : String.
83axiom BadJumpValue : String.
84axiom FinalState : String.
85axiom ReturnMismatch : String.
86
87definition eval_statement : genv → state → IO io_out io_in (trace × state) ≝
88λge,st.
89match st return λ_. IO ??? with
90[ State f fs m ⇒
91  let s ≝ lookup_present ?? (f_graph (func f)) (next f) (next_ok f) in
92  match s return λs. labels_present ? s → IO ??? with
93  [ St_skip l ⇒ λH. return 〈E0, build_state f fs m l ?〉
94  | St_cost cl l ⇒ λH. return 〈Echarge cl, build_state f fs m l ?〉
95  | St_const _ r cst l ⇒ λH.
96      ! v ← opt_to_res … (msg FailedConstant) (eval_constant ? (find_symbol … ge) (sp f) cst);
97      ! locals ← reg_store r v (locals f);
98      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
99  | St_op1 _ _ op dst src l ⇒ λH.
100      ! v ← reg_retrieve (locals f) src;
101      ! v' ← opt_to_res … (msg FailedOp) (eval_unop ?? op v);
102      ! locals ← reg_store dst v' (locals f);
103      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
104  | St_op2 _ _ _  op dst src1 src2 l ⇒ λH.
105      ! v1 ← reg_retrieve (locals f) src1;
106      ! v2 ← reg_retrieve (locals f) src2;
107      ! v' ← opt_to_res … (msg FailedOp) (eval_binop ??? op v1 v2);
108      ! locals ← reg_store dst v' (locals f);
109      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
110  | St_load chunk addr dst l ⇒ λH.
111      ! vaddr ← reg_retrieve (locals f) addr;
112      ! v ← opt_to_res … (msg FailedLoad) (loadv chunk m vaddr);
113      ! locals ← reg_store dst v (locals f);
114      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
115  | St_store chunk addr src l ⇒ λH.
116      ! vaddr ← reg_retrieve (locals f) addr;
117      ! v ← reg_retrieve (locals f) src;
118      ! m' ← opt_to_res … (msg FailedStore) (storev chunk m vaddr v);
119      return 〈E0, build_state f fs m' l ?〉
120  | St_call_id id args dst l ⇒ λH.
121      ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol … ge id);
122      ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr … ge b);
123      ! vs ← m_list_map … (reg_retrieve (locals f)) args;
124      return 〈E0, Callstate fd vs dst (adv l f ?::fs) m〉
125  | St_call_ptr frs args dst l ⇒ λH.
126      ! fv ← reg_retrieve (locals f) frs;
127      ! fd ← opt_to_res … (msg BadFunction) (find_funct … ge fv);
128      ! vs ← m_list_map … (reg_retrieve (locals f)) args;
129      return 〈E0, Callstate fd vs dst (adv l f ?::fs) m〉
130(*
131  | St_tailcall_id id args ⇒ λH.
132      ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol … ge id);
133      ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr … ge b);
134      ! vs ← m_list_map … (reg_retrieve (locals f)) args;
135      return 〈E0, Callstate fd vs (retdst f) fs (free m (sp f))〉
136  | St_tailcall_ptr frs args ⇒ λH.
137      ! fv ← reg_retrieve (locals f) frs;
138      ! fd ← opt_to_res … (msg BadFunction) (find_funct … ge fv);
139      ! vs ← m_list_map … (reg_retrieve (locals f)) args;
140      return 〈E0, Callstate fd vs (retdst f) fs (free m (sp f))〉
141*)
142  | St_cond src ltrue lfalse ⇒ λH.
143      ! v ← reg_retrieve (locals f) src;
144      ! b ← eval_bool_of_val v;
145      return 〈E0, build_state f fs m (if b then ltrue else lfalse) ?〉
146(*
147  | St_jumptable r ls ⇒ λH.
148      ! v ← reg_retrieve (locals f) r;
149      match v with
150      [ Vint _ i ⇒
151          match nth_opt ? (nat_of_bitvector ? i) ls return λx. nth_opt ??? = x → ? with
152          [ None ⇒ λ_. Error ? (msg BadJumpTable)
153          | Some l ⇒ λE. return 〈E0, build_state f fs m l ?〉
154          ] (refl ??)
155      | _ ⇒ Error ? (msg BadJumpValue)
156      ]
157*)
158  | St_return ⇒ λH.
159      ! v ← match f_result (func f) with
160            [ None ⇒ return (None ?)
161            | Some rt ⇒
162                let 〈r,ty〉 ≝ rt in
163                ! v ← reg_retrieve (locals f) r;
164                return (Some ? v)
165            ];
166      return 〈E0, Returnstate v (retdst f) fs (free m (sp f))〉
167  ] (f_closed (func f) (next f) s ?)
168| Callstate fd params dst fs m ⇒
169    match fd return λ_. IO ??? with
170    [ Internal fn ⇒
171        ! locals ← params_store (f_params fn) params (init_locals (f_locals fn));
172        (* CSC: XXX alignment call (concrete_stacksize in OCaml) is missing
173           here *)
174        let 〈m', sp〉 ≝ alloc m 0 (f_stacksize fn) XData in
175        return 〈E0, State (mk_frame fn locals (f_entry fn) ? sp dst) fs m'〉
176    | External fn ⇒
177        ! evargs ← err_to_io … (check_eventval_list params (sig_args (ef_sig fn)));
178        ! evres ← do_io (ef_id fn) evargs (proj_sig_res (ef_sig fn));
179        return 〈Eextcall (ef_id fn) evargs (mk_eventval ? evres), Returnstate (Some ? (mk_val ? evres) (*FIXME should allow None *)) dst fs m〉
180    ]
181| Returnstate v dst fs m ⇒
182    match fs with
183    [ nil ⇒
184        match v with
185        [ Some v' ⇒
186          match v' with
187          [ Vint sz r ⇒ match sz return λsz. bvint sz → monad Res ? with
188                        [ I32 ⇒ λr. return 〈E0, Finalstate r〉
189                        | _ ⇒ λ_. Error ? (msg ReturnMismatch)
190                        ] r
191          | _ ⇒ Error ? (msg ReturnMismatch)
192          ]
193        | _ ⇒ Error ? (msg ReturnMismatch)
194        ]
195    | cons f fs' ⇒
196        ! locals ← match dst with
197                   [ None ⇒ match v with [ None ⇒ OK ? (locals f)
198                                         | _ ⇒ Error ? (msg ReturnMismatch) ]
199                   | Some d ⇒ match v with [ None ⇒ Error ? (msg ReturnMismatch)
200                                           | Some v' ⇒ reg_store d v' (locals f) ] ];
201        return 〈E0, State (mk_frame (func f) locals (next f) ? (sp f) (retdst f)) fs' m〉
202    ]
203| Finalstate r ⇒ Error ? (msg FinalState) (* Already in final state *)
204]. try @(next_ok f) try @lookup_lookup_present try @H
205[ cases b [ @(proj1 ?? H) | @(proj2 ?? H) ]
206| cases (f_entry fn) //
207] qed.
208
209definition RTLabs_is_final : state → option int ≝
210λs. match s with
211[ Finalstate r ⇒ Some ? r
212| _ ⇒ None ?
213].
214
215definition RTLabs_exec : trans_system io_out io_in ≝
216  mk_trans_system … ? (λ_.RTLabs_is_final) eval_statement.
217
218definition make_global : RTLabs_program → genv ≝
219λp. globalenv … (λx.[Init_space x]) p.
220
221definition make_initial_state : RTLabs_program → res state ≝
222λp.
223  let ge ≝ make_global p in
224  do m ← init_mem … (λx.[Init_space x]) p;
225  let main ≝ prog_main ?? p in
226  do b ← opt_to_res ? [MSG MissingSymbol; CTX ? main] (find_symbol … ge main);
227  do f ← opt_to_res ? [MSG BadFunction; CTX ? main] (find_funct_ptr … ge b);
228  OK ? (Callstate f (nil ?) (None ?) (nil ?) m).
229
230definition RTLabs_fullexec : fullexec io_out io_in ≝
231  mk_fullexec … RTLabs_exec make_global make_initial_state.
232
233
234(* Some lemmas about the semantics. *)
235
236(* Note parts of frames and states that are preserved. *)
237
238inductive frame_rel : frame → frame → Prop ≝
239| mk_frame_rel :
240  ∀func,locals,next,next_ok,sp,retdst,locals',next',next_ok'. frame_rel
241   (mk_frame func locals next next_ok sp retdst)
242   (mk_frame func locals' next' next_ok' sp retdst)
243.
244
245inductive state_rel : genv → state → state → Prop ≝
246| normal : ∀ge,f,f',fs,m,m'. frame_rel f f' → state_rel ge (State f fs m) (State f' fs m')
247| to_call : ∀ge,f,fs,m,fd,args,f',dst. frame_rel f f' → ∀b. find_funct_ptr ? ge b = Some ? fd → state_rel ge (State f fs m) (Callstate fd args dst (f'::fs) m)
248(*
249| tail_call : ∀ge,f,fs,m,fd,args,dst,m'. ∀b. find_funct_ptr ?? ge b = Some ? fd → state_rel ge (State f fs m) (Callstate fd args dst fs m')
250*)
251| from_call : ∀ge,fn,locals,next,nok,sp,fs,m,args,dst,m'. state_rel ge (Callstate (Internal ? fn) args dst fs m) (State (mk_frame fn locals next nok sp dst) fs m')
252| to_ret : ∀ge,f,fs,m,rtv,dst,m'. state_rel ge (State f fs m) (Returnstate rtv dst fs m')
253| from_ret : ∀ge,f,fs,rtv,dst,f',m. next f = next f' → frame_rel f f' → state_rel ge (Returnstate rtv dst (f::fs) m) (State f' fs m)
254| finish : ∀ge,r,dst,m. state_rel ge (Returnstate (Some ? (Vint I32 r)) dst [ ] m) (Finalstate r)
255.
256
257lemma bind_ok : ∀A,B,e,f,v. ∀P:B → Type[0].
258  (∀a. e = OK A a → f a = OK ? v → P v) →
259  (match e with [ OK v ⇒ f v | Error m ⇒ Error ? m ] = OK ? v → P v).
260#A #B *
261[ #a #f #v #P #H #E whd in E:(??%?); @(H a) //
262| #m #f #v #P #H #E whd in E:(??%?); destruct
263] qed.
264
265lemma eval_preserves : ∀ge,s,tr,s'.
266  eval_statement ge s = Value ??? 〈tr,s'〉 →
267  state_rel ge s s'.
268#ge *
269[ * #func #locals #next #next_ok #sp #retdst #fs #m
270  #tr #s'
271  whd in ⊢ (??%? → ?);
272  generalize in ⊢ (??(?%)? → ?);
273  cases (lookup_present LabelTag statement (f_graph func) next next_ok)
274  [ #l #LP whd in ⊢ (??%? → ?); #E destruct % %
275  | #c #l #LP whd in ⊢ (??%? → ?); #E destruct % %
276  | #t #r #c #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #locals' #Eloc #E whd in E:(??%?); destruct % %
277  | #t1 #t2 #op #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
278  | #t1 #t2 #t' #op #r1 #r2 #r3 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v1 #Ev1 @bind_ok #v2 #Ev2 @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
279  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
280  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
281  | #id #rs #or #l #LP whd in ⊢ (??%? → ?); @bind_res_value #b #Eb @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct %2 [ % | @b | cases (find_funct_ptr ???) in Efd ⊢ %; normalize [2:#fd'] #E' destruct @refl ]
282  | #r #rs #or #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct cases (find_funct_find_funct_ptr ?? v ??) [ #b * #Ev' #Efn %2 [ % | @b | @Efn ] | ||| cases (find_funct ???) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
283(*
284  | #id #rs #LP whd in ⊢ (??%? → ?); @bind_res_value #b #Eb @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct %3 [ @b | cases (find_funct_ptr ????) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
285  | #r #rs #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct cases (find_funct_find_funct_ptr ?? v ??) [ #r * #b * #c * #Ev' #Efn %3 [ @b | @Efn ] | ||| cases (find_funct ????) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
286*)
287  | #r #l1 #l2 #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #b #Eb #E whd in E:(??%?); destruct % %
288(*  | #r #ls #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev cases v [ #E whd in E:(??%?); destruct | #sz #i whd in ⊢ (??%? → ?); generalize in ⊢ (??(?%)? → ?); cases (nth_opt ?? ls) in ⊢ (∀e:???%. ??(match % with [_ ⇒ ?|_ ⇒ ?]?)? → ?); [ #e #E whd in E:(??%?); destruct | #l' #e #E whd in E:(??%?); destruct % % ] | *: [ 1,3: #vl ] #E whd in E:(??%?); destruct ]*)
289  | #LP whd in ⊢ (??%? → ?); @bind_res_value #v cases (f_result func) [ 2: * #r #t whd in ⊢ (??%? → ?); @bind_ok #v0 #Ev0 ] #E whd in E:(??%?); #E' whd in E':(??%?); destruct %4
290  ]
291| * #fn #args #retdst #stk #m #tr #s'
292  whd in ⊢ (??%? → ?);
293  [ @bind_res_value #loc #Eloc cases (alloc m O ??) #m' #b whd in ⊢ (??%? → ?);
294    #E destruct %3
295  | @bindIO_value #evargs #Eargs whd in ⊢ (??%? → ?); #E destruct
296  ]
297| #v #r * [2: #f #fs ] #m #tr #s'
298  whd in ⊢ (??%? → ?);
299  [ @bind_res_value #loc #Eloc #E whd in E:(??%?); destruct
300    %5 cases f #func #locals #next #next_ok #sp #retdst %
301  | cases v [ normalize #E destruct | * [ 2: * #r normalize #E destruct // | *: normalize #a try #b destruct ] ]
302  ]
303| #r #tr #s' normalize #E destruct
304] qed.
305
306(* Show that, in principle at least, we can calculate which function we called
307   on a transition. The proof is a functional inversion similar to eval_preserves,
308   above. *)
309
310definition func_block_of_exec : ∀ge,s,t,fd,args,dst,fs,m.
311  eval_statement ge s = Value ??? 〈t,Callstate fd args dst fs m〉 →
312  Σb:block. find_funct_ptr … ge b = Some ? fd.
313#ge *
314[ * #func #locals #next #nok #sp #dst #fs #m #tr #fd #args #dst' #fs' #m'
315  whd in ⊢ (??%? → ?); generalize in ⊢ (??(?%)? → ?);
316  cases (lookup_present … nok)
317  (* Function call cases. *)
318  [ 8,9: #x #rs #or #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #fd' #Efd @bind_ok #vs #Evs #E normalize in E; destruct
319    [ %{v} @Efd
320    | cases v in Efd;
321      [ 5: * #b #off #Efd %{b} whd in Efd:(??(???%)?); cases (eq_offset ??) in Efd;
322           [ #E @E | #E normalize in E; destruct ]
323      | *: normalize #A try #B try #C destruct
324      ]
325    ]
326  (* and everything else cannot occur, but we need to work through the
327     definition to find the resulting state to demonstrate that. *)
328  | #l #LP whd in ⊢ (??%? → ?); #E destruct
329  | #c #l #LP whd in ⊢ (??%? → ?); #E destruct
330  | #t #r #c #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #locals' #Eloc #E whd in E:(??%?); destruct
331  | #t1 #t2 #op #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct
332  | #t1 #t2 #t' #op #r1 #r2 #r3 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v1 #Ev1 @bind_ok #v2 #Ev2 @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct
333  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct
334  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct
335  | #r #l1 #l2 #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev @bind_ok #b #Eb #E whd in E:(??%?); destruct
336(*  | #r #ls #LP whd in ⊢ (??%? → ?); @bind_res_value #v #Ev cases v [ #E whd in E:(??%?); destruct | #sz #i whd in ⊢ (??%? → ?); generalize in ⊢ (??(?%)? → ?); cases (nth_opt ?? ls) in ⊢ (∀e:???%. ??(match % with [_ ⇒ ?|_ ⇒ ?]?)? → ?); [ #e #E whd in E:(??%?); destruct | #l' #e #E whd in E:(??%?); destruct ] | *: [1,3: #vl] #E whd in E:(??%?); destruct ]*)
337  | #LP whd in ⊢ (??%? → ?); @bind_res_value #v cases (f_result func) [ 2: * #r #t whd in ⊢ (??%? → ?); @bind_ok #v0 #Ev0 ] #E whd in E:(??%?); #E' whd in E':(??%?); destruct
338  ]
339| * #fn #args #retdst #stk #m #tr #fd' #args' #dst' #fs' #m'
340  whd in ⊢ (??%? → ?);
341  [ @bind_res_value #loc #Eloc cases (alloc m O ??) #m' #b whd in ⊢ (??%? → ?);
342    #E destruct
343  | @bindIO_value #evargs #Eargs whd in ⊢ (??%? → ?); #E destruct
344  ]
345| #v #r * [2: #f #fs ] #m #tr #fd' #args' #dst' #fs' #m'
346  whd in ⊢ (??%? → ?);
347  [ @bind_res_value #loc #Eloc #E whd in E:(??%?); destruct
348  | cases v [ normalize #E destruct | * [ 2: * #r normalize #E destruct | *: normalize #a try #b destruct ] ]
349  ]
350| #r #tr #fd' #args' #dst' #fs' #m'
351  normalize #E destruct
352] qed.
353
354lemma final_cannot_move : ∀ge,s.
355  RTLabs_is_final s ≠ None ? →
356  ∃err. eval_statement ge s = Wrong ??? err.
357#ge *
358[ #f #fs #m * #F cases (F ?) @refl
359| #a #b #c #d #e * #F cases (F ?) @refl
360| #a #b #c #d * #F cases (F ?) @refl
361| #r #F % [2: @refl | skip ]
362] qed.
363
364lemma step_not_final : ∀ge,s,tr,s'.
365  eval_statement ge s = Value … 〈tr,s'〉 →
366  RTLabs_is_final s = None ?.
367#ge #s #tr #s' #EX
368lapply (final_cannot_move ge s)
369cases (RTLabs_is_final s)
370[ // | #r #F cases (F ?) [ #m #E >E in EX; #EX destruct | % #E destruct ]
371qed.
372
373lemma initial_state_is_not_final : ∀p,s.
374  make_initial_state p = OK ? s →
375  RTLabs_is_final s = None ?.
376#p #s whd in ⊢ (??%? → ?);
377@bind_ok #m #Em
378@bind_ok #b #Eb
379@bind_ok #f #Ef
380#E destruct
381@refl
382qed.
Note: See TracBrowser for help on using the repository browser.