source: src/RTLabs/semantics.ma @ 1692

Last change on this file since 1692 was 1681, checked in by campbell, 8 years ago

Checkpoint of stack preservation work in RTLabs.

File size: 14.3 KB
Line 
1
2(* XXX NB: I haven't checked all of these semantics against the prototype
3           compilers yet! *)
4
5include "basics/lists/list.ma".
6
7include "common/Errors.ma".
8include "common/Globalenvs.ma".
9include "common/IO.ma".
10include "common/SmallstepExec.ma".
11
12include "RTLabs/syntax.ma".
13
14definition genv ≝ (genv_t Genv) (fundef internal_function).
15
16record frame : Type[0] ≝
17{ func   : internal_function
18; locals : register_env val
19; next   : label
20; next_ok: present ?? (f_graph func) next
21; sp     : block
22; retdst : option register
23}.
24
25definition adv : ∀l:label. ∀f:frame. present ?? (f_graph (func f)) l → frame ≝
26λl,f,p. mk_frame (func f) (locals f) l p (sp f) (retdst f).
27
28inductive state : Type[0] ≝
29| State :
30   ∀   f : frame.
31   ∀  fs : list frame.
32   ∀   m : mem.
33   state
34| Callstate :
35   ∀  fd : fundef internal_function.
36   ∀args : list val.
37   ∀ dst : option register.
38   ∀ stk : list frame.
39   ∀   m : mem.
40   state
41| Returnstate :
42   ∀ rtv : option val.
43   ∀ dst : option register.
44   ∀ stk : list frame.
45   ∀   m : mem.
46   state.
47
48definition mem_of_state : state → mem ≝
49λs. match s with [ State _ _ m ⇒ m | Callstate _ _ _ _ m ⇒ m | Returnstate _ _ _ m ⇒ m ].
50
51definition build_state ≝ λf.λfs.λm.λn.λp. State (adv n f p) fs m.
52
53definition init_locals : list (register × typ) → register_env val ≝
54foldr ?? (λidt,en. let 〈id,ty〉 ≝ idt in add RegisterTag val en id Vundef) (empty_map ??).
55
56definition reg_store ≝
57λreg,v,locals.
58  update RegisterTag val locals reg v.
59
60axiom WrongNumberOfParameters : String.
61
62let rec params_store (rs:list (register × typ)) (vs:list val) (locals : register_env val) : res (register_env val) ≝
63match rs with
64[ nil ⇒ match vs with [ nil ⇒ OK ? locals | _ ⇒ Error ? (msg WrongNumberOfParameters)]
65| cons rt rst ⇒ match vs with [ nil ⇒ Error ? (msg WrongNumberOfParameters) | cons v vst ⇒
66  let 〈r,ty〉 ≝ rt in
67  let locals' ≝ add RegisterTag val locals r v in
68  params_store rst vst locals'
69] ].
70
71axiom BadRegister : String.
72
73definition reg_retrieve : register_env ? → register → res val ≝
74λlocals,reg. opt_to_res … [MSG BadRegister; CTX ? reg] (lookup ?? locals reg).
75
76axiom FailedOp : String.
77axiom MissingSymbol : String.
78
79axiom MissingStatement : String.
80axiom FailedConstant : String.
81axiom FailedLoad : String.
82axiom FailedStore : String.
83axiom BadFunction : String.
84axiom BadJumpTable : String.
85axiom BadJumpValue : String.
86axiom FinalState : String.
87axiom ReturnMismatch : String.
88
89definition eval_statement : genv → state → IO io_out io_in (trace × state) ≝
90λge,st.
91match st return λ_. IO ??? with
92[ State f fs m ⇒
93  let s ≝ lookup_present ?? (f_graph (func f)) (next f) (next_ok f) in
94  match s return λs. labels_present ? s → IO ??? with
95  [ St_skip l ⇒ λH. return 〈E0, build_state f fs m l ?〉
96  | St_cost cl l ⇒ λH. return 〈Echarge cl, build_state f fs m l ?〉
97  | St_const r cst l ⇒ λH.
98      ! v ← opt_to_res … (msg FailedConstant) (eval_constant (find_symbol … ge) (sp f) cst);
99      ! locals ← reg_store r v (locals f);
100      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
101  | St_op1 _ _ op dst src l ⇒ λH.
102      ! v ← reg_retrieve (locals f) src;
103      ! v' ← opt_to_res … (msg FailedOp) (eval_unop ?? op v);
104      ! locals ← reg_store dst v' (locals f);
105      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
106  | St_op2 op dst src1 src2 l ⇒ λH.
107      ! v1 ← reg_retrieve (locals f) src1;
108      ! v2 ← reg_retrieve (locals f) src2;
109      ! v' ← opt_to_res … (msg FailedOp) (eval_binop op v1 v2);
110      ! locals ← reg_store dst v' (locals f);
111      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
112  | St_load chunk addr dst l ⇒ λH.
113      ! vaddr ← reg_retrieve (locals f) addr;
114      ! v ← opt_to_res … (msg FailedLoad) (loadv chunk m vaddr);
115      ! locals ← reg_store dst v (locals f);
116      return 〈E0, State (mk_frame (func f) locals l ? (sp f) (retdst f)) fs m〉
117  | St_store chunk addr src l ⇒ λH.
118      ! vaddr ← reg_retrieve (locals f) addr;
119      ! v ← reg_retrieve (locals f) src;
120      ! m' ← opt_to_res … (msg FailedStore) (storev chunk m vaddr v);
121      return 〈E0, build_state f fs m' l ?〉
122  | St_call_id id args dst l ⇒ λH.
123      ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol ?? ge id);
124      ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr ?? ge b);
125      ! vs ← m_mmap … (reg_retrieve (locals f)) args;
126      return 〈E0, Callstate fd vs dst (adv l f ?::fs) m〉
127  | St_call_ptr frs args dst l ⇒ λH.
128      ! fv ← reg_retrieve (locals f) frs;
129      ! fd ← opt_to_res … (msg BadFunction) (find_funct ?? ge fv);
130      ! vs ← m_mmap … (reg_retrieve (locals f)) args;
131      return 〈E0, Callstate fd vs dst (adv l f ?::fs) m〉
132(*
133  | St_tailcall_id id args ⇒ λH.
134      ! b ← opt_to_res … [MSG MissingSymbol; CTX ? id] (find_symbol ?? ge id);
135      ! fd ← opt_to_res … [MSG BadFunction; CTX ? id] (find_funct_ptr ?? ge b);
136      ! vs ← m_mmap … (reg_retrieve (locals f)) args;
137      return 〈E0, Callstate fd vs (retdst f) fs (free m (sp f))〉
138  | St_tailcall_ptr frs args ⇒ λH.
139      ! fv ← reg_retrieve (locals f) frs;
140      ! fd ← opt_to_res … (msg BadFunction) (find_funct ?? ge fv);
141      ! vs ← m_mmap … (reg_retrieve (locals f)) args;
142      return 〈E0, Callstate fd vs (retdst f) fs (free m (sp f))〉
143*)
144  | St_cond src ltrue lfalse ⇒ λH.
145      ! v ← reg_retrieve (locals f) src;
146      ! b ← eval_bool_of_val v;
147      return 〈E0, build_state f fs m (if b then ltrue else lfalse) ?〉
148
149  | St_jumptable r ls ⇒ λH.
150      ! v ← reg_retrieve (locals f) r;
151      match v with
152      [ Vint _ i ⇒
153          match nth_opt ? (nat_of_bitvector ? i) ls return λx. nth_opt ??? = x → ? with
154          [ None ⇒ λ_. Error ? (msg BadJumpTable)
155          | Some l ⇒ λE. return 〈E0, build_state f fs m l ?〉
156          ] (refl ??)
157      | _ ⇒ Error ? (msg BadJumpValue)
158      ]
159
160  | St_return ⇒ λH.
161      ! v ← match f_result (func f) with
162            [ None ⇒ return (None ?)
163            | Some rt ⇒
164                let 〈r,ty〉 ≝ rt in
165                ! v ← reg_retrieve (locals f) r;
166                return (Some ? v)
167            ];
168      return 〈E0, Returnstate v (retdst f) fs (free m (sp f))〉
169  ] (f_closed (func f) (next f) s ?)
170| Callstate fd params dst fs m ⇒
171    match fd return λ_. IO ??? with
172    [ Internal fn ⇒
173        ! locals ← params_store (f_params fn) params (init_locals (f_locals fn));
174        (* CSC: XXX alignment call (concrete_stacksize in OCaml) is missing
175           here *)
176        let 〈m', sp〉 ≝ alloc m 0 (f_stacksize fn) Any in
177        return 〈E0, State (mk_frame fn locals (f_entry fn) ? sp dst) fs m'〉
178    | External fn ⇒
179        ! evargs ← err_to_io … (check_eventval_list params (sig_args (ef_sig fn)));
180        ! evres ← do_io (ef_id fn) evargs (proj_sig_res (ef_sig fn));
181        return 〈Eextcall (ef_id fn) evargs (mk_eventval ? evres), Returnstate (Some ? (mk_val ? evres) (*FIXME should allow None *)) dst fs m〉
182    ]
183| Returnstate v dst fs m ⇒
184    match fs with
185    [ nil ⇒ Error ? (msg FinalState) (* Already in final state *)
186    | cons f fs' ⇒
187        ! locals ← match dst with
188                   [ None ⇒ match v with [ None ⇒ OK ? (locals f)
189                                         | _ ⇒ Error ? (msg ReturnMismatch) ]
190                   | Some d ⇒ match v with [ None ⇒ Error ? (msg ReturnMismatch)
191                                           | Some v' ⇒ reg_store d v' (locals f) ] ];
192        return 〈E0, State (mk_frame (func f) locals (next f) ? (sp f) (retdst f)) fs' m〉
193    ]
194]. try @(next_ok f) try @lookup_lookup_present try @H
195[ cases b [ @(proj1 ?? H) | @(proj2 ?? H) ]
196| whd in H; @(All_nth … H ? E)
197| cases (f_entry fn) //
198] qed.
199
200definition RTLabs_is_final : state → option int ≝
201λs. match s with
202[ State _ _ _ ⇒ None ?
203| Callstate _ _ _ _ _ ⇒ None ?
204| Returnstate v _ fs _ ⇒
205    match fs with [ nil ⇒
206      match v with [ Some v' ⇒
207        match v' with
208        [ Vint sz i ⇒ intsize_eq_elim ? sz I32 ? i (λi. Some ? i) (None ?)
209        | _ ⇒ None ? ]
210      | None ⇒ None ? ]
211    | cons _ _ ⇒ None ? ]
212].
213
214definition RTLabs_exec : trans_system io_out io_in ≝
215  mk_trans_system … ? (λ_.RTLabs_is_final) eval_statement.
216
217definition make_global : RTLabs_program → genv ≝
218λp. globalenv Genv ?? (λx.[Init_space x]) p.
219
220definition make_initial_state : RTLabs_program → res state ≝
221λp.
222  let ge ≝ make_global p in
223  do m ← init_mem Genv ?? (λx.[Init_space x]) p;
224  let main ≝ prog_main ?? p in
225  do b ← opt_to_res ? [MSG MissingSymbol; CTX ? main] (find_symbol ? ? ge main);
226  do f ← opt_to_res ? [MSG BadFunction; CTX ? main] (find_funct_ptr ? ? ge b);
227  OK ? (Callstate f (nil ?) (None ?) (nil ?) m).
228
229definition RTLabs_fullexec : fullexec io_out io_in ≝
230  mk_fullexec … RTLabs_exec make_global make_initial_state.
231
232
233(* Some lemmas about the semantics. *)
234
235(* Note parts of frames and states that are preserved. *)
236
237inductive frame_rel : frame → frame → Prop ≝
238| mk_frame_rel :
239  ∀func,locals,next,next_ok,sp,retdst,locals',next',next_ok'. frame_rel
240   (mk_frame func locals next next_ok sp retdst)
241   (mk_frame func locals' next' next_ok' sp retdst)
242.
243
244inductive state_rel : genv → state → state → Prop ≝
245| normal : ∀ge,f,f',fs,m,m'. frame_rel f f' → state_rel ge (State f fs m) (State f' fs m')
246| to_call : ∀ge,f,fs,m,fd,args,f',dst. frame_rel f f' → ∀b. find_funct_ptr ?? ge b = Some ? fd → state_rel ge (State f fs m) (Callstate fd args dst (f'::fs) m)
247(*
248| tail_call : ∀ge,f,fs,m,fd,args,dst,m'. ∀b. find_funct_ptr ?? ge b = Some ? fd → state_rel ge (State f fs m) (Callstate fd args dst fs m')
249*)
250| from_call : ∀ge,fn,locals,next,nok,sp,fs,m,args,dst,m'. state_rel ge (Callstate (Internal ? fn) args dst fs m) (State (mk_frame fn locals next nok sp dst) fs m')
251| to_ret : ∀ge,f,fs,m,rtv,dst,m'. state_rel ge (State f fs m) (Returnstate rtv dst fs m')
252| from_ret : ∀ge,f,fs,rtv,dst,f',m. frame_rel f f' → state_rel ge (Returnstate rtv dst (f::fs) m) (State f' fs m)
253.
254
255lemma bind_ok : ∀A,B,e,f,v. ∀P:B → Prop.
256  (∀a. e = OK A a → f a = OK ? v → P v) →
257  (match e with [ OK v ⇒ f v | Error m ⇒ Error ? m ] = OK ? v → P v).
258#A #B *
259[ #a #f #v #P #H #E whd in E:(??%?); @(H a) //
260| #m #f #v #P #H #E whd in E:(??%?); destruct
261] qed.
262
263lemma bind_value : ∀O,I,A,B,e,f,v. ∀P:B → Prop.
264  (∀a. e = OK A a → f a = OK B v → P v) →
265  (match e »= f with [ OK v ⇒ Value … v | Error m ⇒ Wrong … m ] = Value O I B v → P v).
266#O #I #A #B *
267[ #a #f #v #P #H #E @H [ @a | @refl | normalize in E; cases (f a) in E ⊢ %;
268  [ #v' #E normalize in E; destruct @refl | #m #E normalize in E; destruct ] ]
269| #m #f #v #P #H #E whd in E:(??%?); destruct
270] qed.
271
272lemma bindIO_value : ∀O,I,A,B,e,f,v. ∀P:B → Prop.
273  (∀a. e = Value ??? a → f a = Value ??? v → P v) →
274  (bindIO O I A B e f = Value ??? v → P v).
275#O #I #A #B *
276[ #o #k #f #v #P #H #E whd in E:(??%?); destruct
277| #a #f #v #P #H #E @H [ @a | @refl | @E ]
278| #m #f #v #P #H #E whd in E:(??%?); destruct
279] qed.
280
281lemma eval_perserves : ∀ge,s,tr,s'.
282  eval_statement ge s = Value ??? 〈tr,s'〉 →
283  state_rel ge s s'.
284#ge *
285[ * #func #locals #next #next_ok #sp #retdst #fs #m
286  #tr #s'
287  whd in ⊢ (??%? → ?);
288  generalize in ⊢ (??(?%)? → ?);
289  cases (lookup_present LabelTag statement (f_graph func) next next_ok)
290  [ #l #LP whd in ⊢ (??%? → ?); #E destruct % %
291  | #c #l #LP whd in ⊢ (??%? → ?); #E destruct % %
292  | #r #c #l #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #locals' #Eloc #E whd in E:(??%?); destruct % %
293  | #t1 #t2 #op #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
294  | #op #r1 #r2 #r3 #l #LP whd in ⊢ (??%? → ?); @bind_value #v1 #Ev1 @bind_ok #v2 #Ev2 @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
295  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
296  | #ch #r1 #r2 #l #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #v' #Ev'  @bind_ok #loc #Eloc #E whd in E:(??%?); destruct % %
297  | #id #rs #or #l #LP whd in ⊢ (??%? → ?); @bind_value #b #Eb @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct %2 [ % | @b | cases (find_funct_ptr ????) in Efd ⊢ %; normalize [2:#fd'] #E' destruct @refl ]
298  | #r #rs #or #l #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct cases (find_funct_find_funct_ptr ?? v ??) [ #r * #b * #c * #Ev' #Efn %2 [ % | @b | @Efn ] | ||| cases (find_funct ????) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
299(*
300  | #id #rs #LP whd in ⊢ (??%? → ?); @bind_value #b #Eb @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct %3 [ @b | cases (find_funct_ptr ????) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
301  | #r #rs #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #fd #Efd  @bind_ok #vs #Evs #E whd in E:(??%?); destruct cases (find_funct_find_funct_ptr ?? v ??) [ #r * #b * #c * #Ev' #Efn %3 [ @b | @Efn ] | ||| cases (find_funct ????) in Efd ⊢ %; [2:#x] normalize #E' destruct @refl ]
302*)
303  | #r #l1 #l2 #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev @bind_ok #b #Eb #E whd in E:(??%?); destruct % %
304  | #r #ls #LP whd in ⊢ (??%? → ?); @bind_value #v #Ev cases v [ #E whd in E:(??%?); destruct | #sz #i whd in ⊢ (??%? → ?); generalize in ⊢ (??(?%)? → ?); cases (nth_opt ?? ls) in ⊢ (∀e:???%. ??(match % with [_ ⇒ ?|_ ⇒ ?]?)? → ?); [ #e #E whd in E:(??%?); destruct | #l' #e #E whd in E:(??%?); destruct % % ] | *: #vl #E whd in E:(??%?); destruct ]
305  | #LP whd in ⊢ (??%? → ?); @bind_value #v cases (f_result func) [ 2: * #r #t whd in ⊢ (??%? → ?); @bind_ok #v0 #Ev0 ] #E whd in E:(??%?); #E' whd in E':(??%?); destruct %4
306  ]
307| * #fn #args #retdst #stk #m #tr #s'
308  whd in ⊢ (??%? → ?);
309  [ @bind_value #loc #Eloc cases (alloc m O ??) #m' #b whd in ⊢ (??%? → ?);
310    #E destruct %3
311  | @bindIO_value #evargs #Eargs whd in ⊢ (??%? → ?); #E destruct
312  ]
313| #v #r * [2: #f #fs ] #m #tr #s'
314  whd in ⊢ (??%? → ?);
315  [ @bind_value #loc #Eloc #E whd in E:(??%?); destruct
316    %5 cases f #func #locals #next #next_ok #sp #retdst %
317  | #E destruct
318  ]
319] qed.
320
Note: See TracBrowser for help on using the repository browser.