source: src/RTLabs/import.ma @ 748

include "RTLabs/RTLabs-sem.ma".

let rec n_idents (n:nat) (tag:String) (g:universe tag) : res (Vector (identifier tag) n × (universe tag)) ≝
match n with
[ O ⇒ OK ? 〈[[ ]], g〉
| S m ⇒ do 〈ls, g'〉 ← n_idents m tag g;
        do 〈l, g''〉 ← fresh ? g';
        OK ? 〈l:::ls, g''〉
].

definition pre_registers ≝ Sig nat (Vector nat).

record pre_internal_function : Type[0] ≝
{ pf_sig       : signature
; pf_result    : pre_registers
; pf_params    : list pre_registers
; pf_locals    : list pre_registers
; pf_stacksize : nat
; pf_graph     : list (nat × ((nat → res register) → (nat → res label) → res statement))
; pf_entry     : nat
; pf_exit      : nat
}.
(* XXX projection generation with nat broken *)
definition pf_stacksize ≝ λp.match p with [ mk_pre_internal_function _ _ _ _ s _ _ _ ⇒ s ].
definition pf_graph ≝ λp.match p with [ mk_pre_internal_function _ _ _ _ _ g _ _ ⇒ g ].
definition pf_entry ≝ λp.match p with [ mk_pre_internal_function _ _ _ _ _ _ e _ ⇒ e ].
definition pf_exit ≝ λp.match p with [ mk_pre_internal_function _ _ _ _ _ _ _ e ⇒ e ].

definition make_registers : 
  (nat → option register) → pre_registers → universe RegisterTag →
  res ((nat → option register) × (universe RegisterTag) × registers) ≝
λm,rs0,g.
match rs0 with [ dp n rs ⇒
  do 〈m,grs〉 ← fold_right_i ??? (λn,r,mr.
                  do 〈m,grs〉 ← mr;
                  let 〈g,rs〉 ≝ grs in
                  match m r with
                  [ Some r' ⇒ OK ? 〈m,〈g,r':::rs〉〉
                  | None ⇒ do 〈r',g'〉 ← fresh ? g;
                           OK ? 〈λn. if eqb r n then Some ? r' else m n,〈g',r':::rs〉〉
                  ]) (OK ? 〈m,〈g,[[ ]]〉〉) rs;
  let 〈g',rs'〉 ≝ grs in
    OK ? 〈〈m,g'〉,dp ?? n rs'〉
].

definition make_registers_list :
  (nat → option register) → list pre_registers → universe RegisterTag →
  res ((nat → option register) × (universe RegisterTag) × (list registers)) ≝
λm,lrs,g.
foldr ?? (λrs,acc. do 〈acc',l〉 ← acc;
                   let 〈m,g〉 ≝ acc' in 
                   do 〈mg,rs'〉 ← make_registers m rs g;
                   OK ? 〈mg,rs'::l〉) (OK ? 〈〈m,g〉,[ ]〉) lrs.

definition make_internal_function : pre_internal_function → res (fundef internal_function) ≝
λpre_f.
  let rgen0 ≝ new_universe RegisterTag in
  do 〈rmapgen1, result〉 ← make_registers (λ_.None ?) (pf_result pre_f) rgen0;
  let 〈rmap1, rgen1〉 ≝ rmapgen1 in
  do 〈rmapgen2, params〉 ← make_registers_list rmap1 (pf_params pre_f) rgen1;
  let 〈rmap2, rgen2〉 ≝ rmapgen2 in
  do 〈rmapgen3, locals〉 ← make_registers_list rmap2 (pf_locals pre_f) rgen2;
  let 〈rmap3, rgen3〉 ≝ rmapgen3 in
  let rmap ≝ λn. opt_to_res … (rmap3 n) in
  let max_stmt ≝ foldr ?? (λp,m. max (\fst p) m) 0 (pf_graph pre_f) in
  do 〈labels, gen〉 ← n_idents (S max_stmt) ? (new_universe LabelTag);
  let get_label ≝ λn. opt_to_res … (get_index_weak_v ?? labels n) in
  do graph ← foldr ?? (λp,g0. do g ← g0;
                              let 〈l,s〉 ≝ p in
                              do l' ← get_label l;
                              do s' ← s rmap get_label;
                              OK ? (add ?? g l' s')) (OK ? (empty_map ??)) (pf_graph pre_f);
  do entry ← get_label (pf_entry pre_f);
  do exit ← get_label (pf_exit pre_f);
  OK ? (Internal ? (mk_internal_function
         gen
         rgen3
         (pf_sig pre_f)
         result
         params
         locals
         (pf_stacksize pre_f)
         graph
         entry
         exit
         )).

definition make_regs : (nat → res register) → pre_registers → res registers ≝
λm,p.
match p with
[ dp n ps ⇒
    do rs ← fold_right_i ??? (λn,r,rs0.
                  do rs ← rs0;
                  do r' ← m r;
                  OK ? (r':::rs)) (OK ? [[ ]]) ps;
    OK ? (dp ?? n rs)
].

definition make_regs_list : (nat → res register) → list pre_registers → res (list registers) ≝
λm,ps. foldr ?? (λp,rs0. do rs ← rs0; do r ← make_regs m p; OK ? (r::rs)) (OK ? [ ]) ps.

(* XXX move somewhere sensible *)
let rec mmap_vec (A:Type[0]) (B:Type[0]) (f:A → res B) (n:nat) (v:Vector A n) on v : res (Vector B n) ≝
match v with
[ VEmpty ⇒ OK ? (VEmpty …)
| VCons m hd tl ⇒ do hd' ← f hd;
                  do tl' ← mmap_vec A B f m tl;
                  OK ? (hd':::tl')
].

definition make_addr : (nat → res register) → ∀m:addressing. Vector pre_registers (addr_mode_args m) → res (addr m) ≝
λmp,m. mmap_vec ?? (make_regs mp) ?.

let rec make_St_skip l ≝ λr:nat → res register.λf:nat → res label. do l' ← f l; OK ? (St_skip l').
let rec make_St_cost cl l ≝ λr:nat → res register.λf:nat → res label. do l' ← f l; OK ? (St_cost cl l').
let rec make_St_const rs cst l ≝ λr:nat → res register.λf:nat → res label. do rs' ← make_regs r rs; do l' ← f l; OK ? (St_const rs' cst l').
let rec make_St_op1 op dst src l ≝ λr:nat → res register.λf:nat → res label. do dst' ← make_regs r dst; do src' ← make_regs r src; do l' ← f l; OK ? (St_op1 op dst' src' l').
let rec make_St_op2 op dst src1 src2 l ≝ λr:nat → res register.λf:nat → res label. do dst' ← make_regs r dst; do src1' ← make_regs r src1; do src2' ← make_regs r src2; do l' ← f l; OK ? (St_op2 op dst' src1' src2' l').
let rec make_St_load chunk mode args dst l ≝ λr:nat → res register.λf:nat → res label. do dst' ← make_regs r dst; do l' ← f l; do args' ← make_addr r ? args; OK ? (St_load chunk mode args' dst' l').
let rec make_St_store chunk mode args src l ≝ λr:nat → res register.λf:nat → res label. do src' ← make_regs r src; do l' ← f l; do args' ← make_addr r ? args; OK ? (St_store chunk mode args' src' l').
let rec make_St_call_id id args dst sig l ≝ λr:nat → res register.λf:nat → res label. do args' ← make_regs_list r args; do dst' ← make_regs r dst; do l' ← f l; OK ? (St_call_id id args' dst' sig l').
let rec make_St_call_ptr frs args dst sig l ≝ λr:nat → res register.λf:nat → res label. do frs' ← make_regs r frs; do args' ← make_regs_list r args; do dst' ← make_regs r dst; do l' ← f l; OK ? (St_call_ptr frs' args' dst' sig l').
let rec make_St_tailcall_id id args sig ≝ λr:nat → res register.λf:nat → res label.  do args' ← make_regs_list r args; OK statement (St_tailcall_id id args' sig).
let rec make_St_tailcall_ptr frs args sig ≝ λr:nat → res register.λf:nat → res label. do frs' ← make_regs r frs; do args' ← make_regs_list r args; OK statement (St_tailcall_ptr frs' args' sig).
let rec make_St_condcst cst ltrue lfalse ≝ λr:nat → res register.λf:nat → res label. do ltrue' ← f ltrue; do lfalse' ← f lfalse; OK ? (St_condcst cst ltrue' lfalse').
let rec make_St_cond1 op src ltrue lfalse ≝ λr:nat → res register.λf:nat → res label. do src' ← make_regs r src; do ltrue' ← f ltrue; do lfalse' ← f lfalse;  OK ? (St_cond1 op src' ltrue' lfalse').
let rec make_St_cond2 op src1 src2 ltrue lfalse ≝ λr:nat → res register.λf:nat → res label. do src1' ← make_regs r src1; do src2' ← make_regs r src2; do ltrue' ← f ltrue; do lfalse' ← f lfalse; OK ? (St_cond2 op src1' src2' ltrue' lfalse').
let rec make_St_jumptable rs ls ≝ λr:nat → res register.λf:nat → res label. do rs' ← make_regs r rs; do ls' ← foldr ?? (λl,ls0. do ls ← ls0; do l' ← f l; OK ? (l'::ls)) (OK ? [ ]) ls; OK ? (St_jumptable rs' ls').
let rec make_St_return src ≝ λr:nat → res register.λf:nat → res label. do src' ← make_regs r src; OK statement (St_return src').