source: src/RTLabs/RTLabsMatitaPrinter.ml @ 737

let n_spaces n = String.make n ' '


let print_global (x, size) =
  Printf.sprintf "pair ?? (pair ?? (pair ?? %s [ ]) Any) %d" x size

let print_globals n globs =
  Printf.sprintf "%s(*globals:*)\n%s[%s]"
    (n_spaces n)
    (n_spaces n)
    (MiscPottier.string_of_list (";\n"^n_spaces n) print_global globs)


let print_reg_list rl =
  Printf.sprintf "(dp ?? %d [[%s]])" (List.length rl) (MiscPottier.string_of_list " ; " Register.print rl)

let rec print_args args =
  Printf.sprintf "[[%s]]" (MiscPottier.string_of_list "; " print_reg_list args)

let print_result rl = print_reg_list rl

let print_params rl =
  Printf.sprintf "[%s]" (MiscPottier.string_of_list "; " print_reg_list rl)

let print_locals rl =
  Printf.sprintf "[%s]" (MiscPottier.string_of_list "; " print_reg_list rl)


let print_memory_q = function
  | Memory.MQ_int8signed    -> "Mint8signed"
  | Memory.MQ_int8unsigned  -> "Mint8unsigned"
  | Memory.MQ_int16signed   -> "Mint16signed"
  | Memory.MQ_int16unsigned -> "Mint16unsigned"
  | Memory.MQ_int32         -> "Mint32"
  | Memory.MQ_float32       -> "Mfloat32"
  | Memory.MQ_float64       -> "Mfloat64"
  | Memory.MQ_pointer       -> "Mpointer Any"
  | Memory.MQ_chunk         -> "MXXX"



let print_cmp = function
  | AST.Cmp_eq -> "Ceq"
  | AST.Cmp_ne -> "Cne"
  | AST.Cmp_gt -> "Cgt"
  | AST.Cmp_ge -> "Cge"
  | AST.Cmp_lt -> "Clt"
  | AST.Cmp_le -> "Cle"

let print_cst = function
  | AST.Cst_int i -> Printf.sprintf "Ointconst (repr %d)" i
  | AST.Cst_float f -> Printf.sprintf "Ofloatconst %f" f
  | AST.Cst_addrsymbol id -> Printf.sprintf "Oaddrsymbol id_%s (repr 0)" id
  | AST.Cst_stackoffset off -> Printf.sprintf "Oaddrstack (repr %d)" off

let print_op1 = function
  | AST.Op_cast8unsigned -> "Ocast8unsigned"
  | AST.Op_cast8signed -> "Ocast8signed"
  | AST.Op_cast16unsigned -> "Ocast16unsigned"
  | AST.Op_cast16signed -> "Ocast16signed"
  | AST.Op_negint -> "Onegint"
  | AST.Op_notbool -> "Onotbool"
  | AST.Op_notint -> "Onotint"
  | AST.Op_negf -> "Onegf"
  | AST.Op_absf -> "Oabsf"
  | AST.Op_singleoffloat -> "Osingleoffloat"
  | AST.Op_intoffloat -> "Ointoffloat"
  | AST.Op_intuoffloat -> "Ointuoffloat"
  | AST.Op_floatofint -> "Ofloatofint"
  | AST.Op_floatofintu -> "Ofloatofintu"
  | AST.Op_id -> "Oid"
  | AST.Op_ptrofint -> "Optrofint"
  | AST.Op_intofptr -> "Ointofptr"

let print_op2 = function
  | AST.Op_add -> "Oadd"
  | AST.Op_sub -> "Osub"
  | AST.Op_mul -> "Omul"
  | AST.Op_div -> "Odiv"
  | AST.Op_divu -> "Odivu"
  | AST.Op_mod -> "Omod"
  | AST.Op_modu -> "Omodu"
  | AST.Op_and -> "Oand"
  | AST.Op_or -> "Oor"
  | AST.Op_xor -> "Oxor"
  | AST.Op_shl -> "Oshl"
  | AST.Op_shr -> "Oshr"
  | AST.Op_shru -> "Oshru"
  | AST.Op_addf -> "Oaddf"
  | AST.Op_subf -> "Osubf"
  | AST.Op_mulf -> "Omulf"
  | AST.Op_divf -> "Odivf"
  | AST.Op_cmp cmp -> "(Ocmp " ^ print_cmp cmp ^ ")"
  | AST.Op_cmpu cmp -> "(Ocmpu " ^ (print_cmp cmp) ^ ")"
  | AST.Op_cmpf cmp -> "(Ocmpf " ^ (print_cmp cmp) ^ ")"
  | AST.Op_addp -> "Oaddp"
  | AST.Op_subp -> "Osubp"
  | AST.Op_cmpp cmp -> (print_cmp cmp) ^ "Ocmpp"


let print_addressing = function
  | RTLabs.Aindexed off -> Printf.sprintf "Aindexed (repr %d)" off
  | RTLabs.Aindexed2 -> "Aindexed2"
  | RTLabs.Aglobal (id, off) -> Printf.sprintf "Aglobal %s (repr %d)" id off
  | RTLabs.Abased (id, off) -> Printf.sprintf "Abased %s (repr %d)" id off
  | RTLabs.Ainstack off -> Printf.sprintf "Ainstack (repr %d)" off


let print_sig_type = function
| AST.Sig_int -> "ASTint"
| AST.Sig_float -> "ASTfloat"
| AST.Sig_ptr -> "ASTptr Any"

let print_sig s =
  Printf.sprintf "mk_signature [%s] (%s)"
    (MiscPottier.string_of_list "; " print_sig_type s.AST.args)
    (match s.AST.res with AST.Type_ret t -> "Some ? " ^ print_sig_type t
                        | AST.Type_void  -> "None ?")

let rec print_table = function
  | [] -> ""
  | [lbl] -> lbl
  | lbl :: tbl -> lbl ^ "; " ^ (print_table tbl)


let print_statement = function
  | RTLabs.St_skip lbl -> "make_St_skip " ^ lbl
  | RTLabs.St_cost (cost_lbl, lbl) ->
      Printf.sprintf "make_St_cost C%s %s" cost_lbl lbl
  | RTLabs.St_cst (dests, cst, lbl) ->
      Printf.sprintf "make_St_const %s (%s) %s"
        (print_reg_list dests)
        (print_cst cst)
        lbl
  | RTLabs.St_op1 (op1, dests, srcs, lbl) ->
      Printf.sprintf "make_St_op1 %s %s %s %s"
        (print_op1 op1)
        (print_reg_list dests)
        (print_reg_list srcs)
        lbl
  | RTLabs.St_op2 (op2, dests, srcs1, srcs2, lbl) ->
      Printf.sprintf "make_St_op2 %s %s %s %s %s"
        (print_op2 op2)
        (print_reg_list dests)
        (print_reg_list srcs1)
        (print_reg_list srcs2)
        lbl
  | RTLabs.St_load (chunk, mode, args, dests, lbl) ->
      Printf.sprintf "make_St_load %s (%s) %s %s %s"
        (print_memory_q chunk)
        (print_addressing mode)
        (print_args args)
        (print_reg_list dests)
        lbl
  | RTLabs.St_store (chunk, mode, args, srcs, lbl) ->
      Printf.sprintf "make_St_store %s (%s) %s %s %s"
        (print_memory_q chunk)
        (print_addressing mode)
        (print_args args)
        (print_reg_list srcs)
        lbl
  | RTLabs.St_call_id (f, args, res, sg, lbl) ->
      Printf.sprintf "make_St_call_id id_%s %s %s (%s) %s"
        f
        (print_params args)
        (print_reg_list res)
        (print_sig sg)
        lbl
  | RTLabs.St_call_ptr (f, args, res, sg, lbl) ->
      Printf.sprintf "make_St_call_ptr %s %s %s (%s) %s"
        (print_reg_list f)
        (print_params args)
        (print_reg_list res)
        (print_sig sg)
        lbl
  | RTLabs.St_tailcall_id (f, args, sg) ->
      Printf.sprintf "make_St_tailcall_id id_%s %s (%s)"
        f
        (print_params args)
        (print_sig sg)
  | RTLabs.St_tailcall_ptr (f, args, sg) ->
      Printf.sprintf "make_St_tailcall_ptr %s %s (%s)"
        (print_reg_list f)
        (print_params args)
        (print_sig sg)
  | RTLabs.St_condcst (cst, lbl_true, lbl_false) ->
      Printf.sprintf "make_St_condcst (%s) %s %s"
        (print_cst cst)
        lbl_true
        lbl_false
  | RTLabs.St_cond1 (op1, srcs, lbl_true, lbl_false) ->
      Printf.sprintf "make_St_cond1 %s %s %s %s"
        (print_op1 op1)
        (print_reg_list srcs)
        lbl_true
        lbl_false
  | RTLabs.St_cond2 (op2, srcs1, srcs2, lbl_true, lbl_false) ->
      Printf.sprintf "make_St_cond2 %s %s %s %s %s"
        (print_op2 op2)
        (print_reg_list srcs1)
        (print_reg_list srcs2)
        lbl_true
        lbl_false
  | RTLabs.St_jumptable (rs, tbl) ->
      Printf.sprintf "make_St_jumptable %s [%s]"
        (print_reg_list rs)
        (print_table tbl)
  | RTLabs.St_return rs -> Printf.sprintf "make_St_return %s" (print_reg_list rs)

let print_cost_labels n c =
  let f _ stmt (i,s) =
    match stmt with
    | RTLabs.St_cost (lbl, _) ->
        i+1,
        Printf.sprintf "%sdefinition C%s := costlabel_of_nat %d.\n%s"
          (n_spaces n)
          lbl
          i
          s
    | _ -> i,s
  in
  snd (Label.Map.fold f c (0,""))

let print_labels n c =
  let f lbl _ (i,s) =
    i+1,
    Printf.sprintf "%sdefinition %s := %d.\n%s"
      (n_spaces n)
      lbl
      i
      s
  in
  snd (Label.Map.fold f c (0,""))

let print_graph n c =
  let f lbl stmt s =
    Printf.sprintf "%s(pair ?? %s (%s))%s\n%s"
      (n_spaces n)
      lbl
      (print_statement stmt)
      (if s = "" then "\n]" else ";")
      s in
  "[\n" ^ Label.Map.fold f c ""

let print_internal_decl n f def m =
  Printf.sprintf
    "%sdefinition id_%s := ident_of_nat %d.\n%s%s\n\n%sdefinition pre_%s := mk_pre_internal_function\n%s(%s)\n%s%s\n%s%s\n%s%s\n%s%d\n%s%s\n%s%s\n%s%s."
    (n_spaces n)
    f
    m
    (print_labels n def.RTLabs.f_graph)
    (print_cost_labels n def.RTLabs.f_graph)
    (n_spaces n)
    f
    (n_spaces (n+2))
    (print_sig def.RTLabs.f_sig)
    (n_spaces (n+2))
    (print_result def.RTLabs.f_result)
    (n_spaces (n+2))
    (print_params def.RTLabs.f_params)
    (n_spaces (n+2))
    (print_locals def.RTLabs.f_locals)
    (n_spaces (n+2))
    def.RTLabs.f_stacksize
    (n_spaces (n+2))
    (print_graph (n+2) def.RTLabs.f_graph)
    (n_spaces (n+2))
    def.RTLabs.f_entry
    (n_spaces (n+2))
    def.RTLabs.f_exit



let print_external_decl n f def m =
  Printf.sprintf "%sdefinition id_%s := ident_of_nat %d.\n%sdefinition f_%s := External (mk_external_function id_%s (%s)).\n"
    (n_spaces n)
    f
    m
    (n_spaces n)
    f
    f
    (print_sig def.AST.ef_sig)


let print_fun_decl n (f, def) m = match def with
  | RTLabs.F_int def -> print_internal_decl n f def m
  | RTLabs.F_ext def -> print_external_decl n f def m

let print_fun_decls n functs =
  snd (List.fold_left (fun (i,s) f -> i+1, s ^ (print_fun_decl n f i) ^ "\n\n") (0,"")
    functs)

let print_fun n functs =
  List.fold_left (fun s (f,_) ->
    Printf.sprintf "%sdo f_%s \\larr make_internal_function pre_%s;\n%s"
      (n_spaces n) 
      f
      f
      s) "" functs

let print_fun' n functs =
  List.fold_left (fun s (f,def) ->
    Printf.sprintf "%s(pair ?? id_%s f_%s)::\n%s"
      (n_spaces n) 
      f
      f
      s) "(nil ?)" functs

let print_main n main =
  Printf.sprintf "%s%s"
    (n_spaces n)
    (match main with Some f -> "id_" ^ f | None -> "ident_of_nat 0 (* None! *)")

let print_program p =
  Printf.sprintf "include \"RTLabs/import.ma\".\ninclude \"common/Animation.ma\".\n\n(*program:*)\n\n\n%s\n\ndefinition prog : res RTLabs_program :=\n%s\nOK ? (mk_program ??\n(%s)\n%s\n%s\n).\n"
    (print_fun_decls 2 p.RTLabs.functs)
    (print_fun 2 p.RTLabs.functs)
    (print_fun' 2 p.RTLabs.functs)
    (print_main 2 p.RTLabs.main)
    (print_globals 2 p.RTLabs.vars)