source: src/RTLabs/RTLabsMatitaPrinter.ml @ 2224

let next_id = ref 0
let fresh () = let i = !next_id in next_id := i+1; i

let n_spaces n = String.make n ' '

let print_signedness = function
  | AST.Signed -> "Signed"
  | AST.Unsigned -> "Unsigned"

let print_sig_type = function
  | AST.Sig_int (sz, sg) -> Printf.sprintf "ASTint I%d %s" (sz*8) (print_signedness sg)
  | AST.Sig_float (sz, _) -> Printf.sprintf "ASTfloat F%d" (sz*8)
  | AST.Sig_offset -> "ASTint I32 Unsigned"
  | AST.Sig_ptr -> "ASTptr Any"

let print_global (x, size) =
  Printf.sprintf "pair ?? (pair ?? id_%s Any) %d" x 
    (Driver.RTLabsMemory.concrete_size size)

let print_globals n globs =
  Printf.sprintf "%s(*globals:*)\n%s[%s]"
    (n_spaces n)
    (n_spaces n)
    (MiscPottier.string_of_list (";\n"^n_spaces n) print_global globs)

let print_label l = "lbl_" ^ l

let rec print_args args =
  Printf.sprintf "[[%s]]" (MiscPottier.string_of_list "; " Register.print args)

let print_regty (r,ty) =
  Printf.sprintf "(pair ?? %s (%s))" (Register.print r) (print_sig_type ty)

let print_result = function
| None -> "(None ?)"
| Some rty -> "(Some ? " ^ print_regty rty ^ ")"

let print_params rl =
  Printf.sprintf "[%s]" (MiscPottier.string_of_list "; " Register.print rl)

let print_locals rl =
  Printf.sprintf "[%s]" (MiscPottier.string_of_list "; " print_regty rl)

let print_quantity = function
  | AST.QInt 1 -> "Mint8unsigned"
  | AST.QInt 2 -> "Mint16unsigned"
  | AST.QInt 4 -> "Mint32"
  | AST.QOffset -> "Mint32"
  | AST.QPtr -> "Mpointer Any"
(*
let print_memory_q = function
  | Memory.MQ_int8signed    -> "Mint8signed"
  | Memory.MQ_int8unsigned  -> "Mint8unsigned"
  | Memory.MQ_int16signed   -> "Mint16signed"
  | Memory.MQ_int16unsigned -> "Mint16unsigned"
  | Memory.MQ_int32         -> "Mint32"
  | Memory.MQ_float32       -> "Mfloat32"
  | Memory.MQ_float64       -> "Mfloat64"
  | Memory.MQ_pointer       -> "Mpointer Any"
  | Memory.MQ_chunk         -> "MXXX"
*)


let print_cmp = function
  | AST.Cmp_eq -> "Ceq"
  | AST.Cmp_ne -> "Cne"
  | AST.Cmp_gt -> "Cgt"
  | AST.Cmp_ge -> "Cge"
  | AST.Cmp_lt -> "Clt"
  | AST.Cmp_le -> "Cle"

let print_constant ty = function
  | AST.Cst_int i ->
      Printf.sprintf "Ointconst I%d (repr ? %d)"
        (match ty with AST.Sig_int (sz, _) -> 8*sz | _ -> 32)
        i
  | AST.Cst_float f -> Printf.sprintf "Ofloatconst %f" f
  | AST.Cst_addrsymbol id -> Printf.sprintf "Oaddrsymbol id_%s 0" id
  (*| AST.Cst_stackoffset off -> Printf.sprintf "Oaddrstack (repr %d)" off*)
  | AST.Cst_stack -> Printf.sprintf "Oaddrstack 0"
  | AST.Cst_offset off ->
      Printf.sprintf "Ointconst I%d (repr ? %d)"
        (match ty with AST.Sig_int (sz, _) -> 8*sz | _ -> 32)
        (Driver.CminorMemory.concrete_offset off)
  | AST.Cst_sizeof sz ->
      Printf.sprintf "Ointconst I%d (repr ? %d)"
        (match ty with AST.Sig_int (sz, _) -> 8*sz | _ -> 32)
        (Driver.CminorMemory.concrete_size sz)

let print_op1 = function
  | AST.Op_cast((_,sg),sz) -> Printf.sprintf "(Ocastint %s I%d)" (print_signedness sg) (8*sz)
  | AST.Op_negint -> "Onegint"
  | AST.Op_notbool -> "Onotbool"
  | AST.Op_notint -> "Onotint"
  | AST.Op_id -> "Oid"
  | AST.Op_ptrofint -> "Optrofint"
  | AST.Op_intofptr -> "Ointofptr"

let print_op2 ty = function
  | AST.Op_add -> "Oadd"
  | AST.Op_sub -> "Osub"
  | AST.Op_mul -> "Omul"
  | AST.Op_div -> "Odiv"
  | AST.Op_divu -> "Odivu"
  | AST.Op_mod -> "Omod"
  | AST.Op_modu -> "Omodu"
  | AST.Op_and -> "Oand"
  | AST.Op_or -> "Oor"
  | AST.Op_xor -> "Oxor"
  | AST.Op_shl -> "Oshl"
  | AST.Op_shr -> "Oshr"
  | AST.Op_shru -> "Oshru"
  | AST.Op_cmp cmp -> "(Ocmp " ^ print_cmp cmp ^ ")"
  | AST.Op_cmpu cmp -> "(Ocmpu " ^ (print_cmp cmp) ^ ")"
  | AST.Op_addp -> "Oaddp"
  | AST.Op_subp -> "Osubpi"
  | AST.Op_subpp ->
      Printf.sprintf "(Osubpp I%d)"
        (match ty with AST.Sig_int (sz, _) -> 8*sz | _ -> 32)
  | AST.Op_cmpp cmp -> "(Ocmpp " ^ (print_cmp cmp) ^ ")"



let print_sig s =
  Printf.sprintf "mk_signature [%s] (%s)"
    (MiscPottier.string_of_list "; " print_sig_type s.AST.args)
    (match s.AST.res with AST.Type_ret t -> "Some ? " ^ print_sig_type t
                        | AST.Type_void  -> "None ?")

let rec print_table = function
  | [] -> ""
  | [lbl] -> print_label lbl
  | lbl :: tbl -> (print_label lbl) ^ "; " ^ (print_table tbl)


let print_statement lookup_type = function
  | RTLabs.St_skip lbl
  | RTLabs.St_ind_0 (_, lbl)
  | RTLabs.St_ind_inc (_, lbl)
     -> "make_St_skip " ^ (print_label lbl)
  | RTLabs.St_cost (cost_lbl, lbl) ->
      Printf.sprintf "make_St_cost C%s %s"
        cost_lbl.CostLabel.name (print_label lbl)
  | RTLabs.St_cst (dests, cst, lbl) ->
      Printf.sprintf "make_St_const %s (%s) %s"
        (Register.print dests)
        (print_constant (lookup_type dests) cst)
        (print_label lbl)
  | RTLabs.St_op1 (op1, dests, srcs, lbl) ->
      Printf.sprintf "make_St_op1 %s %s %s %s"
        (print_op1 op1)
        (Register.print dests)
        (Register.print srcs)
        (print_label lbl)
  | RTLabs.St_op2 (op2, dests, srcs1, srcs2, lbl) ->
      Printf.sprintf "make_St_op2 %s %s %s %s %s"
        (print_op2 (lookup_type dests) op2)
        (Register.print dests)
        (Register.print srcs1)
        (Register.print srcs2)
        (print_label lbl)
  | RTLabs.St_load (chunk, addr, dests, lbl) ->
      Printf.sprintf "make_St_load %s %s %s %s"
        (print_quantity chunk)
        (Register.print addr)
        (Register.print dests)
        (print_label lbl)
  | RTLabs.St_store (chunk, addr, srcs, lbl) ->
      Printf.sprintf "make_St_store %s %s %s %s"
        (print_quantity chunk)
        (Register.print addr)
        (Register.print srcs)
        (print_label lbl)
  | RTLabs.St_call_id (f, args, res, sg, lbl) ->
      Printf.sprintf "make_St_call_id id_%s %s (%s) %s"
        f
        (print_params args)
        (match res with None -> "None ?" | Some res -> "Some ? " ^ Register.print res)
        (print_label lbl)
  | RTLabs.St_call_ptr (f, args, res, sg, lbl) ->
      Printf.sprintf "make_St_call_ptr %s %s (%s) %s"
        (Register.print f)
        (print_params args)
        (match res with None -> "None ?" | Some res -> "Some ? " ^ (Register.print res))
        (print_label lbl)
  | RTLabs.St_tailcall_id (f, args, sg) ->
      Printf.sprintf "make_St_tailcall_id id_%s %s"
        f
        (print_params args)
  | RTLabs.St_tailcall_ptr (f, args, sg) ->
      Printf.sprintf "make_St_tailcall_ptr %s %s"
        (Register.print f)
        (print_params args)
  | RTLabs.St_cond (srcs, lbl_true, lbl_false) ->
      Printf.sprintf "make_St_cond %s %s %s"
        (Register.print srcs)
        (print_label lbl_true)
        (print_label lbl_false)
  | RTLabs.St_jumptable (rs, tbl) ->
      Printf.sprintf "make_St_jumptable %s [%s]"
        (Register.print rs)
        (print_table tbl)
  | RTLabs.St_return -> "make_St_return"

let print_cost_labels n c =
  let f _ stmt (i,s) =
    match stmt with
    | RTLabs.St_cost (lbl, _) ->
        i+1,
        Printf.sprintf "%sdefinition C%s := costlabel_of_nat %d.\n%s"
          (n_spaces n)
          lbl
          i
          s
    | _ -> i,s
  in
  snd (Label.Map.fold f c (0,""))

let print_labels n c =
  let f lbl _ (i,s) =
    i+1,
    Printf.sprintf "%sdefinition %s := %d.\n%s"
      (n_spaces n)
      (print_label lbl)
      i
      s
  in
  snd (Label.Map.fold f c (0,""))

let print_graph n lookup_type c =
  let f lbl stmt s =
    Printf.sprintf "%s(pair ?? %s (%s))%s\n%s"
      (n_spaces n)
      (print_label lbl)
      (print_statement lookup_type stmt)
      (if s = "" then "\n]" else ";")
      s in
  "[\n" ^ Label.Map.fold f c ""

let print_internal_decl n f def =
  let env = def.RTLabs.f_params @ def.RTLabs.f_locals in
  let lookup_type r =
    let _,ty = List.find (fun (r',_) -> r = r') env in ty
  in
  Printf.sprintf
    "%sdefinition id_%s := ident_of_nat %d.\n%s%s\n\n%sdefinition pre_%s := mk_pre_internal_function\n%s%s\n%s%s\n%s%s\n%s%d\n%s%s\n%s%s\n%s%s."
    (n_spaces n)
    f
    (fresh ())
    (print_labels n def.RTLabs.f_graph)
    (print_cost_labels n def.RTLabs.f_graph)
    (n_spaces n)
    f
    (n_spaces (n+2))
    (print_result def.RTLabs.f_result)
    (n_spaces (n+2))
    (print_locals def.RTLabs.f_params)
    (n_spaces (n+2))
    (print_locals def.RTLabs.f_locals)
    (n_spaces (n+2))
    (Driver.RTLabsMemory.concrete_size def.RTLabs.f_stacksize)
    (n_spaces (n+2))
    (print_graph (n+2) lookup_type def.RTLabs.f_graph)
    (n_spaces (n+2))
    (print_label def.RTLabs.f_entry)
    (n_spaces (n+2))
    (print_label def.RTLabs.f_exit)



let print_external_decl n f def =
  Printf.sprintf "%sdefinition id_%s := ident_of_nat %d.\n%sdefinition f_%s := External (mk_external_function id_%s (%s)).\n"
    (n_spaces n)
    f
    (fresh ())
    (n_spaces n)
    f
    f
    (print_sig def.AST.ef_sig)


let print_fun_decl n (f, def) = match def with
  | RTLabs.F_int def -> print_internal_decl n f def
  | RTLabs.F_ext def -> print_external_decl n f def

let print_fun_decls n =
  List.fold_left (fun s f -> s ^ (print_fun_decl n f) ^ "\n\n") ""

let print_fun n functs =
  List.fold_left (fun s (f,_) ->
    Printf.sprintf "%sdo f_%s \\larr make_internal_function pre_%s;\n%s"
      (n_spaces n) 
      f
      f
      s) "" functs

let print_fun' n functs =
  List.fold_left (fun s (f,def) ->
    Printf.sprintf "%s(pair ?? id_%s f_%s)::\n%s"
      (n_spaces n) 
      f
      f
      s) "(nil ?)" functs

let print_main n main =
  Printf.sprintf "%s%s"
    (n_spaces n)
    (match main with Some f -> "id_" ^ f | None -> "ident_of_nat 0 (* None! *)")

let define_var_id (id,_) =
  Printf.sprintf "definition id_%s := ident_of_nat %d.\n" id (fresh ())

let define_var_ids =
  List.fold_left (fun s v -> s ^ (define_var_id v)) ""

let print_program p =
  Printf.sprintf "include \"RTLabs/import.ma\".\ninclude \"common/Animation.ma\".\n\n%s\n\n\n%s\n\ndefinition prog : res RTLabs_program :=\n%s\nOK ? (mk_program ??\n%s\n(%s)\n%s\n).\n"
    (define_var_ids p.RTLabs.vars)
    (print_fun_decls 2 p.RTLabs.functs)
    (print_fun 2 p.RTLabs.functs)
    (print_globals 2 p.RTLabs.vars)
    (print_fun' 2 p.RTLabs.functs)
    (print_main 2 p.RTLabs.main)