source: src/ERTLptr/ERTLptr.ma @ 3393

include "ERTL/ERTL.ma".

inductive ertlptr_seq : Type[0] ≝
  | ertlptr_ertl: ertl_seq → ertlptr_seq
  | LOW_ADDRESS : register → label → ertlptr_seq
  | HIGH_ADDRESS : register → label → ertlptr_seq.

definition ERTLptr_uns ≝ mk_unserialized_params
    (* acc_a_reg ≝ *) register
    (* acc_b_reg ≝ *) register
    (* acc_a_arg ≝ *) psd_argument
    (* acc_b_arg ≝ *) psd_argument
    (* dpl_reg   ≝ *) register
    (* dph_reg   ≝ *) register
    (* dpl_arg   ≝ *) psd_argument
    (* dph_arg   ≝ *) psd_argument
    (* snd_arg   ≝ *) psd_argument
    (* pair_move ≝ *) (move_dst × move_src)
    (* call_args ≝ *) ℕ
    (* call_dest ≝ *) unit
    (* ext_seq ≝ *) ertlptr_seq
    (* ext_seq_labels ≝ *)
      (λs.match s with [ LOW_ADDRESS _ l ⇒ [l] | HIGH_ADDRESS _ l ⇒ [l] | _ ⇒ [ ]])
    (* has_tailcall ≝ *) false
    (* paramsT ≝ *) ℕ.
    
definition ERTLptr_functs ≝ mk_get_pseudo_reg_functs ERTLptr_uns
(* acc_a_regs *) (λr.[r])
(* acc_b_regs *) (λr.[r])
(* acc_a_args *) (λarg.match arg with [ Imm _ ⇒ [ ] | Reg r ⇒ [r]])
(* acc_b_args *) (λarg.match arg with [ Imm _ ⇒ [ ] | Reg r ⇒ [r]])
(* dpl_regs *) (λr.[r])
(* dph_regs *) (λr.[r])
(* dpl_args *) (λarg.match arg with [ Imm _ ⇒ [ ] | Reg r ⇒ [r]])
(* dph_args *) (λarg.match arg with [ Imm _ ⇒ [ ] | Reg r ⇒ [r]])
(* snd_args *) (λarg.match arg with [ Imm _ ⇒ [ ] | Reg r ⇒ [r]])
(* pair_move_regs *) (λx.(regs_from_move_dst (\fst x)) @ (regs_from_move_src (\snd x)))
(* f_call_args *) (λ_.[ ])
(* f_call_dest *) (λ_.[ ])
(* ext_seq_regs *) 
  (λs.match s with [ LOW_ADDRESS r _ ⇒ [r] 
                   | HIGH_ADDRESS r _ ⇒ [r] 
                   | ertlptr_ertl s' ⇒ ertl_ext_seq_regs s'
                   ])
(* params_regs *) (λ_.[ ]).

definition ERTLptr ≝ mk_graph_params (mk_uns_params ERTLptr_uns ERTLptr_functs).
definition ertlptr_program ≝ joint_program ERTLptr.
unification hint 0 ≔ ⊢ ertlptr_program ≡ joint_program ERTLptr.
  
definition ertlptr_seq_joint ≝ extension_seq ERTLptr.
coercion ertlptr_seq_to_joint_seq : ∀globals.∀s : ertlptr_seq.joint_seq ERTLptr globals ≝ ertlptr_seq_joint
  on _s : ertlptr_seq to joint_seq ERTLptr ?.
  
definition ERTLptr_premain : ∀p : ertlptr_program.joint_closed_internal_function ERTLptr (prog_var_names ?? p) ≝
λp.
let l1 : label ≝ an_identifier … one in
let l2 : label ≝ an_identifier … (p0 one) in
let l3 : label ≝ an_identifier … (p1 one) in
let res ≝
  mk_joint_internal_function ERTLptr (prog_var_names … p)
  (mk_universe … (p0 (p0 one)))
  (mk_universe … one)
  it 4 0 0 (empty_map …) l1 in
(* todo: args for main? *)
let res ≝ add_graph … l1
  (sequential … (COST_LABEL … (init_cost_label … p)) l2)
  res in
let res ≝ add_graph … l2
  (sequential … (CALL ERTLptr ? (inl … (prog_main … p)) 0 it) l3)
  res in
let res ≝ add_graph … l3
  (GOTO ? l3)
  res in
res.
%
[ ** [2,3: * [2,3,5,6: #p ]] #s whd in ⊢ (??%?→?); #EQ destruct
  %
  [1,3,5: %{I} % whd in ⊢ (??%(??%)→?); #EQ destruct
  |2: %
  |4,6: % whd in ⊢ (??%%→?); #EQ destruct
  ]
| ** [2,3: * [2,3,5,6: #p ]] #s whd in ⊢ (??%?→?); #EQ destruct % try @I %{I I}
| ** [2,3: * [2,3,5,6: #p ]] * whd whd in ⊢ (?%%); //
| ** [2,3: * [2,3,5,6: #p ]] #s whd in ⊢ (??%%→?); #EQ destruct @I
| %{l2} %{(init_cost_label … p)} %
]
qed.