source: src/Cminor/cminorMatitaPrinter.ml @ 950

open AST

let next_id = ref 0
let fresh () = let i = !next_id in next_id := i+1; i

let print_signedness = function
  | Signed -> "Signed"
  | Unsigned -> "Unsigned"

let print_type = function
  | Sig_int (sz, sg) -> Printf.sprintf "ASTint I%d %s" (sz*8) (print_signedness sg)
  | Sig_float (sz, _) -> Printf.sprintf "ASTfloat F%d" (sz*8)
  | Sig_offset -> "ASTint I32 Unsigned"
  | Sig_ptr -> "ASTptr Any"

let print_ret_type = function
  | Type_ret t -> Printf.sprintf "Some ? (%s)" (print_type t)
  | Type_void -> "None ?"


let print_data = function
  (*| Data_reserve n -> Printf.sprintf "Init_space %d" n*)
  | Data_int8 i -> Printf.sprintf "Init_int8 (repr %d)" i
  | Data_int16 i -> Printf.sprintf "Init_int16 (repr %d)" i
  | Data_int32 i -> Printf.sprintf "Init_int32 (repr %d)" i
  | Data_float32 f -> Printf.sprintf "Init_float32 %f" f
  | Data_float64 f -> Printf.sprintf "Init_float64 %f" f

let print_var n (id, sz, init) =
  Printf.sprintf "(pair ?? (pair ?? (pair ?? id_%s [%s]) Any) it)"
    id
    (match init with
     | None -> Printf.sprintf "Init_space %d" (Driver.CminorMemory.concrete_size sz)
     | Some init ->
         (MiscPottier.string_of_list ";" print_data init))

let print_vars n = MiscPottier.string_of_list ";\n" (print_var n) 

let print_cmp = function
  | AST.Cmp_eq -> "Ceq"
  | AST.Cmp_ne -> "Cne"
  | AST.Cmp_gt -> "Cgt"
  | AST.Cmp_ge -> "Cge"
  | AST.Cmp_lt -> "Clt"
  | AST.Cmp_le -> "Cle"

let print_constant = function
  | AST.Cst_int i -> Printf.sprintf "Ointconst (repr %d)" i
  | AST.Cst_float f -> Printf.sprintf "Ofloatconst %f" f
  | AST.Cst_addrsymbol id -> Printf.sprintf "Oaddrsymbol id_%s (repr 0)" id
  (*| AST.Cst_stackoffset off -> Printf.sprintf "Oaddrstack (repr %d)" off*)
  | AST.Cst_stack -> Printf.sprintf "Oaddrstack (repr 0)"
  | AST.Cst_offset off -> Printf.sprintf "Ointconst (repr %d)" (Driver.CminorMemory.concrete_offset off)
  | AST.Cst_sizeof sz -> Printf.sprintf "Ointconst (repr %d)" (Driver.CminorMemory.concrete_size sz)

let print_op1 = function
  | AST.Op_cast((1,Unsigned),_) -> "Ocast8unsigned"
  | AST.Op_cast((1,Signed),_) -> "Ocast8signed"
  | AST.Op_cast((2,Unsigned),_) -> "Ocast16unsigned"
  | AST.Op_cast((2,Signed),_) -> "Ocast16signed"
  | AST.Op_cast((4,_),_) -> "Oid"
  | AST.Op_negint -> "Onegint"
  | AST.Op_notbool -> "Onotbool"
  | AST.Op_notint -> "Onotint"
  | AST.Op_id -> "Oid"
  | AST.Op_ptrofint -> "(Optrofint Any)"
  | AST.Op_intofptr -> "Ointofptr"

let print_op2 = function
  | AST.Op_add -> "Oadd"
  | AST.Op_sub -> "Osub"
  | AST.Op_mul -> "Omul"
  | AST.Op_div -> "Odiv"
  | AST.Op_divu -> "Odivu"
  | AST.Op_mod -> "Omod"
  | AST.Op_modu -> "Omodu"
  | AST.Op_and -> "Oand"
  | AST.Op_or -> "Oor"
  | AST.Op_xor -> "Oxor"
  | AST.Op_shl -> "Oshl"
  | AST.Op_shr -> "Oshr"
  | AST.Op_shru -> "Oshru"
  | AST.Op_cmp cmp -> "(Ocmp " ^ print_cmp cmp ^ ")"
  | AST.Op_cmpu cmp -> "(Ocmpu " ^ (print_cmp cmp) ^ ")"
  | AST.Op_addp -> "Oaddp"
  | AST.Op_subp -> "Osubpi"
  | AST.Op_subpp -> "Osubpp"
  | AST.Op_cmpp cmp -> "(Ocmpp " ^ (print_cmp cmp) ^ ")"

let rec define_expr_labels = function
| Cminor.Expr (e,ty) -> match e with
  | Cminor.Op1 (_, e) -> define_expr_labels e
  | Cminor.Op2 (_, e1, e2) -> define_expr_labels e1 ^ define_expr_labels e2 
  | Cminor.Mem (_, e) -> define_expr_labels e
  | Cminor.Cond (e1, e2, e3) ->
      define_expr_labels e1 ^ define_expr_labels e2 ^ define_expr_labels e3  
  | Cminor.Exp_cost (lab, e) ->
      Printf.sprintf "definition C%s := costlabel_of_nat %d.\n%s"
        lab (fresh ()) (define_expr_labels e)
  | _ -> ""

let print_quantity = function
  | AST.QInt 1 -> "Mint8unsigned"
  | AST.QInt 2 -> "Mint16unsigned"
  | AST.QInt 4 -> "Mint32"
  | AST.QOffset -> "Mint32"
  | AST.QPtr -> "Mpointer Any"

let typeof = function Cminor.Expr (_,ty) -> ty

let rec print_expression p_id = function
| Cminor.Expr (e,ty) -> match e with
  | Cminor.Id id -> Printf.sprintf "Id (%s) %s" (print_type ty) (p_id id)
  | Cminor.Cst cst -> Printf.sprintf "Cst (%s) (%s)" (print_type ty) (print_constant cst)
  | Cminor.Op1 (op1, e) ->
      Printf.sprintf "Op1 (%s) (%s) %s (%s)"
        (print_type (typeof e)) (print_type ty)
        (print_op1 op1) (print_expression p_id e)
  | Cminor.Op2 (op2, e1, e2) ->
      Printf.sprintf "Op2 (%s) (%s) (%s) %s (%s) (%s)"
        (print_type (typeof e1)) (print_type (typeof e2)) (print_type ty)
        (print_op2 op2)
        (print_expression p_id e1)
        (print_expression p_id e2)
  | Cminor.Mem (q, e) ->
      Printf.sprintf "Mem (%s) Any %s (%s)"
        (print_type ty) (print_quantity q) (print_expression p_id e)
  | Cminor.Cond (e1, e2, e3) ->
      let sz,sg = match typeof e1 with Sig_int (sz, sg) -> sz,sg in
      Printf.sprintf "Cond I%d %s (%s) (%s) (%s) (%s)"
        (sz*8) (print_signedness sg)
        (print_type ty)
        (print_expression p_id e1)
        (print_expression p_id e2)
        (print_expression p_id e3)
  | Cminor.Exp_cost (lab, e) ->
      Printf.sprintf "Ecost (%s) C%s (%s)" (print_type ty) lab (print_expression p_id e)

let print_arg p_id e =
  Printf.sprintf "dp ?? (%s) (%s)" (print_type (typeof e)) (print_expression p_id e)

let rec print_args p_id = 
  MiscPottier.string_of_list "; " (print_arg p_id)


let n_spaces n = String.make n ' '


let print_local p_id (id,ty) =
  Printf.sprintf "pair ?? %s (%s)" (p_id id) (print_type ty)

let print_locals p_id vars =
  (MiscPottier.string_of_list "; " (print_local p_id) vars)


let print_table n =
  let f (case, exit) =
    Printf.sprintf "(pair ?? (repr %d) %d)" case exit
  in
  MiscPottier.string_of_list (";\n" ^ n_spaces n) f

let rec define_labels = function
  | Cminor.St_assign (_, e) -> define_expr_labels e
  | Cminor.St_store (_, e1, e2) -> define_expr_labels e1 ^ define_expr_labels e2
  | Cminor.St_call (_, _, args, _) -> String.concat "" (List.map define_expr_labels args)
  | Cminor.St_tailcall (_, args, _) -> String.concat "" (List.map define_expr_labels args)
  | Cminor.St_seq (s1, s2) -> define_labels s1 ^ define_labels s2
  | Cminor.St_ifthenelse (e, s1, s2) -> define_expr_labels e ^ define_labels s1 ^ define_labels s2
  | Cminor.St_loop s -> define_labels s
  | Cminor.St_block s -> define_labels s
  | Cminor.St_switch (e, _, _) -> define_expr_labels e
  | Cminor.St_return (Some e) -> define_expr_labels e
  | Cminor.St_label (l, s) ->
      Printf.sprintf "definition L%s := ident_of_nat %d.\n%s"
        l (fresh ()) (define_labels s)
  | Cminor.St_cost (l, s) ->
      Printf.sprintf "definition C%s := costlabel_of_nat %d.\n%s"
        l (fresh ()) (define_labels s)
  | _ -> ""

let rec print_body p_id n = function
  | Cminor.St_skip -> Printf.sprintf "%sSt_skip" (n_spaces n)
  | Cminor.St_assign (id, e) ->
      Printf.sprintf "%sSt_assign (%s) %s (%s)\n"
        (n_spaces n) (print_type (typeof e))
        (p_id id) (print_expression p_id e)
  | Cminor.St_store (q, e1, e2) ->
      Printf.sprintf "%sSt_store (%s) Any %s (%s) (%s)\n"
        (n_spaces n)
        (print_type (typeof e2))
        (print_quantity q)
        (print_expression p_id e1)
        (print_expression p_id e2)
(* XXX cheat horribly *)
  | Cminor.St_call (None, Cminor.Expr (Cminor.Cst (AST.Cst_addrsymbol f),_), args, sg) ->
      Printf.sprintf "%sSt_call (None ?) (Cst ? (Oaddrsymbol id_%s (repr 0))) [%s]\n"
        (n_spaces n)
        f
        (print_args p_id args)
  | Cminor.St_call (Some id, Cminor.Expr (Cminor.Cst (AST.Cst_addrsymbol f),_), args, sg) ->
      Printf.sprintf "%sSt_call (Some ? %s) (Cst ? (Oaddrsymbol id_%s (repr 0))) [%s]\n"
        (n_spaces n)
        (p_id id)
        f
        (print_args p_id args)
  | Cminor.St_tailcall (Cminor.Expr (Cminor.Cst (AST.Cst_addrsymbol f),_), args, sg) ->
      Printf.sprintf "%sSt_tailcall (Cst ? (Oaddrsymbol id_%s (repr 0))) [%s]\n"
        (n_spaces n)
        f
        (print_args p_id args)
(* XXX regular versions, but the region will be screwed up *)
  | Cminor.St_call (None, f, args, sg) ->
      Printf.sprintf "%sSt_call (None ?) (%s) [%s]\n"
        (n_spaces n)
        (print_expression p_id f)
        (print_args p_id args)
  | Cminor.St_call (Some id, f, args, sg) ->
      Printf.sprintf "%sSt_call (Some ? %s) (%s) [%s]\n"
        (n_spaces n)
        (p_id id)
        (print_expression p_id f)
        (print_args p_id args)
  | Cminor.St_tailcall (f, args, sg) ->
      Printf.sprintf "%sSt_tailcall (%s) [%s]\n"
        (n_spaces n)
        (print_expression p_id f)
        (print_args p_id args)
  | Cminor.St_seq (s1, s2) ->
      Printf.sprintf "%sSt_seq (\n%s%s) (\n%s%s)\n"
        (n_spaces n)
        (print_body p_id (n+2) s1)
        (n_spaces n)
        (print_body p_id n s2)
        (n_spaces n)
  | Cminor.St_ifthenelse (e, s1, s2) ->
      let sz,sg = match typeof e with Sig_int (sz, sg) -> sz,sg in
      Printf.sprintf "%sSt_ifthenelse I%d %s (%s) (\n%s%s) (\n%s%s)\n"
        (n_spaces n)
        (sz*8) (print_signedness sg)
        (print_expression p_id e)
        (print_body p_id (n+2) s1)
        (n_spaces n)
        (print_body p_id (n+2) s2)
        (n_spaces n)
  | Cminor.St_loop s ->
      Printf.sprintf "%sSt_loop (\n%s%s)\n"
        (n_spaces n)
        (print_body p_id (n+2) s)
        (n_spaces n)
  | Cminor.St_block s ->
      Printf.sprintf "%sSt_block (\n%s%s)\n"
        (n_spaces n)
        (print_body p_id (n+2) s)
        (n_spaces n)
  | Cminor.St_exit i ->
      Printf.sprintf "%sSt_exit %d\n" (n_spaces n) i
  | Cminor.St_switch (e, tbl, dflt) ->
      let sz,sg = match typeof e with Sig_int (sz, sg) -> sz,sg in
      Printf.sprintf "%sSt_switch I%d %s (%s) [\n%s%s] %d\n"
        (n_spaces n)
        (sz*8) (print_signedness sg)
        (print_expression p_id e)
        (n_spaces (n+2))
        (print_table ( n+2) tbl)
        dflt
  | Cminor.St_return None -> Printf.sprintf "%sSt_return (None ?)\n" (n_spaces n)
  | Cminor.St_return (Some e) ->
      Printf.sprintf "%sSt_return (Some ? (%s))\n" (n_spaces n) (print_arg p_id e)
  | Cminor.St_label (lbl, s) ->
      Printf.sprintf "%sSt_label L%s (\n%s%s)\n" 
        (n_spaces n)
        lbl
        (print_body p_id n s)
        (n_spaces n)
  | Cminor.St_goto lbl ->
      Printf.sprintf "%sSt_goto L%s\n" (n_spaces n) lbl
  | Cminor.St_cost (lbl, s) ->
      Printf.sprintf "%sSt_cost C%s (\n%s%s)\n"
        (n_spaces n) lbl (print_body p_id n s)
        (n_spaces n)

let print_ids fname vs =
  List.fold_left (fun s (v,_) ->
                  Printf.sprintf "%sdefinition id_%s_%s := ident_of_nat %d.\n"
                                 s fname v (fresh ()))
       "" vs

let print_internal f_name f_def =
  let fid = fresh () in
  let p_id id = Printf.sprintf "id_%s_%s" f_name id in
  Printf.sprintf "definition id_%s := ident_of_nat %d.\n%s%sdefinition f_%s := Internal ? (mk_internal_function\n  (%s)\n  [%s]\n  [%s]\n  %d (\n%s\n)).\n\n"
    f_name
    fid
    (print_ids f_name (f_def.Cminor.f_vars @ f_def.Cminor.f_params))
    (define_labels f_def.Cminor.f_body)
    f_name
    (print_ret_type f_def.Cminor.f_return)
    (print_locals p_id f_def.Cminor.f_params)
    (print_locals p_id f_def.Cminor.f_vars)
    (Driver.CminorMemory.concrete_size f_def.Cminor.f_stacksize)
    (print_body p_id 2 f_def.Cminor.f_body)

let print_sig s =
  Printf.sprintf "mk_signature [%s] (%s)"
    (MiscPottier.string_of_list "; " print_type s.AST.args)
    (match s.AST.res with AST.Type_ret t -> "Some ? " ^ print_type t
                        | AST.Type_void  -> "None ?")



let print_external f def =
  Printf.sprintf "definition id_%s := ident_of_nat %d.\ndefinition f_%s := External internal_function (mk_external_function id_%s (%s)).\n"
    f
    (fresh ())
    f
    f
    (print_sig def.AST.ef_sig)


let print_funct (f_name, f_def) = match f_def with
  | Cminor.F_int f_def -> print_internal f_name f_def
  | Cminor.F_ext f_def -> print_external f_name f_def

let print_functs = List.fold_left (fun s f -> s ^ (print_funct f)) ""


let print_fun' n functs =
  MiscPottier.string_of_list ";\n" (fun (f,def) ->
    Printf.sprintf "%s(pair ?? id_%s f_%s)"
      (n_spaces n) 
      f
      f)
      functs

let print_main n main =
  Printf.sprintf "%s%s"
    (n_spaces n)
    (match main with Some f -> "id_" ^ f | None -> "ident_of_nat 0 (* None! *)")

let define_var_id (id,_,_) =
  Printf.sprintf "definition id_%s := ident_of_nat %d.\n" id (fresh ())

let define_var_ids =
  List.fold_left (fun s v -> s ^ (define_var_id v)) ""

let print_program p =
  Printf.sprintf "include \"Cminor/semantics.ma\".\ninclude \"common/Animation.ma\".\n\n%s\n\n%s\n\ndefinition myprog : Cminor_program :=\nmk_program ?? [\n%s\n]%s\n[%s]\n.\n"
    (define_var_ids p.Cminor.vars)
    (print_functs p.Cminor.functs)
    (print_fun' 2 p.Cminor.functs)
    (print_main 2 p.Cminor.main)
    (print_vars 2 p.Cminor.vars)