source: src/Clight/toCminor.ma @ 2562

Last change on this file since 2562 was 2554, checked in by garnier, 8 years ago

Proof of expression translation correctness "mostly" done for CL to CM. Some inconsistencies found in bit width for constants
regarding boolean operators need to be fixed (either by modifying CL semantics of by making CM code generation inefficient).
An inconsistency between clight and cminor expression evaluation was found for cost labels (placed before and after trace) - not
fixed yet, for fear of breaking proofs. One or two small lemmas missing, and most importantly, binary operators not done yet.

File size: 76.4 KB
Line 
1include "Clight/ClassifyOp.ma".
2include "basics/lists/list.ma".
3include "Clight/fresh.ma".
4
5(* Identify local variables that must be allocated memory. *)
6(* These are the variables whose addresses are taken. *)
7let rec gather_mem_vars_expr (e:expr) : identifier_set SymbolTag ≝
8match e with
9[ Expr ed ty ⇒
10    match ed with
11    [ Ederef e1 ⇒ gather_mem_vars_expr e1
12    | Eaddrof e1 ⇒ gather_mem_vars_addr e1
13    | Eunop _ e1 ⇒ gather_mem_vars_expr e1
14    | Ebinop _ e1 e2 ⇒ gather_mem_vars_expr e1 ∪
15                       gather_mem_vars_expr e2
16    | Ecast _ e1 ⇒ gather_mem_vars_expr e1
17    | Econdition e1 e2 e3 ⇒ gather_mem_vars_expr e1 ∪
18                            gather_mem_vars_expr e2 ∪
19                            gather_mem_vars_expr e3
20    | Eandbool e1 e2 ⇒ gather_mem_vars_expr e1 ∪
21                       gather_mem_vars_expr e2
22    | Eorbool e1 e2 ⇒ gather_mem_vars_expr e1 ∪
23                      gather_mem_vars_expr e2
24    | Efield e1 _ ⇒ gather_mem_vars_expr e1
25    | Ecost _ e1 ⇒ gather_mem_vars_expr e1
26    | _ ⇒ ∅
27    ]
28]
29and gather_mem_vars_addr (e:expr) : identifier_set SymbolTag ≝
30match e with
31[ Expr ed ty ⇒
32    match ed with
33    [ Evar x ⇒ { (x) }
34    | Ederef e1 ⇒ gather_mem_vars_expr e1
35    | Efield e1 _ ⇒ gather_mem_vars_addr e1
36    | _ ⇒ ∅ (* not an lvalue *)
37    ]
38].
39
40let rec gather_mem_vars_stmt (s:statement) : identifier_set SymbolTag ≝
41match s with
42[ Sskip ⇒ ∅
43| Sassign e1 e2 ⇒ gather_mem_vars_expr e1 ∪
44                  gather_mem_vars_expr e2
45| Scall oe1 e2 es ⇒ match oe1 with [ None ⇒ ∅ | Some e1 ⇒ gather_mem_vars_expr e1 ] ∪
46                    gather_mem_vars_expr e2 ∪
47                    (foldl ?? (λs,e. s ∪ gather_mem_vars_expr e) ∅ es)
48| Ssequence s1 s2 ⇒ gather_mem_vars_stmt s1 ∪
49                    gather_mem_vars_stmt s2
50| Sifthenelse e1 s1 s2 ⇒ gather_mem_vars_expr e1 ∪
51                         gather_mem_vars_stmt s1 ∪
52                         gather_mem_vars_stmt s2
53| Swhile e1 s1 ⇒ gather_mem_vars_expr e1 ∪
54                 gather_mem_vars_stmt s1
55| Sdowhile e1 s1 ⇒ gather_mem_vars_expr e1 ∪
56                   gather_mem_vars_stmt s1
57| Sfor s1 e1 s2 s3 ⇒ gather_mem_vars_stmt s1 ∪
58                     gather_mem_vars_expr e1 ∪
59                     gather_mem_vars_stmt s2 ∪
60                     gather_mem_vars_stmt s3
61| Sbreak ⇒ ∅
62| Scontinue ⇒ ∅
63| Sreturn oe1 ⇒ match oe1 with [ None ⇒ ∅ | Some e1 ⇒ gather_mem_vars_expr e1 ]
64| Sswitch e1 ls ⇒ gather_mem_vars_expr e1 ∪
65                  gather_mem_vars_ls ls
66| Slabel _ s1 ⇒ gather_mem_vars_stmt s1
67| Sgoto _ ⇒ ∅
68| Scost _ s1 ⇒ gather_mem_vars_stmt s1
69]
70and gather_mem_vars_ls (ls:labeled_statements) on ls : identifier_set SymbolTag ≝
71match ls with
72[ LSdefault s1 ⇒ gather_mem_vars_stmt s1
73| LScase _ _ s1 ls1 ⇒ gather_mem_vars_stmt s1 ∪
74                      gather_mem_vars_ls ls1
75].
76
77(* Defines where a variable should be allocated. *)
78inductive var_type : Type[0] ≝
79| Global : region → var_type  (* A global, allocated statically in a given region (which one ???)  *)
80| Stack  : nat → var_type     (* On the stack, at a given height *)
81| Local  : var_type           (* Locally (hopefully, in a register) *)
82.
83
84(* A map associating each variable identifier to its allocation mode and its type. *)
85definition var_types ≝ identifier_map SymbolTag (var_type × type).
86
87axiom UndeclaredIdentifier : String.
88
89definition lookup' ≝
90λvars:var_types.λid. opt_to_res … [MSG UndeclaredIdentifier; CTX ? id] (lookup ?? vars id).
91
92(* Assert that an identifier is a local variable with the given typ. *)
93definition local_id : var_types → ident → typ → Prop ≝
94λvars,id,t. match lookup' vars id with [ OK vt ⇒ match (\fst vt) with [ Global _ ⇒ False | _ ⇒ t = typ_of_type (\snd vt) ] | _ ⇒ False ].
95
96(* Note that the semantics allows locals to shadow globals.
97   Parameters start out as locals, but get stack allocated if their address
98   is taken.  We will add code to store them if that's the case.
99 *)
100
101(* Some kind of data is never allocated in registers, even if it fits, typically structured data. *)
102definition always_alloc : type → bool ≝
103λt. match t with
104[ Tarray _ _ ⇒ true
105| Tstruct _ _ ⇒ true
106| Tunion _ _ ⇒ true
107| _ ⇒ false
108].
109
110(* This builds a [var_types] map characterizing the allocation mode, of variables,
111 * and it returns a stack usage for the function (in bytes, according to [sizeof]) *)
112definition characterise_vars : list (ident×region×type) → function → var_types × nat ≝
113λglobals, f.
114  (* globals are added into a map, with var_type Global, region π_2(idrt) and type π_3(idrt) *)
115  let m ≝ foldr ?? (λidrt,m. add ?? m (\fst (\fst idrt)) 〈Global (\snd (\fst idrt)), \snd idrt〉) (empty_map ??) globals in
116  (* variables whose addr is taken in the body of the function are gathered in [mem_vars] *)
117  let mem_vars ≝ gather_mem_vars_stmt (fn_body f) in
118  (* iterate on the parameters and local variables of the function, with a tuple (map, stack_high) as an accumulator *)
119  let 〈m,stacksize〉 ≝ foldr ?? (λv,ms.
120    let 〈m,stack_high〉 ≝ ms in
121    let 〈id,ty〉 ≝ v in         
122    let 〈c,stack_high〉 ≝
123      (* if the (local, parameter) variable is of a compound type OR if its adress is taken, we allocate it on the stack. *)
124      if always_alloc ty ∨ id ∈ mem_vars then
125        〈Stack stack_high,stack_high + sizeof ty〉
126      else
127        〈Local, stack_high〉
128    in
129      〈add ?? m id 〈c, ty〉, stack_high〉) 〈m,0〉 (fn_params f @ fn_vars f) in
130  〈m,stacksize〉.
131
132(* A local variable id' status is not modified by the removal of a global variable id : id' is still local *)
133lemma local_id_add_global : ∀vars,id,r,t,id',t'.
134  local_id (add ?? vars id 〈Global r, t〉) id' t' → local_id vars id' t'.
135#var #id #r #t #id' #t'
136whd in ⊢ (% → ?); whd in ⊢ (match % with [ _ ⇒ ? | _ ⇒ ?] → ?);
137cases (identifier_eq ? id id')
138[ #E >E >lookup_add_hit whd in ⊢ (% → ?); *
139| #NE >lookup_add_miss /2/
140] qed.
141
142(* If I add a variable id ≠ id', then id' is still local *)
143lemma local_id_add_miss : ∀vars,id,vt,id',t'.
144  id ≠ id' → local_id (add ?? vars id vt) id' t' → local_id vars id' t'.
145#vars #id #vt #id' #t' #NE
146whd in ⊢ (% → %);
147whd in ⊢ (match % with [ _ ⇒ ? | _ ⇒ ? ] → match % with [ _ ⇒ ? | _ ⇒ ? ]);
148>lookup_add_miss
149[ #H @H | /2/ ]
150qed.
151
152(* After characterise_vars, a variable in the resulting map is either a global or a "local"(register or stack allocated) *)
153lemma characterise_vars_src : ∀gl,f,vars,n.
154  characterise_vars gl f = 〈vars,n〉 →
155  ∀id. present ?? vars id →
156   (∃r,ty. lookup' vars id = OK ? 〈Global r,ty〉 ∧ Exists ? (λx.x = 〈〈id,r〉,ty〉) gl) ∨
157   ∃t.local_id vars id t.
158#globals #f
159whd in ⊢ (∀_.∀_.??%? → ?);
160elim (fn_params f @ fn_vars f)
161[ #vars #n whd in ⊢ (??%? → ?); #E destruct #i #H %1
162  elim globals in H ⊢ %;
163  [ normalize * #H cases (H (refl ??))
164  | * * #id #rg #ty #tl #IH #H
165    cases (identifier_eq ? i id)
166    [ #E <E %{rg} %{ty} % [ whd in ⊢ (??%?); >lookup_add_hit // | %1 // ]
167    | #NE cases (IH ?)
168      [ #rg' * #ty' * #H1 #H2 %{rg'} %{ty'} %
169        [ whd in ⊢ (??%?); >lookup_add_miss  [ @H1 | @NE ]
170        | %2 @H2
171        ]
172      | whd in H ⊢ %; >lookup_add_miss in H; //
173      ]
174    ]
175  ]
176| * #id #ty #tl #IH #vars #n whd in ⊢ (??(match % with [ _ ⇒ ? ])? → ?); #E #i
177  #H >(contract_pair var_types nat ?) in E;
178  whd in ⊢ (??(match ? with [ _ ⇒ (λ_.λ_.%) ])? → ?);
179  cases (always_alloc ty ∨ id ∈ ?) whd in ⊢ (??(match ? with [ _ ⇒ (λ_.λ_.%) ])? → ?);
180  #H' lapply (extract_pair ???????? H') -H' * #m0 * #n0 * #EQ #EQ2
181  cases (identifier_eq ? i id)
182  [ 1,3: #E' <E' in EQ2:%; #EQ2 %2 %{(typ_of_type ty)}
183         destruct (EQ2) whd whd in ⊢ (match % with [_ ⇒ ? | _ ⇒ ?]);
184         >lookup_add_hit @refl
185  | *: #NE cases (IH m0 n0 ? i ?)
186    [ 1,5: * #rg' * #ty' * #H1 #H2 %1 %{rg'} %{ty'} % //
187           destruct (EQ2) whd in ⊢ (??%?); >lookup_add_miss try @NE @H1
188    | 2,6: * #t #H1 %2 %{t} destruct (EQ2) whd whd in ⊢ (match % with [_ ⇒ ?|_ ⇒ ?]);
189           >lookup_add_miss //
190    | 3,7: <EQ @refl
191    | *: destruct (EQ2) whd in H; >lookup_add_miss in H; //
192    ]
193  ]
194] qed.
195
196(* A local variable in a function is either a parameter or a "local" (:=register or stack alloc'd)
197 * variable, with the right type *)
198lemma characterise_vars_all : ∀l,f,vars,n.
199  characterise_vars l f = 〈vars,n〉 →
200  ∀i,t. local_id vars i t →
201        Exists ? (λx.\fst x = i ∧ typ_of_type (\snd x) = t) (fn_params f @ fn_vars f).
202#globals #f
203whd in ⊢ (∀_.∀_.??%? → ?);
204elim (fn_params f @ fn_vars f)
205[ #vars #n whd in ⊢ (??%? → ?); #E destruct #i #t #H @False_ind
206  elim globals in H;
207  [ normalize //
208  | * * #id #rg #t #tl #IH whd in ⊢ (?%?? → ?); #H @IH @(local_id_add_global … H)
209  ]
210| * #id #ty #tl #IH #vars #n whd in ⊢ (??(match % with [ _ ⇒ ? ])? → ?); #E #i #t
211
212  #H >(contract_pair var_types nat ?) in E;
213  whd in ⊢ (??(match ? with [ _ ⇒ (λ_.λ_.%) ])? → ?);
214  cases (always_alloc ty ∨ id ∈ ?) whd in ⊢ (??(match ? with [ _ ⇒ (λ_.λ_.%) ])? → ?);
215  #H' lapply (extract_pair ???????? H') -H' * #m0 * #n0 * #EQ #EQ2
216
217  cases (identifier_eq ? id i)
218  [ 1,3: #E' >E' in EQ2:%; #EQ2 % %
219    [ 1,3: @refl
220    | *: destruct (EQ2) change with (add ?????) in H:(?%??);
221      whd in H; whd in H:(match % with [_ ⇒ ?|_ ⇒ ?]); >lookup_add_hit in H;
222      whd in ⊢ (% → ?); #E'' >E'' @refl
223    ]
224  | *: #NE %2 @(IH m0 n0)
225    [ 1,3: @sym_eq whd in ⊢ (???(match ?????% with [ _ ⇒ ? ])); >contract_pair @EQ
226    | 2,4: destruct (EQ2) @(local_id_add_miss … H) @NE
227    ]
228  ]
229] qed.
230
231(* The map generated by characterise_vars is "correct" wrt the fresh ident generator of tag [u],
232   i.e. by generating fresh idents with u, we risk no collision with the idents in the map domain. *)
233lemma characterise_vars_fresh : ∀gl,f,vars,n,u.
234  characterise_vars gl f = 〈vars,n〉 →              (* If we generate a map ... *)
235  globals_fresh_for_univ ? gl u →                  (* and the globals are out of the idents generated by u *)
236  fn_fresh_for_univ f u →                          (* and the variables of the function f are cool with u too ... *)
237  fresh_map_for_univ … vars u.                     (* then there won't be collisions between the map and idents made from u *)
238#gl #f #vars #n #u #CH #GL #FN
239#id #H
240cases (characterise_vars_src … CH … H)
241[ * #rg * #ty * #H1 #H2
242  cases (Exists_All … H2 GL) * * #id' #rg' #ty' * #E #H destruct //
243| * #t #H lapply (characterise_vars_all … CH id t H) #EX
244  cases (Exists_All … EX FN) * #id' #ty' * * #E1 #E2 #H' -H destruct //
245] qed.
246
247include "Cminor/syntax.ma".
248include "common/Errors.ma".
249
250alias id "CMexpr" = "cic:/matita/cerco/Cminor/syntax/expr.ind(1,0,0)".
251
252axiom BadlyTypedAccess : String.
253axiom BadLvalue : String.
254axiom MissingField : String.
255
256(* type_should_eq enforces that two types are equal and eliminates this equality by
257   transporting P ty1 to P ty2. If ty1 != ty2, then Error *)
258definition type_should_eq : ∀ty1,ty2. ∀P:type → Type[0]. P ty1 → res (P ty2) ≝
259λty1,ty2,P,p.
260  do E ← assert_type_eq ty1 ty2;
261  OK ? (match E return λx.λ_. P ty1 → P x with [ refl ⇒ λp.p ] p). 
262
263(* same gig for regions *)
264definition region_should_eq : ∀r1,r2. ∀P:region → Type[0]. P r1 → res (P r2).
265* * #P #p try @(OK ? p) @(Error ? (msg TypeMismatch))
266qed.
267
268(* same gig for AST typs *)
269definition typ_should_eq : ∀ty1,ty2. ∀P:typ → Type[0]. P ty1 → res (P ty2) ≝
270λty1,ty2,P,p.
271  match typ_eq ty1 ty2 with
272  [ inl E ⇒ OK ? (p⌈P ty1 ↦ P ty2⌉)
273  | inr _ ⇒ Error ? (msg TypeMismatch)
274  ].
275destruct %
276qed.
277
278alias id "CLunop" = "cic:/matita/cerco/Clight/Csyntax/unary_operation.ind(1,0,0)".
279alias id "CMunop" = "cic:/matita/cerco/common/FrontEndOps/unary_operation.ind(1,0,0)".
280
281(* XXX: For some reason matita refuses to pick the right one unless forced. *)
282alias id "CMnotbool" = "cic:/matita/cerco/common/FrontEndOps/unary_operation.con(0,3,0)".
283
284(* Translates a Clight unary operation into a Cminor one, while checking
285 * that the domain and codomain types are consistent. *)
286definition translate_unop : ∀t,t':typ. CLunop → res (CMunop t t') ≝
287λt,t'.λop:CLunop.
288  match op with
289  [ Onotbool ⇒
290      match t return λt. res (CMunop t t') with
291      [ ASTint sz sg ⇒
292          match t' return λt'. res (CMunop ? t') with
293          [ ASTint sz' sg' ⇒ OK ? (CMnotbool ????)
294          | _ ⇒ Error ? (msg TypeMismatch)
295          ]
296      | ASTptr ⇒
297          match t' return λt'. res (CMunop ? t') with
298          [ ASTint sz' sg' ⇒ OK ? (CMnotbool ????)
299          | _ ⇒ Error ? (msg TypeMismatch)
300          ]
301      | _ ⇒ Error ? (msg TypeMismatch)
302      ]
303  | Onotint ⇒
304      match t' return λt'. res (CMunop t t') with
305      [ ASTint sz sg ⇒ typ_should_eq ?? (λt. CMunop t (ASTint ??)) (Onotint sz sg)
306      | _ ⇒ Error ? (msg TypeMismatch)
307      ]
308  | Oneg ⇒
309      match t' return λt'. res (CMunop t t') with
310      [ ASTint sz sg ⇒ typ_should_eq ?? (λt.CMunop t (ASTint ??)) (Onegint sz sg)
311    (*  | ASTfloat sz ⇒ typ_should_eq ?? (λt.CMunop t (ASTfloat sz)) (Onegf sz) *)
312      | _ ⇒ Error ? (msg TypeMismatch)
313      ]
314  ]. @I qed.
315
316(* Translates a Clight addition into a Cminor one. Four cases to consider :
317  - integer/integer add
318  - fp/fp add
319  - pointer/integer
320  - integer/pointer.
321  Consistency of the type is enforced by explicit checks.
322*)
323
324(* First, how to get rid of a abstract-away pointer or array type *)
325definition fix_ptr_type : ∀ty,n. expr (typ_of_type (ptr_type ty n)) → expr ASTptr ≝
326λty,n,e. e⌈expr (typ_of_type (ptr_type ty n)) ↦ expr ASTptr⌉.
327cases n //
328qed.
329
330definition translate_add ≝
331λty1,ty2,ty'.
332let ty1' ≝ typ_of_type ty1 in
333let ty2' ≝ typ_of_type ty2 in
334match classify_add ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
335[ add_case_ii sz sg ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Oadd ??) e1 e2)
336(*| add_case_ff sz ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Oaddf sz) e1 e2) *)
337(* XXX we cast up to I16 Signed to prevent overflow, but often we could use I8 *)
338| add_case_pi n ty sz sg ⇒
339    λe1,e2. typ_should_eq ??? (Op2 ??? (Oaddp I16) (fix_ptr_type … e1) (Op2 ??? (Omul I16 Signed) (Op1 ?? (Ocastint sz sg I16 Signed) e2) (Cst ? (Ointconst I16 Signed (repr ? (sizeof ty))))))
340| add_case_ip n sz sg ty ⇒
341    λe1,e2. typ_should_eq ??? (Op2 ??? (Oaddp I16) (fix_ptr_type … e2) (Op2 ??? (Omul I16 Signed) (Op1 ?? (Ocastint sz sg I16 Signed) e1) (Cst ? (Ointconst I16 Signed (repr ? (sizeof ty))))))
342| add_default _ _ ⇒ λe1,e2. Error ? (msg TypeMismatch)
343].
344
345
346definition translate_sub ≝
347λty1,ty2,ty'.
348let ty1' ≝ typ_of_type ty1 in
349let ty2' ≝ typ_of_type ty2 in
350match classify_sub ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
351[ sub_case_ii sz sg ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Osub ??) e1 e2)
352(* | sub_case_ff sz ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Osubf sz) e1 e2) *)
353(* XXX could optimise cast as above *)
354| sub_case_pi n ty sz sg ⇒
355    λe1,e2. typ_should_eq ??? (Op2 ??? (Osubpi I16) (fix_ptr_type … e1) (Op2 ??? (Omul I16 Signed) (Op1 ?? (Ocastint sz sg I16 Signed) e2) (Cst ? (Ointconst I16 Signed (repr ? (sizeof ty))))))
356(* XXX check in detail? *)
357| sub_case_pp n1 n2 ty1 ty2 ⇒
358    λe1,e2. match ty' return λty'. res (CMexpr (typ_of_type ty')) with
359    [ Tint sz sg ⇒ OK ? (Op1 ?? (Ocastint I16 Signed sz sg) (Op2 ??? (Odiv I16) (Op2 ??? (Osubpp I16) (fix_ptr_type … e1) (fix_ptr_type ?? e2)) (Cst ? (Ointconst I16 Signed (repr ? (sizeof ty2))))))
360    | _ ⇒ Error ? (msg TypeMismatch)
361    ]
362| sub_default _ _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
363].
364
365definition translate_mul ≝
366λty1,ty2,ty'.
367let ty1' ≝ typ_of_type ty1 in
368let ty2' ≝ typ_of_type ty2 in
369match classify_aop ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
370[ aop_case_ii sz sg ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omul …) e1 e2)
371(* | aop_case_ff sz ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omulf …) e1 e2) *)
372| aop_default _ _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
373].
374
375definition translate_div ≝
376λty1,ty2,ty'.
377let ty1' ≝ typ_of_type ty1 in
378let ty2' ≝ typ_of_type ty2 in
379match classify_aop ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
380[ aop_case_ii sz sg ⇒
381    match sg return λsg. CMexpr (ASTint sz sg) → CMexpr (ASTint sz sg) → res (CMexpr (typ_of_type ty')) with
382    [ Unsigned ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Odivu …) e1 e2)
383    | Signed ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Odiv …) e1 e2)
384    ]
385(* | aop_case_ff sz ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Odivf …) e1 e2) *)
386| aop_default _ _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
387].
388
389definition translate_mod ≝
390λty1,ty2,ty'.
391let ty1' ≝ typ_of_type ty1 in
392let ty2' ≝ typ_of_type ty2 in
393match classify_aop ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
394[ aop_case_ii sz sg ⇒
395    match sg return λsg. CMexpr (ASTint sz sg) → CMexpr (ASTint sz sg) → res (CMexpr (typ_of_type ty')) with
396    [ Unsigned ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omodu …) e1 e2)
397    | Signed ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omod …) e1 e2)
398    ]
399(* no float case *)
400| _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
401].
402
403definition translate_shr ≝
404λty1,ty2,ty'.
405let ty1' ≝ typ_of_type ty1 in
406let ty2' ≝ typ_of_type ty2 in
407match classify_aop ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
408[ aop_case_ii sz sg ⇒
409    match sg return λsg. CMexpr (ASTint sz sg) → CMexpr (ASTint sz sg) → res (CMexpr (typ_of_type ty')) with
410    [ Unsigned ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omodu …) e1 e2)
411    | Signed ⇒ λe1,e2. typ_should_eq ??? (Op2 ??? (Omod …) e1 e2)
412    ]
413(* no float case *)
414| _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
415].
416
417definition complete_cmp : ∀ty'. CMexpr (ASTint I8 Unsigned) → res (CMexpr (typ_of_type ty')) ≝
418λty',e.
419match ty' return λty'. res (CMexpr (typ_of_type ty')) with
420[ Tint sz sg ⇒ OK ? (Op1 ?? (Ocastint I8 Unsigned sz sg) e)
421| _ ⇒ Error ? (msg TypeMismatch)
422].
423
424definition translate_cmp ≝
425λc,ty1,ty2,ty'.
426let ty1' ≝ typ_of_type ty1 in
427let ty2' ≝ typ_of_type ty2 in
428match classify_cmp ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
429[ cmp_case_ii sz sg ⇒
430    match sg return λsg. CMexpr (ASTint sz sg) → CMexpr (ASTint sz sg) → res (CMexpr (typ_of_type ty')) with
431    [ Unsigned ⇒ λe1,e2. complete_cmp ty' (Op2 ??? (Ocmpu … c) e1 e2)
432    | Signed ⇒ λe1,e2. complete_cmp ty' (Op2 ??? (Ocmp … c) e1 e2)
433    ]
434| cmp_case_pp n ty ⇒
435    λe1,e2. complete_cmp ty' (Op2 ??? (Ocmpp … c) (fix_ptr_type … e1) (fix_ptr_type … e2))
436(* | cmp_case_ff sz ⇒ λe1,e2. complete_cmp ty' (Op2 ??? (Ocmpf … c) e1 e2) *)
437| cmp_default _ _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
438].
439
440definition translate_misc_aop ≝
441λty1,ty2,ty',op.
442let ty1' ≝ typ_of_type ty1 in
443let ty2' ≝ typ_of_type ty2 in
444match classify_aop ty1 ty2 return λty1,ty2.λ_. CMexpr (typ_of_type ty1) → CMexpr (typ_of_type ty2) → res (CMexpr (typ_of_type ty')) with
445[ aop_case_ii sz sg ⇒ λe1,e2. typ_should_eq ??? (Op2 ?? (ASTint sz sg) (op sz sg) e1 e2)
446| _ ⇒ λ_.λ_. Error ? (msg TypeMismatch)
447].
448
449definition translate_binop : binary_operation → type → CMexpr ? → type → CMexpr ? → type → res (CMexpr ?) ≝
450λop,ty1,e1,ty2,e2,ty.
451let ty' ≝ typ_of_type ty in
452match op with
453[ Oadd ⇒ translate_add ty1 ty2 ty e1 e2
454| Osub ⇒ translate_sub ty1 ty2 ty e1 e2
455| Omul ⇒ translate_mul ty1 ty2 ty e1 e2
456| Omod ⇒ translate_mod ty1 ty2 ty e1 e2
457| Odiv ⇒ translate_div ty1 ty2 ty e1 e2
458| Oand ⇒ translate_misc_aop ty1 ty2 ty Oand e1 e2
459| Oor  ⇒ translate_misc_aop ty1 ty2 ty Oor e1 e2
460| Oxor ⇒ translate_misc_aop ty1 ty2 ty Oxor e1 e2
461| Oshl ⇒ translate_misc_aop ty1 ty2 ty Oshl e1 e2
462| Oshr ⇒ translate_shr ty1 ty2 ty e1 e2
463| Oeq ⇒ translate_cmp Ceq ty1 ty2 ty e1 e2
464| One ⇒ translate_cmp Cne ty1 ty2 ty e1 e2
465| Olt ⇒ translate_cmp Clt ty1 ty2 ty e1 e2
466| Ogt ⇒ translate_cmp Cgt ty1 ty2 ty e1 e2
467| Ole ⇒ translate_cmp Cle ty1 ty2 ty e1 e2
468| Oge ⇒ translate_cmp Cge ty1 ty2 ty e1 e2
469].
470
471lemma typ_equals : ∀t1,t2. ∀P:∀t. expr t → Prop. ∀v1,v2.
472  typ_should_eq t1 t2 expr v1 = OK ? v2 →
473  P t1 v1 →
474  P t2 v2.
475#t1 #t2 #P #v1 #v2
476whd in ⊢ (??%? → ?); cases (typ_eq t1 t2)
477[ #E destruct #E whd in E:(??%?); destruct //
478| #NE #E normalize in E; destruct
479] qed.
480
481lemma unfix_ptr_type : ∀ty,n,e.∀P:∀t. expr t → Prop.
482  P (typ_of_type (ptr_type ty n)) e →
483  P ASTptr (fix_ptr_type ty n e).
484#ty * [ 2: #n ] #e #P #H @H
485qed.
486
487(* Recall that [expr_vars], defined in Cminor/Syntax.ma, asserts a predicate on
488  all the variables of a program. [translate_binop_vars], given
489  a predicate verified for all variables of subexprs e1 and e2, produces
490  a proof that all variables of [translate_binop op _ e1 _ e2 _] satisfy this
491  predicate. *)
492
493lemma translate_binop_vars : ∀P,op,ty1,e1,ty2,e2,ty,e.
494  expr_vars ? e1 P →
495  expr_vars ? e2 P →
496  translate_binop op ty1 e1 ty2 e2 ty = OK ? e →
497  expr_vars ? e P.
498#P * #ty1 #e1 #ty2 #e2 #ty #e #H1 #H2
499whd in ⊢ (??%? → ?);
500[ inversion (classify_add ty1 ty2) in ⊢ ?;
501  [ #sz #sg #E1 #E2 #E3 destruct >E3 #E4 -E3 change with (typ_should_eq ???? = OK ??) in E4;
502    @(typ_equals … E4) % //
503(*  | #sz #E1 #E2 #E3 destruct >E3 #E4
504    @(typ_equals … E4) % // *)
505  | #n #ty0 #sz #sg #E1 #E2 #E3 destruct >E3 #E4
506    @(typ_equals … E4) -E4 -E3 % [ @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H1)| % // ]
507  | #n #sz #sg #ty0 #E1 #E2 #E3 destruct >E3 #E4
508    @(typ_equals … E4) % [ @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H2)| % // ]
509  | #ty1' #ty2' #E1 #E2 #E3 destruct >E3 #E4 whd in E4:(??%?); destruct
510  ]
511 
512| inversion (classify_sub ty1 ty2) in ⊢ ?;
513  [ #sz #sg #E1 #E2 #E3 destruct >E3 #E4
514    @(typ_equals … E4) % //
515(*  | #sz #E1 #E2 #E3 destruct >E3 #E4
516    @(typ_equals … E4) % // *)
517  | #n #ty0 #sz #sg #E1 #E2 #E3 destruct >E3 #E4
518    @(typ_equals … E4) % [ @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H1)| % // ]
519  | #n1 #n2 #ty1' #ty2' #E1 #E2 #E3 destruct >E3
520    whd in ⊢ (??%? → ?); cases ty in e ⊢ %;
521    [ 2: #sz #sg #e #E4 | 3: #ty #e #E4 | 4: #ty' #n' #e #E4
522    | *: normalize #X1 #X2 try #X3 try #X4 destruct
523    ] whd in E4:(??%?); destruct % // %
524    [ @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H1) | @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H2) ]
525  | #ty1' #ty2' #E1 #E2 #E3 destruct >E3 #E4 whd in E4:(??%?); destruct
526  ]
527| 3,4,5,6,7,8,9,10: inversion (classify_aop ty1 ty2) in ⊢ ?;
528  (* Note that some cases require a split on signedness of integer type. *)
529  [ 1,3,5,7,9,11,13,15: #sz * #E1 #E2 #E3 destruct >E3 #E4
530    @(typ_equals … E4) % //
531  | 2,4,6,8,10,12,14,16,18: #ty1' #ty2' #E1 #E2 #E3 destruct >E3 #E4 whd in E4:(??%?); destruct
532  ]
533| *: inversion (classify_cmp ty1 ty2) in ⊢ ?;
534  [ 1,4,7,10,13,16: #sz * #E1 #E2 #E3 destruct >E3
535  | 2,5,8,11,14,17: #n #ty' #E1 #E2 #E3 destruct >E3
536  | *: #ty1' #ty2' #E1 #E2 #E3 destruct >E3 #E4 whd in E4:(??%?); @⊥ destruct
537  ] whd in ⊢ (??%? → ?); cases ty in e ⊢ %; normalize nodelta
538  try (normalize #X1 #X2 try #X3 try #X4 try #X5 destruct #FAIL)
539  #sz #sg #e #E4
540  whd in E4:(??%?); destruct % try @H1 try @H2
541  try  @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H1)
542  try  @(unfix_ptr_type ??? (λt,e. expr_vars t e P) H2)
543] qed. 
544
545(* We'll need to implement proper translation of pointers if we really do memory
546   spaces.
547(* This function performs leibniz-style subst if r1 = r2, and fails otherwise. *)
548definition check_region : ∀r1:region. ∀r2:region. ∀P:region → Type[0]. P r1 → res (P r2) ≝
549λr1,r2,P.
550  match r1 return λx.P x → res (P r2) with
551  [ Any ⇒   match r2 return λx.P Any → res (P x) with [ Any ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
552  | Data ⇒  match r2 return λx.P Data → res (P x) with [ Data ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
553  | IData ⇒ match r2 return λx.P IData → res (P x) with [ IData ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
554  | PData ⇒ match r2 return λx.P PData → res (P x) with [ PData ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
555  | XData ⇒ match r2 return λx.P XData → res (P x) with [ XData ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
556  | Code ⇒  match r2 return λx.P Code → res (P x) with [ Code ⇒ OK ? | _ ⇒ λ_.Error ? (msg TypeMismatch) ]
557  ].
558
559(* Simple application of [check_region] to translate between terms. *)
560definition translate_ptr : ∀P,r1,r2. (Σe:CMexpr (ASTptr r1). expr_vars ? e P) → res (Σe':CMexpr (ASTptr r2).expr_vars ? e' P) ≝
561λP,r1,r2,e. check_region r1 r2 (λr.Σe:CMexpr (ASTptr r).expr_vars ? e P) e.
562*)
563axiom FIXME : String.
564
565(* Given a source and target type, translate an expession of type source to type target *)
566definition translate_cast : ∀P. ∀ty1:type.∀ty2:type. (Σe:CMexpr (typ_of_type ty1). expr_vars ? e P) → res (Σe':CMexpr (typ_of_type ty2). expr_vars ? e' P) ≝
567λP,ty1,ty2.
568match ty1 return λx.(Σe:CMexpr (typ_of_type x). expr_vars ? e P) → ? with
569[ Tint sz1 sg1 ⇒ λe.
570    match ty2 return λx.res (Σe':CMexpr (typ_of_type x).expr_vars ? e' P) with
571    [ Tint sz2 sg2 ⇒ OK ? (Op1 ?? (Ocastint ? sg1 sz2 ?) e)
572  (*  | Tfloat sz2 ⇒ OK ? (Op1 ?? (match sg1 with [ Unsigned ⇒ Ofloatofintu ?? | _ ⇒ Ofloatofint ??]) e)*)
573    | Tpointer _ ⇒ OK ? (Op1 ?? (Optrofint ??) e)
574    | Tarray _ _ ⇒ OK ? (Op1 ?? (Optrofint ??) e)
575    | _ ⇒ Error ? (msg TypeMismatch)
576    ]
577(* | Tfloat sz1 ⇒ λe.
578    match ty2 return λx.res (Σe':CMexpr (typ_of_type x).expr_vars ? e' P) with
579    [ Tint sz2 sg2 ⇒ OK ? «Op1 ?? (match sg2 with [ Unsigned ⇒ Ointuoffloat ? sz2 | _ ⇒ Ointoffloat ? sz2 ]) e, ?»
580    | Tfloat sz2 ⇒ Error ? (msg FIXME) (* OK ? «Op1 ?? (Oid ?) e, ?» (* FIXME *) *)
581    | _ ⇒ Error ? (msg TypeMismatch)
582    ] *)
583| Tpointer _ ⇒ λe. (* will need changed for memory regions *)
584    match ty2 return λx.res (Σe':CMexpr (typ_of_type x). expr_vars ? e' P) with
585    [ Tint sz2 sg2 ⇒ OK ? «Op1 ?? (Ointofptr sz2 ?) e, ?»
586    | Tarray _ _ ⇒ (*translate_ptr ? r1 r2 e*) OK ? e
587    | Tpointer _ ⇒ OK ? e
588    | _ ⇒ Error ? (msg TypeMismatch)
589    ]
590| Tarray _ _ ⇒ λe. (* will need changed for memory regions *)
591    match ty2 return λx.res (Σe':CMexpr (typ_of_type x).expr_vars ? e' P) with
592    [ Tint sz2 sg2 ⇒ OK ? «Op1 ASTptr (ASTint sz2 sg2) (Ointofptr sz2 ?) e, ?»
593    | Tarray _ _ ⇒ OK ? e
594    | Tpointer _ ⇒ OK ? e
595    | _ ⇒ Error ? (msg TypeMismatch)
596    ]
597| _ ⇒ λ_. Error ? (msg TypeMismatch)
598]. whd normalize nodelta @pi2
599qed.
600
601(* Translate Clight exprs into Cminor ones.
602  Arguments :
603  - vars:var_types, an environment mapping each variable to a couple (allocation mode, type)
604  - e:expr, the expression to be converted
605  Result : res (Σe':CMexpr (typ_of_type (typeof e)). expr_vars ? e' (local_id vars))
606  that is, either
607  . an error
608  . an expression e', matching the type of e, such that e' respect the property that all variables
609    in it are not global. In effect, [translate_expr] will replace global variables by constant symbols.
610*)
611let rec translate_expr (vars:var_types) (e:expr) on e : res (Σe':CMexpr (typ_of_type (typeof e)). expr_vars ? e' (local_id vars)) ≝
612match e return λe. res (Σe':CMexpr (typ_of_type (typeof e)). expr_vars ? e' (local_id vars)) with
613[ Expr ed ty ⇒
614  match ed with
615  [ Econst_int sz i ⇒
616      match ty return λty. res (Σe':CMexpr (typ_of_type ty).  expr_vars ? e' (local_id vars)) with
617      [ Tint sz' sg ⇒ intsize_eq_elim' sz sz' (λsz,sz'. res (Σe':CMexpr (typ_of_type (Tint sz' sg)). expr_vars ? e' (local_id vars)))
618                        (OK ? «Cst ? (Ointconst sz sg i), ?»)
619                        (Error ? (msg TypeMismatch))
620      | _ ⇒ Error ? (msg TypeMismatch)
621      ]
622 (* | Econst_float f ⇒
623      match ty return λty. res (Σe':CMexpr (typ_of_type ty). ?) with
624      [ Tfloat sz ⇒ OK ? «Cst ? (Ofloatconst sz f), ?»
625      | _ ⇒ Error ? (msg TypeMismatch)
626      ] *)
627  | Evar id ⇒
628      (* E is an equality proof of the shape "lookup' vars id = Ok <c,t>" *) 
629      do 〈c,t〉 as E ← lookup' vars id;
630      match c return λx. (c = x) → res (Σe':CMexpr ?. ?) with
631      [ Global r ⇒ λHeq_c.
632          (* We are accessing a global variable in an expression. Its Cminor counterpart also depends on
633             its access mode:
634             - By_value q, where q is a memory chunk specification (whitch should match the type of the global)
635             - By_reference, and we only take the adress of the variable
636             - By_nothing : error
637           *)
638          match access_mode ty return λt.λ_. res (Σe':CMexpr t. expr_vars ? e' (local_id vars)) with
639          [ By_value t ⇒ OK ? «Mem t (Cst ? (Oaddrsymbol id 0)), ?» (* Mem is "load" in compcert *)
640          | By_reference ⇒ OK ? «Cst ? (Oaddrsymbol id 0), ?»
641          | By_nothing _ ⇒ Error ? [MSG BadlyTypedAccess; CTX ? id]
642          ]
643      | Stack n ⇒ λHeq_c.
644          (* We have decided that the variable should be allocated on the stack,
645           * because its adress was taken somewhere or becauste it's a structured data. *)
646          match access_mode ty return λt.λ_. res (Σe':CMexpr t. expr_vars ? e' (local_id vars)) with
647          [ By_value t ⇒ OK ? «Mem t (Cst ? (Oaddrstack n)), ?»
648          | By_reference ⇒ (*match r return λr. res (Σe':CMexpr (ASTptr r). ?) with
649                             [ Any ⇒*) OK ? «Cst ? (Oaddrstack n), ?» (*
650                             | _ ⇒ Error  ? [MSG BadlyTypedAccess; CTX ? id]
651                             ]*)
652          | By_nothing _ ⇒ Error ? [MSG BadlyTypedAccess; CTX ? id]
653          ]
654          (* This is a local variable. Keep it as an identifier in the Cminor code, ensuring that the type of the original expr and of ty match. *)
655      | Local ⇒ λHeq_c. type_should_eq t ty (λt.Σe':CMexpr (typ_of_type t).expr_vars (typ_of_type t) e' (local_id vars))  («Id (typ_of_type t) id, ?»)
656      ] (refl ? c)
657  | Ederef e1 ⇒
658      do e1' ← translate_expr vars e1;
659      (* According to the way the data pointed to by e1 is accessed, the generated Cminor code will vary.
660        - if e1 is a kind of int* ptr, then we load ("Mem") the ptr returned by e1
661        - if e1 is a struct* or a function ptr, then we acess by reference, in which case we :
662           1) check the consistency of the regions in the type of e1 and in the access mode of its type
663           2) return directly the converted CMinor expression "as is" (TODO : what is the strange notation with the ceil function and the mapsto ?)
664      *)
665      match typ_of_type (typeof e1) return λx.(Σz:CMexpr x.expr_vars ? z (local_id vars)) → ? with
666      [ ASTptr ⇒ λe1'.
667          match access_mode ty return λt.λ_. res (Σe':CMexpr t. expr_vars ? e' (local_id vars)) with
668          [ By_value t ⇒ OK ? «Mem t (pi1 … e1'), ?»
669          | By_reference ⇒ OK ? e1'
670          | By_nothing _ ⇒ Error ? (msg BadlyTypedAccess)
671          ]
672      | _ ⇒ λ_. Error ? (msg TypeMismatch)
673      ] e1'             
674  | Eaddrof e1 ⇒
675      do e1' ← translate_addr vars e1;
676      match typ_of_type ty return λx.res (Σz:CMexpr x.?) with
677      [ ASTptr ⇒ OK ? e1'
678(*          match e1' with
679          [ mk_DPair r1 e1' ⇒ region_should_eq r1 r ? e1'
680          ]*)
681      | _ ⇒ Error ? (msg TypeMismatch)
682      ]
683  | Eunop op e1 ⇒
684     match op
685      return λx. (op = x) → res (Σe':CMexpr (typ_of_type ty). expr_vars ? e' (local_id vars))
686      with
687      [ Onotbool ⇒ λHop.
688        match typ_of_type ty
689        return λy. (typ_of_type ty = y) → res (Σe':CMexpr (typ_of_type ty). expr_vars ? e' (local_id vars))
690        with
691        [ ASTint sz sg ⇒  λHtyp_of_type.
692          match sz
693          return λz. (sz = z) → res (Σe':CMexpr (typ_of_type ty). expr_vars ? e' (local_id vars))
694          with
695          [ I32 ⇒ λHsz.
696            do op' ← translate_unop (typ_of_type (typeof e1)) (typ_of_type ty) op;
697            do e1' ← translate_expr vars e1;
698            OK ? «Op1 ?? op' e1', ?»
699          | _ ⇒ λHsz.
700            Error ? (msg TypeMismatch)
701          ] (refl ? sz)
702        | _ ⇒ λHtyp_of_type.
703          Error ? (msg TypeMismatch)
704        ] (refl ? (typ_of_type ty))       
705      | _ ⇒ λHop.
706        do op' ← translate_unop (typ_of_type (typeof e1)) (typ_of_type ty) op;
707        do e1' ← translate_expr vars e1;
708        OK ? «Op1 ?? op' e1', ?»
709      ] (refl ? op)
710  | Ebinop op e1 e2 ⇒
711      do e1' ← translate_expr vars e1;
712      do e2' ← translate_expr vars e2;
713      do e' as E ← translate_binop op (typeof e1) e1' (typeof e2) e2' ty;
714      OK ? «e', ?»
715  | Ecast ty1 e1 ⇒
716      do e1' ← translate_expr vars e1;
717      do e' ← translate_cast ? (typeof e1) ty1 e1';
718      do e' ← typ_should_eq (typ_of_type ty1) (typ_of_type ty) ? e';
719      OK ? e'
720  | Econdition e1 e2 e3 ⇒
721      do e1' ← translate_expr vars e1;
722      do e2' ← translate_expr vars e2;
723      do e2' ← type_should_eq ? ty (λx.Σe:CMexpr (typ_of_type x).?) e2';
724      do e3' ← translate_expr vars e3;
725      do e3' ← type_should_eq ? ty (λx.Σe:CMexpr (typ_of_type x).?) e3';
726      match typ_of_type (typeof e1) return λx.(Σe1':CMexpr x. expr_vars ? e1' (local_id vars)) → res ? with
727      [ ASTint _ _ ⇒ λe1'. OK ? «Cond ??? e1' e2' e3', ?»
728      | _ ⇒ λ_.Error ? (msg TypeMismatch)
729      ] e1'
730  | Eandbool e1 e2 ⇒
731      do e1' ← translate_expr vars e1;
732      do e2' ← translate_expr vars e2;
733      match ty return λty. res (Σe':CMexpr (typ_of_type ty). ?) with
734      [ Tint sz sg ⇒
735          do e2' ← type_should_eq ? (Tint sz sg) (λx.Σe:CMexpr (typ_of_type x).?) e2';
736          match typ_of_type (typeof e1)
737          return λx.
738            (Σe:CMexpr x. expr_vars ? e (local_id vars)) → (res ?)
739          with
740          [ ASTint sz1 _ ⇒ λe1'.
741            OK ? «Cond ??? e1' e2' (Cst ? (Ointconst sz sg (zero ?))), ?»
742          | _ ⇒ λ_. Error ? (msg TypeMismatch)
743          ] e1'
744      | _ ⇒ Error ? (msg TypeMismatch)
745      ]
746(*  | Eandbool e1 e2 ⇒
747      do e1' ← translate_expr vars e1;
748      do e2' ← translate_expr vars e2;
749      match ty return λty. res (Σe':CMexpr (typ_of_type ty). ?) with
750      [ Tint sz sg ⇒
751        match sz
752        return λsz'. (sz = sz') → res (Σe':CMexpr (typ_of_type ?). ?)
753        with
754        [ I32 ⇒ λHsz_eq.
755          do e2' ← type_should_eq ? (Tint I32 sg) (λx.Σe:CMexpr (typ_of_type x).?) e2';
756          match typ_of_type (typeof e1)
757          return λx.
758            (Σe:CMexpr x. expr_vars ? e (local_id vars)) → (res ?)
759          with
760          [ ASTint sz1 _ ⇒ λe1'.
761            OK ? «Cond ??? e1' e2' (Cst ? (Ointconst I32 sg (zero ?))), ?»
762          | _ ⇒ λ_. Error ? (msg TypeMismatch)
763          ] e1'
764        | _ ⇒ λ_. Error ? (msg TypeMismatch)
765        ] (refl ? sz)
766      | _ ⇒ Error ? (msg TypeMismatch)
767      ]*)
768  | Eorbool e1 e2 ⇒
769      do e1' ← translate_expr vars e1;
770      do e2' ← translate_expr vars e2;
771      match ty return λty. res (Σe':CMexpr (typ_of_type ty). ?) with
772      [ Tint sz sg ⇒
773        do e2' ← type_should_eq ? (Tint sz sg) (λx.Σe:CMexpr (typ_of_type x).?) e2';
774        match typ_of_type (typeof e1)
775        return λx.(Σe:CMexpr x. expr_vars ? e (local_id vars)) → res ? with
776        [ ASTint _ _ ⇒ λe1'. OK ? «Cond ??? e1' (Cst ? (Ointconst sz sg (repr ? 1))) e2', ?»
777        | _ ⇒ λ_. Error ? (msg TypeMismatch)
778        ] e1'
779      | _ ⇒ Error ? (msg TypeMismatch)
780      ]     
781  | Esizeof ty1 ⇒
782      match ty return λty. res (Σe':CMexpr (typ_of_type ty). ?) with
783      [ Tint sz sg ⇒ OK ? «Cst ? (Ointconst sz sg (repr ? (sizeof ty1))), ?»
784      | _ ⇒ Error ? (msg TypeMismatch)
785      ]     
786  | Efield e1 id ⇒
787      match typeof e1 with
788      [ Tstruct _ fl ⇒
789          do e1' ← translate_addr vars e1;
790(*          match e1' with
791          [ mk_DPair r e1' ⇒*)
792            do off ← field_offset id fl;
793            match access_mode ty return λt.λ_. res (Σe':CMexpr t. expr_vars ? e' (local_id vars)) with
794            [ By_value t ⇒
795                OK ? «Mem t (Op2 ? (ASTint I16 Signed (* XXX efficiency? *)) ?
796                                   (Oaddp …) e1' (Cst ? (Ointconst I16 Signed (repr ? off)))),?»
797            | By_reference ⇒
798(*                do e1' ← region_should_eq r r' ? e1';*)
799                OK ? «Op2 ASTptr (ASTint I16 Signed (* XXX efficiency? *)) ASTptr
800                        (Oaddp …) e1' (Cst ? (Ointconst I16 Signed (repr ? off))),?»
801            | By_nothing _ ⇒ Error ? (msg BadlyTypedAccess)
802            ]
803      | Tunion _ _ ⇒
804          do e1' ← translate_addr vars e1;
805            match access_mode ty return λt.λ_. res (Σz:CMexpr t.?) with
806            [ By_value t ⇒ OK ? «Mem t e1', ?»
807            | By_reference ⇒ OK ? e1'
808            | By_nothing _ ⇒ Error ? (msg BadlyTypedAccess)
809            ]
810      | _ ⇒ Error ? (msg BadlyTypedAccess)
811      ]           
812  | Ecost l e1 ⇒
813      do e1' ← translate_expr vars e1;
814      do e' ← OK ? «Ecost ? l e1',?»;
815      typ_should_eq (typ_of_type (typeof e1)) (typ_of_type ty) (λx.Σe:CMexpr x.?) e'     
816  ]
817]
818
819(* Translate addr takes an expression e1, and returns a Cminor code computing the address of the result of [e1].   *)
820and translate_addr (vars:var_types) (e:expr) on e : res ((*𝚺r.*) Σe':CMexpr ASTptr. expr_vars ? e' (local_id vars)) ≝
821match e with
822[ Expr ed _ ⇒
823  match ed with
824  [ Evar id ⇒
825      do 〈c,t〉 ← lookup' vars id;
826      match c return λ_. res (Σz:CMexpr ASTptr.?) with
827      [ Global r ⇒ OK ? «Cst ? (Oaddrsymbol id 0), ?»
828      | Stack n ⇒ OK ? «Cst ? (Oaddrstack n), ?»
829      | Local ⇒ Error ? [MSG BadlyTypedAccess; CTX ? id] (* TODO: could rule out? *)
830      ]
831  | Ederef e1 ⇒
832      do e1' ← translate_expr vars e1;
833      match typ_of_type (typeof e1) return λx. (Σz:CMexpr x.expr_vars ? z (local_id vars)) → res (Σz:CMexpr ASTptr. expr_vars ? z (local_id vars)) with
834      [ ASTptr ⇒ λe1'.OK ? e1'
835      | _ ⇒ λ_.Error ? (msg BadlyTypedAccess)
836      ] e1'
837  | Efield e1 id ⇒
838      match typeof e1 with
839      [ Tstruct _ fl ⇒
840          do e1' ← translate_addr vars e1;
841          do off ← field_offset id fl;
842(*          match e1' with
843          [ mk_DPair r e1'' ⇒ OK (𝚺r:region.Σe:CMexpr (ASTptr r).?)*)
844             OK ? «Op2 ASTptr (ASTint I16 Signed (* FIXME inefficient?*)) ASTptr
845                   (Oaddp I16) e1' (Cst ? (Ointconst I16 Signed (repr ? off))), ?»
846      | Tunion _ _ ⇒ translate_addr vars e1
847      | _ ⇒ Error ? (msg BadlyTypedAccess)
848      ]
849  | _ ⇒ Error ? (msg BadLvalue)
850  ]
851].
852whd try @I
853[ >E whd >Heq_c @refl
854| 2,3: @pi2
855| cases e1' //
856| cases e1' //
857| @(translate_binop_vars … E) @pi2
858| % [ % ] @pi2
859| % [ % @pi2 ] whd @I
860| % [ % [ @pi2 | @I ] | @pi2 ]
861| % [ @pi2 | @I ]
862| % [ @pi2 | @I ]
863| @pi2
864| @pi2
865| % [ @pi2 | @I ]
866] qed.
867
868(* We provide a function to work out how to do an assignment to an lvalue
869   expression.  It is used for both Clight assignments and Clight function call
870   destinations, but doesn't take the value to be assigned so that we can use
871   it to form a single St_store when possible (and avoid introducing an
872   unnecessary temporary variable and assignment).
873   *)
874inductive destination (vars:var_types) : Type[0] ≝
875| IdDest : ∀id,ty. local_id vars id (typ_of_type ty) → destination vars
876| MemDest : (Σe:CMexpr ASTptr.expr_vars ? e (local_id vars)) → destination vars.
877
878(* Let a source Clight expression be assign(e1, e2). First of all, observe that [e1] is a
879  /Clight/ expression, not converted by translate_expr. We thus have to do part of the work
880  of [translate_expr] in this function. [translate_dest] will convert e1
881   into a proper destination for an assignement operation. We proceed by case analysis on e1.
882   - if e1 is a variable [id], then we proceed by case analysis on its allocation mode:
883      - if [id] is allocated locally (in a register), then id becomes directly
884        the target for the assignement, as (IdDest vars id t H), where t is the type
885        of id, and H asserts that id is indeed a local variable.
886      - if [id] is a global variable stored in region [r], then we perform [translate_expr]'s
887        job and return an adress, given as a constant symbol corresponding to [id], with
888        region r and memory chunk specified by the access mode of the rhs type ty2 of [e2].
889      - same thing for stack-allocated variables, except that we don't specify any region.
890   - if e1 is not a variable, we use [translate_addr] to generate a Cminor expression computing
891    the adres of e1
892*)
893definition translate_dest ≝
894λvars,e1.
895  match e1 with
896  [ Expr ed1 ty1 ⇒
897      match ed1 with
898      [ Evar id ⇒
899          do 〈c,t〉 as E ← lookup' vars id;
900          match c return λx.? → ? with
901          [ Local ⇒ λE. OK ? (IdDest vars id t ?)
902          | Global r ⇒ λE. OK ? (MemDest ? (Cst ? (Oaddrsymbol id 0)))
903          | Stack n ⇒ λE. OK ? (MemDest ? (Cst ? (Oaddrstack n)))
904          ] E
905      | _ ⇒
906          do e1' ← translate_addr vars e1;
907          OK ? (MemDest ? e1')
908      ]
909  ].
910whd // >E @refl
911qed.
912
913(* [lenv] is the type of maps from Clight labels to Cminor labels. *)
914definition lenv ≝ identifier_map SymbolTag (identifier Label).
915
916axiom MissingLabel : String.
917
918(* Find the Cminor label corresponding to [l] or fail. *)
919definition lookup_label ≝
920λlbls:lenv.λl. opt_to_res … [MSG MissingLabel; CTX ? l] (lookup ?? lbls l).
921
922(* True iff the Cminor label [l] is in the codomain of [lbls] *)
923definition lpresent ≝ λlbls:lenv. λl. ∃l'. lookup_label lbls l' = OK ? l.
924
925(* True iff The Clight label [l] is in the domain of [lbls] *)
926definition label_in_domain ≝ λlbls:lenv. λl. present ?? lbls l.
927
928let rec fresh_list_for_univ (l:list (identifier Label)) (u:universe Label) ≝
929match l with
930[ nil ⇒ True
931| cons elt tl ⇒ fresh_for_univ ? elt u ∧ fresh_list_for_univ tl u].
932
933record labgen : Type[0] ≝ {
934  labuniverse   : universe Label;
935  label_genlist    : list (identifier Label);
936  genlist_is_fresh : fresh_list_for_univ label_genlist labuniverse
937}.
938
939lemma fresh_list_stays_fresh : ∀l,tmp,u,u'. fresh_list_for_univ l u → 〈tmp,u'〉=fresh Label u → fresh_list_for_univ l u'.
940#l elim l
941[ 1: normalize //
942| 2: #hd #tl #Hind #tmp #u #u' #HA #HB
943  whd
944  @conj
945  [ 1: whd in HA ⊢ ?;
946    elim HA #HAleft #HAright
947    @(fresh_remains_fresh ? hd tmp u u') assumption
948  | 2: whd in HA ⊢ ?;
949    elim HA #HAleft #HAright   
950    @Hind //
951  ]
952]
953qed.
954
955definition In ≝ λelttype.λelt.λl.Exists elttype (λx.x=elt) l.   
956
957definition generate_fresh_label :
958 ∀ul. Σlul:(identifier Label × labgen).
959               (And (∀lab. In ? lab (label_genlist ul) → In ? lab (label_genlist (snd … lul)))
960                   (In ? (fst … lul) (label_genlist (snd … lul)))) ≝
961λul.
962let 〈tmp,u〉 as E ≝ fresh ? (labuniverse ul) in
963 «〈tmp, mk_labgen u (tmp::(label_genlist ul)) ?〉, ?».
964[ 1: normalize @conj
965  [ 1: @(fresh_is_fresh ? tmp u (labuniverse ul) ?) assumption
966  | 2: @fresh_list_stays_fresh // ]
967| @conj /2/
968]
969qed.
970
971let rec labels_defined (s:statement) : list ident ≝
972match s with
973[ Ssequence s1 s2 ⇒ labels_defined s1 @ labels_defined s2
974| Sifthenelse _ s1 s2 ⇒ labels_defined s1 @ labels_defined s2
975| Swhile _ s ⇒ labels_defined s
976| Sdowhile _ s ⇒ labels_defined s
977| Sfor s1 _ s2 s3 ⇒ labels_defined s1 @ labels_defined s2 @ labels_defined s3
978| Sswitch _ ls ⇒ labels_defined_switch ls
979| Slabel l s ⇒ l::(labels_defined s)
980| Scost _ s ⇒ labels_defined s
981| _ ⇒ [ ]
982]
983and labels_defined_switch (ls:labeled_statements) : list ident ≝
984match ls with
985[ LSdefault s ⇒ labels_defined s
986| LScase _ _ s ls ⇒ labels_defined s @ labels_defined_switch ls
987].
988
989definition ldefined ≝ λs.λl.Exists ? (λl'.l' = l) (labels_of s).
990
991(* For each label l in s, there exists a matching label l' = lenv(l) defined in s' *)
992definition labels_translated : lenv → statement → stmt → Prop ≝
993λlbls,s,s'.  ∀l.
994  (Exists ? (λl'.l' = l) (labels_defined s)) →
995  ∃l'. lookup_label lbls l = (OK ? l') ∧ ldefined s' l'.
996
997
998(* Invariant on statements, holds during conversion to Cminor *)
999definition stmt_inv ≝  λvars. stmt_P (stmt_vars (local_id vars)).
1000
1001(* I (Ilias) decided to inline the following definition, to make explicit the data constructed.
1002 * This was needed to prove some stuff in translate_statement at some point, but it might be
1003 * useless now. If needed, I can revert this change.  *)
1004definition translate_assign : ∀vars:var_types. expr → expr → res (Σs:stmt. stmt_inv vars s) ≝
1005λvars,e1,e2.
1006do e2' ← translate_expr vars e2;
1007do dest ← translate_dest vars e1;
1008match dest with
1009[ IdDest id ty p ⇒
1010    do e2' ← type_should_eq (typeof e2) ty ? e2';
1011    OK ? «St_assign ? id e2', ?»
1012| MemDest e1' ⇒ OK ? «St_store ? e1' e2', ?»
1013].
1014% try (//) elim e2' /2/ elim e1' /2/
1015qed.
1016
1017definition m_option_map : ∀A,B:Type[0]. (A → res B) → option A → res (option B) ≝
1018λA,B,f,oa.
1019match oa with
1020[ None ⇒ OK ? (None ?)
1021| Some a ⇒ do b ← f a; OK ? (Some ? b)
1022].
1023
1024definition translate_expr_sigma : ∀vars:var_types. expr → res (Σe:(𝚺t:typ.CMexpr t). match e with [ mk_DPair t e ⇒ expr_vars t e (local_id vars) ]) ≝
1025λv,e.
1026  do e' ← translate_expr v e;
1027  OK (Σe:(𝚺t:typ.CMexpr t).?) «❬?, e'❭, ?».
1028whd @pi2
1029qed.
1030
1031(* Add the list of typed variables tmpenv to the environment [var_types] with
1032   the allocation mode Local. *)
1033definition add_tmps : var_types → list (ident × type) → var_types ≝
1034λvs,tmpenv.
1035  foldr ?? (λidty,vs. add ?? vs (\fst idty) 〈Local, \snd idty〉) vs tmpenv.
1036
1037record tmpgen (vars:var_types) : Type[0] ≝ {
1038  tmp_universe : universe SymbolTag;
1039  tmp_env : list (ident × type);
1040  tmp_ok : fresh_map_for_univ … (add_tmps vars tmp_env) tmp_universe;
1041  tmp_preserved :
1042    ∀id,ty. local_id vars id ty → local_id (add_tmps vars tmp_env) id ty
1043}.
1044
1045definition alloc_tmp : ∀vars. type → tmpgen vars → ident × (tmpgen vars) ≝
1046λvars,ty,g.
1047  let 〈tmp,u〉 as E ≝ fresh ? (tmp_universe ? g) in
1048  〈tmp, mk_tmpgen ? u (〈tmp, ty〉::(tmp_env ? g)) ??〉.
1049[ #id #ty'
1050  whd in ⊢ (? → ?%??);
1051  whd in ⊢ (% → %);
1052  whd in ⊢ (? → match % with [_ ⇒ ? | _ ⇒ ?]); #H
1053  >lookup_add_miss
1054  [ @(tmp_preserved … g) @H
1055  | @(fresh_distinct … E) @(tmp_ok … g)
1056    lapply (tmp_preserved … g id ty' H)
1057    whd in ⊢ (% → %);
1058    whd in ⊢ (match % with [_ ⇒ ? | _ ⇒ ?] → ?);
1059    cases (lookup ??? id)
1060    [ * | #x #_ % #E destruct ]
1061  ]
1062| @fresh_map_add
1063  [ @(fresh_map_preserved … E) @(tmp_ok … g)
1064  | @(fresh_is_fresh … E)
1065  ]
1066] qed.
1067
1068
1069lemma lookup_label_hit : ∀lbls,l,l'.
1070  lookup_label lbls l = OK ? l' →
1071  lpresent lbls l'.
1072#lbls #l #l' #E whd %{l} @E
1073qed.
1074
1075(* TODO: is this really needed now? *)
1076
1077definition tmps_preserved : ∀vars:var_types. tmpgen vars → tmpgen vars → Prop ≝
1078λvars,u1,u2.
1079  ∀id,ty. local_id (add_tmps vars (tmp_env … u1)) id ty → local_id (add_tmps vars (tmp_env … u2)) id ty.
1080
1081lemma alloc_tmp_preserves : ∀vars,tmp,u,u',q.
1082  〈tmp,u'〉 = alloc_tmp ? q u → tmps_preserved vars u u'.
1083#vars #tmp * #u1 #e1 #F1 #P1 * #u2 #e2 #F2 #P2 #q
1084whd in ⊢ (???% → ?); generalize in ⊢ (???(?%) → ?);
1085cases (fresh SymbolTag u1) in ⊢ (??%? → ???(match % with [ _ ⇒ ? ]?) → ?);
1086#tmp' #u' #E1 #E2 whd in E2:(???%); destruct
1087#id #ty #H whd in ⊢ (?%??); whd in H ⊢ %;
1088whd in ⊢ match % with [ _ ⇒ ? | _ ⇒ ? ];
1089>lookup_add_miss // @(fresh_distinct … E1) @F1
1090whd in H:(match % with [_ ⇒ ?|_ ⇒ ?]) ⊢ %;
1091cases (lookup ??? id) in H ⊢ %;
1092[ * | #x #_ % #E destruct ]
1093qed.
1094
1095lemma add_tmps_oblivious : ∀vars,s,u.
1096  stmt_inv vars s → stmt_inv (add_tmps vars (tmp_env vars u)) s.
1097#vars #s #u #H
1098@(stmt_P_mp … H)
1099#s' #H1 @(stmt_vars_mp … H1) #id #t #H @(tmp_preserved ? u ?? H)
1100qed.
1101
1102lemma local_id_fresh_tmp : ∀vars,tmp,u,ty,u0.
1103  〈tmp,u〉 = alloc_tmp vars ty u0 → local_id (add_tmps vars (tmp_env … u)) tmp (typ_of_type ty).
1104#vars #tmp #u #ty #u0
1105whd in ⊢ (???% → ?); generalize in ⊢ (???(?%) → ?);
1106cases (fresh SymbolTag (tmp_universe vars u0)) in ⊢ (??%? → ???(match % with [_⇒?]?) → ?);
1107* #tmp' #u' #e #E whd in E:(???%);
1108destruct
1109whd in ⊢ (?%??); whd whd in ⊢ match % with [ _ ⇒ ? | _ ⇒ ? ]; >lookup_add_hit
1110@refl
1111qed.
1112
1113
1114let rec mklabels (ul:labgen) : (identifier Label) × (identifier Label) × labgen ≝
1115  match generate_fresh_label ul with
1116  [ mk_Sig res1 H1 ⇒
1117     let 〈entry_label, ul1〉 as E1 ≝ res1 in
1118     match generate_fresh_label ul1 with
1119     [ mk_Sig res2 H2 ⇒
1120        let 〈exit_label, ul2〉 as E2 ≝ res2 in
1121        〈entry_label, exit_label, ul2〉
1122     ]
1123  ].
1124
1125(* When converting loops into gotos, and in order to eliminate blocks, we have
1126 * to convert continues and breaks into goto's, too. We add some "flags" in
1127 * in argument to [translate_statement], meaning that the next encountered break
1128 * or continue has to be converted into a goto to some contained label.
1129 * ConvertTo l1 l2 means "convert continue to goto l1 and convert break to goto l2".
1130 *)
1131inductive convert_flag : Type[0] ≝
1132| DoNotConvert : convert_flag
1133| ConvertTo    : identifier Label → identifier Label → convert_flag. (* continue, break *)
1134
1135let rec labels_of_flag (flag : convert_flag) : list (identifier Label) ≝
1136match flag with
1137[ DoNotConvert ⇒ [ ]
1138| ConvertTo continue break ⇒ continue :: break :: [ ]
1139].
1140
1141(* For a top-level expression, [label-wf] collapses to "all labels are properly declared" *)
1142definition label_wf ≝
1143λ (s : statement) .λ (s' : stmt) .λ (lbls : lenv). λ (flag : convert_flag).
1144    stmt_P (λs1. stmt_labels (λl.ldefined s' l ∨ lpresent lbls l ∨ In ? l (labels_of_flag flag)) s1) s'.
1145
1146definition return_ok : option typ → stmt → Prop ≝
1147λot.
1148stmt_P (λs.
1149  match s with [ St_return oe ⇒
1150    match oe with [ Some e ⇒ Some ? (dpi1 … e) = ot | None ⇒ None ? = ot ]
1151  | _ ⇒ True ]).
1152
1153(* trans_inv is the invariant which is enforced during the translation from Clight to Cminor.
1154  The involved arguments are the following:
1155  . vars:var_types, an environment mapping variables to their types and allocation modes
1156  . lbls:lenv, a mapping from old (Clight) to fresh and new (Cminor) labels,
1157  . s:statement, a Clight statement,
1158  . uv, a fresh variable generator (containing itself some invariants)
1159  . flag, wich maps "break" and "continue" to "gotos"
1160  . su', a couple of a Cminor statement and fresh variable generator.
1161*)
1162definition trans_inv : ∀vars:var_types . ∀lbls:lenv . statement → tmpgen vars → convert_flag → option typ → ((tmpgen vars) × labgen × stmt) → Prop ≝
1163λvars,lbls,s,uv,flag,rettyp,su'.
1164  let 〈uv', ul', s'〉 ≝ su' in
1165  stmt_inv (add_tmps vars (tmp_env … uv')) s' ∧   (* remaining variables in s' are local*)
1166  labels_translated lbls s s' ∧                   (* all the labels in s are transformed in label of s' using [lbls] as a map *)
1167  tmps_preserved vars uv uv' ∧                    (* the variables generated are local and grows in a monotonic fashion *)
1168  return_ok rettyp s' ∧                           (* return statements have correct typ *)
1169  label_wf s s' lbls flag.                        (* labels are "properly" declared, as defined in [ŀabel_wf].*)
1170
1171axiom ReturnMismatch : String.
1172
1173let rec translate_statement (vars:var_types) (uv:tmpgen vars) (ul:labgen) (lbls:lenv) (flag:convert_flag) (rettyp:option typ) (s:statement) on s
1174  : res (Σsu:(tmpgen vars)×labgen×stmt.trans_inv vars lbls s uv flag rettyp su) ≝
1175match s return λs.res (Σsu:(tmpgen vars)×labgen×stmt.trans_inv vars lbls s uv flag rettyp su) with
1176[ Sskip ⇒ OK ? «〈uv, ul, St_skip〉, ?»
1177| Sassign e1 e2 ⇒
1178    do e2' ← translate_expr vars e2;  (* rhs *)
1179    do dest ← translate_dest vars e1; (* e1 *)
1180    match dest with
1181    [ IdDest id ty p ⇒
1182       do e2' ← type_should_eq (typeof e2) ty ? e2';
1183       OK ? «〈uv, ul, St_assign ? id e2'〉, ?»
1184    | MemDest e1' ⇒
1185       OK ? «〈uv, ul, St_store ? e1' e2'〉, ?»
1186    ]
1187| Scall ret ef args ⇒
1188    do ef' ← translate_expr vars ef;
1189    do ef' ← typ_should_eq (typ_of_type (typeof ef)) ASTptr ? ef';
1190    do args' ← mmap_sigma ??? (translate_expr_sigma vars) args;
1191    match ret with
1192    [ None ⇒ OK ? «〈uv, ul, St_call (None ?) ef' args'〉, ?»
1193    | Some e1 ⇒
1194        do dest ← translate_dest vars e1;
1195        match dest with
1196        [ IdDest id ty p ⇒ OK ? «〈uv, ul, St_call (Some ? 〈id,typ_of_type ty〉) ef' args'〉, ?»
1197        | MemDest e1' ⇒
1198            let 〈tmp, uv1〉 as Etmp ≝ alloc_tmp ? (typeof e1) uv in
1199            OK ? «〈uv1, ul, St_seq (St_call (Some ? 〈tmp,typ_of_type (typeof e1)〉) ef' args') (St_store (typ_of_type (typeof e1)) e1' (Id ? tmp))〉, ?»
1200        ]
1201    ]
1202| Ssequence s1 s2 ⇒
1203    do «fgens1, s1', H1» ← translate_statement vars uv ul lbls flag rettyp s1;
1204    do «fgens2, s2', H2» ← translate_statement vars (fst … fgens1) (snd … fgens1) lbls flag rettyp s2;
1205    OK ? «〈fgens2, St_seq s1' s2'〉, ?»
1206| Sifthenelse e1 s1 s2 ⇒
1207    do e1' ← translate_expr vars e1;
1208    match typ_of_type (typeof e1) return λx.(Σe:CMexpr x.expr_vars ? e ?) → res ? with
1209    [ ASTint _ _ ⇒ λe1'.
1210         do «fgens1, s1', H1» ← translate_statement vars uv ul lbls flag rettyp s1;
1211         do «fgens2, s2', H2» ← translate_statement vars (fst … fgens1) (snd … fgens1) lbls flag rettyp s2;
1212        OK ? «〈fgens2, St_ifthenelse ?? e1' s1' s2'〉, ?»
1213    | _ ⇒ λ_.Error ? (msg TypeMismatch)
1214    ] e1'
1215(* Performing loop conversions while keeping good cost labelling properties is
1216   a little tricky.  In principle we should have a cost label in each branch,
1217   but the behaviour of the next stage means that we can put in Cminor skips and
1218   goto labels before the cost label. *)
1219| Swhile e1 s1 ⇒
1220    do e1' ← translate_expr vars e1;
1221    match typ_of_type (typeof e1) return λx.(Σe:CMexpr x.expr_vars ? e ?) → res ? with
1222    [ ASTint _ _ ⇒ λe1'.         
1223        let 〈labels, ul1〉 as E1 ≝ mklabels ul in
1224        let 〈entry, exit〉 as E2 ≝ labels in
1225        do «fgens2, s1',H1» ← translate_statement vars uv ul1 lbls (ConvertTo entry exit) rettyp s1;
1226        let converted_loop ≝
1227          St_label entry
1228          (St_seq
1229            (St_ifthenelse ?? e1' (St_seq s1' (St_goto entry)) St_skip)
1230            (St_label exit St_skip))
1231        in         
1232          OK ? «〈fgens2, converted_loop〉, ?»
1233    | _ ⇒ λ_.Error ? (msg TypeMismatch)
1234    ] e1'
1235| Sdowhile e1 s1 ⇒
1236    do e1' ← translate_expr vars e1;
1237    match typ_of_type (typeof e1) return λx.(Σe:CMexpr x. expr_vars ? e ?) → res ? with
1238    [ ASTint _ _ ⇒ λe1'.
1239        let 〈labels, ul1〉 as E1 ≝ mklabels ul in
1240        let 〈condexpr, exit〉 as E2 ≝ labels in
1241        let 〈body, ul2〉 ≝ generate_fresh_label … ul1 in
1242        do «fgens2, s1', H1» ← translate_statement vars uv ul2 lbls (ConvertTo condexpr exit) rettyp s1;
1243        (* This is particularly carefully implemented, we need to reach the
1244           cost label in s1' or the cost label after the loop (if they are
1245           present) after the ifthenelse, and we're only allowed skips and
1246           goto labels in between.  So we structure it like a while with a goto
1247           into the middle (the CFG will be essentially the same, anyway.) *)
1248        let converted_loop ≝
1249        St_seq
1250          (St_seq
1251            (St_goto body)
1252            (St_label condexpr
1253              (St_ifthenelse ?? e1'
1254                (St_label body
1255                  (St_seq
1256                    s1'
1257                    (St_goto condexpr)))
1258                St_skip)))
1259          (St_label exit St_skip)
1260        in
1261        OK ? «〈fgens2, converted_loop〉, ?»
1262    | _ ⇒ λ_.Error ? (msg TypeMismatch)
1263    ] e1'
1264| Sfor s1 e1 s2 s3 ⇒
1265    do e1' ← translate_expr vars e1;
1266    match typ_of_type (typeof e1) return λx.(Σe:CMexpr x. expr_vars ? e ?) → res ? with
1267    [ ASTint _ _ ⇒ λe1'.
1268        let 〈labels, ul1〉 as E ≝ mklabels ul in
1269        let 〈continue, exit〉 as E2 ≝ labels in
1270        let 〈entry, ul2〉 ≝ generate_fresh_label … ul1 in
1271        do «fgens2, s1', H1» ← translate_statement vars uv ul2 lbls flag rettyp s1;
1272        (* The choice of flag is arbitrary - Clight's semantics give no meaning
1273           to continue or break in s2 because in C it must be an expression. *)
1274        do «fgens3, s2', H2» ← translate_statement vars (fst … fgens2) (snd … fgens2) lbls flag rettyp s2;
1275        do «fgens4, s3', H3» ← translate_statement vars (fst … fgens3) (snd … fgens3) lbls (ConvertTo continue exit) rettyp s3;
1276        let converted_loop ≝
1277          St_seq
1278            s1'
1279            (St_label entry
1280              (St_seq
1281                (St_ifthenelse ?? e1' (St_seq s3' (St_label continue (St_seq s2' (St_goto entry)))) St_skip)
1282                (St_label exit St_skip)
1283            ))
1284        in
1285          OK ? «〈fgens4, converted_loop〉, ?»
1286    | _ ⇒ λ_.Error ? (msg TypeMismatch)
1287    ] e1'
1288| Sbreak ⇒
1289   match flag return λf.flag = f → ? with
1290   [ DoNotConvert ⇒ λEflag.
1291     Error ? (msg FIXME)
1292   | ConvertTo continue_label break_label ⇒ λEflag.
1293     OK ? «〈uv, ul, St_goto break_label〉, ?»
1294   ] (refl ? flag)
1295| Scontinue ⇒
1296  match flag return λf.flag = f → ? with
1297  [ DoNotConvert ⇒ λEflag.
1298    Error ? (msg FIXME)
1299  | ConvertTo continue_label break_label ⇒ λEflag.
1300    OK ? «〈uv, ul, St_goto continue_label〉, ?»
1301  ] (refl ? flag)
1302| Sreturn ret ⇒
1303    match ret with
1304    [ None ⇒
1305        match rettyp return λx.res (Σy.trans_inv … x y) with
1306        [ None ⇒ OK ? «〈uv, ul, St_return (None ?)〉, ?»
1307        | _ ⇒ Error ? (msg ReturnMismatch)
1308        ]
1309    | Some e1 ⇒
1310        match rettyp return λx.res (Σy.trans_inv … x y) with
1311        [ Some rty ⇒
1312            do e1' ← translate_expr vars e1;
1313            do e1' ← typ_should_eq (typ_of_type (typeof e1)) rty ? e1';
1314            OK ? «〈uv, ul, St_return (Some ? (mk_DPair … e1'))〉, ?»
1315        | _ ⇒ Error ? (msg ReturnMismatch)
1316        ]
1317    ]
1318| Sswitch e1 ls ⇒ Error ? (msg FIXME)
1319| Slabel l s1 ⇒
1320    do l' as E ← lookup_label lbls l;
1321    do «fgens1, s1', H1» ← translate_statement vars uv ul lbls flag rettyp s1;
1322    OK ? «〈fgens1, St_label l' s1'〉, ?»
1323| Sgoto l ⇒
1324    do l' as E ← lookup_label lbls l;
1325    OK ? «〈uv, ul, St_goto l'〉, ?»
1326| Scost l s1 ⇒
1327    do «fgens1, s1', H1» ← translate_statement vars uv ul lbls flag rettyp s1;
1328    OK ? «〈fgens1, St_cost l s1'〉, ?»
1329].
1330try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj
1331try (@I)
1332try (#l #H elim H)
1333try (#size #sign #H assumption)
1334try (#H1 try #H2 assumption)
1335[ 1,5: @(tmp_preserved … p) ]
1336[ 1,3: elim e2' | 2,9,23: elim e1' | 4,7,13: elim ef' ]
1337[ 1,2,3,4,5,6,7,8 : #e #Hvars @(expr_vars_mp … Hvars) #i #t #Hlocal @(tmp_preserved … Hlocal) ]
1338[ 1: @All_mp [ 1: @(λe.match e with [ mk_DPair t e0 ⇒ expr_vars t e0 (local_id vars) ])
1339             | 2: * #t #e #Hev whd in Hev ⊢ %; @(expr_vars_mp … Hev) #i #t #Hp @(tmp_preserved … Hp)
1340             | 3: elim args' // ]
1341| 7: (* we should be able to merge this case with the previous ... *)
1342     @All_mp [ 1: @(λe.match e with [ mk_DPair t e0 ⇒ expr_vars t e0 (local_id vars) ])
1343             | 2: * #t #e #Hev whd in Hev ⊢ %; @(expr_vars_mp … Hev) #i #t #Hp @(tmp_preserved … Hp)
1344             | 3: elim args' // ]
1345| 2: @(local_id_fresh_tmp vars tmp uv1 (typeof e1) uv Etmp)
1346| 3:  @(All_mp (𝚺 t:typ.expr t) (λe. match e with [ mk_DPair t e0 ⇒ expr_vars t e0 (local_id vars)]))
1347       [ 1: #a #Ha elim a in Ha ⊢ ?; #ta #a #Ha whd @(expr_vars_mp ?? (local_id vars))
1348       [ 1: #i0 #t0 #H0 @(tmp_preserved vars uv1 i0 t0 H0)
1349       | 2: assumption ]
1350       | 2: elim args' // ]
1351| 4: @(local_id_fresh_tmp vars tmp uv1 (typeof e1) uv Etmp) ]
1352[ 1: #size #sign | 2: ]
1353[ 1,2: #H @(alloc_tmp_preserves vars tmp uv uv1 … Etmp) @H ]
1354try @refl (* Does (at least) the return_ok cases *)
1355try @(match fgens1 return λx.x=fgens1 → ? with
1356     [ mk_Prod uv1 ul1 ⇒ λHfgens1.? ] (refl ? fgens1))
1357try @(match fgens2 return λx.x=fgens2 → ? with
1358     [ mk_Prod uv2 ul2 ⇒ λHfgens2.? ] (refl ? fgens2))
1359try @(match fgens3 return λx.x=fgens3 → ? with
1360     [ mk_Prod uv3 ul3 ⇒ λHfgens3.? ] (refl ? fgens3))
1361try @(match fgens4 return λx.x=fgens4 → ? with
1362     [ mk_Prod uv4 ul4 ⇒ λHfgens4.? ] (refl ? fgens4))
1363whd in H1 H2 H3 ⊢ ?; destruct whd nodelta in H1 H2 H3;
1364try (elim H1 -H1 * * * #Hstmt_inv1 #Hlabels_tr1 #Htmps_pres1 #Hret1)
1365try (elim H2 -H2 * * * #Hstmt_inv2 #Hlabels_tr2 #Htmps_pres2 #Hret2)
1366try (elim H3 -H3 * * * #Hstmt_inv3 #Hlabels_tr3 #Htmps_pres3 #Hret3)
1367[ 1,2: #Hind1 #Hind2 | 3,4,8,10: #Hind | 5: #Hind1 #Hind2 #Hind3 ]
1368try @conj try @conj try @conj try @conj try @conj try @conj try (whd @I) try assumption
1369[ 1,7: @(stmt_P_mp … Hstmt_inv1) #e #Hvars @(stmt_vars_mp … Hvars) #i #t #Hlocal @(Htmps_pres2 … Hlocal)
1370| 2: #l #H cases (Exists_append ???? H) #Hcase
1371         [ 1: elim (Hlabels_tr1 l Hcase) #label #Hlabel @(ex_intro … label) @conj
1372           [ 1: @(proj1 ?? Hlabel)
1373           | 2: normalize @Exists_append_l @(proj2 … Hlabel) ]
1374         | 2: elim (Hlabels_tr2 l Hcase) #label #Hlabel @(ex_intro … label) @conj
1375           [ 1: @(proj1 ?? Hlabel)
1376           | 2: normalize @Exists_append_r @(proj2 … Hlabel) ]
1377         ]
1378| 3,9: #id #ty #H @(Htmps_pres2 … (Htmps_pres1 id ty H)) ]
1379[ 1: @(stmt_P_mp … Hind2) | 2: @(stmt_P_mp … Hind1) ]
1380[ 1,2: #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1381     #l * try * [ 1,4: #H %1 %1 normalize in H ⊢ %; try (@Exists_append_l @H); try (@Exists_append_r @H)
1382                | 2,5: #H %1 %2 assumption
1383                | 3,6: #H %2 assumption ]
1384(* if/then/else *)
1385| 3: whd elim e1' #e #Hvars @(expr_vars_mp … Hvars) #i #t #Hlocal @(tmp_preserved … Hlocal)
1386| 4: whd #l #H
1387       cases (Exists_append ???? H) #Hcase
1388         [ 1: elim (Hlabels_tr1 l Hcase) #label #Hlabel @(ex_intro … label) @conj
1389           [ 1: @(proj1 ?? Hlabel)
1390           | 2: normalize @Exists_append_l @(proj2 … Hlabel) ]
1391         | 2: elim (Hlabels_tr2 l Hcase) #label #Hlabel @(ex_intro … label) @conj
1392           [ 1: @(proj1 ?? Hlabel)
1393           | 2: normalize @Exists_append_r @(proj2 … Hlabel) ]
1394         ]
1395]                 
1396[ 1: 1: @(stmt_P_mp … Hind2) | 2: @(stmt_P_mp … Hind1) ]
1397[ 1,2: #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1398     #l * try * [ 1,4: #H %1 %1 normalize in H ⊢ %; try (@Exists_append_l @H); try (@Exists_append_r @H)
1399                | 2,5: #H %1 %2 assumption
1400                | 3,6: #H %2 assumption ] ]
1401try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @I try assumption
1402[ 1,7,19: whd elim e1' #e #Hvars @(expr_vars_mp … Hvars) #i #t #Hlocal @(tmp_preserved … Hlocal)
1403| 2,8: whd #l #H normalize in H;
1404       elim (Hlabels_tr1 … H) #label #Hlabel @(ex_intro … label)
1405       @conj
1406       [ 1,3: @(proj1 … Hlabel)
1407       | 2,4: whd @or_intror normalize in ⊢ (???%);
1408              [ @Exists_append_l @Exists_append_l @Exists_append_l | %2 @Exists_append_l @Exists_append_l @Exists_append_l ]
1409              @(proj2 … Hlabel) ]
1410| whd %1 %1 normalize /2/
1411| 4,12: @(stmt_P_mp … Hind) #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1412   #l * try * [ 1,5: #H %1 %1 normalize %2 [ 2: %2 ] @Exists_append_l @Exists_append_l try @Exists_append_l @H
1413              | 2,6: #H %1 %2 assumption
1414              | 3,7: #H <H %1 %1 normalize /2/
1415              | 4,8: #H normalize in H; elim H [ 1,3: #E <E %1 %1 normalize %2 [2: %2]
1416                                                 @Exists_append_r normalize /2/
1417                                               | 2,4: * ]
1418              ]
1419| normalize %1 %1 %1 //
1420| 6,11: normalize %1 %1 %2 [ @Exists_append_r normalize /2/ | %1 % ]
1421| whd %1 %1 normalize %2 %1 %
1422| 10,13: normalize %1 %1 %1 %
1423| normalize %1 %1 %2 %2 /2/
1424| whd #label * [ 1: #Eq @(ex_intro … l') @conj [ 1: destruct // | whd /2/ ]
1425               | 2: #H elim (Hlabels_tr1 label H)
1426                    #lab * #Hlookup #Hdef @(ex_intro … lab) @conj
1427                    [ 1: // | 2: whd %2 assumption ]
1428               ]
1429| normalize %1 %1 %1 %
1430| @(stmt_P_mp … Hind) #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1431  #l * try * [ 1: #H %1 %1 normalize %2 @H
1432             | 2: #H %1 %2 assumption
1433             | 3: #H %2 assumption ]
1434| @(stmt_P_mp … Hstmt_inv1) #s0 #Hstmt_vars @(stmt_vars_mp … Hstmt_vars) #i #t
1435  #H @(Htmps_pres3 … (Htmps_pres2 … H))
1436| @(stmt_P_mp … Hstmt_inv2) #s0 #Hstmt_vars @(stmt_vars_mp … Hstmt_vars) #i #t
1437  #H @(Htmps_pres3 … H)
1438| % //
1439| whd #l #H normalize in H;
1440  cases (Exists_append … H) #Hcase
1441  [ 1: elim (Hlabels_tr1 l Hcase) #label #Hlabel @(ex_intro … label) @conj
1442    [ 1: @(proj1 … Hlabel)
1443    | 2: normalize @Exists_append_l @(proj2 … Hlabel)
1444    ]
1445  | 2: cases (Exists_append … Hcase) #Hcase2
1446    [ 1: elim (Hlabels_tr2 l Hcase2) #label #Hlabel @(ex_intro … label) @conj
1447      [ 1: @(proj1 … Hlabel)
1448      | 2: normalize >append_nil >append_nil >append_cons
1449           @Exists_append_r @Exists_append_l @Exists_append_r %2
1450           @(proj2 … Hlabel)
1451      ]
1452    | 2: elim (Hlabels_tr3 l Hcase2) #label #Hlabel @(ex_intro … label) @conj
1453      [ 1: @(proj1 … Hlabel)
1454      | 2: normalize >append_nil >append_nil >append_cons
1455         @Exists_append_r @Exists_append_l @Exists_append_l
1456         @(proj2 … Hlabel)
1457      ]
1458    ]
1459  ]
1460| #id #ty #H @(Htmps_pres3 … (Htmps_pres2 … (Htmps_pres1 … H)))
1461| @(stmt_P_mp … Hind3) #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1462   #l * try * [ 1: #H %1 %1 normalize @Exists_append_l @H
1463              | 2: #H %1 %2 assumption
1464              | 3: #H %2 assumption ]
1465| whd %1 %1 normalize /2/
1466| @(stmt_P_mp … Hind1) #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1467   #l * try * [ 1: #H %1 %1 normalize @Exists_append_r @(Exists_add ?? (nil ?))
1468                   @Exists_append_r @Exists_append_l @Exists_append_l
1469                   @Exists_append_l assumption
1470              | 2: #H %1 %2 assumption
1471              | 3: #H <H %1 %1 normalize
1472                   @Exists_append_r %2 @Exists_append_l @Exists_append_l
1473                   @Exists_append_r %1 %
1474              | 4: * [ 1: #Eq <Eq %1 %1 whd normalize
1475                       @Exists_append_r @(Exists_add ?? (nil ?)) @Exists_append_r
1476                       @Exists_append_r whd %1 //
1477                     | 2: * ]
1478              ]
1479| % %1 normalize @Exists_append_r %2 @Exists_append_l @Exists_append_l
1480  @Exists_append_r % %
1481| @(stmt_P_mp … Hind2) #s0 #Hstmt_labels @(stmt_labels_mp … Hstmt_labels)
1482   #l * try * [ 1: #H %1 %1 normalize @Exists_append_r @(Exists_add ?? (nil ?))
1483                   @Exists_append_r @Exists_append_l @Exists_append_l                   
1484                   @Exists_append_r %2 @Exists_append_l assumption
1485              | 2: #H %1 %2 assumption
1486              | 3: /2/
1487              ]
1488| whd %1 %1 normalize /2/
1489| whd %1 %1 normalize
1490  @Exists_append_r @(Exists_add ?? (nil ?)) @Exists_append_r @Exists_append_r
1491  whd %1 //
1492| normalize %2 /3/
1493| normalize /4/
1494| whd %1 %2 whd @(ex_intro … l) @E
1495] qed.
1496
1497axiom ParamGlobalMixup : String.
1498
1499(* params and statement aren't real parameters, they're just there for giving the invariant. *)
1500definition alloc_params :
1501 ∀vars:var_types.∀lbls,statement,uv,flag,rettyp. list (ident×type) → (Σsu:(tmpgen vars)×labgen×stmt. trans_inv vars lbls statement uv flag rettyp su)
1502   → res (Σsu:(tmpgen vars)×labgen×stmt.trans_inv vars lbls statement uv flag rettyp su) ≝   
1503λvars,lbls,statement,uv,ul,rettyp,params,s. foldl ?? (λsu,it.
1504  let 〈id,ty〉 ≝ it in
1505  do «result,Is» ← su;
1506  let 〈fgens1, s〉 as Eresult ≝ result in
1507  do 〈t,ty'〉 as E ← lookup' vars id;
1508  match t return λx.? → res (Σsu:(tmpgen vars)×labgen×stmt.trans_inv vars lbls statement uv ul rettyp su) with
1509  [ Local ⇒ λE. OK (Σs:(tmpgen vars)×labgen×stmt.?) «result,Is»
1510  | Stack n ⇒ λE.
1511      OK ? «〈fgens1, St_seq (St_store ? (Cst ? (Oaddrstack n)) (Id (typ_of_type ty') id)) s〉, ?»
1512  | Global _ ⇒ λE. Error ? [MSG ParamGlobalMixup; CTX ? id]
1513  ] E) (OK ? s) params.
1514whd
1515@(match fgens1 return λx.x=fgens1 → ? with
1516  [ mk_Prod uv1 ul1 ⇒ λHfgens1.? ] (refl ? fgens1))
1517whd in Is ⊢ %; destruct whd in Is;
1518try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @conj try @I
1519elim Is * * * #Hincl #Hstmt_inv #Hlab_tr #Hret #Htmp_pr try assumption
1520@(expr_vars_mp … (tmp_preserved … uv1)) whd >E @refl
1521qed.
1522
1523axiom DuplicateLabel : String.
1524
1525definition lenv_list_inv : lenv → lenv → list ident → Prop ≝
1526λlbls0,lbls,ls.
1527 ∀l,l'. lookup_label lbls l = OK ? l' →
1528 Exists ? (λl'. l' = l) ls ∨ lookup_label lbls0 l = OK ? l'.
1529
1530lemma lookup_label_add : ∀lbls,l,l'.
1531  lookup_label (add … lbls l l') l = OK ? l'.
1532#lbls #l #l' whd in ⊢ (??%?); >lookup_add_hit @refl
1533qed.
1534
1535lemma lookup_label_miss : ∀lbls,l,l',l0.
1536  l0 ≠ l →
1537  lookup_label (add … lbls l l') l0 = lookup_label lbls l0.
1538#lbls #l #l' #l0 #NE
1539whd in ⊢ (??%%);
1540>lookup_add_miss
1541[ @refl | @NE ]
1542qed.
1543
1544let rec populate_lenv (ls:list ident) (ul:labgen) (lbls:lenv): res ((Σlbls':lenv. lenv_list_inv lbls lbls' ls) × labgen) ≝
1545match ls return λls.res ((Σlbls':lenv. lenv_list_inv lbls lbls' ls) × labgen) with
1546[ nil ⇒ OK ? 〈«lbls, ?», ul〉
1547| cons l t ⇒
1548  match lookup_label lbls l return λlook. lookup_label lbls l = look → ? with
1549  [ OK _    ⇒ λ_.Error ? (msg DuplicateLabel)
1550  | Error _ ⇒ λLOOK.
1551    match generate_fresh_label … ul with
1552    [ mk_Sig ret H ⇒
1553       do 〈packed_lbls, ul1〉 ← populate_lenv t (snd ?? ret) (add … lbls l (fst ?? ret));
1554       match packed_lbls with
1555       [ mk_Sig lbls' Hinv ⇒ OK ? 〈«lbls', ?», ul1〉 ]
1556    ]
1557  ] (refl ? (lookup_label lbls l))
1558].
1559[ 1: whd #l #l' #Hlookup %2 assumption
1560| 2: whd in Hinv; whd #cl_lab #cm_lab #Hlookup
1561     @(eq_identifier_elim … l cl_lab)
1562     [ 1: #Heq %1 >Heq whd %1 //
1563     | 2: #Hneq cases (Hinv cl_lab cm_lab Hlookup)
1564           [ 1: #H %1 %2 @H
1565           | 2: #LOOK' %2 >lookup_label_miss in LOOK'; /2/ #H @H ]
1566     ]
1567]
1568qed.
1569
1570definition build_label_env :
1571   ∀body:statement. res ((Σlbls:lenv. ∀l,l'.lookup_label lbls l = OK ? l' → Exists ? (λl'.l' = l) (labels_defined body)) × labgen) ≝
1572λbody.
1573  let initial_labgen ≝ mk_labgen (new_universe ?) (nil ?) ?  in
1574  do 〈label_map, u〉 ← populate_lenv (labels_defined body) initial_labgen (empty_map ??);
1575  let lbls ≝ pi1 ?? label_map in
1576  let H    ≝ pi2 ?? label_map in
1577  OK ? 〈«lbls, ?», u〉.
1578[ 1: #l #l' #E cases (H l l' E) //
1579     whd in ⊢ (??%? → ?); #H destruct
1580| 2: whd @I ]
1581qed.
1582
1583lemma local_id_split : ∀vars,tmpgen,i,t.
1584  local_id (add_tmps vars (tmp_env vars tmpgen)) i t →
1585  local_id vars i t ∨ Exists ? (λx. \fst x = i ∧ typ_of_type (\snd x) = t) (tmp_env … tmpgen).
1586#vars #tmpgen #i #t
1587whd in ⊢ (?%?? → ?);
1588elim (tmp_env vars tmpgen)
1589[ #H %1 @H
1590| * #id #ty #tl #IH
1591  cases (identifier_eq ? i id)
1592  [ #E >E #H %2 whd %1 % [ @refl | whd in H; whd in H:(match % with [_⇒?|_⇒?]); >lookup_add_hit in H; #E1 >E1 @refl ]
1593  | #NE #H cases (IH ?)
1594    [ #H' %1 @H'
1595    | #H' %2 %2 @H'
1596    | whd in H; whd in H:(match % with [ _ ⇒ ? | _ ⇒ ? ]);
1597      >lookup_add_miss in H; [ #H @H | @NE ]
1598    ]
1599  ]
1600] qed.
1601
1602lemma Exists_squeeze : ∀A,P,l1,l2,l3.
1603  Exists A P (l1@l3) → Exists A P (l1@l2@l3).
1604#A #P #l1 #l2 #l3 #EX
1605cases (Exists_append … EX)
1606[ #EX1 @Exists_append_l @EX1
1607| #EX3 @Exists_append_r @Exists_append_r @EX3
1608] qed.
1609
1610(* This lemma allows to merge two stmt_P in one. Used in the following parts to merge an invariant on variables
1611   and an invariant on labels. *)
1612lemma stmt_P_conj : ∀ (P1:stmt → Prop). ∀ (P2:stmt → Prop). ∀ s. stmt_P P1 s → stmt_P P2 s → stmt_P (λs.P1 s ∧ P2 s) s.
1613#P1 #P2 #s elim s
1614normalize /6 by proj1, proj2, conj/
1615qed.
1616
1617definition translate_function :
1618  ∀tmpuniverse:universe SymbolTag.
1619  ∀globals:list (ident×region×type).
1620  ∀f:function.
1621    globals_fresh_for_univ ? globals tmpuniverse →
1622    fn_fresh_for_univ f tmpuniverse →
1623  res internal_function ≝
1624λtmpuniverse, globals, f, Fglobals, Ffn.
1625  do 〈env_pack, ul〉 ← build_label_env (fn_body f);
1626    match env_pack with
1627    [ mk_Sig lbls Ilbls ⇒
1628      let 〈vartypes, stacksize〉 as E ≝ characterise_vars globals f in
1629      let uv ≝ mk_tmpgen vartypes tmpuniverse [ ] ?? in
1630      do s0 ← translate_statement vartypes uv ul lbls DoNotConvert (opttyp_of_type (fn_return f)) (fn_body f);
1631      do «fgens, s1, Is» ← alloc_params vartypes lbls ? uv DoNotConvert (opttyp_of_type (fn_return f)) (fn_params f) s0;
1632      let params ≝ map ?? (λv.〈\fst v, typ_of_type (\snd v)〉) (fn_params f) in
1633      let vars ≝ map ?? (λv.〈\fst v, typ_of_type (\snd v)〉) (tmp_env ? (fst ?? fgens) @ fn_vars f) in
1634      do D ← check_distinct_env ?? (params @ vars);
1635      OK ? (mk_internal_function
1636        (opttyp_of_type (fn_return f))
1637        params
1638        vars
1639        D
1640        stacksize
1641        s1 ?)
1642  ].
1643[ 1: #i #t #Hloc whd @Hloc
1644| 2: whd #id #Hpresent normalize in Hpresent:(???%?); whd in Hpresent;
1645      @(characterise_vars_fresh … (sym_eq … E)) //
1646| 3: @(match fgens return λx.x=fgens → ? with
1647     [ mk_Prod uv' ul' ⇒ λHfgens.? ] (refl ? fgens))
1648     whd in Is; <Hfgens in Is; #Is whd in Is ⊢ %;
1649     elim Is * * * #Hstmt_inv #Hlab_trans #Htmps_pres #Hreturn #Hlabel_wf
1650     (* merge Hlabel_wf with Hstmt_inv and eliminate right away *)
1651     @(stmt_P_mp … (stmt_P_conj … (stmt_P_conj … Hstmt_inv Hlabel_wf) Hreturn))
1652     #s * * #Hstmt_vars #Hstmt_labels #Hstmt_return %
1653     [ 1: (* prove that variables are either parameters or locals *)
1654        @(stmt_vars_mp … Hstmt_vars) #i #t #H
1655        (* Case analysis: (i, t) is either in vartypes, or in (tmp_env vartypes uv) *)
1656        cases (local_id_split … H)
1657        [ 1: #H' >map_append
1658          @Exists_map [ 1: #x @(And (\fst x = i) (typ_of_type (\snd x) = t))  (* * #id #ty @(〈id, typ_of_type ty〉=〈i, t〉)*)
1659                      | 2: whd @Exists_squeeze @(characterise_vars_all globals f ?? (sym_eq ??? E) i t H')
1660                      | 3: * #id #ty * #E1 #E2 <E1 <E2 @refl
1661                      ]
1662        | 2: #EX @Exists_append_r whd in ⊢ (???%); <map_append @Exists_append_l
1663          @Exists_map [ 1: #x @(And (\fst x = i) (typ_of_type (\snd x) = t))
1664                      | 2: <Hfgens @EX
1665                      | 3: * #id #ty * #E1 #E2 <E1 <E2 % @refl
1666                      ]
1667        ]
1668     | 2: (* prove that labels are properly declared. *)
1669          @(stmt_labels_mp … Hstmt_labels) #l * *
1670          [ 1: #H assumption
1671          | 2: * #cl_label #Hlookup lapply (Ilbls cl_label l Hlookup) #Hdefined
1672                cases (Hlab_trans … Hdefined) #lx * #LOOKUPx >LOOKUPx in Hlookup; #Ex destruct (Ex)
1673                #H @H
1674          ]
1675     | cases s in Hstmt_return; // * normalize [2: * #t #e ]
1676       cases (fn_return f) normalize #A try #B try #C try #D try #E destruct //
1677    ]
1678] qed.   
1679
1680definition translate_fundef :
1681  ∀tmpuniverse:universe SymbolTag.
1682  ∀globals:list (ident×region×type).
1683    globals_fresh_for_univ ? globals tmpuniverse →
1684  ∀f:clight_fundef.
1685    fd_fresh_for_univ f tmpuniverse →
1686  res (fundef internal_function) ≝
1687λtmpuniverse,globals,Fglobals,f.
1688match f return λf. fd_fresh_for_univ f ? → ? with
1689[ CL_Internal fn ⇒ λFf. do fn' ← translate_function tmpuniverse globals fn Fglobals Ff; OK ? (Internal ? fn')
1690| CL_External fn argtys retty ⇒ λ_. OK ? (External ? (mk_external_function fn (signature_of_type argtys retty)))
1691].
1692
1693let rec map_partial_All (A,B:Type[0]) (P:A → Prop) (f:∀a:A. P a → res B)
1694  (l:list A) (H:All A P l) on l : res (list B) ≝
1695match l return λl. All A P l → ? with
1696[ nil ⇒ λ_. OK (list B) (nil B)
1697| cons hd tl ⇒ λH.
1698    do b_hd ← f hd (proj1 … H);
1699    do b_tl ← map_partial_All A B P f tl (proj2 … H);
1700      OK (list B) (cons B b_hd b_tl)
1701] H.
1702
1703definition clight_to_cminor : clight_program → res Cminor_program ≝
1704λp.
1705  let tmpuniverse ≝ universe_for_program p in
1706  let fun_globals ≝ map ?? (λidf. 〈\fst idf,Code,type_of_fundef (\snd idf)〉) (prog_funct ?? p) in
1707  let var_globals ≝ map ?? (λv. 〈\fst (\fst v), \snd (\fst v), \snd (\snd v)〉) (prog_vars ?? p) in
1708  let globals ≝ fun_globals @ var_globals in
1709  do fns ← map_partial_All ??? (λx,H. do f ← translate_fundef tmpuniverse globals ? (\snd x) H; OK ? 〈\fst x, f〉) (prog_funct ?? p) ?;
1710    OK ? (mk_program ??
1711      (map ?? (λv. 〈\fst v, \fst (\snd v)〉) (prog_vars ?? p))
1712      fns
1713      (prog_main ?? p)).
1714cases (prog_fresh p) * #H1 #H2 #H3
1715[ @(All_mp … H1) #x * //
1716| @All_append
1717  [ elim (prog_funct ?? p) in H1 ⊢ %; // * #id #fd #tl #IH * * #Hhd1 #Hhd2 #Htl % // @IH @Htl
1718  | whd in H3; elim (prog_vars ?? p) in H3 ⊢ %; // #hd #tl #IH * #Hhd #Htl % /2/
1719  ]
1720] qed.
1721
1722(* It'd be nice to go back to some generic thing like
1723
1724 transform_partial_program2 … p (translate_fundef tmpuniverse globals) (λi. OK ? (\fst i)).
1725
1726   rather than the messier definition above.
1727*)
Note: See TracBrowser for help on using the repository browser.