source: src/Clight/frontend_misc.ma @ 2438

(* Various small homeless results. *)

include "Clight/TypeComparison.ma".
include "Clight/Csem.ma".
include "common/Pointers.ma".
include "basics/jmeq.ma".
include "basics/star.ma". (* well-founded relations *)
include "common/IOMonad.ma".
include "common/IO.ma".
include "basics/lists/listb.ma".
include "basics/lists/list.ma".

(* --------------------------------------------------------------------------- *)
(* Misc. *)
(* --------------------------------------------------------------------------- *)

lemma eq_intsize_identity : ∀id. eq_intsize id id = true.
* normalize //
qed.

lemma sz_eq_identity : ∀s. sz_eq_dec s s = inl ?? (refl ? s).
* normalize // 
qed.

lemma type_eq_identity : ∀t. type_eq t t = true.
#t normalize elim (type_eq_dec t t)
[ 1: #Heq normalize //
| 2: #H destruct elim H #Hcontr elim (Hcontr (refl ? t)) ] qed.

lemma type_neq_not_identity : ∀t1, t2. t1 ≠ t2 → type_eq t1 t2 = false.
#t1 #t2 #Hneq normalize elim (type_eq_dec t1 t2)
[ 1: #Heq destruct elim Hneq #Hcontr elim (Hcontr (refl ? t2))
| 2: #Hneq' normalize // ] qed.

lemma le_S_O_absurd : ∀x:nat. S x ≤ 0 → False. /2 by absurd/ qed.

lemma some_inj : ∀A : Type[0]. ∀a,b : A. Some ? a = Some ? b → a = b. #A #a #b #H destruct (H) @refl qed.

lemma prod_eq_lproj : ∀A,B : Type[0]. ∀a : A. ∀b : B. ∀c : A × B. 〈a,b〉 = c → a = \fst c.
#A #B #a #b * #a' #b' #H destruct @refl
qed.

lemma prod_eq_rproj : ∀A,B : Type[0]. ∀a : A. ∀b : B. ∀c : A × B. 〈a,b〉 = c → b = \snd c.
#A #B #a #b * #a' #b' #H destruct @refl
qed.

lemma bindIO_Error : ∀err,f. bindIO io_out io_in (val×trace) (trace×state) (Error … err) f = Wrong io_out io_in (trace×state) err.
// qed.

lemma bindIO_Value : ∀v,f. bindIO io_out io_in (val×trace) (trace×state) (Value … v) f = (f v).
// qed.

lemma bindIO_elim :
         ∀A.
         ∀P : (IO io_out io_in A) → Prop.
         ∀e : res A. (*IO io_out io_in A.*)
         ∀f.
         (∀v. (e:IO io_out io_in A) = OK … v →  P (f v)) →
         (∀err. (e:IO io_out io_in A) = Error … err →  P (Wrong ??? err)) →
         P (bindIO io_out io_in ? A (e:IO io_out io_in A) f).
#A #P * try /2/ qed.

lemma opt_to_io_Value :
  ∀A,B,C,err,x,res. opt_to_io A B C err x = return res → x = Some ? res.
#A #B #C #err #x cases x normalize
[ 1: #res #Habsurd destruct
| 2: #c #res #Heq destruct @refl ]
qed.  

lemma some_inversion :
  ∀A,B:Type[0].
  ∀e:option A.
  ∀res:B.
  ∀f:A → option B. 
 match e with
 [ None ⇒ None ?
 | Some x ⇒ f x ] = Some ? res → 
 ∃x. e = Some ? x ∧ f x = Some ? res.
 #A #B #e #res #f cases e normalize nodelta
[ 1: #Habsurd destruct (Habsurd)
| 2: #a #Heq %{a} @conj >Heq @refl ] 
qed.

lemma cons_inversion :
  ∀A,B:Type[0].
  ∀e:list A.
  ∀res:B.
  ∀f:A → list A → option B. 
 match e with
 [ nil ⇒ None ?
 | cons hd tl ⇒ f hd tl ] = Some ? res → 
 ∃hd,tl. e = hd::tl ∧ f hd tl = Some ? res.
#A #B #e #res #f cases e normalize nodelta
[ 1: #Habsurd destruct (Habsurd)
| 2: #hd #tl #Heq %{hd} %{tl} @conj >Heq @refl ]
qed.

lemma if_opt_inversion :
  ∀A:Type[0].
  ∀x.
  ∀y:A.
  ∀e:bool.
 (if e then
    x
  else
    None ?) = Some ? y → 
 e = true ∧ x = Some ? y.
#A #x #y * normalize
#H destruct @conj @refl
qed.

lemma andb_inversion :
  ∀a,b : bool. andb a b = true → a = true ∧ b = true.
* * normalize /2 by conj, refl/ qed.  

lemma identifier_eq_i_i : ∀tag,i. ∃pf. identifier_eq tag i i = inl … pf.
#tag #i cases (identifier_eq ? i i)
[ 1: #H %{H} @refl
| 2: * #Habsurd @(False_ind … (Habsurd … (refl ? i))) ]
qed.

(* --------------------------------------------------------------------------- *)
(* Useful facts on various boolean operations. *)
(* --------------------------------------------------------------------------- *)
 
lemma andb_lsimpl_true : ∀x. andb true x = x. // qed.
lemma andb_lsimpl_false : ∀x. andb false x = false. normalize // qed.
lemma andb_comm : ∀x,y. andb x y = andb y x. // qed.
lemma notb_true : notb true = false. // qed.
lemma notb_false : notb false = true. % #H destruct qed.
lemma notb_fold : ∀x. if x then false else true = (¬x). // qed.

(* --------------------------------------------------------------------------- *)
(* Useful facts on Z. *)
(* --------------------------------------------------------------------------- *)

lemma Zltb_to_Zleb_true : ∀a,b. Zltb a b = true → Zleb a b = true.
#a #b #Hltb lapply (Zltb_true_to_Zlt … Hltb) #Hlt @Zle_to_Zleb_true 
/3 by Zlt_to_Zle, transitive_Zle/ qed.

lemma Zle_to_Zle_to_eq : ∀a,b. Zle a b → Zle b a → a = b.
#a #b elim b
[ 1: elim a // #a' normalize [ 1: @False_ind | 2: #_ @False_ind ] ]
#b' elim a normalize
[ 1: #_ @False_ind
| 2: #a' #H1 #H2 >(le_to_le_to_eq … H1 H2) @refl
| 3: #a' #_ @False_ind
| 4: @False_ind
| 5: #a' @False_ind
| 6: #a' #H2 #H1 >(le_to_le_to_eq … H1 H2) @refl
] qed.

lemma Zleb_true_to_Zleb_true_to_eq : ∀a,b. (Zleb a b = true) → (Zleb b a = true) → a = b.
#a #b #H1 #H2 
/3 by Zle_to_Zle_to_eq, Zleb_true_to_Zle/
qed.

lemma Zltb_dec : ∀a,b. (Zltb a b = true) ∨ (Zltb a b = false ∧ Zleb b a = true).
#a #b
lapply (Z_compare_to_Prop … a b)
cases a
[ 1: | 2,3: #a' ]
cases b
whd in match (Z_compare OZ OZ); normalize nodelta
[ 2,3,5,6,8,9: #b' ]
whd in match (Zleb ? ?);
try /3 by or_introl, or_intror, conj, I, refl/
whd in match (Zltb ??);
whd in match (Zleb ??); #_
[ 1: cases (decidable_le (succ a') b')
     [ 1: #H lapply (le_to_leb_true … H) #H %1 assumption
     | 2:  #Hnotle lapply (not_le_to_lt … Hnotle) #Hlt %2  @conj try @le_to_leb_true
           /2 by monotonic_pred/ @(not_le_to_leb_false … Hnotle) ]
| 2: cases (decidable_le (succ b') a')
     [ 1: #H lapply (le_to_leb_true … H) #H %1 assumption
     | 2:  #Hnotle lapply (not_le_to_lt … Hnotle) #Hlt %2  @conj try @le_to_leb_true
           /2 by monotonic_pred/ @(not_le_to_leb_false … Hnotle) ]
] qed.

lemma Zleb_unsigned_OZ : ∀bv. Zleb OZ (Z_of_unsigned_bitvector 16 bv) = true.
#bv elim bv try // #n' * #tl normalize /2/ qed.

lemma Zltb_unsigned_OZ : ∀bv. Zltb (Z_of_unsigned_bitvector 16 bv) OZ = false.
#bv elim bv try // #n' * #tl normalize /2/ qed.

lemma Z_of_unsigned_not_neg : ∀bv. 
  (Z_of_unsigned_bitvector 16 bv = OZ) ∨ (∃p. Z_of_unsigned_bitvector 16 bv = pos p).
#bv elim bv
[ 1: normalize %1 @refl
| 2: #n #hd #tl #Hind cases hd
     [ 1: normalize %2 /2 by ex_intro/
     | 2: cases Hind normalize [ 1: #H %1 @H | 2: * #p #H >H %2 %{p} @refl ]
     ]
] qed.

lemma free_not_in_bounds : ∀x. if Zleb (pos one) x 
                                then Zltb x OZ 
                                else false = false.
#x lapply (Zltb_to_Zleb_true x OZ)
elim (Zltb_dec … x OZ)
[ 1: #Hlt >Hlt #H lapply (H (refl ??)) elim x
     [ 2,3: #x' ] normalize in ⊢ (% → ?);
     [ 1: #Habsurd destruct (Habsurd)
     | 2,3: #_ @refl ]
| 2: * #Hlt #Hle #_ >Hlt cases (Zleb (pos one) x) @refl ]
qed.

lemma free_not_valid : ∀x. if Zleb (pos one) x 
                            then Zltb x OZ 
                            else false = false.
#x 
cut (Zle (pos one) x ∧ Zlt x OZ → False)
[ * #H1 #H2 lapply (transitive_Zle … (monotonic_Zle_Zsucc … H1) (Zlt_to_Zle … H2)) #H @H ] #Hguard
cut (Zleb (pos one) x = true ∧ Zltb x OZ = true → False)
[ * #H1 #H2 @Hguard @conj /2 by Zleb_true_to_Zle/ @Zltb_true_to_Zlt assumption ]
cases (Zleb (pos one) x) cases (Zltb x OZ) 
/2 by refl/ #H @(False_ind … (H (conj … (refl ??) (refl ??))))
qed.

(* follows from (0 ≤ a < b → mod a b = a) *)
axiom Z_of_unsigned_bitvector_of_small_Z :
  ∀z. OZ ≤ z → z < Z_two_power_nat 16 → Z_of_unsigned_bitvector 16 (bitvector_of_Z 16 z) = z.

theorem Zle_to_Zlt_to_Zlt: ∀n,m,p:Z. n ≤ m → m < p → n < p.
#n #m #p #Hle #Hlt /4 by monotonic_Zle_Zplus_r, Zle_to_Zlt, Zlt_to_Zle, transitive_Zle/
qed.

(* --------------------------------------------------------------------------- *)
(* Useful facts on blocks. *)
(* --------------------------------------------------------------------------- *)

lemma not_eq_block : ∀b1,b2. b1 ≠ b2 → eq_block b1 b2 = false.
#b1 #b2 #Hneq
@(eq_block_elim … b1 b2)
[ 1: #Heq destruct elim Hneq #H @(False_ind … (H (refl ??)))
| 2: #_ @refl ] qed.

lemma not_eq_block_rev : ∀b1,b2. b2 ≠ b1 → eq_block b1 b2 = false.
#b1 #b2 #Hneq
@(eq_block_elim … b1 b2)
[ 1: #Heq destruct elim Hneq #H @(False_ind … (H (refl ??)))
| 2: #_ @refl ] qed.

definition block_DeqSet : DeqSet ≝ mk_DeqSet block eq_block ?.
* #r1 #id1 * #r2 #id2 @(eqZb_elim … id1 id2)
[ 1: #Heq >Heq cases r1 cases r2 normalize
     >eqZb_z_z normalize try // @conj #H destruct (H)
     try @refl
| 2: #Hneq cases r1 cases r2 normalize
     >(eqZb_false … Hneq) normalize @conj
     #H destruct (H) elim Hneq #H @(False_ind … (H (refl ??)))
] qed.

(* --------------------------------------------------------------------------- *)
(* General results on lists. *)
(* --------------------------------------------------------------------------- *)

(* If mem succeeds in finding an element, then the list can be partitioned around this element. *)
lemma list_mem_split : ∀A. ∀l : list A. ∀x : A. mem … x l → ∃l1,l2. l = l1 @ [x] @ l2.
#A #l elim l 
[ 1: normalize #x @False_ind
| 2: #hd #tl #Hind #x whd in ⊢ (% → ?); *
     [ 1: #Heq %{(nil ?)} %{tl} destruct @refl
     | 2: #Hmem lapply (Hind … Hmem) * #l1 * #l2 #Heq_tl >Heq_tl
          %{(hd :: l1)} %{l2} @refl
     ]
] qed.

lemma cons_to_append : ∀A. ∀hd : A. ∀l : list A. hd :: l = [hd] @ l. #A #hd #l @refl qed.

lemma fold_append :
  ∀A,B:Type[0]. ∀l1, l2 : list A. ∀f:A → B → B. ∀seed. foldr ?? f seed (l1 @ l2) = foldr ?? f (foldr ?? f seed l2) l1.
#A #B #l1 elim l1 //
#hd #tl #Hind #l2 #f #seed normalize >Hind @refl
qed.

lemma filter_append : ∀A:Type[0]. ∀l1,l2 : list A. ∀f. filter ? f (l1 @ l2) = (filter ? f l1) @ (filter ? f l2).
#A #l1 elim l1 //
#hd #tl #Hind #l2 #f
>cons_to_append >associative_append
normalize cases (f hd) normalize
<Hind @refl
qed.

lemma filter_cons_unfold : ∀A:Type[0]. ∀f. ∀hd,tl. 
  filter ? f (hd :: tl) = 
  if f hd then 
    (hd :: filter A f tl) 
  else 
    (filter A f tl).
#A #f #hd #tl elim tl // qed.


lemma filter_elt_empty : ∀A:DeqSet. ∀elt,l. filter (carr A) (λx.¬(x==elt)) l = [ ] → All (carr A) (λx. x = elt) l.
#A #elt #l elim l
[ 1: //
| 2: #hd #tl #Hind >filter_cons_unfold
     lapply (eqb_true A hd elt)
     cases (hd==elt) normalize nodelta
     [ 2: #_ #Habsurd destruct
     | 1: * #H1 #H2 #Heq lapply (Hind Heq) #Hall whd @conj //
          @H1 @refl
     ]
] qed.

lemma nil_append : ∀A. ∀(l : list A). [ ] @ l = l. // qed.

alias id "meml" = "cic:/matita/basics/lists/list/mem.fix(0,2,1)".

lemma mem_append : ∀A:Type[0]. ∀elt : A. ∀l1,l2. mem … elt (l1 @ l2) ↔ (mem … elt l1) ∨ (mem … elt l2).
#A #elt #l1 elim l1
[ 1: #l2 normalize @conj [ 1: #H %2 @H | 2: * [ 1: @False_ind | 2: #H @H ] ]
| 2: #hd #tl #Hind #l2 @conj
     [ 1: whd in match (meml ???); *
          [ 1: #Heq >Heq %1 normalize %1 @refl
          | 2: #H1 lapply (Hind l2) * #HA #HB normalize
               elim (HA H1)
               [ 1: #H %1 %2 assumption | 2: #H %2 assumption ]
          ]
     | 2: normalize *
          [ 1: * /2 by or_introl, or_intror/
               #H %2 elim (Hind l2) #_ #H' @H' %1 @H
          | 2: #H %2 elim (Hind l2) #_ #H' @H' %2 @H ]
     ]
] qed.

lemma mem_append_forward : ∀A:Type[0]. ∀elt : A. ∀l1,l2. mem … elt (l1 @ l2) → (mem … elt l1) ∨ (mem … elt l2).
#A #elt #l1 #l2 #H elim (mem_append … elt l1 l2) #H' #_ @H' @H qed.

lemma mem_append_backwards : ∀A:Type[0]. ∀elt : A. ∀l1,l2. (mem … elt l1) ∨ (mem … elt l2) → mem … elt (l1 @ l2) .
#A #elt #l1 #l2 #H elim (mem_append … elt l1 l2) #_ #H' @H' @H qed.

(* --------------------------------------------------------------------------- *)
(* Generic properties of equivalence relations *)
(* --------------------------------------------------------------------------- *)

lemma triangle_diagram :
  ∀acctype : Type[0].
  ∀eqrel : acctype → acctype → Prop.
  ∀refl_eqrel  : reflexive ? eqrel.
  ∀trans_eqrel : transitive ? eqrel.
  ∀sym_eqrel   : symmetric ? eqrel.
  ∀a,b,c. eqrel a b → eqrel a c → eqrel b c.
#acctype #eqrel #R #T #S #a #b #c
#H1 #H2 @(T … (S … H1) H2)
qed.

lemma cotriangle_diagram :
  ∀acctype : Type[0].
  ∀eqrel : acctype → acctype → Prop.
  ∀refl_eqrel  : reflexive ? eqrel.
  ∀trans_eqrel : transitive ? eqrel.
  ∀sym_eqrel   : symmetric ? eqrel.
  ∀a,b,c. eqrel b a → eqrel c a → eqrel b c.
#acctype #eqrel #R #T #S #a #b #c
#H1 #H2 @S @(T … H2 (S … H1))
qed.

(* --------------------------------------------------------------------------- *)
(* Quick and dirty implementation of finite sets relying on lists. The
 * implementation is split in two: an abstract equivalence defined using inclusion
 * of lists, and a concrete one where equivalence is defined as the closure of
 * duplication, contraction and transposition of elements. We rely on the latter
 * to prove stuff on folds over sets.  *)
(* --------------------------------------------------------------------------- *)

definition lset ≝ λA:Type[0]. list A.

(* The empty set. *)
definition empty_lset ≝ λA:Type[0]. nil A.

(* Standard operations. *)
definition lset_union ≝ λA:Type[0].λl1,l2 : lset A. l1 @ l2.

definition lset_remove ≝ λA:DeqSet.λl:lset (carr A).λelt:carr A. (filter … (λx.¬x==elt) l).

definition lset_difference ≝ λA:DeqSet.λl1,l2:lset (carr A). (filter … (λx.¬ (memb ? x l2)) l1).

(* Standard predicates on sets *)
definition lset_in ≝ λA:Type[0].λx : A. λl : lset A. mem … x l.

definition lset_disjoint ≝ λA:Type[0].λl1, l2 : lset A. 
  ∀x,y. mem … x l1 → mem … y l2 → x ≠ y.
  
definition lset_inclusion ≝ λA:Type[0].λl1,l2.
  All A (λx1. mem … x1 l2) l1.

(* Definition of abstract set equivalence. *)
definition lset_eq ≝ λA:Type[0].λl1,l2.
  lset_inclusion A l1 l2 ∧
  lset_inclusion A l2 l1.

(* Properties of inclusion. *)  
lemma reflexive_lset_inclusion : ∀A. ∀l. lset_inclusion A l l.
#A #l elim l try //
#hd #tl #Hind whd @conj
[ 1: %1 @refl
| 2: whd in Hind; @(All_mp … Hind)
     #a #H whd %2 @H
] qed.

lemma transitive_lset_inclusion : ∀A. ∀l1,l2,l3. lset_inclusion A l1 l2 → lset_inclusion A l2 l3 → lset_inclusion A l1 l3 .
#A #l1 #l2 #l3
#Hincl1 #Hincl2 @(All_mp … Hincl1)
whd in Hincl2;
#a elim l2 in Hincl2;
[ 1: normalize #_ @False_ind
| 2: #hd #tl #Hind whd in ⊢ (% → ?);
     * #Hmem #Hincl_tl whd in ⊢ (% → ?);
     * [ 1: #Heq destruct @Hmem
       | 2: #Hmem_tl @Hind assumption ]
] qed.

lemma cons_preserves_inclusion : ∀A. ∀l1,l2. lset_inclusion A l1 l2 → ∀x. lset_inclusion A l1 (x::l2).
#A #l1 #l2 #Hincl #x @(All_mp … Hincl) #a #Hmem whd %2 @Hmem qed.

lemma cons_monotonic_inclusion : ∀A. ∀l1,l2. lset_inclusion A l1 l2 → ∀x. lset_inclusion A (x::l1) (x::l2).
#A #l1 #l2 #Hincl #x whd @conj
[ 1: /2 by or_introl/
| 2: @(All_mp … Hincl) #a #Hmem whd %2 @Hmem ] qed.

lemma lset_inclusion_concat : ∀A. ∀l1,l2. lset_inclusion A l1 l2 → ∀l3. lset_inclusion A l1 (l3 @ l2).
#A #l1 #l2 #Hincl #l3 elim l3 
try /2 by cons_preserves_inclusion/
qed.

lemma lset_inclusion_concat_monotonic : ∀A. ∀l1,l2. lset_inclusion A l1 l2 → ∀l3. lset_inclusion A (l3 @ l1) (l3 @ l2).
#A #l1 #l2 #Hincl #l3 elim l3
try @Hincl #hd #tl #Hind @cons_monotonic_inclusion @Hind 
qed.
 
(* lset_eq is an equivalence relation. *)
lemma reflexive_lset_eq : ∀A. ∀l. lset_eq A l l. /2 by conj/ qed.

lemma transitive_lset_eq : ∀A. ∀l1,l2,l3. lset_eq A l1 l2 → lset_eq A l2 l3 → lset_eq A l1 l3.
#A #l1 #l2 #l3 * #Hincl1 #Hincl2 * #Hincl3 #Hincl4
@conj @(transitive_lset_inclusion ??l2) assumption
qed.

lemma symmetric_lset_eq : ∀A. ∀l1,l2. lset_eq A l1 l2 → lset_eq A l2 l1.
#A #l1 #l2 * #Hincl1 #Hincl2 @conj assumption
qed.

(* Properties of inclusion vs union and equality. *)
lemma lset_union_inclusion : ∀A:Type[0]. ∀a,b,c.  
  lset_inclusion A a c → lset_inclusion ? b c → lset_inclusion ? (lset_union ? a b) c.
#A #a #b #c #H1 #H2 whd whd in match (lset_union ???);
@All_append assumption qed.

lemma lset_inclusion_union : ∀A:Type[0]. ∀a,b,c.  
  lset_inclusion A a b ∨ lset_inclusion A a c → lset_inclusion ? a (lset_union ? b c).
#A #a #b #c *
[ 1: @All_mp #elt #Hmem @mem_append_backwards %1 @Hmem
| 2: @All_mp #elt #Hmem @mem_append_backwards %2 @Hmem
] qed.

lemma lset_inclusion_eq : ∀A : Type[0]. ∀a,b,c : lset A.
  lset_eq ? a b → lset_inclusion ? b c → lset_inclusion ? a c.
#A #a #b #c * #H1 #H2 #H3 @(transitive_lset_inclusion … H1 H3)
qed.

lemma lset_inclusion_eq2 : ∀A : Type[0]. ∀a,b,c : lset A.
  lset_eq ? b c → lset_inclusion ? a b → lset_inclusion ? a c.
#A #a #b #c * #H1 #H2 #H3 @(transitive_lset_inclusion … H3 H1)
qed.

(* Properties of lset_eq and mem *)
lemma lset_eq_mem :
  ∀A:Type[0].
  ∀s1,s2 : lset A.
  lset_eq ? s1 s2 →
  ∀b.mem ? b s1 → mem ? b s2.
#A #s1 #s2 * #Hincl12 #_ #b
whd in Hincl12; elim s1 in Hincl12;
[ 1: normalize #_ *
| 2: #hd #tl #Hind whd in ⊢ (% → % → ?); * #Hmem' #Hall * #Heq
     [ 1: destruct (Heq) assumption
     | 2: @Hind assumption ]
] qed.

lemma lset_eq_memb :
  ∀A : DeqSet.
  ∀s1,s2 : lset (carr A).
  lset_eq ? s1 s2 →
  ∀b.memb ? b s1 = true → memb ? b s2 = true.
#A #s1 #s2 #Heq #b
lapply (memb_to_mem A s1 b) #H1 #H2 
lapply (H1 H2) #Hmem lapply (lset_eq_mem … Heq ? Hmem) @mem_to_memb
qed.

lemma lset_eq_memb_eq :
  ∀A : DeqSet.
  ∀s1,s2 : lset (carr A).
  lset_eq ? s1 s2 →
  ∀b.memb ? b s1 = memb ? b s2.
#A #s1 #s2 #Hlset_eq #b
lapply (lset_eq_memb … Hlset_eq b)
lapply (lset_eq_memb … (symmetric_lset_eq … Hlset_eq) b)  
cases (b∈s1)
[ 1: #_ #H lapply (H (refl ??)) #Hmem >H @refl
| 2: cases (b∈s2) // #H lapply (H (refl ??)) #Habsurd destruct
] qed.

lemma lset_eq_filter_eq :
  ∀A : DeqSet.
  ∀s1,s2 : lset (carr A).
  lset_eq ? s1 s2 →  
  ∀l.
     (filter ? (λwb.¬wb∈s1) l) =
     (filter ? (λwb.¬wb∈s2) l).
#A #s1 #s2 #Heq #l elim l
[ 1: @refl
| 2: #hd #tl #Hind >filter_cons_unfold >filter_cons_unfold
      >(lset_eq_memb_eq … Heq) cases (hd∈s2)
      normalize in match (notb ?); normalize nodelta
      try @Hind >Hind @refl
] qed.

lemma cons_monotonic_eq : ∀A. ∀l1,l2 : lset A. lset_eq A l1 l2 → ∀x. lset_eq A (x::l1) (x::l2).
#A #l1 #l2 #Heq #x cases Heq #Hincl1 #Hincl2
@conj
[ 1: @cons_monotonic_inclusion
| 2: @cons_monotonic_inclusion ]
assumption
qed.

(* Properties of difference and remove *)
lemma lset_difference_unfold :
  ∀A : DeqSet.
  ∀s1, s2 : lset (carr A).
  ∀hd. lset_difference A (hd :: s1) s2 =
    if hd∈s2 then
      lset_difference A s1 s2
    else
      hd :: (lset_difference A s1 s2).
#A #s1 #s2 #hd normalize
cases (hd∈s2) @refl 
qed.

lemma lset_difference_unfold2 :
  ∀A : DeqSet.
  ∀s1, s2 : lset (carr A).
  ∀hd. lset_difference A s1 (hd :: s2) =
       lset_difference A (lset_remove ? s1 hd) s2.
#A #s1
elim s1
[ 1: //
| 2: #hd1 #tl1 #Hind #s2 #hd
     whd in match (lset_remove ???);
     whd in match (lset_difference A ??);
     whd in match (memb ???);
     lapply (eqb_true … hd1 hd)
     cases (hd1==hd) normalize nodelta
     [ 1: * #H #_ lapply (H (refl ??)) -H #H
           @Hind
     | 2: * #_ #Hguard >lset_difference_unfold
          cases (hd1∈s2) normalize in match (notb ?); normalize nodelta
          <Hind @refl ]
] qed.          

lemma lset_difference_disjoint :
 ∀A : DeqSet.
 ∀s1,s2 : lset (carr A).
  lset_disjoint A s1 (lset_difference A s2 s1).
#A #s1 elim s1
[ 1: #s2 normalize #x #y *
| 2: #hd1 #tl1 #Hind #s2 >lset_difference_unfold2 #x #y
     whd in ⊢ (% → ?); *
     [ 2: @Hind
     | 1: #Heq >Heq elim s2
          [ 1: normalize *
          | 2: #hd2 #tl2 #Hind2 whd in match (lset_remove ???);
               lapply (eqb_true … hd2 hd1)
               cases (hd2 == hd1) normalize in match (notb ?); normalize nodelta * #H1 #H2
               [ 1: @Hind2
               | 2: >lset_difference_unfold cases (hd2 ∈ tl1) normalize nodelta try @Hind2
                     whd in ⊢ (% → ?); *
                     [ 1: #Hyhd2 destruct % #Heq lapply (H2 … (sym_eq … Heq)) #Habsurd destruct
                     | 2: @Hind2 ]
               ]
          ]
    ]
] qed.


lemma lset_remove_split : ∀A : DeqSet. ∀l1,l2 : lset A. ∀elt. lset_remove A (l1 @ l2) elt = (lset_remove … l1 elt) @ (lset_remove … l2 elt).
#A #l1 #l2 #elt /2 by filter_append/ qed.

lemma lset_inclusion_remove : 
  ∀A : DeqSet.
  ∀s1, s2 : lset A.
  lset_inclusion ? s1 s2 → 
  ∀elt. lset_inclusion ? (lset_remove ? s1 elt) (lset_remove ? s2 elt).
#A #s1 elim s1
[ 1: normalize //
| 2: #hd1 #tl1 #Hind1 #s2 * #Hmem #Hincl
     elim (list_mem_split ??? Hmem) #s2A * #s2B #Hs2_eq destruct #elt
     whd in match (lset_remove ???);
     @(match (hd1 == elt)
       return λx. (hd1 == elt = x) → ?
       with
       [ true ⇒ λH. ?
       | false ⇒ λH. ? ] (refl ? (hd1 == elt))) normalize in match (notb ?);
     normalize nodelta
     [ 1:  @Hind1 @Hincl
     | 2: whd @conj
          [ 2: @(Hind1 … Hincl)
          | 1: >lset_remove_split >lset_remove_split
               normalize in match (lset_remove A [hd1] elt);
               >H normalize nodelta @mem_append_backwards %2
               @mem_append_backwards %1 normalize %1 @refl ]
     ]
] qed.

lemma lset_difference_lset_eq :
  ∀A : DeqSet. ∀a,b,c.
   lset_eq A b c →
   lset_eq A (lset_difference A a b) (lset_difference A a c).
#A #a #b #c #Heq
whd in match (lset_difference ???) in ⊢ (??%%);   
elim a
[ 1: normalize @conj @I
| 2: #hda #tla #Hind whd in match (foldr ?????) in ⊢ (??%%);
     >(lset_eq_memb_eq … Heq hda) cases (hda∈c)
     normalize in match (notb ?); normalize nodelta
     try @Hind @cons_monotonic_eq @Hind
] qed.

lemma lset_difference_lset_remove_commute :
  ∀A:DeqSet.
  ∀elt,s1,s2.
  (lset_difference A (lset_remove ? s1 elt) s2) =
  (lset_remove A (lset_difference ? s1 s2) elt).
#A #elt #s1 #s2
elim s1 try //
#hd #tl #Hind
>lset_difference_unfold
whd in match (lset_remove ???);
@(match (hd==elt) return λx. (hd==elt) = x → ?
  with
  [ true ⇒ λHhd. ?
  | false ⇒ λHhd. ?
  ] (refl ? (hd==elt)))
@(match (hd∈s2) return λx. (hd∈s2) = x → ?
  with
  [ true ⇒ λHmem. ?
  | false ⇒ λHmem. ?
  ] (refl ? (hd∈s2)))
>notb_true >notb_false normalize nodelta try //
try @Hind
[ 1:  whd in match (lset_remove ???) in ⊢ (???%); >Hhd
     elim (eqb_true ? elt elt) #_ #H >(H (refl ??))
     normalize in match (notb ?); normalize nodelta @Hind
| 2: >lset_difference_unfold >Hmem @Hind
| 3: whd in match (lset_remove ???) in ⊢ (???%);
     >lset_difference_unfold >Hhd >Hmem
     normalize in match (notb ?);
     normalize nodelta >Hind @refl
] qed.

(* Inversion lemma on emptyness *)
lemma lset_eq_empty_inv : ∀A. ∀l. lset_eq A l [ ] → l = [ ].
#A #l elim l //
#hd' #tl' normalize #Hind * * @False_ind
qed.

(* Inversion lemma on singletons *)
lemma lset_eq_singleton_inv : ∀A,hd,l. lset_eq A [hd] (hd::l) → All ? (λx.x=hd) l.
#A #hd #l
* #Hincl1 whd in ⊢ (% → ?); * #_ @All_mp
normalize #a * [ 1: #H @H | 2: @False_ind ]
qed.

(* Permutation of two elements on top of the list is ok. *)
lemma lset_eq_permute : ∀A,l,x1,x2. lset_eq A (x1 :: x2 :: l) (x2 :: x1 :: l).
#A #l #x1 #x2 @conj normalize
[ 1: /5 by cons_preserves_inclusion, All_mp, or_introl, or_intror, conj/
| 2: /5 by cons_preserves_inclusion, All_mp, or_introl, or_intror, conj/
] qed.

(* "contraction" of an element. *)
lemma lset_eq_contract : ∀A,l,x. lset_eq A (x :: x :: l) (x :: l).
#A #l #x @conj
[ 1: /5 by or_introl, conj, transitive_lset_inclusion/
| 2: /5 by cons_preserves_inclusion, cons_monotonic_inclusion/ ]
qed.

(* We don't need more than one instance of each element. *)
lemma lset_eq_filter : ∀A:DeqSet.∀tl.∀hd.
  lset_eq A (hd :: (filter ? (λy.notb (eqb A y hd)) tl)) (hd :: tl).
#A #tl elim tl
[ 1: #hd normalize /4 by or_introl, conj, I/
| 2: #hd' #tl' #Hind #hd >filter_cons_unfold
     lapply (eqb_true A hd' hd) cases (hd'==hd)
     [ 2: #_ normalize in match (notb ?); normalize nodelta
          lapply (cons_monotonic_eq … (Hind hd) hd') #H
          lapply (lset_eq_permute ? tl' hd' hd) #H'
          @(transitive_lset_eq ? ? (hd'::hd::tl') ? … H')
          @(transitive_lset_eq ? ?? (hd'::hd::tl') … H)
          @lset_eq_permute
     | 1: * #Heq #_ >(Heq (refl ??)) normalize in match (notb ?); normalize nodelta
          lapply (Hind hd) #H
          @(transitive_lset_eq ? ? (hd::tl') (hd::hd::tl') H)
          @conj
          [ 1: whd @conj /2 by or_introl/ @cons_preserves_inclusion @cons_preserves_inclusion
               @reflexive_lset_inclusion
          | 2: whd @conj /2 by or_introl/ ]
     ]
] qed.

lemma lset_inclusion_filter_self : 
  ∀A:DeqSet.∀l,pred.
    lset_inclusion A (filter ? pred l) l.
#A #l #pred elim l
[ 1: normalize @I
| 2: #hd #tl #Hind whd in match (filter ???);
     cases (pred hd) normalize nodelta
     [ 1: @cons_monotonic_inclusion @Hind
     | 2: @cons_preserves_inclusion @Hind ]
] qed.    

lemma lset_inclusion_filter_monotonic : 
  ∀A:DeqSet.∀l1,l2. lset_inclusion (carr A) l1 l2 → 
  ∀elt. lset_inclusion A (filter ? (λx.¬(x==elt)) l1) (filter ? (λx.¬(x==elt)) l2).
#A #l1 elim l1
[ 1: #l2 normalize //
| 2: #hd1 #tl1 #Hind #l2 whd in ⊢ (% → ?); * #Hmem1 #Htl1_incl #elt
     whd >filter_cons_unfold
     lapply (eqb_true A hd1 elt) cases (hd1==elt)
     [ 1: * #H1 #_ lapply (H1 (refl ??)) #H1_eq >H1_eq in Hmem1; #Hmem
          normalize in match (notb ?); normalize nodelta @Hind assumption
     | 2: * #_ #Hneq normalize in match (notb ?); normalize nodelta
          whd @conj
          [ 1: elim l2 in Hmem1; try //
               #hd2 #tl2 #Hincl whd in ⊢ (% → ?); *
               [ 1: #Heq >Heq in Hneq; normalize
                    lapply (eqb_true A hd2 elt) cases (hd2==elt)
                    [ 1: * #H #_ #H2 lapply (H2 (H (refl ??))) #Habsurd destruct (Habsurd)
                    | 2: #_ normalize nodelta #_ /2 by or_introl/ ]
               | 2: #H lapply (Hincl H) #Hok
                    normalize cases (hd2==elt) normalize nodelta 
                    [ 1: @Hok
                    | 2: %2 @Hok ] ]
          | 2: @Hind assumption ] ] ]
qed.

(* removing an element of two equivalent sets conserves equivalence. *)
lemma lset_eq_filter_monotonic : 
  ∀A:DeqSet.∀l1,l2. lset_eq (carr A) l1 l2 → 
  ∀elt. lset_eq A (filter ? (λx.¬(x==elt)) l1) (filter ? (λx.¬(x==elt)) l2).
#A #l1 #l2 * #Hincl1 #Hincl2 #elt @conj
/2 by lset_inclusion_filter_monotonic/
qed.

(* ---------------- Concrete implementation of sets --------------------- *)

(* We can give an explicit characterization of equivalent sets: they are permutations with repetitions, i,e.
   a composition of transpositions and duplications. We restrict ourselves to DeqSets. *)
inductive iso_step_lset (A : DeqSet) : lset A → lset A → Prop ≝
| lset_transpose : ∀a,x,b,y,c. iso_step_lset A (a @ [x] @ b @ [y] @ c) (a @ [y] @ b @ [x] @ c)
| lset_weaken : ∀a,x,b. iso_step_lset A (a @ [x] @ b) (a @ [x] @ [x] @ b)
| lset_contract : ∀a,x,b. iso_step_lset A (a @ [x] @ [x] @ b) (a @ [x] @ b).

(* The equivalence is the reflexive, transitive and symmetric closure of iso_step_lset *)
inductive lset_eq_concrete (A : DeqSet) : lset A → lset A → Prop ≝
| lset_trans : ∀a,b,c. iso_step_lset A a b → lset_eq_concrete A b c → lset_eq_concrete A a c
| lset_refl  : ∀a. lset_eq_concrete A a a.

(* lset_eq_concrete is symmetric and transitive *)
lemma transitive_lset_eq_concrete : ∀A,l1,l2,l3. lset_eq_concrete A l1 l2 → lset_eq_concrete A l2 l3 → lset_eq_concrete A l1 l3.
#A #l1 #l2 #l3 #Hequiv
elim Hequiv //
#a #b #c #Hstep #Hequiv #Hind #Hcl3 lapply (Hind Hcl3) #Hbl3
@(lset_trans ???? Hstep Hbl3)
qed.

lemma symmetric_step : ∀A,l1,l2. iso_step_lset A l1 l2 → iso_step_lset A l2 l1.
#A #l1 #l2 * /2/ qed.

lemma symmetric_lset_eq_concrete : ∀A,l1,l2. lset_eq_concrete A l1 l2 → lset_eq_concrete A l2 l1.
#A #l1 #l2 #H elim H //
#a #b #c #Hab #Hbc #Hcb 
@(transitive_lset_eq_concrete ???? Hcb ?)
@(lset_trans … (symmetric_step ??? Hab) (lset_refl …))
qed.
  
(* lset_eq_concrete is conserved by cons. *)
lemma equivalent_step_cons : ∀A,l1,l2. iso_step_lset A l1 l2 → ∀x. iso_step_lset A (x :: l1) (x :: l2).
#A #l1 #l2 * // qed. (* That // was impressive. *)

lemma lset_eq_concrete_cons : ∀A,l1,l2. lset_eq_concrete A l1 l2 → ∀x. lset_eq_concrete A (x :: l1) (x :: l2).
#A #l1 #l2 #Hequiv elim Hequiv try //
#a #b #c #Hab #Hbc #Hind #x %1{(equivalent_step_cons ??? Hab x) (Hind x)}
qed.

lemma absurd_list_eq_append : ∀A.∀x.∀l1,l2:list A. [ ] = l1 @ [x] @ l2 → False.
#A #x #l1 #l2 elim l1 normalize
[ 1: #Habsurd destruct
| 2: #hd #tl #_ #Habsurd destruct
] qed.

(* Inversion lemma for emptyness, step case *)
lemma equivalent_iso_step_empty_inv : ∀A,l. iso_step_lset A l [] → l = [ ].
#A #l elim l //
#hd #tl #Hind #H inversion H
[ 1: #a #x #b #y #c #_ #Habsurd
      @(False_ind … (absurd_list_eq_append ? y … Habsurd))
| 2: #a #x #b #_ #Habsurd
      @(False_ind … (absurd_list_eq_append ? x … Habsurd))
| 3: #a #x #b #_ #Habsurd
      @(False_ind … (absurd_list_eq_append ? x … Habsurd))
] qed.

(* Same thing for non-emptyness *)
lemma equivalent_iso_step_cons_inv : ∀A,l1,l2. l1 ≠ [ ] → iso_step_lset A l1 l2 → l2 ≠ [ ].
#A #l1 elim l1
[ 1: #l2 * #H @(False_ind … (H (refl ??)))
| 2: #hd #tl #H #l2 #_ #Hstep % #Hl2 >Hl2 in Hstep; #Hstep
     lapply (equivalent_iso_step_empty_inv … Hstep) #Habsurd destruct
] qed.

lemma lset_eq_concrete_cons_inv : ∀A,l1,l2. l1 ≠ [ ] → lset_eq_concrete A l1 l2 → l2 ≠ [ ].
#A #l1 #l2 #Hl1 #H lapply Hl1 elim H
[ 2: #a #H @H
| 1: #a #b #c #Hab #Hbc #H #Ha lapply (equivalent_iso_step_cons_inv … Ha Hab) #Hb @H @Hb
] qed.

lemma lset_eq_concrete_empty_inv : ∀A,l1,l2. l1 = [ ] → lset_eq_concrete A l1 l2 → l2 = [ ].
#A #l1 #l2 #Hl1 #H lapply Hl1 elim H //
#a #b #c #Hab #Hbc #Hbc_eq #Ha >Ha in Hab; #H_b lapply (equivalent_iso_step_empty_inv … ?? (symmetric_step … H_b))
#Hb @Hbc_eq @Hb
qed.

(* Square equivalence diagram *)
lemma square_lset_eq_concrete :
  ∀A. ∀a,b,a',b'. lset_eq_concrete A a b → lset_eq_concrete A a a' → lset_eq_concrete A b b' → lset_eq_concrete A a' b'.
#A #a #b #a' #b' #H1 #H2 #H3
@(transitive_lset_eq_concrete ???? (symmetric_lset_eq_concrete … H2))
@(transitive_lset_eq_concrete ???? H1)
@H3
qed.

(* Make the transposition of elements visible at top-level *)
lemma transpose_lset_eq_concrete : 
  ∀A. ∀x,y,a,b,c,a',b',c'.
  lset_eq_concrete A (a @ [x] @ b @ [y] @ c) (a' @ [x] @ b' @ [y] @ c') →
  lset_eq_concrete A (a @ [y] @ b @ [x] @ c) (a' @ [y] @ b' @ [x] @ c').
#A #x #y #a #b #c #a' #b' #c
#H @(square_lset_eq_concrete ????? H) /2 by lset_trans, lset_refl, lset_transpose/
qed.

lemma switch_lset_eq_concrete : 
  ∀A. ∀a,b,c. lset_eq_concrete A (a@[b]@c) ([b]@a@c).
#A #a elim a //
#hda #tla #Hind #b #c lapply (Hind hda c) #H
lapply (lset_eq_concrete_cons … H b)
#H' normalize in H' ⊢ %; @symmetric_lset_eq_concrete
/3 by lset_transpose, lset_trans, symmetric_lset_eq_concrete/
qed.

(* Folding a commutative and idempotent function on equivalent sets yields the same result. *)
lemma lset_eq_concrete_fold : 
  ∀A : DeqSet.
  ∀acctype : Type[0].
  ∀l1,l2 : list (carr A).
  lset_eq_concrete A l1 l2 →
  ∀f:carr A → acctype → acctype.
  (∀x1,x2. ∀acc. f x1 (f x2 acc) = f x2 (f x1 acc)) → 
  (∀x.∀acc. f x (f x acc) = f x acc) →
  ∀acc. foldr ?? f acc l1 = foldr ?? f acc l2.
#A #acctype #l1 #l2 #Heq #f #Hcomm #Hidem
elim Heq
try //
#a' #b' #c' #Hstep #Hbc #H #acc <H -H
elim Hstep
[ 1: #a #x #b #y #c
     >fold_append >fold_append >fold_append >fold_append
     >fold_append >fold_append >fold_append >fold_append
     normalize
     cut (f x (foldr A acctype f (f y (foldr A acctype f acc c)) b) =
          f y (foldr A acctype f (f x (foldr A acctype f acc c)) b)) [   
     elim c
     [ 1: normalize elim b
          [ 1: normalize >(Hcomm x y) @refl
          | 2: #hdb #tlb #Hind normalize
               >(Hcomm x hdb) >(Hcomm y hdb) >Hind @refl ]
     | 2: #hdc #tlc #Hind normalize elim b
          [ 1: normalize >(Hcomm x y) @refl
          | 2: #hdb #tlb #Hind normalize
               >(Hcomm x hdb) >(Hcomm y hdb) >Hind @refl ] ]
     ]
     #Hind >Hind @refl
| 2: #a #x #b
     >fold_append >fold_append >fold_append >(fold_append ?? ([x]@[x]))
     normalize >Hidem @refl
| 3: #a #x #b
     >fold_append  >(fold_append ?? ([x]@[x])) >fold_append >fold_append
     normalize >Hidem @refl
] qed.

(* Folding over equivalent sets yields equivalent results, for any equivalence. *)
lemma inj_to_fold_inj :
  ∀A,acctype : Type[0].
  ∀eqrel : acctype → acctype → Prop.
  ∀refl_eqrel  : reflexive ? eqrel.
  ∀trans_eqrel : transitive ? eqrel.
  ∀sym_eqrel   : symmetric ? eqrel.
  ∀f           : A → acctype → acctype.
  (∀x:A.∀acc1:acctype.∀acc2:acctype.eqrel acc1 acc2→eqrel (f x acc1) (f x acc2)) →
  ∀l : list A. ∀acc1, acc2 : acctype. eqrel acc1 acc2 → eqrel (foldr … f acc1 l) (foldr … f acc2 l).
#A #acctype #eqrel #R #T #S #f #Hinj #l elim l
//
#hd #tl #Hind #acc1 #acc2 #Heq normalize @Hinj @Hind @Heq
qed.

(* We need to extend the above proof to arbitrary equivalence relation instead of
   just standard equality. *)
lemma lset_eq_concrete_fold_ext : 
  ∀A : DeqSet.
  ∀acctype : Type[0].
  ∀eqrel : acctype → acctype → Prop.
  ∀refl_eqrel  : reflexive ? eqrel.
  ∀trans_eqrel : transitive ? eqrel.
  ∀sym_eqrel   : symmetric ? eqrel.
  ∀f:carr A → acctype → acctype.
  (∀x,acc1,acc2. eqrel acc1 acc2 → eqrel (f x acc1) (f x acc2)) →
  (∀x1,x2. ∀acc. eqrel (f x1 (f x2 acc)) (f x2 (f x1 acc))) → 
  (∀x.∀acc. eqrel (f x (f x acc)) (f x acc)) →
  ∀l1,l2 : list (carr A).
  lset_eq_concrete A l1 l2 →  
  ∀acc. eqrel (foldr ?? f acc l1) (foldr ?? f acc l2).
#A #acctype #eqrel #R #T #S #f #Hinj #Hcomm #Hidem #l1 #l2 #Heq
elim Heq
try //
#a' #b' #c' #Hstep #Hbc #H inversion Hstep
[ 1: #a #x #b #y #c #HlA #HlB #_ #acc
     >HlB in H; #H @(T … ? (H acc))
     >fold_append >fold_append >fold_append >fold_append
     >fold_append >fold_append >fold_append >fold_append
     normalize 
     cut (eqrel (f x (foldr ? acctype f (f y (foldr ? acctype f acc c)) b))
                (f y (foldr ? acctype f (f x (foldr ? acctype f acc c)) b))) 
     [ 1:
     elim c
     [ 1: normalize elim b
          [ 1: normalize @(Hcomm x y)
          | 2: #hdb #tlb #Hind normalize
               lapply (Hinj hdb ?? Hind) #Hind'
               lapply (T … Hind' (Hcomm ???)) #Hind''
               @S @(triangle_diagram ? eqrel R T S … Hind'') @Hcomm ]
     | 2: #hdc #tlc #Hind normalize elim b
          [ 1: normalize @(Hcomm x y)
          | 2: #hdb #tlb #Hind normalize
               lapply (Hinj hdb ?? Hind) #Hind'
               lapply (T … Hind' (Hcomm ???)) #Hind''
               @S @(triangle_diagram ? eqrel R T S … Hind'') @Hcomm ]
     ] ]
     #Hind @(inj_to_fold_inj … eqrel R T S ? Hinj … Hind)
| 2: #a #x #b #HeqA #HeqB #_ #acc >HeqB in H; #H @(T … (H acc))
     >fold_append >fold_append >fold_append >(fold_append ?? ([x]@[x]))
     normalize @(inj_to_fold_inj … eqrel R T S ? Hinj) @S @Hidem
| 3: #a #x #b #HeqA #HeqB #_ #acc >HeqB in H; #H @(T … (H acc))
     >fold_append >(fold_append ?? ([x]@[x])) >fold_append >fold_append
     normalize @(inj_to_fold_inj … eqrel R T S ? Hinj) @Hidem
] qed.

(* Prepare some well-founded induction principles on lists. The idea is to perform
   an induction on the sequence of filterees of a list : taking the first element,
   filtering it out of the tail, etc. We give such principles for pairs of lists
   and isolated lists.  *)

(* The two lists [l1,l2] share at least the head of l1. *)
definition head_shared ≝ λA. λl1,l2 : list A.
match l1 with
[ nil ⇒ l2 = (nil ?)
| cons hd _ ⇒  mem … hd l2
].

(* Relation on pairs of lists, as described above. *)
definition filtered_lists : ∀A:DeqSet. relation (list (carr A)×(list (carr A))) ≝
λA:DeqSet. λll1,ll2.
let 〈la1,lb1〉 ≝ ll1 in
let 〈la2,lb2〉 ≝ ll2 in
match la2 with
[ nil ⇒ False
| cons hda2 tla2 ⇒
    head_shared ? la2 lb2 ∧
    la1 = filter … (λx.¬(x==hda2)) tla2 ∧
    lb1 = filter … (λx.¬(x==hda2)) lb2
].

(* Notice the absence of plural : this relation works on a simple list, not a pair. *)
definition filtered_list : ∀A:DeqSet. relation (list (carr A)) ≝
λA:DeqSet. λl1,l2.
match l2 with
[ nil ⇒ False
| cons hd2 tl2 ⇒
    l1 = filter … (λx.¬(x==hd2)) l2
].

(* Relation on lists based on their lengths. We know this one is well-founded. *)
definition length_lt : ∀A:DeqSet. relation (list (carr A)) ≝
λA:DeqSet. λl1,l2. lt (length ? l1) (length ? l2).

(* length_lt can be extended on pairs by just measuring the first component *)
definition length_fst_lt : ∀A:DeqSet. relation (list (carr A) × (list (carr A))) ≝
λA:DeqSet. λll1,ll2. lt (length ? (\fst ll1)) (length ? (\fst ll2)).

lemma filter_length : ∀A. ∀l. ∀f. |filter A f l| ≤ |l|.
#A #l #f elim l //
#hd #tl #Hind whd in match (filter ???); cases (f hd) normalize nodelta
[ 1: /2 by le_S_S/
| 2: @le_S @Hind
] qed.

(* The order on lists defined by their length is wf *)
lemma length_lt_wf : ∀A. ∀l. WF (list (carr A)) (length_lt A) l.
#A #l % elim l
[ 1: #a normalize in ⊢ (% → ?); #H lapply (le_S_O_absurd ? H) @False_ind
| 2: #hd #tl #Hind #a #Hlt % #a' #Hlt' @Hind whd in Hlt Hlt'; whd
@(transitive_le … Hlt') @(monotonic_pred … Hlt)
qed.

(* Order on pairs of list by measuring the first proj *)
lemma length_fst_lt_wf : ∀A. ∀ll. WF ? (length_fst_lt A) ll.
#A * #l1 #l2 % elim l1
[ 1: * #a1 #a2 normalize in ⊢ (% → ?); #H lapply (le_S_O_absurd ? H) @False_ind
| 2: #hd1 #tl1 #Hind #a #Hlt % #a' #Hlt' @Hind whd in Hlt Hlt'; whd
@(transitive_le … Hlt') @(monotonic_pred … Hlt)
qed.

lemma length_to_filtered_lists : ∀A. subR ? (filtered_lists A) (length_fst_lt A).
#A whd * #a1 #a2 * #b1 #b2 elim b1
[ 1: @False_ind
| 2: #hd1 #tl1 #Hind whd in ⊢ (% → ?); * * #Hmem #Ha1 #Ha2 whd
     >Ha1 whd in match (length ??) in ⊢ (??%); @le_S_S @filter_length
] qed.

lemma length_to_filtered_list : ∀A. subR ? (filtered_list A) (length_lt A).
#A whd #a #b elim b
[ 1: @False_ind
| 2: #hd #tl #Hind whd in ⊢ (% → ?); whd in match (filter ???);
     lapply (eqb_true ? hd hd) * #_ #H >(H (refl ??)) normalize in match (notb ?);
     normalize nodelta #Ha whd @le_S_S >Ha @filter_length ]
qed.

(* Prove well-foundedness by embedding in lt *)
lemma filtered_lists_wf : ∀A. ∀ll. WF ? (filtered_lists A) ll.
#A #ll @(WF_antimonotonic … (length_to_filtered_lists A)) @length_fst_lt_wf
qed.

lemma filtered_list_wf : ∀A. ∀l. WF ? (filtered_list A) l.
#A #l @(WF_antimonotonic … (length_to_filtered_list A)) @length_lt_wf
qed.

definition Acc_elim : ∀A,R,x. WF A R x → (∀a. R a x → WF A R a) ≝
λA,R,x,acc.
match acc with
[ wf _ a0 ⇒ a0 ].

(* Stolen from Coq. Warped to avoid prop-to-type restriction. *)
let rec WF_rect
  (A : Type[0])
  (R : A → A → Prop)
  (P : A → Type[0])
  (f : ∀ x : A.
       (∀ y : A. R y x → WF ? R y) →
       (∀ y : A. R y x → P y) → P x)
  (x : A)
  (a : WF A R x) on a : P x ≝
f x (Acc_elim … a) (λy:A. λRel:R y x. WF_rect A R P f y ((Acc_elim … a) y Rel)).

lemma lset_eq_concrete_filter : ∀A:DeqSet.∀tl.∀hd.
  lset_eq_concrete A (hd :: (filter ? (λy.notb (eqb A y hd)) tl)) (hd :: tl).
#A #tl elim tl
[ 1: #hd //
| 2: #hd' #tl' #Hind #hd >filter_cons_unfold 
     lapply (eqb_true A hd' hd)
     cases (hd'==hd)
     [ 2: #_ normalize in match (notb false); normalize nodelta
          >cons_to_append >(cons_to_append … hd')
          >cons_to_append in ⊢ (???%); >(cons_to_append … hd') in ⊢ (???%);
          @(transpose_lset_eq_concrete ? hd' hd [ ] [ ] (filter A (λy:A.¬y==hd) tl') [ ] [ ] tl')
          >nil_append >nil_append >nil_append >nil_append
          @lset_eq_concrete_cons >nil_append >nil_append
          @Hind
    | 1: * #H1 #_ lapply (H1 (refl ??)) #Heq normalize in match (notb ?); normalize nodelta
         >Heq >cons_to_append >cons_to_append in ⊢ (???%); >cons_to_append in ⊢ (???(???%));
         @(square_lset_eq_concrete A ([hd]@filter A (λy:A.¬y==hd) tl') ([hd]@tl'))
         [ 1: @Hind
         | 2: %2
         | 3: %1{???? ? (lset_refl ??)} /2 by lset_weaken/ ]
    ]
] qed.


(* The "abstract", observational definition of set equivalence implies the concrete one. *)

lemma lset_eq_to_lset_eq_concrete_aux : 
  ∀A,ll.
    head_shared … (\fst ll) (\snd ll) →
    lset_eq (carr A) (\fst ll) (\snd ll) → 
    lset_eq_concrete A (\fst ll) (\snd ll).
#A #ll @(WF_ind ????? (filtered_lists_wf A ll))
* *
[ 1: #b2 #Hwf #Hind_wf whd in ⊢ (% → ?); #Hb2 >Hb2 #_ %2
| 2: #hd1 #tl1 #b2 #Hwf #Hind_wf whd in ⊢ (% → ?); #Hmem
     lapply (list_mem_split ??? Hmem) * #l2A * #l2B #Hb2 #Heq
     destruct
     lapply (Hind_wf 〈filter … (λx.¬x==hd1) tl1,filter … (λx.¬x==hd1) (l2A@l2B)〉)
     cut (filtered_lists A 〈filter A (λx:A.¬x==hd1) tl1,filter A (λx:A.¬x==hd1) (l2A@l2B)〉 〈hd1::tl1,l2A@[hd1]@l2B〉)
     [ @conj try @conj try @refl whd 
       [ 1: /2 by /
       | 2: >filter_append in ⊢ (???%); >filter_append in ⊢ (???%);
            whd in match (filter ?? [hd1]);
            elim (eqb_true A hd1 hd1) #_ #H >(H (refl ??)) normalize in match (notb ?);
            normalize nodelta <filter_append @refl ] ]
     #Hfiltered #Hind_aux lapply (Hind_aux Hfiltered) -Hind_aux
     cut (lset_eq A (filter A (λx:A.¬x==hd1) tl1) (filter A (λx:A.¬x==hd1) (l2A@l2B)))
     [ 1: lapply (lset_eq_filter_monotonic … Heq hd1)
          >filter_cons_unfold >filter_append >(filter_append … [hd1])
          whd in match (filter ?? [hd1]);
          elim (eqb_true A hd1 hd1) #_ #H >(H (refl ??)) normalize in match (notb ?);
          normalize nodelta <filter_append #Hsol @Hsol ]
     #Hset_eq
     cut (head_shared A (filter A (λx:A.¬x==hd1) tl1) (filter A (λx:A.¬x==hd1) (l2A@l2B)))
     [ 1: lapply Hset_eq cases (filter A (λx:A.¬x==hd1) tl1)
          [ 1: whd in ⊢ (% → ?); * #_ elim (filter A (λx:A.¬x==hd1) (l2A@l2B)) //
               #hd' #tl' normalize #Hind * @False_ind
          | 2: #hd' #tl' * #Hincl1 #Hincl2 whd elim Hincl1 #Hsol #_ @Hsol ] ]
     #Hshared #Hind_aux lapply (Hind_aux Hshared Hset_eq)
     #Hconcrete_set_eq
     >cons_to_append
     @(transitive_lset_eq_concrete ? ([hd1]@tl1) ([hd1]@l2A@l2B) (l2A@[hd1]@l2B))
     [ 2: @symmetric_lset_eq_concrete @switch_lset_eq_concrete ]
     lapply (lset_eq_concrete_cons … Hconcrete_set_eq hd1) #Hconcrete_cons_eq
     @(square_lset_eq_concrete … Hconcrete_cons_eq)
     [ 1: @(lset_eq_concrete_filter ? tl1 hd1)
     | 2: @(lset_eq_concrete_filter ? (l2A@l2B) hd1) ]
] qed.

lemma lset_eq_to_lset_eq_concrete : ∀A,l1,l2. lset_eq (carr A) l1 l2 → lset_eq_concrete A l1 l2.
#A *
[ 1: #l2 #Heq >(lset_eq_empty_inv … (symmetric_lset_eq … Heq)) //
| 2: #hd1 #tl1 #l2 #Hincl lapply Hincl lapply (lset_eq_to_lset_eq_concrete_aux ? 〈hd1::tl1,l2〉) #H @H 
     whd elim Hincl * //
] qed.


(* The concrete one implies the abstract one. *)
lemma lset_eq_concrete_to_lset_eq : ∀A,l1,l2. lset_eq_concrete A l1 l2 → lset_eq A l1 l2.
#A #l1 #l2 #Hconcrete
elim Hconcrete try //
#a #b #c #Hstep #Heq_bc_concrete #Heq_bc
cut (lset_eq A a b)
[ 1: elim Hstep
     [ 1: #a' elim a'
          [ 2: #hda #tla #Hind #x #b' #y #c' >cons_to_append
               >(associative_append ? [hda] tla ?)
               >(associative_append ? [hda] tla ?)
               @cons_monotonic_eq >nil_append >nil_append @Hind
          | 1: #x #b' #y #c' >nil_append >nil_append
               elim b' try //
               #hdb #tlc #Hind >append_cons >append_cons in ⊢ (???%);
               >associative_append >associative_append
               lapply (cons_monotonic_eq … Hind hdb) #Hind'                
               @(transitive_lset_eq ? ([x]@[hdb]@tlc@[y]@c') ([hdb]@[x]@tlc@[y]@c'))
               /2 by transitive_lset_eq/ ]
     | 2: #a' elim a'
          [ 2: #hda #tla #Hind #x #b' >cons_to_append
               >(associative_append ? [hda] tla ?)
               >(associative_append ? [hda] tla ?)
               @cons_monotonic_eq >nil_append >nil_append @Hind
          | 1: #x #b' >nil_append >nil_append @conj normalize
               [ 1: @conj [ 1: %1 @refl ] elim b'
                    [ 1: @I
                    | 2: #hdb #tlb #Hind normalize @conj
                         [ 1: %2 %2 %1 @refl
                         | 2: @(All_mp … Hind) #a0 *
                              [ 1: #Heq %1 @Heq
                              | 2: * /2 by or_introl, or_intror/ ] ] ]
                    #H %2 %2 %2 @H
               | 2: @conj try @conj try /2 by or_introl, or_intror/ elim b'
                    [ 1: @I
                    | 2: #hdb #tlb #Hind normalize @conj
                         [ 1: %2 %1 @refl
                         | 2: @(All_mp … Hind) #a0 *
                              [ 1: #Heq %1 @Heq
                              | 2: #H %2 %2 @H ] ] ] ] ]
     | 3: #a #x #b elim a try @lset_eq_contract
          #hda #tla #Hind @cons_monotonic_eq @Hind ] ]
#Heq_ab @(transitive_lset_eq … Heq_ab Heq_bc)
qed.

lemma lset_eq_fold :
  ∀A : DeqSet.
  ∀acctype : Type[0].
  ∀eqrel : acctype → acctype → Prop.
  ∀refl_eqrel  : reflexive ? eqrel.
  ∀trans_eqrel : transitive ? eqrel.
  ∀sym_eqrel   : symmetric ? eqrel.
  ∀f:carr A → acctype → acctype.
  (∀x,acc1,acc2. eqrel acc1 acc2 → eqrel (f x acc1) (f x acc2)) →
  (∀x1,x2. ∀acc. eqrel (f x1 (f x2 acc)) (f x2 (f x1 acc))) → 
  (∀x.∀acc. eqrel (f x (f x acc)) (f x acc)) →
  ∀l1,l2 : list (carr A).
  lset_eq A l1 l2 →  
  ∀acc. eqrel (foldr ?? f acc l1) (foldr ?? f acc l2).
#A #acctype #eqrel #refl_eqrel #trans_eqrel #sym_eqrel #f #Hinj #Hsym #Hcontract #l1 #l2 #Heq #acc
lapply (lset_eq_to_lset_eq_concrete … Heq) #Heq_concrete 
@(lset_eq_concrete_fold_ext A acctype eqrel refl_eqrel trans_eqrel sym_eqrel f Hinj Hsym Hcontract l1 l2 Heq_concrete acc)
qed.