source: src/ASM/Interpret.ma @ 1666

Last change on this file since 1666 was 1666, checked in by sacerdot, 6 years ago

PreStatus? datatype change: the code_memory field is not a left parameter.
This greatly simplify the dependent type madness due to policy depending
on the code_memory and not really on the status. On the other hand it
makes the rest of the code uglier.

Note: the changes have not been propagated yet to ASMCosts, CostsProof? and
Interpret2. The AssemlyProof? is almost repaired.

File size: 33.8 KB
Line 
1include "ASM/StatusProofs.ma".
2include "ASM/Fetch.ma".
3
4definition sign_extension: Byte → Word ≝
5  λc.
6    let b ≝ get_index_v ? 8 c 1 ? in
7      [[ b; b; b; b; b; b; b; b ]] @@ c.
8  normalize;
9  repeat (@ (le_S_S ?));
10  @ (le_O_n);
11qed.
12   
13lemma eq_a_to_eq: ∀a,b. eq_a a b = true → a=b.
14 # a
15 # b
16 cases a
17 cases b
18 normalize
19 # K
20 try %
21 cases (eq_true_false K)
22qed.
23
24lemma is_a_to_mem_to_is_in:
25 ∀he,a,m,q. is_a he … a = true → mem … eq_a (S m) q he = true → is_in … q a = true.
26 # he
27 # a
28 # m
29 # q
30 elim q
31 [ normalize
32   # _
33   # K
34   assumption
35 | # m'
36   # t
37   # q'
38   # II
39   # H1
40   # H2
41   normalize
42   change with (orb ??) in H2: (??%?);
43   cases (inclusive_disjunction_true … H2)
44   [ # K
45     < (eq_a_to_eq … K)
46     > H1
47     %
48   | # K
49     > II
50     try assumption
51     cases (is_a t a)
52     normalize
53     %
54   ]
55 ]
56qed.
57
58lemma execute_1_technical:
59  ∀n, m: nat.
60  ∀v: Vector addressing_mode_tag (S n).
61  ∀q: Vector addressing_mode_tag (S m).
62  ∀a: addressing_mode.
63    bool_to_Prop (is_in ? v a) →
64    bool_to_Prop (subvector_with ? ? ? eq_a v q) →
65    bool_to_Prop (is_in ? q a).
66 # n
67 # m
68 # v
69 # q
70 # a
71 elim v
72 [ normalize
73   # K
74   cases K
75 | # n'
76   # he
77   # tl
78   # II
79   whd in ⊢ (% → ? → ?);
80   lapply (refl … (is_in … (he:::tl) a))
81   cases (is_in … (he:::tl) a) in ⊢ (???% → %);
82   [ # K
83     # _
84     normalize in K;
85     whd in ⊢ (% → ?);
86     lapply (refl … (subvector_with … eq_a (he:::tl) q));
87     cases (subvector_with … eq_a (he:::tl) q) in ⊢ (???% → %);
88     [ # K1
89       # _
90       change with ((andb ? (subvector_with …)) = true) in K1;
91       cases (conjunction_true … K1)
92       # K3
93       # K4
94       cases (inclusive_disjunction_true … K)
95       # K2
96       [ > (is_a_to_mem_to_is_in … K2 K3)
97         %
98       | @ II
99         [ > K2
100           %
101         | > K4
102           %
103         ]
104       ]
105     | # K1
106       # K2
107       normalize in K2;
108       cases K2;
109     ]
110   | # K1
111     # K2
112     normalize in K2;
113     cases K2
114   ]
115 ]
116qed.
117
118include alias "arithmetics/nat.ma".
119include alias "ASM/BitVectorTrie.ma".
120
121definition execute_1_preinstruction':
122  ∀ticks: nat × nat.
123  ∀a, m: Type[0]. ∀cm. (a → PreStatus m cm → Word) → preinstruction a →
124  ∀s: PreStatus m cm.
125    Σs': PreStatus m cm.
126      Or (clock ?? s' = \fst ticks + clock … s) (clock ?? s' = \snd ticks + clock … s) ≝
127  λticks: nat × nat.
128  λa, m: Type[0]. λcm.
129  λaddr_of: a → PreStatus m cm → Word.
130  λinstr: preinstruction a.
131  λs: PreStatus m cm.
132  let add_ticks1 ≝ λs: PreStatus m cm. set_clock ?? s (\fst ticks + clock ?? s) in
133  let add_ticks2 ≝ λs: PreStatus m cm. set_clock ?? s (\snd ticks + clock ?? s) in
134  match instr in preinstruction return λx. Σs': PreStatus m cm. Or (clock ?? s' = \fst ticks + clock ?? s) (clock ?? s' = \snd ticks + clock ?? s) with
135        [ ADD addr1 addr2 ⇒
136            let s ≝ add_ticks1 s in
137            let 〈result, flags〉 ≝ add_8_with_carry (get_arg_8 … s false addr1)
138                                                   (get_arg_8 … s false addr2) false in
139            let cy_flag ≝ get_index' ? O  ? flags in
140            let ac_flag ≝ get_index' ? 1 ? flags in
141            let ov_flag ≝ get_index' ? 2 ? flags in
142            let s ≝ set_arg_8 … s ACC_A result in
143              set_flags … s cy_flag (Some Bit ac_flag) ov_flag
144        | ADDC addr1 addr2 ⇒
145            let s ≝ add_ticks1 s in
146            let old_cy_flag ≝ get_cy_flag ?? s in
147            let 〈result, flags〉 ≝ add_8_with_carry (get_arg_8 … s false addr1)
148                                                   (get_arg_8 … s false addr2) old_cy_flag in
149            let cy_flag ≝ get_index' ? O ? flags in
150            let ac_flag ≝ get_index' ? 1 ? flags in
151            let ov_flag ≝ get_index' ? 2 ? flags in
152            let s ≝ set_arg_8 … s ACC_A result in
153              set_flags … s cy_flag (Some Bit ac_flag) ov_flag
154        | SUBB addr1 addr2 ⇒
155            let s ≝ add_ticks1 s in
156            let old_cy_flag ≝ get_cy_flag ?? s in
157            let 〈result, flags〉 ≝ sub_8_with_carry (get_arg_8 … s false addr1)
158                                                   (get_arg_8 … s false addr2) old_cy_flag in
159            let cy_flag ≝ get_index' ? O ? flags in
160            let ac_flag ≝ get_index' ? 1 ? flags in
161            let ov_flag ≝ get_index' ? 2 ? flags in
162            let s ≝ set_arg_8 … s ACC_A result in
163              set_flags … s cy_flag (Some Bit ac_flag) ov_flag
164        | ANL addr ⇒
165          let s ≝ add_ticks1 s in
166          match addr with
167            [ inl l ⇒
168              match l with
169                [ inl l' ⇒
170                  let 〈addr1, addr2〉 ≝ l' in
171                  let and_val ≝ conjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
172                    set_arg_8 … s addr1 and_val
173                | inr r ⇒
174                  let 〈addr1, addr2〉 ≝ r in
175                  let and_val ≝ conjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
176                    set_arg_8 … s addr1 and_val
177                ]
178            | inr r ⇒
179              let 〈addr1, addr2〉 ≝ r in
180              let and_val ≝ andb (get_cy_flag … s) (get_arg_1 … s addr2 true) in
181               set_flags … s and_val (None ?) (get_ov_flag ?? s)
182            ]
183        | ORL addr ⇒
184          let s ≝ add_ticks1 s in
185          match addr with
186            [ inl l ⇒
187              match l with
188                [ inl l' ⇒
189                  let 〈addr1, addr2〉 ≝ l' in
190                  let or_val ≝ inclusive_disjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
191                    set_arg_8 … s addr1 or_val
192                | inr r ⇒
193                  let 〈addr1, addr2〉 ≝ r in
194                  let or_val ≝ inclusive_disjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
195                    set_arg_8 … s addr1 or_val
196                ]
197            | inr r ⇒
198              let 〈addr1, addr2〉 ≝ r in
199              let or_val ≝ (get_cy_flag … s) ∨ (get_arg_1 … s addr2 true) in
200               set_flags … s or_val (None ?) (get_ov_flag … s)
201            ]
202        | XRL addr ⇒
203          let s ≝ add_ticks1 s in
204          match addr with
205            [ inl l' ⇒
206              let 〈addr1, addr2〉 ≝ l' in
207              let xor_val ≝ exclusive_disjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
208                set_arg_8 … s addr1 xor_val
209            | inr r ⇒
210              let 〈addr1, addr2〉 ≝ r in
211              let xor_val ≝ exclusive_disjunction_bv ? (get_arg_8 … s true addr1) (get_arg_8 … s true addr2) in
212                set_arg_8 … s addr1 xor_val
213            ]
214        | INC addr ⇒
215            match addr return λx. bool_to_Prop (is_in … [[ acc_a;registr;direct;indirect;dptr ]] x) → Σs': PreStatus m cm. Or (clock ?? s' = \fst ticks + clock … s) (clock ?? s' = \snd ticks + clock … s) with
216              [ ACC_A ⇒ λacc_a: True.
217                let s' ≝ add_ticks1 s in
218                let 〈 carry, result 〉 ≝ half_add ? (get_arg_8 … s' true ACC_A) (bitvector_of_nat 8 1) in
219                 set_arg_8 … s' ACC_A result
220              | REGISTER r ⇒ λregister: True.
221                let s' ≝ add_ticks1 s in
222                let 〈 carry, result 〉 ≝ half_add ? (get_arg_8 … s' true (REGISTER r)) (bitvector_of_nat 8 1) in
223                 set_arg_8 … s' (REGISTER r) result
224              | DIRECT d ⇒ λdirect: True.
225                let s' ≝ add_ticks1 s in
226                let 〈 carry, result 〉 ≝ half_add ? (get_arg_8 … s' true (DIRECT d)) (bitvector_of_nat 8 1) in
227                 set_arg_8 … s' (DIRECT d) result
228              | INDIRECT i ⇒ λindirect: True.
229                let s' ≝ add_ticks1 s in
230                let 〈 carry, result 〉 ≝ half_add ? (get_arg_8 … s' true (INDIRECT i)) (bitvector_of_nat 8 1) in
231                 set_arg_8 … s' (INDIRECT i) result
232              | DPTR ⇒ λdptr: True.
233                let s' ≝ add_ticks1 s in
234                let 〈 carry, bl 〉 ≝ half_add ? (get_8051_sfr … s' SFR_DPL) (bitvector_of_nat 8 1) in
235                let 〈 carry, bu 〉 ≝ full_add ? (get_8051_sfr … s' SFR_DPH) (zero 8) carry in
236                let s ≝ set_8051_sfr … s' SFR_DPL bl in
237                 set_8051_sfr … s' SFR_DPH bu
238              | _ ⇒ λother: False. ⊥
239              ] (subaddressing_modein … addr)
240        | NOP ⇒
241           let s ≝ add_ticks2 s in
242            s
243        | DEC addr ⇒
244           let s ≝ add_ticks1 s in
245           let 〈 result, flags 〉 ≝ sub_8_with_carry (get_arg_8 … s true addr) (bitvector_of_nat 8 1) false in
246             set_arg_8 … s addr result
247        | MUL addr1 addr2 ⇒
248           let s ≝ add_ticks1 s in
249           let acc_a_nat ≝ nat_of_bitvector 8 (get_8051_sfr … s SFR_ACC_A) in
250           let acc_b_nat ≝ nat_of_bitvector 8 (get_8051_sfr … s SFR_ACC_B) in
251           let product ≝ acc_a_nat * acc_b_nat in
252           let ov_flag ≝ product ≥ 256 in
253           let low ≝ bitvector_of_nat 8 (product mod 256) in
254           let high ≝ bitvector_of_nat 8 (product ÷ 256) in
255           let s ≝ set_8051_sfr … s SFR_ACC_A low in
256             set_8051_sfr … s SFR_ACC_B high
257        | DIV addr1 addr2 ⇒
258           let s ≝ add_ticks1 s in
259           let acc_a_nat ≝ nat_of_bitvector 8 (get_8051_sfr … s SFR_ACC_A) in
260           let acc_b_nat ≝ nat_of_bitvector 8 (get_8051_sfr … s SFR_ACC_B) in
261             match acc_b_nat with
262               [ O ⇒ set_flags … s false (None Bit) true
263               | S o ⇒
264                 let q ≝ bitvector_of_nat 8 (acc_a_nat ÷ (S o)) in
265                 let r ≝ bitvector_of_nat 8 (acc_a_nat mod 256) in
266                 let s ≝ set_8051_sfr … s SFR_ACC_A q in
267                 let s ≝ set_8051_sfr … s SFR_ACC_B r in
268                   set_flags … s false (None Bit) false
269               ]
270        | DA addr ⇒
271            let s ≝ add_ticks1 s in
272            let 〈acc_nu, acc_nl〉 ≝ split ? 4 4 (get_8051_sfr … s SFR_ACC_A) in
273              if (gtb (nat_of_bitvector ? acc_nl) 9) ∨ (get_ac_flag … s) then
274                let 〈result, flags〉 ≝ add_8_with_carry (get_8051_sfr … s SFR_ACC_A) (bitvector_of_nat 8 6) false in
275                let cy_flag ≝ get_index' ? O ? flags in
276                let 〈acc_nu', acc_nl'〉 ≝ split ? 4 4 result in
277                  if (gtb (nat_of_bitvector ? acc_nu') 9) ∨ cy_flag then
278                    let 〈 carry, nu 〉 ≝ half_add ? acc_nu' (bitvector_of_nat 4 6) in
279                    let new_acc ≝ nu @@ acc_nl' in
280                    let s ≝ set_8051_sfr … s SFR_ACC_A new_acc in
281                      set_flags … s cy_flag (Some ? (get_ac_flag … s)) (get_ov_flag … s)
282                  else
283                    s
284              else
285                s
286        | CLR addr ⇒
287          match addr return λx. bool_to_Prop (is_in … [[ acc_a; carry; bit_addr ]] x) → Σs': PreStatus m cm. Or (clock ?? s' = \fst ticks + clock … s) (clock ?? s' = \snd ticks + clock … s) with
288            [ ACC_A ⇒ λacc_a: True.
289              let s ≝ add_ticks1 s in
290               set_arg_8 … s ACC_A (zero 8)
291            | CARRY ⇒ λcarry: True.
292              let s ≝ add_ticks1 s in
293               set_arg_1 … s CARRY false
294            | BIT_ADDR b ⇒ λbit_addr: True.
295              let s ≝ add_ticks1 s in
296               set_arg_1 … s (BIT_ADDR b) false
297            | _ ⇒ λother: False. ⊥
298            ] (subaddressing_modein … addr)
299        | CPL addr ⇒
300          match addr return λx. bool_to_Prop (is_in … [[ acc_a; carry; bit_addr ]] x) → Σs': PreStatus m cm. Or (clock ?? s' = \fst ticks + clock … s) (clock ?? s' = \snd ticks + clock … s) with
301            [ ACC_A ⇒ λacc_a: True.
302                let s ≝ add_ticks1 s in
303                let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
304                let new_acc ≝ negation_bv ? old_acc in
305                 set_8051_sfr … s SFR_ACC_A new_acc
306            | CARRY ⇒ λcarry: True.
307                let s ≝ add_ticks1 s in
308                let old_cy_flag ≝ get_arg_1 … s CARRY true in
309                let new_cy_flag ≝ ¬old_cy_flag in
310                 set_arg_1 … s CARRY new_cy_flag
311            | BIT_ADDR b ⇒ λbit_addr: True.
312                let s ≝ add_ticks1 s in
313                let old_bit ≝ get_arg_1 … s (BIT_ADDR b) true in
314                let new_bit ≝ ¬old_bit in
315                 set_arg_1 … s (BIT_ADDR b) new_bit
316            | _ ⇒ λother: False. ?
317            ] (subaddressing_modein … addr)
318        | SETB b ⇒
319            let s ≝ add_ticks1 s in
320            set_arg_1 … s b false
321        | RL _ ⇒ (* DPM: always ACC_A *)
322            let s ≝ add_ticks1 s in
323            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
324            let new_acc ≝ rotate_left … 1 old_acc in
325              set_8051_sfr … s SFR_ACC_A new_acc
326        | RR _ ⇒ (* DPM: always ACC_A *)
327            let s ≝ add_ticks1 s in
328            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
329            let new_acc ≝ rotate_right … 1 old_acc in
330              set_8051_sfr … s SFR_ACC_A new_acc
331        | RLC _ ⇒ (* DPM: always ACC_A *)
332            let s ≝ add_ticks1 s in
333            let old_cy_flag ≝ get_cy_flag ?? s in
334            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
335            let new_cy_flag ≝ get_index' ? O ? old_acc in
336            let new_acc ≝ shift_left … 1 old_acc old_cy_flag in
337            let s ≝ set_arg_1 … s CARRY new_cy_flag in
338              set_8051_sfr … s SFR_ACC_A new_acc
339        | RRC _ ⇒ (* DPM: always ACC_A *)
340            let s ≝ add_ticks1 s in
341            let old_cy_flag ≝ get_cy_flag ?? s in
342            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
343            let new_cy_flag ≝ get_index' ? 7 ? old_acc in
344            let new_acc ≝ shift_right … 1 old_acc old_cy_flag in
345            let s ≝ set_arg_1 … s CARRY new_cy_flag in
346              set_8051_sfr … s SFR_ACC_A new_acc
347        | SWAP _ ⇒ (* DPM: always ACC_A *)
348            let s ≝ add_ticks1 s in
349            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
350            let 〈nu,nl〉 ≝ split ? 4 4 old_acc in
351            let new_acc ≝ nl @@ nu in
352              set_8051_sfr … s SFR_ACC_A new_acc
353        | PUSH addr ⇒
354            match addr return λx. bool_to_Prop (is_in … [[ direct ]] x) → Σs': PreStatus m cm. Or (clock ?? s' = \fst ticks + clock … s) (clock ?? s' = \snd ticks + clock … s) with
355              [ DIRECT d ⇒ λdirect: True.
356                let s ≝ add_ticks1 s in
357                let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
358                let s ≝ set_8051_sfr … s SFR_SP new_sp in
359                  write_at_stack_pointer … s d
360              | _ ⇒ λother: False. ⊥
361              ] (subaddressing_modein … addr)
362        | POP addr ⇒
363            let s ≝ add_ticks1 s in
364            let contents ≝ read_at_stack_pointer ?? s in
365            let 〈new_sp, flags〉 ≝ sub_8_with_carry (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) false in
366            let s ≝ set_8051_sfr … s SFR_SP new_sp in
367              set_arg_8 … s addr contents
368        | XCH addr1 addr2 ⇒
369            let s ≝ add_ticks1 s in
370            let old_addr ≝ get_arg_8 … s false addr2 in
371            let old_acc ≝ get_8051_sfr … s SFR_ACC_A in
372            let s ≝ set_8051_sfr … s SFR_ACC_A old_addr in
373              set_arg_8 … s addr2 old_acc
374        | XCHD addr1 addr2 ⇒
375            let s ≝ add_ticks1 s in
376            let 〈acc_nu, acc_nl〉 ≝ split … 4 4 (get_8051_sfr … s SFR_ACC_A) in
377            let 〈arg_nu, arg_nl〉 ≝ split … 4 4 (get_arg_8 … s false addr2) in
378            let new_acc ≝ acc_nu @@ arg_nl in
379            let new_arg ≝ arg_nu @@ acc_nl in
380            let s ≝ set_8051_sfr … s SFR_ACC_A new_acc in
381              set_arg_8 … s addr2 new_arg
382        | RET ⇒
383            let s ≝ add_ticks1 s in
384            let high_bits ≝ read_at_stack_pointer ?? s in
385            let 〈new_sp, flags〉 ≝ sub_8_with_carry (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) false in
386            let s ≝ set_8051_sfr … s SFR_SP new_sp in
387            let low_bits ≝ read_at_stack_pointer ?? s in
388            let 〈new_sp, flags〉 ≝ sub_8_with_carry (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) false in
389            let s ≝ set_8051_sfr … s SFR_SP new_sp in
390            let new_pc ≝ high_bits @@ low_bits in
391              set_program_counter … s new_pc
392        | RETI ⇒
393            let s ≝ add_ticks1 s in
394            let high_bits ≝ read_at_stack_pointer ?? s in
395            let 〈new_sp, flags〉 ≝ sub_8_with_carry (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) false in
396            let s ≝ set_8051_sfr … s SFR_SP new_sp in
397            let low_bits ≝ read_at_stack_pointer ?? s in
398            let 〈new_sp, flags〉 ≝ sub_8_with_carry (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) false in
399            let s ≝ set_8051_sfr … s SFR_SP new_sp in
400            let new_pc ≝ high_bits @@ low_bits in
401              set_program_counter … s new_pc
402        | MOVX addr ⇒
403          let s ≝ add_ticks1 s in
404          (* DPM: only copies --- doesn't affect I/O *)
405          match addr with
406            [ inl l ⇒
407              let 〈addr1, addr2〉 ≝ l in
408                set_arg_8 … s addr1 (get_arg_8 … s false addr2)
409            | inr r ⇒
410              let 〈addr1, addr2〉 ≝ r in
411                set_arg_8 … s addr1 (get_arg_8 … s false addr2)
412            ]
413        | MOV addr ⇒
414          let s ≝ add_ticks1 s in
415          match addr with
416            [ inl l ⇒
417              match l with
418                [ inl l' ⇒
419                  match l' with
420                    [ inl l'' ⇒
421                      match l'' with
422                        [ inl l''' ⇒
423                          match l''' with
424                            [ inl l'''' ⇒
425                              let 〈addr1, addr2〉 ≝ l'''' in
426                                set_arg_8 … s addr1 (get_arg_8 … s false addr2)
427                            | inr r'''' ⇒
428                              let 〈addr1, addr2〉 ≝ r'''' in
429                                set_arg_8 … s addr1 (get_arg_8 … s false addr2)
430                            ]
431                        | inr r''' ⇒
432                          let 〈addr1, addr2〉 ≝ r''' in
433                            set_arg_8 … s addr1 (get_arg_8 … s false addr2)
434                        ]
435                    | inr r'' ⇒
436                      let 〈addr1, addr2〉 ≝ r'' in
437                       set_arg_16 … s (get_arg_16 … s addr2) addr1
438                    ]
439                | inr r ⇒
440                  let 〈addr1, addr2〉 ≝ r in
441                   set_arg_1 … s addr1 (get_arg_1 … s addr2 false)
442                ]
443            | inr r ⇒
444              let 〈addr1, addr2〉 ≝ r in
445               set_arg_1 … s addr1 (get_arg_1 … s addr2 false)
446            ]
447          | JC addr ⇒
448                  if get_cy_flag ?? s then
449                    let s ≝ add_ticks1 s in
450                      set_program_counter … s (addr_of addr s)
451                  else
452                    let s ≝ add_ticks2 s in
453                      s
454            | JNC addr ⇒
455                  if ¬(get_cy_flag ?? s) then
456                   let s ≝ add_ticks1 s in
457                     set_program_counter … s (addr_of addr s)
458                  else
459                   let s ≝ add_ticks2 s in
460                    s
461            | JB addr1 addr2 ⇒
462                  if get_arg_1 … s addr1 false then
463                   let s ≝ add_ticks1 s in
464                    set_program_counter … s (addr_of addr2 s)
465                  else
466                   let s ≝ add_ticks2 s in
467                    s
468            | JNB addr1 addr2 ⇒
469                  if ¬(get_arg_1 … s addr1 false) then
470                   let s ≝ add_ticks1 s in
471                    set_program_counter … s (addr_of addr2 s)
472                  else
473                   let s ≝ add_ticks2 s in
474                    s
475            | JBC addr1 addr2 ⇒
476                  let s ≝ set_arg_1 … s addr1 false in
477                    if get_arg_1 … s addr1 false then
478                     let s ≝ add_ticks1 s in
479                      set_program_counter … s (addr_of addr2 s)
480                    else
481                     let s ≝ add_ticks2 s in
482                      s
483            | JZ addr ⇒
484                    if eq_bv ? (get_8051_sfr … s SFR_ACC_A) (zero 8) then
485                     let s ≝ add_ticks1 s in
486                      set_program_counter … s (addr_of addr s)
487                    else
488                     let s ≝ add_ticks2 s in
489                      s
490            | JNZ addr ⇒
491                    if ¬(eq_bv ? (get_8051_sfr … s SFR_ACC_A) (zero 8)) then
492                     let s ≝ add_ticks1 s in
493                      set_program_counter … s (addr_of addr s)
494                    else
495                     let s ≝ add_ticks2 s in
496                      s
497            | CJNE addr1 addr2 ⇒
498                  match addr1 with
499                    [ inl l ⇒
500                        let 〈addr1, addr2'〉 ≝ l in
501                        let new_cy ≝ ltb (nat_of_bitvector ? (get_arg_8 … s false addr1))
502                                                 (nat_of_bitvector ? (get_arg_8 … s false addr2')) in
503                          if ¬(eq_bv ? (get_arg_8 … s false addr1) (get_arg_8 … s false addr2')) then
504                            let s ≝ add_ticks1 s in
505                            let s ≝ set_program_counter … s (addr_of addr2 s) in
506                              set_flags … s new_cy (None ?) (get_ov_flag ?? s)
507                          else
508                            let s ≝ add_ticks2 s in
509                              set_flags … s new_cy (None ?) (get_ov_flag ?? s)
510                    | inr r' ⇒
511                        let 〈addr1, addr2'〉 ≝ r' in
512                        let new_cy ≝ ltb (nat_of_bitvector ? (get_arg_8 … s false addr1))
513                                                 (nat_of_bitvector ? (get_arg_8 … s false addr2')) in
514                          if ¬(eq_bv ? (get_arg_8 … s false addr1) (get_arg_8 … s false addr2')) then
515                            let s ≝ add_ticks1 s in
516                            let s ≝ set_program_counter … s (addr_of addr2 s) in
517                              set_flags … s new_cy (None ?) (get_ov_flag ?? s)
518                          else
519                            let s ≝ add_ticks2 s in
520                              set_flags … s new_cy (None ?) (get_ov_flag ?? s)
521                    ]
522            | DJNZ addr1 addr2 ⇒
523              let 〈result, flags〉 ≝ sub_8_with_carry (get_arg_8 … s true addr1) (bitvector_of_nat 8 1) false in
524              let s ≝ set_arg_8 … s addr1 result in
525                if ¬(eq_bv ? result (zero 8)) then
526                 let s ≝ add_ticks1 s in
527                  set_program_counter … s (addr_of addr2 s)
528                else
529                 let s ≝ add_ticks2 s in
530                  s
531 |_ ⇒ ?            ]. (*15s*)
532    try (cases(other))
533    try assumption (*20s*)
534    try (% @False) (*6s*) (* Bug exploited here to implement solve :-*)
535    try (
536      @ (execute_1_technical … (subaddressing_modein …))
537      @ I
538    ) (*66s*)
539    normalize nodelta /2 by or_introl, or_intror/ (*35s*)
540    (*CSC: the times are now much longer. I suspect because the inclusion of
541      all StatusProofs makes the search space larger :-( *)
542qed.
543
544definition execute_1_preinstruction:
545  ∀ticks: nat × nat.
546  ∀a, m: Type[0]. ∀cm. (a → PreStatus m cm → Word) → preinstruction a →
547  PreStatus m cm → PreStatus m cm ≝ execute_1_preinstruction'.
548 
549lemma execute_1_preinstruction_ok:
550 ∀ticks,a,m,cm,f,i,s.
551  clock ?? (execute_1_preinstruction ticks a m cm f i s) = \fst ticks + clock … s ∨
552  clock ?? (execute_1_preinstruction ticks a m cm f i s) = \snd ticks + clock … s.
553 #ticks #a #m #cm #f #i #s whd in match execute_1_preinstruction; normalize nodelta @pi2
554qed.
555
556definition execute_1_0: ∀cm. ∀s: Status cm. ∀current:instruction × Word × nat.
557  Σs': Status cm. clock ?? s' = \snd current + clock … s ≝
558  λcm,s0,instr_pc_ticks.
559    let 〈instr_pc, ticks〉 ≝ instr_pc_ticks in
560    let 〈instr, pc〉 ≝ 〈fst … instr_pc, snd … instr_pc〉 in
561    let s ≝ set_program_counter … s0 pc in
562      match instr return λ_.Status cm with
563      [ RealInstruction instr ⇒ execute_1_preinstruction 〈ticks, ticks〉 [[ relative ]] …
564        (λx. λs.
565        match x return λs. bool_to_Prop (is_in ? [[ relative ]] s) → Word with
566        [ RELATIVE r ⇒ λ_. \snd (half_add ? (program_counter … s) (sign_extension r))
567        | _ ⇒ λabsd. ⊥
568        ] (subaddressing_modein … x)) instr s
569      | MOVC addr1 addr2 ⇒
570          let s ≝ set_clock … s (ticks + clock … s) in
571          match addr2 return λx. bool_to_Prop (is_in … [[ acc_dptr; acc_pc ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
572            [ ACC_DPTR ⇒ λacc_dptr: True.
573              let big_acc ≝ (zero 8) @@ (get_8051_sfr … s SFR_ACC_A) in
574              let dptr ≝ (get_8051_sfr … s SFR_DPH) @@ (get_8051_sfr … s SFR_DPL) in
575              let 〈carry, new_addr〉 ≝ half_add ? dptr big_acc in
576              let result ≝ lookup ? ? new_addr cm (zero ?) in
577                set_8051_sfr … s SFR_ACC_A result
578            | ACC_PC ⇒ λacc_pc: True.
579              let big_acc ≝ (zero 8) @@ (get_8051_sfr … s SFR_ACC_A) in
580              let 〈carry, inc_pc〉 ≝ half_add ? (program_counter ?? s) (bitvector_of_nat 16 1) in
581              (* DPM: Under specified: does the carry from PC incrementation affect the *)
582              (*      addition of the PC with the DPTR? At the moment, no.              *)
583              let s ≝ set_program_counter … s inc_pc in
584              let 〈carry, new_addr〉 ≝ half_add ? inc_pc big_acc in
585              let result ≝ lookup ? ? new_addr cm (zero ?) in
586                set_8051_sfr … s SFR_ACC_A result
587            | _ ⇒ λother: False. ⊥
588            ] (subaddressing_modein … addr2)
589      | JMP _ ⇒ (* DPM: always indirect_dptr *)
590          let s ≝ set_clock … s (ticks + clock … s) in
591          let dptr ≝ (get_8051_sfr … s SFR_DPH) @@ (get_8051_sfr … s SFR_DPL) in
592          let big_acc ≝ (zero 8) @@ (get_8051_sfr … s SFR_ACC_A) in
593          let 〈carry, jmp_addr〉 ≝ half_add ? big_acc dptr in
594          let 〈carry, new_pc〉 ≝ half_add ? (program_counter … s) jmp_addr in
595            set_program_counter … s new_pc
596      | LJMP addr ⇒
597          let s ≝ set_clock … s (ticks + clock … s) in
598          match addr return λx. bool_to_Prop (is_in … [[ addr16 ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
599            [ ADDR16 a ⇒ λaddr16: True.
600                set_program_counter … s a
601            | _ ⇒ λother: False. ⊥
602            ] (subaddressing_modein … addr)
603      | SJMP addr ⇒
604          let s ≝ set_clock … s (ticks + clock … s) in
605          match addr return λx. bool_to_Prop (is_in … [[ relative ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
606            [ RELATIVE r ⇒ λrelative: True.
607                let 〈carry, new_pc〉 ≝ half_add ? (program_counter … s) (sign_extension r) in
608                  set_program_counter … s new_pc
609            | _ ⇒ λother: False. ⊥
610            ] (subaddressing_modein … addr)
611      | AJMP addr ⇒
612          let s ≝ set_clock … s (ticks + clock … s) in
613          match addr return λx. bool_to_Prop (is_in … [[ addr11 ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
614            [ ADDR11 a ⇒ λaddr11: True.
615              let 〈pc_bu, pc_bl〉 ≝ split ? 8 8 (program_counter … s) in
616              let 〈nu, nl〉 ≝ split ? 4 4 pc_bu in
617              let bit ≝ get_index' ? O ? nl in
618              let 〈relevant1, relevant2〉 ≝ split ? 3 8 a in
619              let new_addr ≝ (nu @@ (bit ::: relevant1)) @@ relevant2 in
620              let 〈carry, new_pc〉 ≝ half_add ? (program_counter … s) new_addr in
621                set_program_counter … s new_pc
622            | _ ⇒ λother: False. ⊥
623            ] (subaddressing_modein … addr)
624      | ACALL addr ⇒
625          let s ≝ set_clock … s (ticks + clock … s) in
626          match addr return λx. bool_to_Prop (is_in … [[ addr11 ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
627            [ ADDR11 a ⇒ λaddr11: True.
628              let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
629              let s ≝ set_8051_sfr … s SFR_SP new_sp in
630              let 〈pc_bu, pc_bl〉 ≝ split ? 8 8 (program_counter … s) in
631              let s ≝ write_at_stack_pointer … s pc_bl in
632              let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
633              let s ≝ set_8051_sfr … s SFR_SP new_sp in
634              let s ≝ write_at_stack_pointer … s pc_bu in
635              let 〈thr, eig〉 ≝ split ? 3 8 a in
636              let 〈fiv, thr'〉 ≝ split ? 5 3 pc_bu in
637              let new_addr ≝ (fiv @@ thr) @@ pc_bl in
638                set_program_counter … s new_addr
639            | _ ⇒ λother: False. ⊥
640            ] (subaddressing_modein … addr)
641        | LCALL addr ⇒
642          let s ≝ set_clock … s (ticks + clock … s) in
643          match addr return λx. bool_to_Prop (is_in … [[ addr16 ]] x) → Σs': Status cm. clock ?? s' = ticks + clock … s0 with
644            [ ADDR16 a ⇒ λaddr16: True.
645              let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
646              let s ≝ set_8051_sfr … s SFR_SP new_sp in
647              let 〈pc_bu, pc_bl〉 ≝ split ? 8 8 (program_counter … s) in
648              let s ≝ write_at_stack_pointer … s pc_bl in
649              let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
650              let s ≝ set_8051_sfr … s SFR_SP new_sp in
651              let s ≝ write_at_stack_pointer … s pc_bu in
652                set_program_counter … s a
653            | _ ⇒ λother: False. ⊥
654            ] (subaddressing_modein … addr)
655        ]. (*10s*)
656    [||||||||*:try assumption]
657    [1,2,3,4,5,7: @pi2 (*35s*)
658    |8: lapply (execute_1_preinstruction_ok 〈ticks, ticks〉 [[ relative ]] …
659        (λx. λs.
660        match x return λs. bool_to_Prop (is_in ? [[ relative ]] s) → Word with
661        [ RELATIVE r ⇒ λ_. \snd (half_add ? (program_counter … s) (sign_extension r))
662        | _ ⇒ λabsd. ⊥
663        ] (subaddressing_modein … x)) instr1 s1) try @absd * #H @H
664    |*: normalize nodelta try // (*17s*)
665        >clock_set_program_counter // (* Andrea:??*) ]
666qed.
667
668definition current_instruction_cost ≝
669  λcm.λs: Status cm.
670    \snd (fetch cm (program_counter … s)).
671
672definition execute_1': ∀cm.∀s:Status cm.
673  Σs':Status cm. clock ?? s' = current_instruction_cost cm s + clock … s ≝
674  λcm. λs: Status cm.
675    let instr_pc_ticks ≝ fetch cm (program_counter … s) in
676     execute_1_0 cm s instr_pc_ticks.
677
678definition execute_1: ∀cm. Status cm → Status cm ≝ execute_1'.
679
680lemma execute_1_ok: ∀cm.∀s. clock ?? (execute_1 cm s) = current_instruction_cost … s + clock … s.
681 #cm #s whd in match execute_1; normalize nodelta @pi2
682qed-. (*x Andrea: indexing takes ages here *)
683
684definition execute_1_pseudo_instruction0: (nat × nat) → ∀cm. PseudoStatus cm → ? → ? → PseudoStatus cm ≝
685  λticks,cm,s,instr,pc.
686  let s ≝ set_program_counter ?? s pc in
687  let s ≝
688    match instr with
689    [ Instruction instr ⇒ execute_1_preinstruction ticks … (λx, y. address_of_word_labels cm x) instr s
690    | Comment cmt ⇒ set_clock … s (\fst ticks + clock … s)
691    | Cost cst ⇒ s
692    | Jmp jmp ⇒
693       let s ≝ set_clock … s (\fst ticks + clock … s) in
694        set_program_counter … s (address_of_word_labels cm jmp)
695    | Call call ⇒
696      let s ≝ set_clock ?? s (\fst ticks + clock … s) in
697      let a ≝ address_of_word_labels cm call in
698      let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
699      let s ≝ set_8051_sfr … s SFR_SP new_sp in
700      let 〈pc_bu, pc_bl〉 ≝ split ? 8 8 (program_counter … s) in
701      let s ≝ write_at_stack_pointer … s pc_bl in
702      let 〈carry, new_sp〉 ≝ half_add ? (get_8051_sfr … s SFR_SP) (bitvector_of_nat 8 1) in
703      let s ≝ set_8051_sfr … s SFR_SP new_sp in
704      let s ≝ write_at_stack_pointer … s pc_bu in
705        set_program_counter … s a
706    | Mov dptr ident ⇒
707      let s ≝ set_clock ?? s (\fst ticks + clock … s) in
708      let the_preamble ≝ \fst cm in
709      let data_labels ≝ construct_datalabels the_preamble in
710        set_arg_16 … s (get_arg_16 … s (DATA16 (lookup_def ? ? data_labels ident (zero ?)))) dptr
711    ]
712  in
713    s.
714  normalize
715  @I
716qed.
717
718definition execute_1_pseudo_instruction: (Word → nat × nat) → ∀cm. PseudoStatus cm → PseudoStatus cm ≝
719  λticks_of,cm,s.
720  let 〈instr, pc〉 ≝ fetch_pseudo_instruction (\snd cm) (program_counter … s) in
721  let ticks ≝ ticks_of (program_counter … s) in
722   execute_1_pseudo_instruction0 ticks cm s instr pc.
723
724let rec execute (n: nat) (cm:?) (s: Status cm) on n: Status cm ≝
725  match n with
726    [ O ⇒ s
727    | S o ⇒ execute o … (execute_1 … s)
728    ].
729
730let rec execute_pseudo_instruction (n: nat) (ticks_of: Word → nat × nat) (cm:?) (s: PseudoStatus cm) on n: PseudoStatus cm ≝
731  match n with
732    [ O ⇒ s
733    | S o ⇒ execute_pseudo_instruction o ticks_of … (execute_1_pseudo_instruction ticks_of … s)
734    ].
Note: See TracBrowser for help on using the repository browser.