source: src/ASM/CostsProof.ma @ 3363

include "ASM/ASMCostsSplit.ma".
include "ASM/WellLabeled.ma".
include "ASM/Status.ma".
include "common/StructuredTraces.ma".
include "arithmetics/bigops.ma".

include alias "arithmetics/nat.ma".
include alias "basics/logic.ma".

let rec compute_max_trace_label_label_cost
  (prog: labelled_object_code)
   (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
      (the_trace: trace_label_label (OC_abstract_status prog) trace_ends_flag
        start_status final_status) on the_trace: nat ≝
  match the_trace with
  [ tll_base ends_flag initial final given_trace labelled_proof ⇒
      compute_max_trace_any_label_cost … given_trace
  ]
and compute_max_trace_any_label_cost
  (prog: labelled_object_code)
  (trace_ends_flag: trace_ends_with_ret)
   (start_status: Status (cm prog))
   (final_status: Status (cm prog))
     (the_trace: trace_any_label (OC_abstract_status prog) trace_ends_flag start_status final_status)
       on the_trace: nat ≝
  match the_trace with
  [ tal_base_not_return the_status _ _ _ _ ⇒ current_instruction_cost … the_status
  | tal_base_return the_status _ _ _ ⇒ current_instruction_cost … the_status
  | tal_base_call pre_fun_call start_fun_call final _ _ _ call_trace _ ⇒
      let current_instruction_cost ≝ current_instruction_cost … pre_fun_call in
      let call_trace_cost ≝ compute_max_trace_label_return_cost … call_trace in
        call_trace_cost + current_instruction_cost
  | tal_base_tailcall pre_fun_call start_fun_call final _ _ call_trace ⇒
      let current_instruction_cost ≝ current_instruction_cost … pre_fun_call in
      let call_trace_cost ≝ compute_max_trace_label_return_cost … call_trace in
        call_trace_cost + current_instruction_cost
  | tal_step_call end_flag pre_fun_call start_fun_call after_fun_call final
     _ _ _ call_trace _ final_trace ⇒
      let current_instruction_cost ≝ current_instruction_cost … pre_fun_call in
      let call_trace_cost ≝ compute_max_trace_label_return_cost … call_trace in
      let final_trace_cost ≝ compute_max_trace_any_label_cost prog end_flag … final_trace in
        call_trace_cost + current_instruction_cost + final_trace_cost
  | tal_step_default end_flag status_pre status_init status_end _ tail_trace _ _ ⇒
      let current_instruction_cost ≝ current_instruction_cost … status_pre in
      let tail_trace_cost ≝
       compute_max_trace_any_label_cost prog end_flag
        status_init status_end tail_trace
      in
        current_instruction_cost + tail_trace_cost
  ]
and compute_max_trace_label_return_cost
  (prog: labelled_object_code)
  (start_status: Status (cm prog))
  (final_status: Status (cm prog))
    (the_trace: trace_label_return (OC_abstract_status prog) start_status final_status)
      on the_trace: nat ≝
  match the_trace with
  [ tlr_base before after trace_to_lift ⇒ compute_max_trace_label_label_cost … trace_to_lift
  | tlr_step initial labelled final labelled_trace ret_trace ⇒
      let labelled_cost ≝ compute_max_trace_label_label_cost … labelled_trace in
      let return_cost ≝ compute_max_trace_label_return_cost … ret_trace in
        labelled_cost + return_cost
  ].

include alias "arithmetics/nat.ma".

let rec compute_max_trace_label_label_cost_is_ok
  (prog: labelled_object_code)
   (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
      (the_trace: trace_label_label (OC_abstract_status prog) trace_ends_flag
        start_status final_status) on the_trace:
          clock … (cm prog) … final_status = (compute_max_trace_label_label_cost prog trace_ends_flag start_status final_status the_trace) + (clock … (cm prog) … start_status) ≝ ?
and compute_max_trace_any_label_cost_is_ok
  (prog: labelled_object_code)
  (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
     (the_trace: trace_any_label (OC_abstract_status prog) trace_ends_flag start_status final_status)
       on the_trace:
         clock … (cm prog) … final_status = (compute_max_trace_any_label_cost prog trace_ends_flag start_status final_status the_trace) + (clock … (cm prog) … start_status) ≝ ?
and compute_max_trace_label_return_cost_is_ok
  (prog: labelled_object_code)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
    (the_trace: trace_label_return (OC_abstract_status prog) start_status final_status)
      on the_trace:
        clock … (cm prog) … final_status = (compute_max_trace_label_return_cost prog start_status final_status the_trace) + clock … (cm prog) … start_status ≝ ?.
  [1:
    cases the_trace
    #ends_flag #start_status #end_status #any_label_trace #is_costed
    @compute_max_trace_any_label_cost_is_ok
  |2:
    cases the_trace
    [1,2:
      #start_status #final_status #is_next #is_not_return try (#is_costed)
      change with (current_instruction_cost … start_status) in ⊢ (???(?%?));
      cases(proj2 … is_next) @execute_1_ok_clock
    |3:
      #status_pre_fun_call #status_start_fun_call #status_final #is_next
      #classifier_assm #after_return_assm #call_trace #costed_assm
      whd in match (compute_max_trace_any_label_cost … (tal_base_call …));
      >(compute_max_trace_label_return_cost_is_ok prog … call_trace)
      >associative_plus @eq_f cases(proj2 … is_next)
      @execute_1_ok_clock
    |4:
      #status_pre_fun_call #status_start_fun_call #status_final #is_next
      #classifier_assm #call_trace
      whd in match (compute_max_trace_any_label_cost … (tal_base_tailcall …));
      >(compute_max_trace_label_return_cost_is_ok … call_trace)
      >associative_plus @eq_f cases(proj2 … is_next)
      @execute_1_ok_clock
    |5:
      #end_flag #status_pre_fun_call #status_start_fun_call #status_after_fun_call
      #status_final #is_next #is_call #is_after_return #call_trace #not_costed #final_trace
      change with (
      let current_instruction_cost ≝ current_instruction_cost … status_pre_fun_call in
      let call_trace_cost ≝ compute_max_trace_label_return_cost … … call_trace in
      let final_trace_cost ≝ compute_max_trace_any_label_cost prog end_flag … final_trace in
        call_trace_cost + current_instruction_cost + final_trace_cost) in ⊢ (???(?%?));
      normalize nodelta;
      >(compute_max_trace_any_label_cost_is_ok prog end_flag status_after_fun_call
          status_final final_trace)
      >(compute_max_trace_label_return_cost_is_ok prog status_start_fun_call
        status_after_fun_call call_trace)
      cases(proj2 … is_next) in match (clock … (cm prog) status_start_fun_call);
      >(execute_1_ok_clock … status_pre_fun_call)
      <associative_plus in ⊢ (??%?);
      <commutative_plus in match (
        compute_max_trace_any_label_cost prog end_flag status_after_fun_call status_final final_trace
          + compute_max_trace_label_return_cost prog status_start_fun_call status_after_fun_call call_trace);
      >associative_plus in ⊢ (??%?); >associative_plus in ⊢ (???%); >associative_plus in ⊢ (???%);
      @eq_f >commutative_plus in ⊢ (??%?); >associative_plus in ⊢ (??%?);
      @eq_f @commutative_plus
    |6:
      #end_flag #status_pre #status_init #status_end #is_next
      #trace_any_label #is_other #is_not_costed
      change with (
      let current_instruction_cost ≝ current_instruction_cost … status_pre in
      let tail_trace_cost ≝
       compute_max_trace_any_label_cost prog end_flag
        status_init status_end trace_any_label
      in
        current_instruction_cost + tail_trace_cost) in ⊢ (???(?%?));
      normalize nodelta;
      >(compute_max_trace_any_label_cost_is_ok prog end_flag
         status_init status_end trace_any_label)
      cases(proj2 … is_next) in match (clock … (cm prog) status_init);
      >(execute_1_ok_clock … status_pre)
      >commutative_plus >associative_plus >associative_plus @eq_f
      @commutative_plus
    ]
  |3:
    cases the_trace
    [1:
      #status_before #status_after #trace_to_lift
      @compute_max_trace_label_label_cost_is_ok
    |2:
      #status_initial #status_labelled #status_final #labelled_trace #ret_trace
      >(compute_max_trace_label_return_cost_is_ok prog status_labelled status_final ret_trace);
      >(compute_max_trace_label_label_cost_is_ok prog doesnt_end_with_ret status_initial status_labelled labelled_trace);
      <associative_plus in ⊢ (??%?);
      >commutative_plus in match (
        compute_max_trace_label_return_cost prog status_labelled status_final ret_trace
          + compute_max_trace_label_label_cost prog doesnt_end_with_ret status_initial status_labelled labelled_trace);
      %
    ]
  ]
qed.

let rec compute_trace_label_label_cost_using_paid
  (prog:labelled_object_code)
   (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
      (the_trace: trace_label_label (OC_abstract_status prog) trace_ends_flag
        start_status final_status) on the_trace: nat ≝
  match the_trace with
  [ tll_base ends_flag initial final given_trace labelled_proof ⇒
      compute_paid_trace_label_label prog … the_trace +
      compute_trace_any_label_cost_using_paid … given_trace
  ]
and compute_trace_any_label_cost_using_paid
  (prog:labelled_object_code)
  (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
     (the_trace: trace_any_label (OC_abstract_status prog) trace_ends_flag start_status final_status)
       on the_trace: nat ≝
  match the_trace with
  [ tal_base_not_return the_status _ _ _ _ ⇒ 0
  | tal_base_return the_status _ _ _ ⇒ 0
  | tal_base_call pre_fun_call start_fun_call final _ _ _ call_trace _ ⇒
      compute_trace_label_return_cost_using_paid … call_trace
  | tal_base_tailcall pre_fun_call start_fun_call final _ _ call_trace ⇒
      compute_trace_label_return_cost_using_paid … call_trace
  | tal_step_call end_flag pre_fun_call start_fun_call after_fun_call final
     _ _ _ call_trace _ final_trace ⇒
      let call_trace_cost ≝ compute_trace_label_return_cost_using_paid … call_trace in
      let final_trace_cost ≝ compute_trace_any_label_cost_using_paid prog end_flag … final_trace in
        call_trace_cost + final_trace_cost
  | tal_step_default end_flag status_pre status_init status_end _ tail_trace _ _ ⇒
     compute_trace_any_label_cost_using_paid prog end_flag
      status_init status_end tail_trace
  ]
and compute_trace_label_return_cost_using_paid
  (prog:labelled_object_code)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
    (the_trace: trace_label_return (OC_abstract_status prog) start_status final_status)
      on the_trace: nat ≝
  match the_trace with
  [ tlr_base before after trace_to_lift ⇒ compute_trace_label_label_cost_using_paid … trace_to_lift
  | tlr_step initial labelled final labelled_trace ret_trace ⇒
      let labelled_cost ≝ compute_trace_label_label_cost_using_paid … labelled_trace in
      let return_cost ≝ compute_trace_label_return_cost_using_paid … ret_trace in
        labelled_cost + return_cost
  ].

let rec compute_trace_label_label_cost_using_paid_ok
  (prog:labelled_object_code)
   (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
      (the_trace: trace_label_label (OC_abstract_status prog) trace_ends_flag
        start_status final_status) on the_trace:
 compute_trace_label_label_cost_using_paid prog … the_trace =
 compute_max_trace_label_label_cost … the_trace ≝ ?
and compute_trace_any_label_cost_using_paid_ok
  (prog:labelled_object_code)
  (trace_ends_flag: trace_ends_with_ret)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
     (the_trace: trace_any_label (OC_abstract_status prog)
      trace_ends_flag start_status final_status) on the_trace:      
  compute_paid_trace_any_label prog trace_ends_flag … the_trace
  +compute_trace_any_label_cost_using_paid prog trace_ends_flag … the_trace
  =compute_max_trace_any_label_cost prog trace_ends_flag … the_trace ≝ ?
and compute_trace_label_return_cost_using_paid_ok
  (prog:labelled_object_code)
    (start_status: Status (cm prog))
    (final_status: Status (cm prog))
    (the_trace: trace_label_return (OC_abstract_status prog)
     start_status final_status) on the_trace:
 compute_trace_label_return_cost_using_paid prog … the_trace =
 compute_max_trace_label_return_cost prog … the_trace ≝ ?.
[ cases the_trace #endsf #ss #es #tr #H normalize
  @compute_trace_any_label_cost_using_paid_ok
| cases the_trace
  [ #ss #fs #H1 #H2 #H3 whd in ⊢ (??(?%%)%); <plus_n_O %
  | #ss #fs #H1 #H2 whd in ⊢ (??(?%%)%); <plus_n_O %
  | #sp #ss #sf #H1 #H2 #tr1 #tr2 #H3
    whd in ⊢ (???%); whd in ⊢ (??(??%)?); whd in ⊢ (??(?%?)?);
    >compute_trace_label_return_cost_using_paid_ok in ⊢ (??%?);
    >commutative_plus in ⊢ (??%?); @eq_f %
  | #sp #ss #sf #H1 #H2 #tr1
    whd in ⊢ (???%); whd in ⊢ (??(??%)?); whd in ⊢ (??(?%?)?);
    >compute_trace_label_return_cost_using_paid_ok in ⊢ (??%?);
    >commutative_plus in ⊢ (??%?); @eq_f %
  | #ef #spfc #ssfc #safc #sf #H1 #H2 #H3 #tr1 #H4 #tr2 whd in ⊢ (??(?%%)%);
    <compute_trace_any_label_cost_using_paid_ok
    <compute_trace_label_return_cost_using_paid_ok
    -compute_trace_label_label_cost_using_paid_ok
    -compute_trace_label_return_cost_using_paid_ok
    -compute_trace_any_label_cost_using_paid_ok
    >commutative_plus in ⊢ (???(?%?));
    >commutative_plus in ⊢ (??(??%)?);
    >associative_plus >associative_plus in ⊢ (???%); @eq_f2 try %
    <associative_plus <commutative_plus %
  | #ef #sp #si #se #H1 #tr #H2 #H3 whd in ⊢ (??(?%%)%); >associative_plus @eq_f2
    [ % | @compute_trace_any_label_cost_using_paid_ok ]
  ]
| cases the_trace
  [ #sb #sa #tr normalize @compute_trace_label_label_cost_using_paid_ok
  | #si #sl #sf #tr1 #tr2 normalize @eq_f2
    [ @compute_trace_label_label_cost_using_paid_ok
    | @compute_trace_label_return_cost_using_paid_ok ]]]
qed.

include alias "ASM/BitVectorTrie.ma".
include alias "arithmetics/nat.ma".
include alias "basics/logic.ma".
include alias "arithmetics/bigops.ma".

(*
(* This shoudl go in bigops! *)
theorem bigop_sum_rev: ∀k1,k2,p,B,nil.∀op:Aop B nil.∀f:nat→B.
 \big[op,nil]_{i<k1+k2|p i} (f i) =
 op \big[op,nil]_{i<k2|p (i+k1)} (f (i+k1)) \big[op,nil]_{i<k1|p i} (f i).
 #k1 #k2 #p #B #nil #op #f >bigop_sum
 >commutative_plus @same_bigop #i @leb_elim normalize
 [2,4: //
 | #H1 #H2 <plus_minus_m_m //
 | #H1 #H2 #H3 <plus_minus_m_m //]
qed.
*)
(* This is taken by sigma_pi.ma that does not compile now *)
definition natAop ≝ mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n)) 
   (λa,b,c.sym_eq ??? (associative_plus a b c)).

definition natACop ≝ mk_ACop nat 0 natAop commutative_plus.

definition natDop ≝ mk_Dop nat 0 natACop times (λn.(sym_eq ??? (times_n_O n)))
   distributive_times_plus.

unification hint  0 ≔ ;
   S ≟ mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n)) 
   (λa,b,c.sym_eq ??? (associative_plus a b c))
(* ---------------------------------------- *) ⊢
   plus ≡ op ? ? S.

unification hint  0 ≔ ;
   S ≟ mk_ACop nat 0 (mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n)) 
   (λa,b,c.sym_eq ??? (associative_plus a b c))) commutative_plus
(* ---------------------------------------- *) ⊢
   plus ≡ op ? ? S.
   
unification hint  0 ≔ ;
   S ≟ natDop
(* ---------------------------------------- *) ⊢
   plus ≡ sum ? ? S.

unification hint  0 ≔ ;
   S ≟ natDop
(* ---------------------------------------- *) ⊢
   times ≡ prod ? ? S.
(*
notation > "Σ_{ ident i < n } f"
  with precedence 20
for @{'bigop $n plus 0 (λ${ident i}.true) (λ${ident i}. $f)}.

notation < "Σ_{ ident i < n } f"
  with precedence 20
for @{'bigop $n plus 0 (λ${ident i}:$X.true) (λ${ident i}:$Y. $f)}.

definition tech_cost_of_label0:
 ∀cost_labels: BitVectorTrie costlabel 16.
 ∀cost_map: identifier_map CostTag nat.
 ∀codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k).
 ∀ctrace:list (Σk:costlabel.∃b.lookup_opt … b cost_labels = Some ? k).
 ∀i,p. present … cost_map (nth_safe ? i ctrace p).
 #cost_labels #cost_map #codom_dom #ctrace #i #p
 cases (nth_safe … i ctrace ?) normalize #id * #id_pc #K
 lapply (codom_dom … K) #k_pres >(lookup_lookup_present … k_pres)
 % #abs destruct (abs)
qed.
*)
include alias "arithmetics/nat.ma".
include alias "basics/logic.ma".
(*
lemma ltb_rect:
 ∀P:Type[0].∀n,m. (n < m → P) → (¬ n < m → P) → P.
 #P #n #m lapply (refl … (ltb n m)) cases (ltb n m) in ⊢ (???% → %); #E #H1 #H2
 [ @H1 @leb_true_to_le @E | @H2 @leb_false_to_not_le @E ]
qed.

lemma same_ltb_rect:
 ∀P,n,m,H1,H2,n',m',H1',H2'.
  ltb n m = ltb n' m' → (∀x,y. H1 x = H1' y) → (∀x,y. H2 x = H2' y) →
   ltb_rect P n m H1 H2 =
   ltb_rect P n' m' H1' H2'.
 #P #n #m #H1 #H2 #n' #m' #H1' #H2' #E #K1 #K2 whd in ⊢ (??%?);
 cut (∀xxx,yyy,xxx',yyy'.
   match ltb n m
   return λx:bool.
           eq bool (ltb n m) x
            → (lt n m → P) → (Not (lt n m) → P) → P
    with
    [ true ⇒ 
        λE0:eq bool (ltb n m) true.
         λH10:lt n m → P.
          λH20:Not (lt n m) → P. H10 (xxx E0)
    | false ⇒
        λE0:eq bool (ltb n m) false.
         λH10:lt n m → P.
          λH20:Not (lt n m) → P. H20 (yyy E0)] 
    (refl … (ltb n m)) H1 H2 =
   match ltb n' m'
   return λx:bool.
           eq bool (ltb n' m') x
            → (lt n' m' → P) → (Not (lt n' m') → P) → P
    with
    [ true ⇒ 
        λE0:eq bool (ltb n' m') true.
         λH10:lt n' m' → P.
          λH20:Not (lt n' m') → P. H10 (xxx' E0)
    | false ⇒
        λE0:eq bool (ltb n' m') false.
         λH10:lt n' m' → P.
          λH20:Not (lt n' m') → P. H20 (yyy' E0)] 
    (refl … (ltb n' m')) H1' H2'
  ) [2: #X @X]
 >E cases (ltb n' m') #xxx #yyy #xxx' #yyy' normalize
 [ @K1 | @K2 ]
qed.

definition tech_cost_of_label:
 ∀cost_labels: BitVectorTrie costlabel 16.
 ∀cost_map: identifier_map CostTag nat.
 ∀codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k).
 list (Σk:costlabel.∃b.lookup_opt … b cost_labels = Some ? k) →
 nat → nat
≝ λcost_labels,cost_map,codom_dom,ctrace,i.
 ltb_rect ? i (|ctrace|)
 (λH. lookup_present ?? cost_map (nth_safe ? i ctrace H) ?)
 (λ_.0).
 @tech_cost_of_label0 @codom_dom
qed.

lemma tech_cost_of_label_shift:
 ∀cost_labels,cost_map,codom_dom,l1,l2,i.
  i < |l2| →
   tech_cost_of_label cost_labels cost_map codom_dom l2 i =
   tech_cost_of_label cost_labels cost_map codom_dom (l1@l2) (i+|l1|).
 #cost_labels #cost_Map #codom_dom #l1 #l2 #i #H
 whd in match tech_cost_of_label; normalize nodelta @same_ltb_rect
 [ @(ltb_rect ? i (|l2|)) @(ltb_rect ? (i+|l1|) (|l1@l2|)) #K1 #K2
   whd in match ltb; normalize nodelta
   [1: >le_to_leb_true try assumption applyS le_to_leb_true / by /
   |4: >not_le_to_leb_false try assumption applyS not_le_to_leb_false
       change with (¬ ? ≤ ?) in K1; applyS K1
   |2: @⊥ @(absurd (i+|l1| < |l1@l2|)) / by / >length_append
       applyS (monotonic_lt_plus_r … (|l1|)) / by /
   |3: @⊥ @(absurd ?? K2) >length_append in K1; #K1 /2 by lt_plus_to_lt_l/ ]
 | #H1 #H2
   generalize in match (tech_cost_of_label0 ??? (l1@l2) ??);
   <(shift_nth_safe … H1) #p %
 | / by / ]
qed.

lemma tech_cost_of_label_prefix:
 ∀cost_labels,cost_map,codom_dom,l1,l2,i.
  i < |l1| →
   tech_cost_of_label cost_labels cost_map codom_dom l1 i =
   tech_cost_of_label cost_labels cost_map codom_dom (l1@l2) i.
 #cost_labels #cost_map #codom_dom #l1 #l2 #i #H
 whd in match tech_cost_of_label; normalize nodelta @same_ltb_rect
 [1:
   whd in match ltb; normalize nodelta
   >(le_to_leb_true … H) applyS le_to_leb_true
   >length_append whd in H; >commutative_plus @le_plus_a assumption
 |2:
   #K1 #K2
   generalize in match (tech_cost_of_label0 ??? (l1@l2) ??);
   <(shift_nth_prefix … l1 i l2 K1 K2) //
 |3:
   #_ #_ %
 ]
qed.
*)

(* in the standard library there are two Aop's!!! *)
lemma fold_sum' : ∀A,B.∀nil : B.∀op : Aop B nil.∀I,J,p.∀f : A → B.
\fold[op, nil]_{i ∈ I@J | p i} (f i) =
op (\fold[op, nil]_{i ∈ I | p i} (f i))
 (\fold[op, nil]_{i ∈ J | p i} (f i)).
#A #B #nil #op #I elim I -I [ #J #p #g >nill % ]
#hd #tl #IH #J #p #f whd in ⊢ (??%(????%?)); cases p normalize nodelta
[ <assoc @eq_f ] @IH
qed.

lemma lookup_present_to_lookup_def : ∀tag,A,m,x,x_prf,def.
lookup_def tag A m x def = lookup_present tag A m x x_prf.
#tag #A #m #x #x_prf #def
whd in ⊢ (??%%); whd in x_prf; cases (lookup … m x) in x_prf;
[ * #ABS cases (ABS ?) % ]
#y #prf % qed.

let rec compute_trace_label_return_using_paid_ok_with_trace
 (prog: labelled_object_code)
 (initial: Status (cm prog))
 (final: Status (cm prog))
 (trace: trace_label_return (OC_abstract_status prog) initial final)
 on trace:
 ∀unrepeating_witness: tlr_unrepeating … trace.
  let ctrace ≝ flatten_trace_label_return (OC_abstract_status prog) … trace in
  compute_trace_label_return_cost_using_paid prog … trace =
   (Σ_{i ∈ ctrace} (ASM_cost_map prog i))
    ≝ ?
and compute_trace_any_label_using_paid_ok_with_trace
 (prog: labelled_object_code)
 (trace_ends_flag: trace_ends_with_ret)
 (initial: Status (cm prog))
 (final: Status (cm prog))
 (trace: trace_any_label (OC_abstract_status prog) trace_ends_flag initial final)
 on trace:
  ∀unrepeating_witness: tal_unrepeating … trace.
  let ctrace ≝ flatten_trace_any_label (OC_abstract_status prog) … trace_ends_flag … trace in
  compute_trace_any_label_cost_using_paid … trace =
   (Σ_{i ∈ ctrace} (ASM_cost_map prog i))
    ≝ ?
and compute_trace_label_label_using_paid_ok_with_trace
 (prog: labelled_object_code)
 (trace_ends_flag: trace_ends_with_ret)
 (initial: Status (cm prog))
 (final: Status (cm prog))
 (trace: trace_label_label (OC_abstract_status prog) trace_ends_flag initial final)
 (unrepeating_witness: tll_unrepeating … trace)
 on trace:
 ∀unrepeating_witness: tll_unrepeating … trace.
  let ctrace ≝ flatten_trace_label_label (OC_abstract_status prog) … trace in
  compute_trace_label_label_cost_using_paid … trace =
   (Σ_{i ∈ ctrace} (ASM_cost_map prog i))
    ≝ ?.
  cases trace normalize nodelta
  [ #sb #sa #tr #unrepeating_witness whd in ⊢ (??%?);
    whd in match (flatten_trace_label_return ????);
    @compute_trace_label_label_using_paid_ok_with_trace
    assumption
  | #si #sl #sf #tr1 #tr2 #unrepeating_witness
    whd in ⊢ (??%?);
    whd in match flatten_trace_label_return; normalize nodelta
    whd in match (observables_trace_label_return ?????);
    >costlabels_of_observables_append
    change with (? = \fold[natAop,0]_{i ∈ ?}(?)) >fold_sum' @eq_f2
    [ @compute_trace_label_label_using_paid_ok_with_trace
      -compute_trace_label_label_using_paid_ok_with_trace
      inversion unrepeating_witness
      #tll_unrepeating #tlr_unrepeating #_ assumption
    | @(compute_trace_label_return_using_paid_ok_with_trace)
      -compute_trace_label_return_using_paid_ok_with_trace
      inversion unrepeating_witness
      #tll_unrepeating #tlr_unrepeating #_ assumption
    ]
  |9:
    #end_flag #start_status #end_status #trace_any_label #costed_assm
    #unrepeating_witness'
    whd in ⊢ (??%?); whd in ⊢ (??(?%?)?);
    whd in match flatten_trace_label_label; normalize nodelta
    whd in match (observables_trace_label_label ??????);
    >compute_trace_any_label_using_paid_ok_with_trace
    [1:
      change with (? = ? + ?) @eq_f2 [2: %]
      change with (? = lookup_def ? ? ? ? ?)
      whd in match (as_label_safe); normalize nodelta
      @opt_safe_elim #cost_lbl whd in ⊢ (??%?→?); #Some_assm
      cases (compute_costs ?) #m * #A #B
      >(lookup_present_to_lookup_def … (A … Some_assm)) [2: //]
      <(B … (Some_assm))
      cases (pi2 ?? (block_cost ??)) try % assumption
    |2:
      assumption
    ]
  |3:
    #start_status #final_status #execute_assm #classifier_assm #costed_assm
    #unrepeating_witness
    %
  |4:
    #start_status #final_status #execute_assm #classifier_assm #unrepeating_witness
    %
  |5:
    #status_pre_fun_call #status_start_fun_call #status_final #execute_assm
    #classifier_assm #after_return_assm #trace_label_return #costed_assm #unrepeating_witness
    whd in ⊢ (??%?);
    whd in match flatten_trace_any_label; normalize nodelta
    whd in match (observables_trace_any_label ??????);
    >(costlabels_of_observables_append … [?])
    >costlabels_of_observables_trace_label_return_id_irrelevant [2: %{one} ]
    @compute_trace_label_return_using_paid_ok_with_trace
    //
  |6:
    #status_pre_fun_call #status_start_fun_call #status_final #execute_assm
    #classifier_assm #trace_label_return #unrepeating_witness
    whd in ⊢ (??%?);
    whd in match flatten_trace_any_label; normalize nodelta
    whd in match (observables_trace_any_label ??????);
    >(costlabels_of_observables_append … [?])
    >costlabels_of_observables_trace_label_return_id_irrelevant [2: %{one} ]
    @compute_trace_label_return_using_paid_ok_with_trace
    //
  |7:
    #end_flag #status_pre_fun_call #status_start_fun_call #status_after_fun_call
    #status_final #execute_assm #classifier_assm #after_return_assm #trace_label_return
    #costed_assm #trace_any_label #unrepeating_witness
    whd in ⊢ (??%?);
    whd in match flatten_trace_any_label in ⊢ (???%); normalize nodelta
    whd in match (observables_trace_any_label ??????);
    >(costlabels_of_observables_append … [?])
    >costlabels_of_observables_append
    >costlabels_of_observables_trace_label_return_id_irrelevant [2: %{one} ]
    >fold_sum' change with (? = \fold[plus,0]_{i∈?@?}?) >fold_sum'
    cases unrepeating_witness * #H1 #H2 #H3 @eq_f2
    [ @compute_trace_label_return_using_paid_ok_with_trace
    | @compute_trace_any_label_using_paid_ok_with_trace
    ] assumption
  |8:
    #end_flag #status_pre_fun_call #status_start_fun_call #status_final
    #execute_assm #trace_any_label #classifier_assm #costed_assm #unrepeating_witness
    whd in ⊢ (??%?);
    @compute_trace_any_label_using_paid_ok_with_trace
    cases unrepeating_witness
    #memb_1 #tal_unrepeating assumption
  ]
qed.

lemma compute_max_trace_label_return_cost_ok_with_trace :
  ∀prog: labelled_object_code.
  ∀initial: Status (cm prog).
  ∀final: Status (cm prog).
  ∀trace: trace_label_return (OC_abstract_status prog) initial final.
  ∀unrepeating_witness: tlr_unrepeating … trace.
    let cost_map ≝ ASM_cost_map … prog in
    let ctrace ≝ flatten_trace_label_return … trace in
      clock … (cm prog) … final = clock … (cm prog) … initial +
        (Σ_{i ∈ ctrace} (cost_map i)).
  #prog #initial #final #trace #unrepeating_witness normalize nodelta
  <compute_trace_label_return_using_paid_ok_with_trace try assumption
  >compute_trace_label_return_cost_using_paid_ok >commutative_plus //
qed.