source: src/ASM/CostsProof.ma @ 1964

Last change on this file since 1964 was 1964, checked in by tranquil, 8 years ago

introduced as_label_of_cost and adapted accordingly. Equality of cost mapping sums

File size: 32.1 KB
Line 
1include "ASM/ASMCostsSplit.ma".
2include "ASM/WellLabeled.ma".
3include "ASM/Status.ma".
4include "common/StructuredTraces.ma".
5include "arithmetics/bigops.ma".
6
7include alias "arithmetics/nat.ma".
8include alias "basics/logic.ma".
9
10let rec compute_max_trace_label_label_cost
11  (cm: ?)
12  (cost_labels: BitVectorTrie costlabel 16)
13   (trace_ends_flag: trace_ends_with_ret)
14    (start_status: Status cm) (final_status: Status cm)
15      (the_trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag
16        start_status final_status) on the_trace: nat ≝
17  match the_trace with
18  [ tll_base ends_flag initial final given_trace labelled_proof ⇒
19      compute_max_trace_any_label_cost … given_trace
20  ]
21and compute_max_trace_any_label_cost
22  (cm: ?)
23  (cost_labels: BitVectorTrie costlabel 16)
24  (trace_ends_flag: trace_ends_with_ret)
25   (start_status: Status cm) (final_status: Status cm)
26     (the_trace: trace_any_label (ASM_abstract_status cm cost_labels) trace_ends_flag start_status final_status)
27       on the_trace: nat ≝
28  match the_trace with
29  [ tal_base_not_return the_status _ _ _ _ ⇒ current_instruction_cost cm the_status
30  | tal_base_return the_status _ _ _ ⇒ current_instruction_cost cm the_status
31  | tal_base_call pre_fun_call start_fun_call final _ _ _ call_trace _ ⇒
32      let current_instruction_cost ≝ current_instruction_cost cm pre_fun_call in
33      let call_trace_cost ≝ compute_max_trace_label_return_cost … call_trace in
34        call_trace_cost + current_instruction_cost
35  | tal_step_call end_flag pre_fun_call start_fun_call after_fun_call final
36     _ _ _ call_trace _ final_trace ⇒
37      let current_instruction_cost ≝ current_instruction_cost cm pre_fun_call in
38      let call_trace_cost ≝ compute_max_trace_label_return_cost … call_trace in
39      let final_trace_cost ≝ compute_max_trace_any_label_cost cm cost_labels end_flag … final_trace in
40        call_trace_cost + current_instruction_cost + final_trace_cost
41  | tal_step_default end_flag status_pre status_init status_end _ tail_trace _ _ ⇒
42      let current_instruction_cost ≝ current_instruction_cost cm status_pre in
43      let tail_trace_cost ≝
44       compute_max_trace_any_label_cost cm cost_labels end_flag
45        status_init status_end tail_trace
46      in
47        current_instruction_cost + tail_trace_cost
48  ]
49and compute_max_trace_label_return_cost
50  (cm: ?)
51  (cost_labels: BitVectorTrie costlabel 16)
52  (start_status: Status cm) (final_status: Status cm)
53    (the_trace: trace_label_return (ASM_abstract_status cm cost_labels) start_status final_status)
54      on the_trace: nat ≝
55  match the_trace with
56  [ tlr_base before after trace_to_lift ⇒ compute_max_trace_label_label_cost … trace_to_lift
57  | tlr_step initial labelled final labelled_trace ret_trace ⇒
58      let labelled_cost ≝ compute_max_trace_label_label_cost … labelled_trace in
59      let return_cost ≝ compute_max_trace_label_return_cost … ret_trace in
60        labelled_cost + return_cost
61  ].
62
63include alias "arithmetics/nat.ma".
64
65let rec compute_max_trace_label_label_cost_is_ok
66  (cm: ?)
67  (cost_labels: BitVectorTrie costlabel 16)
68   (trace_ends_flag: trace_ends_with_ret)
69    (start_status: Status cm) (final_status: Status cm)
70      (the_trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag
71        start_status final_status) on the_trace:
72          clock … cm … final_status = (compute_max_trace_label_label_cost cm cost_labels trace_ends_flag start_status final_status the_trace) + (clock … cm … start_status) ≝ ?
73and compute_max_trace_any_label_cost_is_ok
74  (cm: ?)
75  (cost_labels: BitVectorTrie costlabel 16)
76  (trace_ends_flag: trace_ends_with_ret)
77   (start_status: Status cm) (final_status: Status cm)
78     (the_trace: trace_any_label (ASM_abstract_status cm cost_labels) trace_ends_flag start_status final_status)
79       on the_trace:
80         clock … cm … final_status = (compute_max_trace_any_label_cost cm cost_labels trace_ends_flag start_status final_status the_trace) + (clock … cm … start_status) ≝ ?
81and compute_max_trace_label_return_cost_is_ok
82  (cm: ?)
83  (cost_labels: BitVectorTrie costlabel 16)
84  (start_status: Status cm) (final_status: Status cm)
85    (the_trace: trace_label_return (ASM_abstract_status cm cost_labels) start_status final_status)
86      on the_trace:
87        clock … cm … final_status = (compute_max_trace_label_return_cost cm cost_labels start_status final_status the_trace) + clock … cm … start_status ≝ ?.
88  [1:
89    cases the_trace
90    #ends_flag #start_status #end_status #any_label_trace #is_costed
91    normalize @compute_max_trace_any_label_cost_is_ok
92  |2:
93    cases the_trace
94    [1,2:
95      #start_status #final_status #is_next #is_not_return try (#is_costed)
96      change with (current_instruction_cost cm start_status) in ⊢ (???(?%?));
97      cases(is_next) @execute_1_ok_clock
98    |3:
99      #status_pre_fun_call #status_start_fun_call #status_final #is_next
100      #classifier_assm #after_return_assm #call_trace #costed_assm
101      whd in match (compute_max_trace_any_label_cost … (tal_base_call …));
102      >(compute_max_trace_label_return_cost_is_ok … call_trace)
103      >associative_plus @eq_f cases(is_next)
104      @execute_1_ok_clock
105    |4:
106      #end_flag #status_pre_fun_call #status_start_fun_call #status_after_fun_call
107      #status_final #is_next #is_call #is_after_return #call_trace #not_costed #final_trace
108      change with (
109      let current_instruction_cost ≝ current_instruction_cost cm status_pre_fun_call in
110      let call_trace_cost ≝ compute_max_trace_label_return_cost cm … call_trace in
111      let final_trace_cost ≝ compute_max_trace_any_label_cost cm cost_labels end_flag … final_trace in
112        call_trace_cost + current_instruction_cost + final_trace_cost) in ⊢ (???(?%?));
113      normalize nodelta;
114      >(compute_max_trace_any_label_cost_is_ok … cost_labels end_flag status_after_fun_call
115          status_final final_trace)
116      >(compute_max_trace_label_return_cost_is_ok … cost_labels status_start_fun_call
117        status_after_fun_call call_trace)
118      cases(is_next) in match (clock … cm status_start_fun_call);
119      >(execute_1_ok_clock cm status_pre_fun_call)
120      <associative_plus in ⊢ (??%?);
121      <commutative_plus in match (
122        compute_max_trace_any_label_cost cm cost_labels end_flag status_after_fun_call status_final final_trace
123          + compute_max_trace_label_return_cost cm cost_labels status_start_fun_call status_after_fun_call call_trace);
124      >associative_plus in ⊢ (??%?); >associative_plus in ⊢ (???%); >associative_plus in ⊢ (???%);
125      @eq_f >commutative_plus in ⊢ (??%?); >associative_plus in ⊢ (??%?);
126      @eq_f @commutative_plus
127    |5:
128      #end_flag #status_pre #status_init #status_end #is_next
129      #trace_any_label #is_other #is_not_costed
130      change with (
131      let current_instruction_cost ≝ current_instruction_cost cm status_pre in
132      let tail_trace_cost ≝
133       compute_max_trace_any_label_cost cm cost_labels end_flag
134        status_init status_end trace_any_label
135      in
136        current_instruction_cost + tail_trace_cost) in ⊢ (???(?%?));
137      normalize nodelta;
138      >(compute_max_trace_any_label_cost_is_ok cm cost_labels end_flag
139         status_init status_end trace_any_label)
140      cases(is_next) in match (clock … cm status_init);
141      >(execute_1_ok_clock … status_pre)
142      >commutative_plus >associative_plus >associative_plus @eq_f
143      @commutative_plus
144    ]
145  |3:
146    cases the_trace
147    [1:
148      #status_before #status_after #trace_to_lift
149      normalize @compute_max_trace_label_label_cost_is_ok
150    |2:
151      #status_initial #status_labelled #status_final #labelled_trace #ret_trace
152      normalize
153      >(compute_max_trace_label_return_cost_is_ok cm cost_labels status_labelled status_final ret_trace);
154      >(compute_max_trace_label_label_cost_is_ok cm cost_labels doesnt_end_with_ret status_initial status_labelled labelled_trace);
155      <associative_plus in ⊢ (??%?);
156      >commutative_plus in match (
157        compute_max_trace_label_return_cost cm cost_labels status_labelled status_final ret_trace
158          + compute_max_trace_label_label_cost cm cost_labels doesnt_end_with_ret status_initial status_labelled labelled_trace);
159      %
160    ]
161  ]
162qed.
163
164let rec compute_trace_label_label_cost_using_paid
165  (cm: ?)
166  (cost_labels: BitVectorTrie costlabel 16)
167   (trace_ends_flag: trace_ends_with_ret)
168    (start_status: Status cm) (final_status: Status cm)
169      (the_trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag
170        start_status final_status) on the_trace: nat ≝
171  match the_trace with
172  [ tll_base ends_flag initial final given_trace labelled_proof ⇒
173      compute_paid_trace_label_label cm cost_labels … the_trace +
174      compute_trace_any_label_cost_using_paid … given_trace
175  ]
176and compute_trace_any_label_cost_using_paid
177  (cm: ?)
178  (cost_labels: BitVectorTrie costlabel 16)
179  (trace_ends_flag: trace_ends_with_ret)
180   (start_status: Status cm) (final_status: Status cm)
181     (the_trace: trace_any_label (ASM_abstract_status cm cost_labels) trace_ends_flag start_status final_status)
182       on the_trace: nat ≝
183  match the_trace with
184  [ tal_base_not_return the_status _ _ _ _ ⇒ 0
185  | tal_base_return the_status _ _ _ ⇒ 0
186  | tal_base_call pre_fun_call start_fun_call final _ _ _ call_trace _ ⇒
187      compute_trace_label_return_cost_using_paid … call_trace
188  | tal_step_call end_flag pre_fun_call start_fun_call after_fun_call final
189     _ _ _ call_trace _ final_trace ⇒
190      let call_trace_cost ≝ compute_trace_label_return_cost_using_paid … call_trace in
191      let final_trace_cost ≝ compute_trace_any_label_cost_using_paid cm cost_labels end_flag … final_trace in
192        call_trace_cost + final_trace_cost
193  | tal_step_default end_flag status_pre status_init status_end _ tail_trace _ _ ⇒
194     compute_trace_any_label_cost_using_paid cm cost_labels end_flag
195      status_init status_end tail_trace
196  ]
197and compute_trace_label_return_cost_using_paid
198  (cm: ?)
199  (cost_labels: BitVectorTrie costlabel 16)
200  (start_status: Status cm) (final_status: Status cm)
201    (the_trace: trace_label_return (ASM_abstract_status cm cost_labels) start_status final_status)
202      on the_trace: nat ≝
203  match the_trace with
204  [ tlr_base before after trace_to_lift ⇒ compute_trace_label_label_cost_using_paid … trace_to_lift
205  | tlr_step initial labelled final labelled_trace ret_trace ⇒
206      let labelled_cost ≝ compute_trace_label_label_cost_using_paid … labelled_trace in
207      let return_cost ≝ compute_trace_label_return_cost_using_paid … ret_trace in
208        labelled_cost + return_cost
209  ].
210
211let rec compute_trace_label_label_cost_using_paid_ok
212  (cm: ?)
213  (cost_labels: BitVectorTrie costlabel 16)
214   (trace_ends_flag: trace_ends_with_ret)
215    (start_status: Status cm) (final_status: Status cm)
216      (the_trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag
217        start_status final_status) on the_trace:
218 compute_trace_label_label_cost_using_paid cm cost_labels … the_trace =
219 compute_max_trace_label_label_cost … the_trace ≝ ?
220and compute_trace_any_label_cost_using_paid_ok
221  (cm: ?)
222  (cost_labels: BitVectorTrie costlabel 16)
223  (trace_ends_flag: trace_ends_with_ret)
224   (start_status: Status cm) (final_status: Status cm)
225     (the_trace: trace_any_label (ASM_abstract_status cm cost_labels)
226      trace_ends_flag start_status final_status) on the_trace:     
227  compute_paid_trace_any_label cm cost_labels trace_ends_flag … the_trace
228  +compute_trace_any_label_cost_using_paid cm cost_labels trace_ends_flag … the_trace
229  =compute_max_trace_any_label_cost cm cost_labels trace_ends_flag … the_trace ≝ ?
230and compute_trace_label_return_cost_using_paid_ok
231  (cm: ?)
232  (cost_labels: BitVectorTrie costlabel 16)
233  (start_status: Status cm) (final_status: Status cm)
234    (the_trace: trace_label_return (ASM_abstract_status cm cost_labels)
235     start_status final_status) on the_trace:
236 compute_trace_label_return_cost_using_paid cm cost_labels … the_trace =
237 compute_max_trace_label_return_cost cm cost_labels … the_trace ≝ ?.
238[ cases the_trace #endsf #ss #es #tr #H normalize
239  @compute_trace_any_label_cost_using_paid_ok
240| cases the_trace
241  [ #ss #fs #H1 #H2 #H3 whd in ⊢ (??(?%%)%); <plus_n_O %
242  | #ss #fs #H1 #H2 whd in ⊢ (??(?%%)%); <plus_n_O %
243  |
244    #sp #ss #sf #H1 #H2 #tr1 #tr2 #H3
245    whd in ⊢ (???%); whd in ⊢ (??(??%)?); whd in ⊢ (??(?%?)?);
246    >compute_trace_label_return_cost_using_paid_ok in ⊢ (??%?);
247    >commutative_plus in ⊢ (??%?); @eq_f %
248  | #ef #spfc #ssfc #safc #sf #H1 #H2 #H3 #tr1 #H4 #tr2 whd in ⊢ (??(?%%)%);
249    <compute_trace_any_label_cost_using_paid_ok
250    <compute_trace_label_return_cost_using_paid_ok
251    -compute_trace_label_label_cost_using_paid_ok
252    -compute_trace_label_return_cost_using_paid_ok
253    -compute_trace_any_label_cost_using_paid_ok
254    >commutative_plus in ⊢ (???(?%?));
255    >commutative_plus in ⊢ (??(??%)?);
256    >associative_plus >associative_plus in ⊢ (???%); @eq_f2 try %
257    <associative_plus <commutative_plus %
258  | #ef #sp #si #se #H1 #tr #H2 #H3 whd in ⊢ (??(?%%)%); >associative_plus @eq_f2
259    [ % | @compute_trace_any_label_cost_using_paid_ok ]
260  ]
261| cases the_trace
262  [ #sb #sa #tr normalize @compute_trace_label_label_cost_using_paid_ok
263  | #si #sl #sf #tr1 #tr2 normalize @eq_f2
264    [ @compute_trace_label_label_cost_using_paid_ok
265    | @compute_trace_label_return_cost_using_paid_ok ]]]
266qed.
267
268include alias "ASM/BitVectorTrie.ma".
269
270(*
271let rec compute_cost_trace_label_label
272  (cm: BitVectorTrie Byte 16)
273  (cost_labels: BitVectorTrie costlabel 16)
274   (trace_ends_flag: trace_ends_with_ret)
275    (start_status: Status cm) (final_status: Status cm)
276      (the_trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag
277        start_status final_status) on the_trace:
278         list (Σk:costlabel. ∃pc: Word. lookup_opt … pc cost_labels = Some … k) ≝
279  match the_trace with
280  [ tll_base ends_flag initial final given_trace labelled_proof ⇒
281     let pc ≝ program_counter ? cm initial in
282     let label ≝
283      match lookup_opt … pc cost_labels return λx: option ?. x ≠ None … → costlabel with
284      [ None ⇒ λabs. ⊥
285      | Some l ⇒ λ_. l ] labelled_proof in
286      (mk_Sig ?? label ?)::compute_cost_trace_any_label cm cost_labels ends_flag initial final … given_trace
287  ]
288and compute_cost_trace_any_label
289  (cm: BitVectorTrie Byte 16)
290  (cost_labels: BitVectorTrie costlabel 16)
291  (trace_ends_flag: trace_ends_with_ret)
292   (start_status: Status cm) (final_status: Status cm)
293     (the_trace: trace_any_label (ASM_abstract_status cm cost_labels) trace_ends_flag start_status final_status)
294       on the_trace: list (Σk:costlabel. ∃pc. lookup_opt … pc cost_labels = Some … k) ≝
295  match the_trace with
296  [ tal_base_not_return the_status _ _ _ _ ⇒ [ ]
297  | tal_base_call pre_fun_call start_fun_call final _ _ _ call_trace _ ⇒
298      compute_cost_trace_label_return … call_trace
299  | tal_base_return the_status _ _ _ ⇒ [ ]
300  | tal_step_call end_flag pre_fun_call start_fun_call after_fun_call final
301     _ _ _ call_trace _ final_trace ⇒
302      let call_cost_trace ≝ compute_cost_trace_label_return … call_trace in
303      let final_cost_trace ≝ compute_cost_trace_any_label cm cost_labels end_flag … final_trace in
304        call_cost_trace @ final_cost_trace
305  | tal_step_default end_flag status_pre status_init status_end _ tail_trace _ _ ⇒
306       compute_cost_trace_any_label cm cost_labels end_flag
307        status_init status_end tail_trace
308  ]
309and compute_cost_trace_label_return
310  (cm: BitVectorTrie Byte 16)
311  (cost_labels: BitVectorTrie costlabel 16)
312  (start_status: Status cm) (final_status: Status cm)
313    (the_trace: trace_label_return (ASM_abstract_status cm cost_labels) start_status final_status)
314      on the_trace: list (Σk:costlabel. ∃pc. lookup_opt … pc cost_labels = Some … k) ≝
315  match the_trace with
316  [ tlr_base before after trace_to_lift ⇒ compute_cost_trace_label_label cm … trace_to_lift
317  | tlr_step initial labelled final labelled_trace ret_trace ⇒
318      let labelled_cost ≝ compute_cost_trace_label_label cm … labelled_trace in
319      let return_cost ≝ compute_cost_trace_label_return cm … ret_trace in
320        labelled_cost @ return_cost
321  ].
322 [1:
323  %{pc} whd in match label;  generalize in match labelled_proof; whd in ⊢ (% → ?);
324   whd in match (as_costed ??); whd in match (as_label ??); normalize nodelta
325   cases (lookup_opt costlabel … (program_counter … initial) cost_labels)
326   normalize
327  [ #abs cases abs #absurd @⊥ @absurd % | // ]
328 | cases abs #absurd @absurd % ]
329qed.
330*)
331
332include alias "arithmetics/nat.ma".
333include alias "basics/logic.ma".
334
335include alias "arithmetics/bigops.ma".
336
337(* This shoudl go in bigops! *)
338theorem bigop_sum_rev: ∀k1,k2,p,B,nil.∀op:Aop B nil.∀f:nat→B.
339 \big[op,nil]_{i<k1+k2|p i} (f i) =
340 op \big[op,nil]_{i<k2|p (i+k1)} (f (i+k1)) \big[op,nil]_{i<k1|p i} (f i).
341 #k1 #k2 #p #B #nil #op #f >bigop_sum
342 >commutative_plus @same_bigop #i @leb_elim normalize
343 [2,4: //
344 | #H1 #H2 <plus_minus_m_m //
345 | #H1 #H2 #H3 <plus_minus_m_m //]
346qed.
347
348(* This is taken by sigma_pi.ma that does not compile now *)
349definition natAop ≝ mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n))
350   (λa,b,c.sym_eq ??? (associative_plus a b c)).
351
352definition natACop ≝ mk_ACop nat 0 natAop commutative_plus.
353
354definition natDop ≝ mk_Dop nat 0 natACop times (λn.(sym_eq ??? (times_n_O n)))
355   distributive_times_plus.
356
357unification hint  0 ≔ ;
358   S ≟ mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n))
359   (λa,b,c.sym_eq ??? (associative_plus a b c))
360(* ---------------------------------------- *) ⊢
361   plus ≡ op ? ? S.
362
363unification hint  0 ≔ ;
364   S ≟ mk_ACop nat 0 (mk_Aop nat 0 plus (λa.refl ? a) (λn.sym_eq ??? (plus_n_O n))
365   (λa,b,c.sym_eq ??? (associative_plus a b c))) commutative_plus
366(* ---------------------------------------- *) ⊢
367   plus ≡ op ? ? S.
368   
369unification hint  0 ≔ ;
370   S ≟ natDop
371(* ---------------------------------------- *) ⊢
372   plus ≡ sum ? ? S.
373
374unification hint  0 ≔ ;
375   S ≟ natDop
376(* ---------------------------------------- *) ⊢
377   times ≡ prod ? ? S.
378
379notation > "Σ_{ ident i < n } f"
380  with precedence 20
381for @{'bigop $n plus 0 (λ${ident i}.true) (λ${ident i}. $f)}.
382
383notation < "Σ_{ ident i < n } f"
384  with precedence 20
385for @{'bigop $n plus 0 (λ${ident i}:$X.true) (λ${ident i}:$Y. $f)}.
386
387definition tech_cost_of_label0:
388 ∀cost_labels: BitVectorTrie costlabel 16.
389 ∀cost_map: identifier_map CostTag nat.
390 ∀codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k).
391 ∀ctrace:list (Σk:costlabel.∃b.lookup_opt … b cost_labels = Some ? k).
392 ∀i,p. present … cost_map (nth_safe ? i ctrace p).
393 #cost_labels #cost_map #codom_dom #ctrace #i #p
394 cases (nth_safe … i ctrace ?) normalize #id * #id_pc #K
395 lapply (codom_dom … K) #k_pres >(lookup_lookup_present … k_pres)
396 % #abs destruct (abs)
397qed.
398
399include alias "arithmetics/nat.ma".
400include alias "basics/logic.ma".
401
402lemma ltb_rect:
403 ∀P:Type[0].∀n,m. (n < m → P) → (¬ n < m → P) → P.
404 #P #n #m lapply (refl … (ltb n m)) cases (ltb n m) in ⊢ (???% → %); #E #H1 #H2
405 [ @H1 @leb_true_to_le @E | @H2 @leb_false_to_not_le @E ]
406qed.
407
408lemma same_ltb_rect:
409 ∀P,n,m,H1,H2,n',m',H1',H2'.
410  ltb n m = ltb n' m' → (∀x,y. H1 x = H1' y) → (∀x,y. H2 x = H2' y) →
411   ltb_rect P n m H1 H2 =
412   ltb_rect P n' m' H1' H2'.
413 #P #n #m #H1 #H2 #n' #m' #H1' #H2' #E #K1 #K2 whd in ⊢ (??%?);
414 cut (∀xxx,yyy,xxx',yyy'.
415   match ltb n m
416   return λx:bool.
417           eq bool (ltb n m) x
418            → (lt n m → P) → (Not (lt n m) → P) → P
419    with
420    [ true ⇒
421        λE0:eq bool (ltb n m) true.
422         λH10:lt n m → P.
423          λH20:Not (lt n m) → P. H10 (xxx E0)
424    | false ⇒
425        λE0:eq bool (ltb n m) false.
426         λH10:lt n m → P.
427          λH20:Not (lt n m) → P. H20 (yyy E0)]
428    (refl … (ltb n m)) H1 H2 =
429   match ltb n' m'
430   return λx:bool.
431           eq bool (ltb n' m') x
432            → (lt n' m' → P) → (Not (lt n' m') → P) → P
433    with
434    [ true ⇒
435        λE0:eq bool (ltb n' m') true.
436         λH10:lt n' m' → P.
437          λH20:Not (lt n' m') → P. H10 (xxx' E0)
438    | false ⇒
439        λE0:eq bool (ltb n' m') false.
440         λH10:lt n' m' → P.
441          λH20:Not (lt n' m') → P. H20 (yyy' E0)]
442    (refl … (ltb n' m')) H1' H2'
443  ) [2: #X @X]
444 >E cases (ltb n' m') #xxx #yyy #xxx' #yyy' normalize
445 [ @K1 | @K2 ]
446qed.
447
448definition tech_cost_of_label:
449 ∀cost_labels: BitVectorTrie costlabel 16.
450 ∀cost_map: identifier_map CostTag nat.
451 ∀codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k).
452 list (Σk:costlabel.∃b.lookup_opt … b cost_labels = Some ? k) →
453 nat → nat
454≝ λcost_labels,cost_map,codom_dom,ctrace,i.
455 ltb_rect ? i (|ctrace|)
456 (λH. lookup_present ?? cost_map (nth_safe ? i ctrace H) ?)
457 (λ_.0).
458 @tech_cost_of_label0 @codom_dom
459qed.
460
461lemma shift_nth_safe:
462 ∀T,i,l2,l1,K1,K2.
463  nth_safe T i l1 K1 = nth_safe T (i+|l2|) (l2@l1) K2.
464 #T #i #l2 elim l2 normalize
465  [ #l1 #K1 <plus_n_O #K2 %
466  | #hd #tl #IH #l1 #K1 <plus_n_Sm #K2 change with (? < ?) in K1; change with (? < ?) in K2;
467    whd in ⊢ (???%); @IH ]
468qed.
469
470lemma shift_nth_prefix:
471 ∀T,l1,i,l2,K1,K2.
472  nth_safe T i l1 K1 = nth_safe T i (l1@l2) K2.
473  #T #l1 elim l1 normalize
474  [
475    #i #l1 #K1 cases(lt_to_not_zero … K1)
476  |
477    #hd #tl #IH #i #l2
478    cases i
479    [
480      //
481    |
482      #i' #K1 #K2 whd in ⊢ (??%%);
483      @IH
484    ]
485  ]
486qed.
487
488lemma tech_cost_of_label_shift:
489 ∀cost_labels,cost_map,codom_dom,l1,l2,i.
490  i < |l2| →
491   tech_cost_of_label cost_labels cost_map codom_dom l2 i =
492   tech_cost_of_label cost_labels cost_map codom_dom (l1@l2) (i+|l1|).
493 #cost_labels #cost_Map #codom_dom #l1 #l2 #i #H
494 whd in match tech_cost_of_label; normalize nodelta @same_ltb_rect
495 [ @(ltb_rect ? i (|l2|)) @(ltb_rect ? (i+|l1|) (|l1@l2|)) #K1 #K2
496   whd in match ltb; normalize nodelta
497   [1: >le_to_leb_true try assumption applyS le_to_leb_true / by /
498   |4: >not_le_to_leb_false try assumption applyS not_le_to_leb_false
499       change with (¬ ? ≤ ?) in K1; applyS K1
500   |2: @⊥ @(absurd (i+|l1| < |l1@l2|)) / by / >length_append
501       applyS (monotonic_lt_plus_r … (|l1|)) / by /
502   |3: @⊥ @(absurd ?? K2) >length_append in K1; #K1 /2 by lt_plus_to_lt_l/ ]
503 | #H1 #H2
504   generalize in match (tech_cost_of_label0 ??? (l1@l2) ??);
505   <(shift_nth_safe … H1) #p %
506 | / by / ]
507qed.
508
509lemma tech_cost_of_label_prefix:
510 ∀cost_labels,cost_map,codom_dom,l1,l2,i.
511  i < |l1| →
512   tech_cost_of_label cost_labels cost_map codom_dom l1 i =
513   tech_cost_of_label cost_labels cost_map codom_dom (l1@l2) i.
514 #cost_labels #cost_map #codom_dom #l1 #l2 #i #H
515 whd in match tech_cost_of_label; normalize nodelta @same_ltb_rect
516 [1:
517   whd in match ltb; normalize nodelta
518   >(le_to_leb_true … H) applyS le_to_leb_true
519   >length_append whd in H; >commutative_plus @le_plus_a assumption
520 |2:
521   #K1 #K2
522   generalize in match (tech_cost_of_label0 ??? (l1@l2) ??);
523   <(shift_nth_prefix … l1 i l2 K1 K2) //
524 |3:
525   #_ #_ %
526 ]
527qed.
528   
529let rec compute_trace_label_return_using_paid_ok_with_trace
530 (cm: ?) (cost_labels: BitVectorTrie costlabel 16)
531 (cost_map: identifier_map CostTag nat)
532 (initial: Status cm) (final: Status cm)
533 (trace: trace_label_return (ASM_abstract_status cm cost_labels) initial final)
534 (codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k))
535 on trace:
536 ∀unrepeating_witness: tlr_unrepeating … trace.
537 ∀dom_codom:(∀k. ∀k_pres:present … cost_map k. ∀pc. lookup_opt … pc cost_labels = Some … k →
538   pi1 … (block_cost cm pc cost_labels) = lookup_present … k_pres).
539  let ctrace ≝ flatten_trace_label_return (ASM_abstract_status cm cost_labels) … trace in
540  compute_trace_label_return_cost_using_paid cm … trace =
541   (Σ_{i < |ctrace|} (tech_cost_of_label cost_labels cost_map codom_dom ctrace i))
542    ≝ ?
543and compute_trace_any_label_using_paid_ok_with_trace
544 (cm: ?) (cost_labels: BitVectorTrie costlabel 16)
545 (trace_ends_flag: trace_ends_with_ret)
546 (cost_map: identifier_map CostTag nat)
547 (initial: Status cm) (final: Status cm)
548 (trace: trace_any_label (ASM_abstract_status cm cost_labels) trace_ends_flag initial final)
549 (codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k))
550 (dom_codom:(∀k. ∀k_pres:present … cost_map k. ∀pc. lookup_opt … pc cost_labels = Some … k →
551   pi1 … (block_cost cm pc cost_labels) = lookup_present … k_pres))
552 on trace:
553  ∀unrepeating_witness: tal_unrepeating … trace.
554  let ctrace ≝ flatten_trace_any_label (ASM_abstract_status cm cost_labels) … trace_ends_flag … trace in
555  compute_trace_any_label_cost_using_paid … trace =
556   (Σ_{i < |ctrace|} (tech_cost_of_label cost_labels cost_map codom_dom ctrace i))
557    ≝ ?
558and compute_trace_label_label_using_paid_ok_with_trace
559 (cm: ?) (cost_labels: BitVectorTrie costlabel 16)
560 (trace_ends_flag: trace_ends_with_ret)
561 (cost_map: identifier_map CostTag nat)
562 (initial: Status cm) (final: Status cm)
563 (trace: trace_label_label (ASM_abstract_status cm cost_labels) trace_ends_flag initial final)
564 (unrepeating_witness: tll_unrepeating … trace)
565 (codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k))
566 (dom_codom:(∀k. ∀k_pres:present … cost_map k. ∀pc. lookup_opt … pc cost_labels = Some … k →
567   pi1 … (block_cost cm pc cost_labels) = lookup_present … k_pres))
568 on trace:
569 ∀unrepeating_witness: tll_unrepeating … trace.
570  let ctrace ≝ flatten_trace_label_label (ASM_abstract_status cm cost_labels) … trace in
571  compute_trace_label_label_cost_using_paid … trace =
572   (Σ_{i < |ctrace|} (tech_cost_of_label cost_labels cost_map codom_dom ctrace i))
573    ≝ ?.
574  cases trace normalize nodelta
575  [ #sb #sa #tr #unrepeating_witness #dom_codom whd in ⊢ (??%?);
576    whd in match (flatten_trace_label_return ????);
577    @compute_trace_label_label_using_paid_ok_with_trace
578    assumption
579  | #si #sl #sf #tr1 #tr2 #unrepeating_witness #dom_codom
580    whd in ⊢ (??%?);
581    whd in match (flatten_trace_label_return ????);
582    >append_length >bigop_sum_rev >commutative_plus @eq_f2
583    [ >(compute_trace_label_return_using_paid_ok_with_trace … cost_map … codom_dom ? dom_codom)
584      -compute_trace_label_return_using_paid_ok_with_trace
585      [1:
586        @same_bigop [//] #i #H #_ -dom_codom @tech_cost_of_label_shift //
587      |2:
588        inversion unrepeating_witness
589        #tll_unrepeating #tlr_unrepeating #_ assumption
590      ]
591    | >(compute_trace_label_label_using_paid_ok_with_trace … cost_map … codom_dom … dom_codom)
592      -compute_trace_label_label_using_paid_ok_with_trace
593      [1:
594        @same_bigop [//] #i #H #_ @(tech_cost_of_label_prefix … H)
595      |2,3:
596        inversion unrepeating_witness
597        #tll_unrepeating #tlr_unrepeating #_ assumption
598      ]
599    ]
600  |8:
601    #end_flag #start_status #end_status #trace_any_label #costed_assm
602    #unrepeating_witness'
603    whd in ⊢ (??%?); whd in ⊢ (??(?%?)?);
604    >(compute_trace_any_label_using_paid_ok_with_trace … cost_map … codom_dom … dom_codom)
605    [1:
606      whd in match (flatten_trace_label_label ?????);
607      >bigop_0 in ⊢ (???%); >commutative_plus @eq_f2
608      [1:
609        @same_bigop [//] #i #H #_ -dom_codom >(plus_n_O i) >plus_n_Sm
610        <(tech_cost_of_label_shift ??? [?] ? i) try assumption <(plus_n_O i) %
611      |2:
612        change with (? = lookup_present ? ? ? ? ?)
613        generalize in match (tech_cost_of_label0 ? ? ? ? ? ?);
614        normalize in match (nth_safe ? ? ? ?);
615        whd in costed_assm; lapply costed_assm whd in match (as_label ??);
616        inversion (lookup_opt ? ? (program_counter … cm start_status) cost_labels)
617        [1:
618          #_ #absurd @⊥ cases absurd #absurd @absurd %
619        |2:
620          normalize nodelta #cost_label #Some_assm #_ #p
621          cases (dom_codom ? p ? Some_assm)
622          cases (block_cost ???)
623          #cost #block_cost_assm
624          cases (block_cost_assm ??? trace_any_label ??)
625          try @refl assumption
626        ]
627      ]
628    |2:
629      assumption
630    ]
631  |3:
632    #start_status #final_status #execute_assm #classifier_assm #costed_assm
633    #unrepeating_witness
634    %
635  |4:
636    #start_status #final_status #execute_assm #classifier_assm #unrepeating_witness
637    %
638  |5:
639    #status_pre_fun_call #status_start_fun_call #status_final #execute_assm
640    #classifier_assm #after_return_assm #trace_label_return #costed_assm #unrepeating_witness
641    whd in ⊢ (??%?);
642    @(compute_trace_label_return_using_paid_ok_with_trace … cost_map … codom_dom ? dom_codom)
643    assumption
644  |6:
645    #end_flag #status_pre_fun_call #status_start_fun_call #status_after_fun_call
646    #status_final #execute_assm #classifier_assm #after_return_assm #trace_label_return
647    #costed_assm #trace_any_label #unrepeating_witness
648    whd in ⊢ (??%?);
649    >(compute_trace_label_return_using_paid_ok_with_trace … cost_map … codom_dom ? dom_codom)
650    [1:
651      >(compute_trace_any_label_using_paid_ok_with_trace … cost_map … codom_dom … dom_codom)
652      [1:
653        >length_append >bigop_sum_rev >commutative_plus @eq_f2
654        [ @same_bigop [2: #i #H #_ -dom_codom @tech_cost_of_label_shift assumption
655                      |1: #i #H % ]
656        | @same_bigop [#i #H %] #i #H #_ @(tech_cost_of_label_prefix … H)
657        ]
658      |2:
659        inversion unrepeating_witness
660        * #memb_1 #tal_unrepeating #tlr_unrepeating #_ assumption
661      ]
662    |2:
663      inversion unrepeating_witness
664      * #memb_1 #tal_unrepeating #tlr_unrepeating #_ assumption
665    ]
666  |7:
667    #end_flag #status_pre_fun_call #status_start_fun_call #status_final
668    #execute_assm #trace_any_label #classifier_assm #costed_assm #unrepeating_witness
669    whd in ⊢ (??%?);
670    @(compute_trace_any_label_using_paid_ok_with_trace … cost_map … codom_dom … dom_codom)
671    inversion unrepeating_witness
672    #memb_1 #tal_unrepeating #_ assumption
673  ]
674qed.
675 
676lemma compute_max_trace_label_return_cost_ok_with_trace_aux:
677  ∀code_memory: BitVectorTrie Byte 16.
678  ∀cost_labels: BitVectorTrie costlabel 16.
679  ∀cost_map: identifier_map CostTag nat.
680  ∀initial: Status code_memory.
681  ∀final: Status code_memory.
682  ∀trace: trace_label_return (ASM_abstract_status code_memory cost_labels) initial final.
683  ∀unrepeating_witness: tlr_unrepeating … trace.
684  ∀codom_dom: (∀pc,k. lookup_opt … pc cost_labels = Some … k → present … cost_map k).
685  ∀dom_codom: (∀k. ∀k_pres:present … cost_map k. ∀pc. lookup_opt … pc cost_labels = Some … k →
686      pi1 … (block_cost code_memory pc cost_labels) = lookup_present … k_pres).
687        let ctrace ≝ flatten_trace_label_return … trace in
688          clock … code_memory … final =
689            clock … code_memory … initial + (Σ_{i < |ctrace|} (tech_cost_of_label cost_labels cost_map codom_dom ctrace i)).
690  #code_memory #cost_labels #cost_map
691  #initial #final #trace #unrepeating_witness #codom_dom #dom_codom normalize nodelta
692  <compute_trace_label_return_using_paid_ok_with_trace try assumption
693  >commutative_plus >compute_trace_label_return_cost_using_paid_ok //
694qed.
695
696theorem compute_max_trace_label_return_cost_ok_with_trace:
697  ∀code_memory: BitVectorTrie Byte 16.
698  ∀cost_labels: BitVectorTrie costlabel 16.
699  ∀cost_labels_injective:
700   (∀pc,pc',l.
701     lookup_opt costlabel 16 pc cost_labels=Some costlabel l
702      →lookup_opt costlabel 16 pc' cost_labels=Some costlabel l→pc=pc').
703  ∀initial: Status code_memory.
704  ∀final: Status code_memory.
705  ∀trace: trace_label_return (ASM_abstract_status code_memory cost_labels) initial final.
706  ∀unrepeating_witness: tlr_unrepeating … trace.
707    let cost_map ≝ traverse_code code_memory cost_labels cost_labels_injective in
708    let ctrace ≝ flatten_trace_label_return … trace in
709      clock … code_memory … final = clock … code_memory … initial + (Σ_{i < |ctrace|} (tech_cost_of_label cost_labels cost_map ? ctrace i)).
710  [1:
711    #code_memory #cost_labels #cost_labels_injective #initial #final #trace #unrepeating_witness
712    @compute_max_trace_label_return_cost_ok_with_trace_aux try assumption
713  |2:
714    skip
715  ]
716  normalize nodelta
717  cases (traverse_code ???)
718  #cost_map * #dom_codom #codom_dom try assumption
719  #pc #k #lookup_opt_assm @(dom_codom … lookup_opt_assm)
720  lapply (sym_eq ? ? ? lookup_opt_assm)
721  -lookup_opt_assm #lookup_opt_assm
722  @nat_of_bitvector_lt_bound
723qed.
Note: See TracBrowser for help on using the repository browser.