source: src/ASM/BitVectorTrie.ma @ 1474

Last change on this file since 1474 was 1474, checked in by mulligan, 8 years ago

adding missing asmcosts file for computing the costs of an assembly program!

File size: 22.5 KB
Line 
1include "basics/types.ma".
2
3include "utilities/option.ma".
4include "ASM/BitVector.ma".
5
6inductive BitVectorTrie (A: Type[0]): nat → Type[0] ≝
7  Leaf: A → BitVectorTrie A O
8| Node: ∀n: nat. BitVectorTrie A n → BitVectorTrie A n → BitVectorTrie A (S n)
9| Stub: ∀n: nat. BitVectorTrie A n.
10
11let rec fold (A, B: Type[0]) (n: nat) (f: BitVector n → A → B → B)
12 (t: BitVectorTrie A n) (b: B) on t: B ≝
13 (match t return λx.λ_.x = n → B with
14  [ Leaf l ⇒ λ_.f (zero ?) l b
15  | Node h l r ⇒ λK.
16    fold A B h (λx.f ((VCons ? h false x)⌈(S h) ↦ n⌉)) l
17      (fold A B h (λx.f ((VCons ? h true x)⌈(S h) ↦ n⌉)) r b)
18  | Stub _ ⇒ λ_.b
19  ]) (refl ? n).
20 @K
21qed.
22
23lemma Sm_leq_n_m_leq_n:
24  ∀m, n: nat.
25    S m ≤ n → m ≤ n.
26  #m #n /2/
27qed.
28
29let rec bvtfold_aux
30  (a, b: Type[0]) (f: BitVector 16 → a → b → b) (seed: b) (n: nat)
31    on n: n ≤ 16 → BitVectorTrie a n → BitVector (16 - n) → b ≝
32  match n return λn: nat. n ≤ 16 → BitVectorTrie a n → BitVector (16 - n) → b with
33  [ O    ⇒ λinvariant: 0 ≤ 16. λtrie: BitVectorTrie a 0. λpath: BitVector 16.
34    match trie return λx: nat. λtrie': BitVectorTrie a x. ∀prf: x = 0. b with
35    [ Leaf l      ⇒ λproof. f path l seed
36    | Stub s      ⇒ λproof. seed
37    | Node n' l r ⇒ λabsrd. ⊥
38    ] (refl … 0)
39  | S n' ⇒ λinvariant: S n' ≤ 16. λtrie: BitVectorTrie a (S n'). λpath: BitVector (16 - S n').
40    match trie return λx: nat. λtrie': BitVectorTrie a x. ∀prf: x = S n'. b with
41    [ Leaf l      ⇒ λabsrd. ⊥
42    | Stub s      ⇒ λproof. seed
43    | Node n'' l r ⇒ λproof.
44        bvtfold_aux a b f (bvtfold_aux a b f seed n' ? (l⌈BitVectorTrie a n'' ↦ BitVectorTrie a n'⌉) ((false:::path)⌈S (16 - S n') ↦ 16 - n'⌉)) n' ? (r⌈BitVectorTrie a n'' ↦ BitVectorTrie a n'⌉) ((true:::path)⌈S (16 - S n') ↦ 16 - n'⌉)
45    ] (refl … (S n'))
46  ].
47  [ 1, 2: destruct(absrd)
48  | 3,8: >minus_S_S <minus_Sn_m // @le_S_S_to_le //
49  | 4,7: destruct(proof) %
50  | 5,6: @Sm_leq_n_m_leq_n // ]
51qed.
52
53(* these two can probably be generalized w/r/t the second type and
54 * some sort of equality relationship *)
55lemma fold_eq:
56  ∀A: Type[0].
57  ∀n: nat.
58  ∀f.
59  ∀t.
60  ∀P, Q: Prop.
61  (P → Q) → (∀a,t',P,Q.(P → Q) → f a t' P → f a t' Q) → fold A ? n f t P → fold A ? n f t Q.
62 #A #n #f #t #P #Q #H
63 generalize in match (refl ? n) generalize in match H -H; generalize in match Q -Q; generalize in match P -P;
64 elim t in f ⊢ (? → ? → ? → ???% → ? → ???%%%? → ???%%%?)
65 [ #a #f #P #Q #HPQ #_ #Hf #HP whd in HP; whd @(Hf (zero 0) a P Q HPQ HP)
66 | #h #l #r #Hl #Hr #f #P #Q #HPQ #_ #Hf #HP normalize normalize in HP; @(Hl ? (fold A Prop h (λx.f (true:::x)) r P) (fold A Prop h (λx.f (true:::x)) r Q) ? (refl ? h) ?)
67   [ @(Hr ? P Q HPQ (refl ? h) ?)
68     #a #t' #X #Y #HXY #Hff @(Hf (true:::a) t' X Y HXY Hff)
69   | #a #t' #X #Y #HXY #Hff @(Hf (false:::a) t' X Y HXY Hff) ]
70 | #h #f #P #Q #HPQ #_ #Hf #HP whd in HP; whd @(HPQ HP) ]
71  @HP
72qed.
73 
74lemma fold_init:
75  ∀A:Type[0].
76  ∀n:nat.
77  ∀f.
78  ∀t.
79  ∀P: Prop.
80  (∀a,t',P.f a t' P → P) → fold A Prop n f t P → P.
81 #A #n #f #t #P #H generalize in match (refl ? n) generalize in match H -H; generalize in match P -P;
82 elim t in f ⊢ (? → ? → ???% → ???%%%? → ?) -t
83 [ #a #f #P #Hf #_ normalize @(Hf [[]])
84 | #h #l #r #Hl #Hr #f #P #Hf #_ normalize #HP @(Hr (λx.f (true:::x)))
85   [ #a #t' #X @(Hf (true:::a) t' X) | @(refl ? h) | @(Hl (λx.f (false:::x)))
86     [ #a #t' #X @(Hf (false:::a) t' X) | @(refl ? h) | @HP ]
87   ]
88 | #h #f #P #Hf #_ normalize //
89
90
91 ]
92qed.
93 
94definition forall
95 ≝
96  λA.λn.λt:BitVectorTrie A n.λP.fold ? ? ? (λk.λa.λacc.(P k a) ∧ acc) t True.
97 
98lemma forall_nodel:
99  ∀A:Type[0].
100  ∀n:nat.
101  ∀l,r.
102  ∀P:BitVector (S n) → A → Prop.
103  forall A (S n) (Node ? n l r) P → forall A n l (λx.λa.P (false:::x) a).
104 #A #n #l #r #P #Hl
105 whd @(fold_eq A n ? ? (fold A ? n (λk.λa.λacc.P (true:::k) a∧acc) r True) True)
106 [ //
107 | #n #t' #X #Y #HXY #HX %1
108   [ @(proj1 ? ? HX) | @HXY @(proj2 ? ? HX) ]
109 | whd in Hl @Hl ]
110qed.
111 
112lemma forall_noder:
113  ∀A:Type[0].
114  ∀n:nat.
115  ∀l,r.
116  ∀P:BitVector (S n) → A → Prop.
117  forall A (S n) (Node ? n l r) P → forall A n r (λx.λa.P (true:::x) a).
118 #A #n #l #r #P #Hr
119 whd @(fold_init A n (λk.λa.λacc.P (false:::k) a∧acc) l) 
120 [ #n #t' #P #HP @(proj2 ? ? HP)
121 | @Hr
122 ]
123qed.
124
125lemma forall_node:
126  ∀A.∀n.∀l,r.∀P:BitVector (S n) → A → Prop.
127  forall A n l (λx.λa.P (false:::x) a) → forall A n r (λx.λa.P (true:::x) a) →
128  forall A (S n) (Node ? n l r) P.
129 #A #n #l #r #P #Hl #Hr
130 normalize @(fold_eq … True)
131 [ #_ @Hr
132 | #x #t' #X #Y #HXY #HP %1 [ @(proj1 … HP) | @HXY @(proj2 … HP) ]
133 | @Hl
134 ]
135qed.
136
137let rec lookup_opt (A: Type[0]) (n: nat)
138                (b: BitVector n) (t: BitVectorTrie A n) on t
139       : option A ≝
140 (match t return λx.λ_. BitVector x → option A with
141  [ Leaf l ⇒ λ_.Some ? l
142  | Node h l r ⇒ λb. lookup_opt A ? (tail … b) (if head' … b then r else l)
143  | Stub _ ⇒ λ_.None ?
144  ]) b.
145
146definition member ≝
147  λA.
148  λn.
149  λb: BitVector n.
150  λt: BitVectorTrie A n.
151  match lookup_opt A n b t with
152  [ None ⇒ false
153  | _    ⇒ true
154  ].
155
156definition member_p ≝
157  λA.
158  λn.
159  λb: BitVector n.
160  λt: BitVectorTrie A n.
161  match lookup_opt A n b t with
162  [ None ⇒ False
163  | _    ⇒ True
164  ].
165 
166lemma forall_lookup:
167 ∀A.
168  ∀n.
169  ∀t:BitVectorTrie A n.
170  ∀P:BitVector n → A → Prop.
171  forall A n t P → ∀a:A.∀b.lookup_opt A n b t = Some ? a → P b a.
172 #A #n #t #P generalize in match (refl ? n) elim t in P ⊢ (???% → ??%%? → ? → ? → ??(??%%%)? → ?)
173 [ #x #f #_ #Hf #a #b whd in Hf; #Hb normalize in Hb; destruct >(BitVector_O b) @(proj1 ? ? Hf)
174 | #h #l #r #Hl #Hr #f #_ #Hf #a #b #Hb cases (BitVector_Sn h b)
175   #hd #bla elim bla -bla #tl #Htl >Htl in Hb; #Hb cases hd in Hb;
176   [ #Hb normalize in Hb; @(Hr (λx.λa.f (true:::x) a) (refl ? h))
177     [ @(forall_noder A h l r f Hf)
178     | @Hb
179     ]
180   | #Hb normalize in Hb; @(Hl (λx.λa.f (false:::x) a) (refl ? h))
181     [ @(forall_nodel A h l r f Hf)
182     | @Hb
183     ]
184   ]
185 | #n #f #_ #Hf #a #b #Hb normalize in Hb; destruct
186qed.
187
188lemma lookup_forall:
189 ∀A:Type[0].∀n.∀t:BitVectorTrie A n.∀P:BitVector n → A → Prop. 
190 (∀a:A.∀b:BitVector n.lookup_opt A n b t = Some ? a → P b a) → forall A n t P.
191 #A #n #t elim t
192 [ #x #P #HP normalize %1 [ @HP normalize @refl | // ]
193 | #h #l #r #Hl #Hr #P #HP @forall_node
194   [ @Hl #a #b #Hlookup @HP normalize @Hlookup
195   | @Hr #a #b #Hlookup @HP normalize @Hlookup
196   ]
197 | #n #P #HP normalize //
198 ]   
199qed.
200 
201let rec lookup (A: Type[0]) (n: nat)
202                (b: BitVector n) (t: BitVectorTrie A n) (a: A) on b
203       : A ≝
204  (match b return λx.λ_. x = n → A with
205    [ VEmpty ⇒
206      (match t return λx.λ_. O = x → A with
207        [ Leaf l ⇒ λ_.l
208        | Node h l r ⇒ λK.⊥
209        | Stub s ⇒ λ_.a
210        ])
211    | VCons o hd tl ⇒
212      match t return λx.λ_. (S o) = x → A with
213        [ Leaf l ⇒ λK.⊥
214        | Node h l r ⇒
215           match hd with
216             [ true ⇒ λK. lookup A h (tl⌈o ↦ h⌉) r a
217             | false ⇒ λK. lookup A h (tl⌈o ↦ h⌉) l a
218             ]
219        | Stub s ⇒ λ_. a]
220    ]) (refl ? n).
221  [1,2:
222    destruct
223  |*:
224    @ injective_S
225    //
226  ]
227qed.
228
229alias id "bvt_lookup" = "cic:/matita/cerco/ASM/BitVectorTrie/lookup.fix(0,2,5)".
230
231let rec prepare_trie_for_insertion (A: Type[0]) (n: nat) (b: BitVector n) (a:A) on b : BitVectorTrie A n ≝
232   match b with
233    [ VEmpty ⇒ Leaf A a
234    | VCons o hd tl ⇒
235      match hd with
236        [ true ⇒  Node A o (Stub A o) (prepare_trie_for_insertion A o tl a)
237        | false ⇒ Node A o (prepare_trie_for_insertion A o tl a) (Stub A o)
238        ]
239    ].
240
241let rec insert (A: Type[0]) (n: nat) (b: BitVector n) (a: A) on b: BitVectorTrie A n → BitVectorTrie A n ≝
242  (match b with
243    [ VEmpty ⇒ λ_. Leaf A a
244    | VCons o hd tl ⇒ λt.
245          match t return λy.λ_. S o = y → BitVectorTrie A (S o) with
246            [ Leaf l ⇒ λprf.⊥
247            | Node p l r ⇒ λprf.
248               match hd with
249                [ true ⇒  Node A o (l⌈p ↦ o⌉) (insert A o tl a (r⌈p ↦ o⌉))
250                | false ⇒ Node A o (insert A o tl a (l⌈p ↦ o⌉)) (r⌈p ↦ o⌉)
251                ]
252            | Stub p ⇒ λprf. (prepare_trie_for_insertion A ? (hd:::tl) a)
253            ] (refl ? (S o))
254    ]).
255  [ destruct
256  |*:
257    @ injective_S
258    //
259  ]
260qed.
261 
262let rec update (A: Type[0]) (n: nat) (b: BitVector n) (a: A) on b: BitVectorTrie A n → option (BitVectorTrie A n) ≝
263  (match b with
264    [ VEmpty ⇒ λt. match t return λy.λ_. O = y → option (BitVectorTrie A O) with
265                   [ Leaf _ ⇒ λ_. Some ? (Leaf A a)
266                   | Stub _ ⇒ λ_. None ?
267                   | Node _ _ _ ⇒ λprf. ⊥
268                   ] (refl ? O)
269    | VCons o hd tl ⇒ λt.
270          match t return λy.λ_. S o = y → option (BitVectorTrie A (S o)) with
271            [ Leaf l ⇒ λprf.⊥
272            | Node p l r ⇒ λprf.
273               match hd with
274                [ true ⇒  option_map ?? (λv. Node A o (l⌈p ↦ o⌉) v) (update A o tl a (r⌈p ↦ o⌉))
275                | false ⇒ option_map ?? (λv. Node A o v (r⌈p ↦ o⌉)) (update A o tl a (l⌈p ↦ o⌉))
276                ]
277            | Stub p ⇒ λprf. None ?
278            ] (refl ? (S o))
279    ]).
280  [ 1,2: destruct
281  |*:
282    @ injective_S @sym_eq @prf
283  ]
284qed.
285
286let rec merge (A: Type[0]) (n: nat) (b: BitVectorTrie A n) on b: BitVectorTrie A n → BitVectorTrie A n ≝
287  match b return λx. λ_. BitVectorTrie A x → BitVectorTrie A x with
288  [ Stub _ ⇒ λc. c
289  | Leaf l ⇒ λc. match c with [ Leaf a ⇒ Leaf ? a | _ ⇒ Leaf ? l ]
290  | Node p l r ⇒
291    λc.
292    (match c return λx. λ_. x = (S p) → BitVectorTrie A (S p) with
293    [ Node p' l' r' ⇒ λprf. Node ? ? (merge ?? l (l'⌈p' ↦ p⌉)) (merge ?? r (r'⌈p' ↦ p⌉))
294    | Stub _ ⇒ λprf. Node ? p l r
295    | Leaf _ ⇒ λabsd. ?
296    ] (refl ? (S p)))
297  ].
298  [1:
299      destruct(absd)
300  |2,3:
301      @ injective_S
302        assumption
303  ]
304qed.
305
306lemma BitVectorTrie_O:
307 ∀A:Type[0].∀v:BitVectorTrie A 0.(∃w. v ≃ Leaf A w) ∨ v ≃ Stub A 0.
308 #A #v generalize in match (refl … O) cases v in ⊢ (??%? → (?(??(λ_.?%%??)))(?%%??))
309  [ #w #_ %1 %[@w] %
310  | #n #l #r #abs @⊥ destruct(abs)
311  | #n #EQ %2 >EQ %]
312qed.
313
314lemma BitVectorTrie_Sn:
315 ∀A:Type[0].∀n.∀v:BitVectorTrie A (S n).(∃l,r. v ≃ Node A n l r) ∨ v ≃ Stub A (S n).
316 #A #n #v generalize in match (refl … (S n)) cases v in ⊢ (??%? → (?(??(λ_.??(λ_.?%%??))))%)
317  [ #m #abs @⊥ destruct(abs)
318  | #m #l #r #EQ %1 <(injective_S … EQ) %[@l] %[@r] //
319  | #m #EQ %2 // ]
320qed.
321
322lemma lookup_prepare_trie_for_insertion_hit:
323 ∀A:Type[0].∀a,v:A.∀n.∀b:BitVector n.
324  lookup … b (prepare_trie_for_insertion … b v) a = v.
325 #A #a #v #n #b elim b // #m #hd #tl #IH cases hd normalize //
326qed.
327 
328lemma lookup_insert_hit:
329 ∀A:Type[0].∀a,v:A.∀n.∀b:BitVector n.∀t:BitVectorTrie A n.
330  lookup … b (insert … b v t) a = v.
331 #A #a #v #n #b elim b -b -n //
332 #n #hd #tl #IH #t cases(BitVectorTrie_Sn … t)
333  [ * #l * #r #JMEQ >JMEQ cases hd normalize //
334  | #JMEQ >JMEQ cases hd normalize @lookup_prepare_trie_for_insertion_hit ]
335qed.
336
337lemma lookup_prepare_trie_for_insertion_miss:
338 ∀A:Type[0].∀a,v:A.∀n.∀c,b:BitVector n.
339  (notb (eq_bv ? b c)) → lookup … b (prepare_trie_for_insertion … c v) a = a.
340 #A #a #v #n #c elim c
341  [ #b >(BitVector_O … b) normalize #abs @⊥ //
342  | #m #hd #tl #IH #b cases(BitVector_Sn … b) #hd' * #tl' #JMEQ >JMEQ
343    cases hd cases hd' normalize
344    [2,3: #_ cases tl' //
345    |*: change with (bool_to_Prop (notb (eq_bv ???)) → ?) /2/ ]]
346qed.
347 
348lemma lookup_insert_miss:
349 ∀A:Type[0].∀a,v:A.∀n.∀c,b:BitVector n.∀t:BitVectorTrie A n.
350  (notb (eq_bv ? b c)) → lookup … b (insert … c v t) a = lookup … b t a.
351 #A #a #v #n #c elim c -c -n
352  [ #b #t #DIFF @⊥ whd in DIFF; >(BitVector_O … b) in DIFF //
353  | #n #hd #tl #IH #b cases(BitVector_Sn … b) #hd' * #tl' #JMEQ >JMEQ
354    #t cases(BitVectorTrie_Sn … t)
355    [ * #l * #r #JMEQ >JMEQ cases hd cases hd' #H normalize in H;
356     [1,4: change in H with (bool_to_Prop (notb (eq_bv ???))) ] normalize // @IH //
357    | #JMEQ >JMEQ cases hd cases hd' #H normalize in H;
358     [1,4: change in H with (bool_to_Prop (notb (eq_bv ???))) ] normalize
359     [3,4: cases tl' // | *: @lookup_prepare_trie_for_insertion_miss //]]]
360qed.
361
362lemma lookup_stub:
363 ∀A.∀n.∀b.∀a.
364 lookup A n b (Stub A ?) a = a.
365 #A #n #b #a cases n in b ⊢ (??(??%%%?)?)
366 [ #b >(BitVector_O b) normalize @refl
367 | #h #b cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb >Hb cases hd
368   [ normalize @refl
369   | normalize @refl
370   ]
371 ]   
372qed.   
373
374lemma lookup_opt_lookup_miss:
375  ∀A:Type[0].∀n:nat.∀b:BitVector n.∀t:BitVectorTrie A n.∀a:A.
376  lookup_opt A n b t = None A → ∀x.lookup A n b t x = x.
377 #A #n #b #t #a generalize in match (refl ? n) elim t in b ⊢ (???% → ??(??%%%)? → ? → ?)
378 [ #a #B #_ #H #x normalize in H; >(BitVector_O B) normalize destruct
379 | #h #l #r #Hl #Hr #b #_ #H #x cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb
380   >Hb >Hb in H; cases hd
381   [ normalize #Hlookup @(Hr ? (refl ? h)) @Hlookup
382   | normalize #Hlookup @(Hl ? (refl ? h)) @Hlookup
383   ]
384 | #n #B #_ #H #x @lookup_stub
385 ]
386qed.
387
388lemma lookup_opt_lookup_hit:
389  ∀A:Type[0].∀n:nat.∀b:BitVector n.∀t:BitVectorTrie A n.∀a:A.
390  lookup_opt A n b t = Some A a → ∀x.lookup A n b t x = a.
391 #A #n #b #t #a generalize in match (refl ? n) elim t in b ⊢ (???% → ??(??%%%)? → ? → ?)
392 [ #a #B #_ #H #x normalize in H; >(BitVector_O B) normalize destruct @refl
393 | #h #l #r #Hl #Hr #b #_ #H #x cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb
394   >Hb >Hb in H; cases hd
395   [ normalize #Hlookup @(Hr ? (refl ? h)) @Hlookup
396   | normalize #Hlookup @(Hl ? (refl ? h)) @Hlookup
397   ]
398 | #n #B #_ #H #x normalize in H; destruct
399 ]
400qed.
401
402lemma lookup_lookup_opt_hit:
403  ∀A.∀n.∀b.∀t.∀x,a.
404  lookup A n b t x = a → x ≠ a → lookup_opt A n b t = Some A a.
405 #A #n #b #t #x #a generalize in match (refl ? n) elim t in b ⊢ (???% → ? → ?)
406 [ #z #B #_ #H #Hx >(BitVector_O B) in H; normalize #H >H @refl
407 | #h #l #r #Hl #Hr #B #_ #H #Hx cases (BitVector_Sn h B) #hd #X elim X; -X #tl #HB
408   >HB >HB in H; cases hd
409   [ normalize #H >(Hr tl (refl ? h) H Hx) @refl
410   | normalize #H >(Hl tl (refl ? h) H Hx) @refl
411   ]
412 | #n #B #_ #H #Hx cases B in H;
413   [ normalize #Hx' | #n' #b #v normalize #Hx' ]
414   @⊥ @(absurd (eq ? x a)) [1,3: @Hx' |2,4: @Hx ]
415 ]
416qed.
417
418lemma lookup_opt_prepare_trie_for_insertion_hit:
419 ∀A:Type[0].∀v:A.∀n.∀b:BitVector n.
420  lookup_opt … b (prepare_trie_for_insertion … b v) = Some A v.
421 #A #v #n #b elim b // #m #hd #tl #IH cases hd normalize //
422qed.
423
424lemma lookup_opt_prepare_trie_for_insertion_miss:
425 ∀A:Type[0].∀v:A.∀n.∀c,b:BitVector n.
426  (notb (eq_bv ? b c)) → lookup_opt … b (prepare_trie_for_insertion … c v) = None ?.
427 #A #v #n #c elim c
428  [ #b >(BitVector_O … b) normalize #abs @⊥ //
429  | #m #hd #tl #IH #b cases(BitVector_Sn … b) #hd' * #tl' #JMEQ >JMEQ
430    cases hd cases hd' normalize
431    [2,3: #_ cases tl' //
432    |*: change with (bool_to_Prop (notb (eq_bv ???)) → ?) @IH ]]
433qed.
434
435lemma lookup_opt_insert_hit:
436 ∀A:Type[0].∀v:A.∀n.∀b:BitVector n.∀t:BitVectorTrie A n.
437  lookup_opt … b (insert … b v t) = Some A v.
438 #A #v #n #b #t elim t in b ⊢ (??(??%%%)?)
439 [ #x #b >(BitVector_O b) normalize @refl
440 | #h #l #r #Hl #Hr #b cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb >Hb cases hd
441   [ normalize @Hr
442   | normalize @Hl
443   ]
444 | #n' #b cases n' in b ⊢ ?
445   [ #b >(BitVector_O b) normalize @refl
446   | #m #b cases (BitVector_Sn m b) #hd #X elim X -X; #tl #Hb >Hb cases hd
447     normalize @lookup_opt_prepare_trie_for_insertion_hit
448   ]
449 ]
450qed.
451
452lemma lookup_opt_insert_miss:
453 ∀A:Type[0].∀v:A.∀n.∀c,b:BitVector n.∀t:BitVectorTrie A n.
454  (notb (eq_bv ? b c)) → lookup_opt … b (insert … c v t) = lookup_opt … b t.
455 #A #v #n #c elim c -c -n
456  [ #b #t #DIFF @⊥ whd in DIFF; >(BitVector_O … b) in DIFF //
457  | #n #hd #tl #IH #b cases(BitVector_Sn … b) #hd' * #tl' #JMEQ >JMEQ
458    #t cases(BitVectorTrie_Sn … t)
459    [ * #l * #r #JMEQ >JMEQ cases hd cases hd' #H normalize in H;
460     [1,4: change in H with (bool_to_Prop (notb (eq_bv ???))) ] normalize // @IH //
461    | #JMEQ >JMEQ cases hd cases hd' #H normalize in H;
462     [1,4: change in H with (bool_to_Prop (notb (eq_bv ???))) ] normalize
463     [3,4: cases tl' // | *: @lookup_opt_prepare_trie_for_insertion_miss //]]]
464qed.
465
466lemma forall_insert_inv1:
467  ∀A.∀n.∀b.∀a.∀t.∀P.
468  forall A n (insert A n b a t) P → P b a.
469 #A #n #b #a #t #P #H @(forall_lookup ? ? (insert A n b a t))
470 [ @H
471 | >(lookup_opt_insert_hit A ? n b) @(refl ? (Some A a))
472 ]
473qed.
474
475lemma forall_insert_inv2a:
476  ∀A:Type[0].∀n:nat.∀b.∀a.∀t.∀P.
477  lookup_opt A n b t = (None A)  → forall A n (insert A n b a t) P → forall A n t P.
478 #A #n #b #a #t generalize in match (refl ? n) elim t in b ⊢ (???% → ? → ??(??%%%)? → ??%%% → ??%%%)
479 [ #x #b #_ #P >(BitVector_O b) normalize #H destruct
480 | #h #l #r #Hl #Hr #b #_ #P cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb >Hb cases hd #Hlookup #H
481   [ normalize in H; normalize
482     @(fold_eq … (fold A ? ? (λx.λa0.λacc.P (true:::x) a0∧acc) (insert … tl a r) True) … H)
483     [ #Hfold @(Hr tl (refl ? h) ? Hlookup Hfold)
484     | #x #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ?HP)) ]
485     ]
486   | normalize in H; normalize     
487     @(fold_eq … True)
488     [ #_ @(fold_init A h (λx.λa0.λacc.P (false:::x) a0 ∧ acc) (insert A h tl a l))
489       [ #z #t' #X #HX @(proj2 ? ? HX)
490       | @H ]
491     | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
492     | @(Hl tl (refl ? h) ? Hlookup) normalize
493       @(fold_eq … (fold A ? ? (λx.λa0.λacc.P (true:::x) a0∧acc) r True))
494       [ //
495       | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
496       | @H
497       ]
498     ]
499   ]
500 | #n #b #_ #P #Hlookup #Hf normalize // ]
501qed.
502
503lemma forall_insert_inv2b:
504  ∀A:Type[0].∀n:nat.∀b:BitVector n.∀a:A.∀t.∀P:(BitVector n → A → Prop).
505  (∀x.(lookup_opt A n b t = Some A x) → P b x) → forall A n (insert A n b a t) P → forall A n t P.
506 #A #n #b #a #t generalize in match (refl ? n) elim t in b ⊢ (???% → % → ? → ??%%% → ?)
507 [ #x #b #_ #P >(BitVector_O b) normalize #HP #Hf %1 [ @HP @refl | @(proj2 ? ? Hf) ]
508 | #h #l #r #Hl #Hr #b #_ cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb >Hb cases hd #P #HP #Hf
509   [ normalize in Hf; normalize
510     @(fold_eq … (fold A ? ? (λx.λa0.λacc.P (true:::x) a0∧acc) (insert … tl a r) True) … Hf)
511     [ #Hfold @(Hr tl (refl ? h) ? HP Hfold)
512     | #x #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
513     ]
514   | normalize in H; normalize     
515     @(fold_eq … True)
516     [ #_ @(fold_init A h (λx.λa0.λacc.P (false:::x) a0 ∧ acc) (insert A h tl a l))
517       [ #z #t' #X #HX @(proj2 ? ? HX)
518       | @Hf ]
519     | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
520     | @(Hl tl (refl ? h) ? HP) normalize
521       @(fold_eq … (fold A ? ? (λx.λa0.λacc.P (true:::x) a0∧acc) r True))
522       [ //
523       | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
524       | @Hf
525       ]
526     ]
527   ]
528 | #n #b #_ #P #Hlookup #Hf normalize // ]
529qed.
530
531lemma forall_prepare_tree_for_insertion:
532 ∀A:Type[0].∀h:nat.∀b:BitVector h.∀a:A.∀P.
533 P b a →
534 forall A h (prepare_trie_for_insertion A h b a) P.
535 #A #h #b elim b
536 [ #a #P #HP normalize %1 [ @HP | // ]
537 | #h #x #tl #Ha #a #P cases x #HP normalize @Ha @HP
538 ]
539qed.
540
541lemma forall_insert:
542  ∀A:Type[0].∀n:nat.∀b:BitVector n.∀a:A.∀t.∀P.
543  forall A n t P → P b a → forall A n (insert A n b a t) P.
544 #A #n #b #a #t generalize in match (refl ? n) elim t in b ⊢ (???% → % → ??%%% → %%? → ??%%%)
545 [ #x #b #_ #P >(BitVector_O b) normalize #H1 #H2 /2/
546 | #h #l #r #Hl #Hr #b #_ cases (BitVector_Sn h b) #hd #X elim X -X; #tl #Hb >Hb cases hd #P #Hf #HP
547   [ normalize in Hf; normalize
548     @(fold_eq A … (fold A … (λx.λa0.λacc.P (true:::x) a0∧acc) r True) … Hf)
549     [ #Hp @(Hr tl (refl ? h) ? Hp HP)
550     | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
551     ]
552   | normalize in Hf; normalize
553     @(fold_eq … True)
554     [ #_ @(fold_init A h (λx.λa0.λacc.P (false:::x) a0∧acc) l)
555       [ #z #t' #X #HX @(proj2 ? ? HX)
556       | @Hf ]
557     | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
558     | @(Hl tl (refl ? h) ? ? HP)
559       normalize @(fold_eq … (fold A ? ? (λx.λa0.λacc.P (true:::x) a0∧acc) r True))
560       [ //
561       | #z #t' #X #Y #HXY #HP %1 [ @(proj1 ? ? HP) | @(HXY (proj2 ? ? HP)) ]
562       | @Hf
563       ]
564     ]
565   ]
566 | #n #b #_ elim b in t ⊢ (% → ? → ? → ??%%%)
567   [ #b #P #Hf #HP normalize %1 [ @HP | // ]
568   | #h #hd #tl #H #b #P #Hf cases hd #HP normalize @(forall_prepare_tree_for_insertion A h tl a ? HP)
569   ]
570 ]
571qed.
572
573lemma update_fail : ∀A,n,b,a,t.
574  update A n b a t = None ? →
575  lookup_opt A n b t = None ?.
576#A #n elim n
577[ #b @(vector_inv_n … b) #a #t cases (BitVectorTrie_O … t)
578  [ * #x #E >E normalize #NE destruct
579  | #E >E normalize //
580  ]
581| #m #IH #b @(vector_inv_n … b) #hd #tl #a #t cases (BitVectorTrie_Sn … t)
582  [ * #t1 * #t2 #E >E cases hd whd in ⊢ (??%? → ??%?)
583    #X lapply (option_map_none … X) @IH
584  | #E >E normalize //
585  ]
586] qed.
587
588lemma update_lookup_opt_same : ∀A,n,b,a,t,t'.
589  update A n b a t = Some ? t' →
590  lookup_opt A n b t' = Some ? a.
591#A #n elim n
592[ #b #a #t #t' @(vector_inv_n … b)
593  cases (BitVectorTrie_O … t)
594  [ * #x #E >E normalize #E' destruct @refl
595  | #E >E normalize #E' destruct
596  ]
597| #m #IH #b #a #t #t'
598  @(vector_inv_n … b) #bhd #btl
599  cases (BitVectorTrie_Sn … t)
600  [ * #t1 * #t2 #E' >E'
601    whd in ⊢ (??%? → ??%?) cases bhd #U
602    cases (option_map_some ????? U)
603    #tn' * #U' #E'' <E''
604    whd in ⊢ (??%?) whd in ⊢ (??(???%%)?)
605    @(IH … U')
606  | #E >E normalize #E' destruct
607  ]
608] qed.
609
610lemma update_lookup_opt_other : ∀A,n,b,a,t,t'.
611  update A n b a t = Some ? t' →
612  ∀b'. b ≠ b' →
613  lookup_opt A n b' t = lookup_opt A n b' t'.
614#A #n elim n
615[ #b #a #t #t' #E #b'
616  @(vector_inv_n … b) @(vector_inv_n … b')
617  * #NE cases (NE (refl ??))
618| #m #IH #b #a #t #t'
619  @(vector_inv_n … b) #bhd #btl
620  cases (BitVectorTrie_Sn … t)
621  [ * #t1 * #t2 #E >E whd in ⊢ (??%? → ?) cases bhd
622    #U cases (option_map_some ????? U) #tn' * #U' #E' <E'
623    #b' @(vector_inv_n … b') #bhd' #btl'
624    cases bhd'
625    [ 2,3: #_ @refl
626    | *: #NE whd in ⊢ (??%%) whd in ⊢ (??(???%%)(???%%))
627         @(IH … U') % #E'' >E'' in NE * #H @H @refl
628    ]
629  | #E >E whd in ⊢ (??%? → ?) #NE destruct
630  ]
631] qed.
Note: See TracBrowser for help on using the repository browser.