source: LTS/utils.ma @ 3563

Last change on this file since 3563 was 3563, checked in by sacerdot, 4 years ago

bind_inversion on Opt moved to utils + some progress

File size: 12.1 KB
Line 
1(**************************************************************************)
2(*       ___                                                              *)
3(*      ||M||                                                             *)
4(*      ||A||       A project by Andrea Asperti                           *)
5(*      ||T||                                                             *)
6(*      ||I||       Developers:                                           *)
7(*      ||T||         The HELM team.                                      *)
8(*      ||A||         http://helm.cs.unibo.it                             *)
9(*      \   /                                                             *)
10(*       \ /        This file is distributed under the terms of the       *)
11(*        v         GNU General Public License Version 2                  *)
12(*                                                                        *)
13(**************************************************************************)
14
15include "basics/lists/listb.ma".
16include "../src/utilities/hide.ma".
17include "../src/ASM/Util.ma".
18include "../src/utilities/option.ma".
19
20lemma bind_inversion : ∀A,B : Type[0].∀m : option A.
21∀f : A → option B.∀y : B.
22! x ← m; f x = return y →
23∃ x.(m = return x) ∧ (f x = return y).
24#A #B * [| #a] #f #y normalize #EQ [destruct]
25%{a} %{(refl …)} //
26qed.
27
28(*NO DUPLICATES in lists*)
29
30let rec no_duplicates (A : DeqSet) (l : list A) on l : Prop ≝
31match l with
32[ nil ⇒ True
33| cons x xs ⇒ ¬ (bool_to_Prop (x ∈ xs)) ∧ no_duplicates … xs
34].
35
36lemma no_duplicates_append_r : ∀A : DeqSet.∀l1,l2 : list A.no_duplicates … (l1 @ l2) →
37no_duplicates … l2.
38#A #l1 elim l1 // #x #xs normalize #IH #l2 * /2/
39qed.
40
41lemma no_duplicates_append_l : ∀A : DeqSet.∀l1,l2 : list A.no_duplicates … (l1 @ l2) →
42no_duplicates … l1.
43#A #l1 elim l1 // #x #xs normalize #IH #l2 * #H1 #H2 % [2: /2/ ]
44inversion(x ∈ xs @l2) in H1; normalize [ #_ * #H @⊥ @H %] #H1 #_
45% inversion(x ∈ xs) normalize [2: //] #H3 #_ >(memb_append_l1 … H3) in H1;
46#EQ destruct(EQ)
47qed.
48
49lemma no_duplicates_append_commute : ∀ A : DeqSet.∀l1,l2 : list A.
50no_duplicates … (l1 @ l2) →
51no_duplicates … (l2 @ l1).
52#A #l1 elim l1
53[ #l2 >append_nil //]
54#x #xs #IH #l2 * #H1 #H2 lapply(IH … H2) lapply H1 -H1 -IH -H2
55elim l2 -l1
56[ >append_nil #H1 #H2 % // ]
57#y #ys #IH * #H1 * #H2 #H3 %
58[2: @IH
59   [ % #H4 @H1 cases(memb_append … H4)
60     [ #H5 >memb_append_l1 //
61     | #H5 >memb_append_l2 // @orb_Prop_r >H5 //
62     ]
63   | //
64   ]
65| % #H4 cases(memb_append … H4)
66  [ #H5 @(absurd ?? H2) >memb_append_l1 //
67  | whd in match (memb ???); inversion(y==x)
68    [ #H5 #_ <(\P H5) in H1; #H1 @H1 >memb_append_l2 //
69    | #_ normalize nodelta #H5 @(absurd ?? H2) >memb_append_l2 //
70    ]
71  ]
72]
73qed.
74
75lemma memb_not_append : ∀D : DeqSet.∀l1,l2 : list D.∀x : D.
76x ∈ l1 = false → x ∈ l2 = false → x ∈ (l1 @ l2) = false.
77#D #l1 elim l1
78[ #l2 #x #_ #H @H ]
79#x #xs #IH #l2 #x1 whd in match (memb ???); inversion (x1 == x) normalize nodelta
80[ #_ #EQ destruct] #EQx1 #EQxs #EQl2 whd in match (memb ???); >EQx1
81normalize nodelta @IH //
82qed.
83
84lemma memb_no_duplicates_append : ∀A : DeqSet.∀x.∀l1,l2 : list A .
85no_duplicates … (l1 @ l2) → x ∈  l1 → x ∈ l2 → False.
86#A #x #l1 elim l1 // #x1 #xs #IH #l2 * #H1 #H2 whd in match (memb ???);
87inversion (x == x1) normalize nodelta
88[ #H3 #_ #H4 >memb_append_l2 in H1; [2: <(\P H3) @H4 ] * #H @H %
89| #_ @IH //
90]
91qed.
92
93(* subset *)
94
95let rec subset (A : Type[0]) (l1,l2 : list A) on l1 : Prop ≝
96match l1 with
97[ nil ⇒ True
98| cons x xs ⇒ mem … x l2 ∧ subset … xs l2
99].
100
101interpretation "subset" 'subseteq a b = (subset ? a b).
102
103lemma subset_append_l2 : ∀A,l2,l1.subset A l2 (l1 @ l2).
104#A #l2 elim l2 // normalize #x #xs #IH #l1 % // @mem_append_l2 whd /2/
105qed.
106
107lemma refl_subset : ∀A.reflexive … (subset A).
108#A #l1 elim l1 // #x #xs #IH normalize % /2/ change with ([?]@xs) in match (x :: xs);
109@subset_append_l2
110qed.
111
112lemma subset_def : ∀A : DeqSet.∀l1,l2 : list A.(∀x.x ∈l1 → x ∈ l2) → l1 ⊆ l2.
113#A #l1 elim l1 // #x #xs #IH #l2 #H %
114[ @memb_to_mem >H // >memb_hd //
115| @IH #y #H1 @H >memb_cons // >H1 //
116]
117qed.
118
119lemma subset_append : ∀A.∀l1,l2,l3 : list A.l1 ⊆ l3 → l2 ⊆ l3 → (l1 @ l2) ⊆ l3.
120#A #l1 elim l1 // #x #xs #IH #l2 #l3 * #H1 #H2 #H3 % /2/
121qed.
122
123lemma subset_def_inv : ∀A.∀l1,l2 : list A. l1 ⊆ l2 → ∀x.mem … x l1 → mem … x l2.
124#A #l1 elim l1 [ #l2 * #x * ] #x #xs #IH #l2 * #H1 #H2 #y *
125[ #EQ destruct // | #H3 @IH // ]
126qed.
127
128lemma transitive_subset : ∀A.transitive … (subset A).
129#A #l1 elim l1 // #x #xs #IH #l2 #l3 * #H1 #H2 #H3 %
130[ @(subset_def_inv … H3) // | @IH // ]
131qed.
132
133lemma subset_append_h1 : ∀A.∀l1,l2,l3 : list A.l1 ⊆ l3 → l1 ⊆ (l3 @ l2).
134#A #l1 elim l1 // #x #x2 #IH #l2 #l3 * #H1 #H2 % [ @mem_append_l1 // | @IH // ]
135qed.
136
137lemma subset_append_h2 : ∀A.∀l1,l2,l3 : list A.l2 ⊆ l3 → l2 ⊆ (l1 @ l3).
138#A #l1 elim l1 // #x #xs #IH #l2 elim l2 // #y #ys #IH #l3 * #H1 #H2 %
139[ @mem_append_l2 // | @IH // ]
140qed.
141
142(* list of elements with decidable equality *)
143
144let rec eqb_list (D : DeqSet) (l1 : list D) on l1 : list D → bool ≝
145match l1 with
146[ nil ⇒ λl2.match l2 with [nil ⇒ true | _ ⇒ false ]
147| cons x xs ⇒ λl2.match l2 with [ cons y ys ⇒ x == y ∧ eqb_list … xs ys | _ ⇒ false ]
148].
149
150definition DeqSet_List : DeqSet → DeqSet ≝
151λX.mk_DeqSet (list X) (eqb_list …) ?.
152#x elim x [ * /2 by refl, conj/ #y #ys normalize % #EQ destruct] -x
153#x #xs #IH * [ normalize % #EQ destruct] #y #ys normalize % inversion(x == y)
154#EQ normalize nodelta
155[ #H >(proj1 … (IH ys) H) @eq_f2 [2: %] @(proj1 … (eqb_true …)) assumption
156| #EQ destruct
157| #EQ1 destruct @(proj2 … (IH …)) %
158| #EQ1 destruct <EQ @(proj2 … (eqb_true …)) %
159]
160qed.
161
162unification hint  0 ≔ C;
163    X ≟ DeqSet_List C
164(* ---------------------------------------- *) ⊢
165    list C ≡ carr X.
166
167
168unification hint  0 ≔ D,p1,p2;
169    X ≟ DeqSet_List D
170(* ---------------------------------------- *) ⊢
171    eqb_list D p1 p2 ≡ eqb X p1 p2.
172
173lemma mem_list : ∀A : Type[0].
174∀l : list A.∀x : A.mem … x l →
175∃l1,l2.l=l1 @ [x] @ l2.
176#A #l elim l
177[ #x *]
178#x #xs #IH #y *
179[ #EQ destruct %{[]} %{xs} %
180| #H cases(IH … H) #l1 * #l2 #EQ destruct
181  %{(x :: l1)} %{l2} %
182]
183qed.
184
185(* associative list *)
186
187definition associative_list : DeqSet → Type[0] → Type[0] ≝
188λA,B.list (A × (list B)).
189
190let rec update_list (A : DeqSet) (B : Type[0]) (l : associative_list A B)
191   on l : A → list B → associative_list A B ≝
192λa,b.match l with
193    [ nil ⇒ [〈a,b〉]
194    | cons x xs ⇒ if (a == (\fst x)) then 〈a,b〉 :: xs
195                  else x :: (update_list … xs a b) 
196    ].
197
198let rec get_element (A :DeqSet) (B : Type[0]) (l: associative_list A B) on l : A → list B ≝
199λa.match l with [ nil ⇒ nil ?
200                | cons x xs ⇒ if (a == \fst x) then \snd x else get_element … xs a
201                ].
202
203let rec domain_of_associative_list (A :DeqSet) (B : Type[0]) (l: associative_list A B) on l : list A ≝
204 match l with
205  [ nil ⇒ []
206  | cons x xs ⇒ \fst x :: domain_of_associative_list … xs
207  ].
208
209lemma get_element_append_l:
210 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
211  x ∈ domain_of_associative_list … l1 →
212   get_element … (l1@l2) x = get_element … l1 x.
213#A #B #l1 elim l1 normalize [ #l2 #x * ] #hd #tl #IH #l2 #x cases (dec_eq … x (\fst hd))
214#H [ >(\b H) | >(\bf H) ] normalize /2/
215qed.
216
217lemma get_element_append_r:
218 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
219  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l1)) →
220   get_element ?? (l1@l2) x = get_element … l2 x.
221#A #B #l1 elim l1 normalize [ #l2 #x // ] #hd #tl #IH #l2 #x cases (dec_eq … x (\fst hd))
222#H [ >(\b H) | >(\bf H) ] normalize /2 by/ * #K cases (K I)
223qed.
224
225lemma get_element_append_l1 :
226 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
227  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l2)) →
228   get_element ?? (l1@l2) x = get_element … l1 x.
229#A #B #l1 elim l1 normalize [2: #x #xs #IH #l2 #a #H >IH // ]
230#l2 elim l2 // #y #ys #IH #a normalize cases(a == \fst y) normalize
231[ * #H @⊥ @H % ] #H @IH assumption
232qed.
233
234lemma get_element_append_r1 :
235 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
236  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l1)) →
237   get_element ?? (l1@l2) x = get_element … l2 x.
238#A #B #l1 elim l1 normalize // #x #xs #IH #l2 #a cases (?==?)
239normalize [* #H cases H //] #H >IH normalize //
240qed.
241
242lemma memb_append_l22 : ∀A : DeqSet.∀x : A.∀l1,l2 : list A.
243¬ (x ∈ l1) → x∈ l1 @ l2 = (x ∈ l2).
244#A #x #l1 elim l1 normalize // #y #ys #IH #l2 cases(x==y)
245normalize [*] @IH
246qed.
247
248lemma memb_append_l12 : ∀A : DeqSet.∀x : A.∀l1,l2 : list A.
249¬ (x ∈ l2) → x∈ l1 @ l2 = (x ∈ l1).
250#A #x #l1 elim l1
251[ #l2 #H whd in match (append ???); @not_b_to_eq_false @Prop_notb >H % ]
252#y #ys #IH #l2 #H1 whd in match (memb ???); >IH //
253qed.
254
255lemma foldr_map_append :
256  ∀A,B:Type[0]. ∀l1, l2 : list A.
257   ∀f:A → list B. ∀seed.
258    foldr ?? (λx,acc. (f x) @ acc) seed (l1 @ l2) =
259     append ? (foldr ?? (λx,acc. (f x) @ acc) (nil ?) l1)
260       (foldr  ?? (λx,acc. (f x) @ acc) seed l2).
261#A #B #l1 elim l1 normalize // /3 by eq_f, trans_eq/
262qed.
263
264lemma cons_append : ∀A.∀x : A.∀l.x::l = ([x]@l).
265//
266qed.
267
268lemma domain_of_associative_list_append : ∀A,B.∀l1,l2 : associative_list A B.
269domain_of_associative_list ?? (l1 @ l2) =
270 (domain_of_associative_list ?? l1) @ (domain_of_associative_list ?? l2).
271#A #B #l1 elim l1 // #x #xs #IH #l2 normalize //
272qed.
273
274(*monoids*)
275
276record monoid: Type[1] ≝
277 { carrier :> DeqSet
278 ; op: carrier → carrier → carrier
279 ; e: carrier
280 ; neutral_r : ∀x. op … x e = x
281 ; neutral_l : ∀x. op … e x = x
282 ; is_associative: ∀x,y,z. op … (op … x y) z = op … x (op … y z)
283 }.
284 
285definition is_abelian ≝ λM : monoid.
286∀x,y : M.op … M x y = op … M y x.
287 
288record monoid_action (I : monoid) (M : Type[0]) : Type[0] ≝
289{ act :2> I → M → M
290; act_neutral : ∀x.act (e …) x = x
291; act_op : ∀i,j,x.act (op … i j) x = act j (act i x)
292}.
293
294(* partial order *)
295
296record partial_order (A : Type[0]) : Type[0] ≝
297{ po_rel :2> A → A → Prop
298; refl_po_rel : reflexive … po_rel
299; antisym_po_rel : ∀x,y : A.po_rel … x y → po_rel … y x → x = y
300; trans_po_rel : transitive … po_rel
301}.
302
303(* fold2 *)
304
305let rec foldr2 (A : Type[0]) (B : Type[0]) (C : Type[0]) (a : A) (l1 : list B)
306(l2 : list C) (f : A → B → C → A) on l1 : option A≝
307match l1 with
308[ nil ⇒ match l2 with [ nil ⇒ return a | cons y ys ⇒ None ? ]
309| cons x xs ⇒
310        match l2 with
311        [ nil ⇒ None ?
312        | cons y ys ⇒ ! ih ← (foldr2 … a xs ys f);
313                      return f ih x y
314        ]
315].
316
317(* dependent map*)
318
319let rec dependent_map (A,B : Type[0]) (l : list A) (f : ∀a : A.mem … a l → B) on l : list B ≝
320(match l return λx.l=x → ? with
321[ nil ⇒ λ_.nil ?
322| cons x xs ⇒ λprf.(f x ?) :: dependent_map A B xs (λx,prf1.f x ?)
323])(refl …).
324[ >prf %% | >prf %2 assumption]
325qed.
326
327lemma dependent_map_append : ∀A,B,l1,l2,f.
328dependent_map A B (l1 @ l2) (λa,prf.f a prf) =
329(dependent_map A B l1 (λa,prf.f a ?)) @ (dependent_map A B l2 (λa,prf.f a ?)).
330[2: @hide_prf /2/ | 3: @hide_prf /2/]
331#A #B #l1 elim l1 normalize /2/
332qed.
333
334lemma rewrite_in_dependent_map : ∀A,B,l1,l2,f.
335        ∀EQ:l1 = l2.
336         dependent_map A B l1 (λa,prf.f a prf) =
337         dependent_map A B l2 (λa,prf.f a ?).
338[2: >EQ // | #A #B #l1 #l2 #f #EQ >EQ in f; #f % ]
339qed.
340
341definition applica : ∀A,B : Type[0].∀ l : list A.(∀a : A.mem … a l → B) → ∀a : A.mem … a l → B ≝
342λA,B,l,f,x,prf.f x prf.
343
344lemma proof_irrelevance_temp :  ∀A,B : Type[0].∀l : list A.
345∀f : (∀a : A.mem … a l → B).∀x.∀prf1,prf2.
346applica … f x prf1 = applica … f x prf2.
347//
348qed.
349
350lemma proof_irrelevance_all : ∀A,B : Type[0].∀l : list A.
351∀f : (∀a : A.mem … a l → B).∀x.∀prf1,prf2.
352f x prf1 = f x prf2.
353#A #B #l #f #x #prf1 #prf2 @proof_irrelevance_temp
354qed.
355
356lemma dependent_map_extensional : ∀A,B : Type[0].∀l : list A.
357∀f,g : (∀a.mem … a l → B).(∀a,prf1,prf2.f a prf1 = g a prf2) →
358dependent_map … l f = dependent_map … l g.
359#A #B #l elim l // #x #xs #IH #f #g #H whd in ⊢ (??%%);
360@eq_f2 // @IH //
361qed.
Note: See TracBrowser for help on using the repository browser.