source: LTS/utils.ma @ 3562

Last change on this file since 3562 was 3554, checked in by piccolo, 5 years ago
File size: 11.9 KB
Line 
1(**************************************************************************)
2(*       ___                                                              *)
3(*      ||M||                                                             *)
4(*      ||A||       A project by Andrea Asperti                           *)
5(*      ||T||                                                             *)
6(*      ||I||       Developers:                                           *)
7(*      ||T||         The HELM team.                                      *)
8(*      ||A||         http://helm.cs.unibo.it                             *)
9(*      \   /                                                             *)
10(*       \ /        This file is distributed under the terms of the       *)
11(*        v         GNU General Public License Version 2                  *)
12(*                                                                        *)
13(**************************************************************************)
14
15include "basics/lists/listb.ma".
16include "../src/utilities/hide.ma".
17include "../src/ASM/Util.ma".
18include "../src/utilities/option.ma".
19
20(*NO DUPLICATES in lists*)
21
22let rec no_duplicates (A : DeqSet) (l : list A) on l : Prop ≝
23match l with
24[ nil ⇒ True
25| cons x xs ⇒ ¬ (bool_to_Prop (x ∈ xs)) ∧ no_duplicates … xs
26].
27
28lemma no_duplicates_append_r : ∀A : DeqSet.∀l1,l2 : list A.no_duplicates … (l1 @ l2) →
29no_duplicates … l2.
30#A #l1 elim l1 // #x #xs normalize #IH #l2 * /2/
31qed.
32
33lemma no_duplicates_append_l : ∀A : DeqSet.∀l1,l2 : list A.no_duplicates … (l1 @ l2) →
34no_duplicates … l1.
35#A #l1 elim l1 // #x #xs normalize #IH #l2 * #H1 #H2 % [2: /2/ ]
36inversion(x ∈ xs @l2) in H1; normalize [ #_ * #H @⊥ @H %] #H1 #_
37% inversion(x ∈ xs) normalize [2: //] #H3 #_ >(memb_append_l1 … H3) in H1;
38#EQ destruct(EQ)
39qed.
40
41lemma no_duplicates_append_commute : ∀ A : DeqSet.∀l1,l2 : list A.
42no_duplicates … (l1 @ l2) →
43no_duplicates … (l2 @ l1).
44#A #l1 elim l1
45[ #l2 >append_nil //]
46#x #xs #IH #l2 * #H1 #H2 lapply(IH … H2) lapply H1 -H1 -IH -H2
47elim l2 -l1
48[ >append_nil #H1 #H2 % // ]
49#y #ys #IH * #H1 * #H2 #H3 %
50[2: @IH
51   [ % #H4 @H1 cases(memb_append … H4)
52     [ #H5 >memb_append_l1 //
53     | #H5 >memb_append_l2 // @orb_Prop_r >H5 //
54     ]
55   | //
56   ]
57| % #H4 cases(memb_append … H4)
58  [ #H5 @(absurd ?? H2) >memb_append_l1 //
59  | whd in match (memb ???); inversion(y==x)
60    [ #H5 #_ <(\P H5) in H1; #H1 @H1 >memb_append_l2 //
61    | #_ normalize nodelta #H5 @(absurd ?? H2) >memb_append_l2 //
62    ]
63  ]
64]
65qed.
66
67lemma memb_not_append : ∀D : DeqSet.∀l1,l2 : list D.∀x : D.
68x ∈ l1 = false → x ∈ l2 = false → x ∈ (l1 @ l2) = false.
69#D #l1 elim l1
70[ #l2 #x #_ #H @H ]
71#x #xs #IH #l2 #x1 whd in match (memb ???); inversion (x1 == x) normalize nodelta
72[ #_ #EQ destruct] #EQx1 #EQxs #EQl2 whd in match (memb ???); >EQx1
73normalize nodelta @IH //
74qed.
75
76lemma memb_no_duplicates_append : ∀A : DeqSet.∀x.∀l1,l2 : list A .
77no_duplicates … (l1 @ l2) → x ∈  l1 → x ∈ l2 → False.
78#A #x #l1 elim l1 // #x1 #xs #IH #l2 * #H1 #H2 whd in match (memb ???);
79inversion (x == x1) normalize nodelta
80[ #H3 #_ #H4 >memb_append_l2 in H1; [2: <(\P H3) @H4 ] * #H @H %
81| #_ @IH //
82]
83qed.
84
85(* subset *)
86
87let rec subset (A : Type[0]) (l1,l2 : list A) on l1 : Prop ≝
88match l1 with
89[ nil ⇒ True
90| cons x xs ⇒ mem … x l2 ∧ subset … xs l2
91].
92
93interpretation "subset" 'subseteq a b = (subset ? a b).
94
95lemma subset_append_l2 : ∀A,l2,l1.subset A l2 (l1 @ l2).
96#A #l2 elim l2 // normalize #x #xs #IH #l1 % // @mem_append_l2 whd /2/
97qed.
98
99lemma refl_subset : ∀A.reflexive … (subset A).
100#A #l1 elim l1 // #x #xs #IH normalize % /2/ change with ([?]@xs) in match (x :: xs);
101@subset_append_l2
102qed.
103
104lemma subset_def : ∀A : DeqSet.∀l1,l2 : list A.(∀x.x ∈l1 → x ∈ l2) → l1 ⊆ l2.
105#A #l1 elim l1 // #x #xs #IH #l2 #H %
106[ @memb_to_mem >H // >memb_hd //
107| @IH #y #H1 @H >memb_cons // >H1 //
108]
109qed.
110
111lemma subset_append : ∀A.∀l1,l2,l3 : list A.l1 ⊆ l3 → l2 ⊆ l3 → (l1 @ l2) ⊆ l3.
112#A #l1 elim l1 // #x #xs #IH #l2 #l3 * #H1 #H2 #H3 % /2/
113qed.
114
115lemma subset_def_inv : ∀A.∀l1,l2 : list A. l1 ⊆ l2 → ∀x.mem … x l1 → mem … x l2.
116#A #l1 elim l1 [ #l2 * #x * ] #x #xs #IH #l2 * #H1 #H2 #y *
117[ #EQ destruct // | #H3 @IH // ]
118qed.
119
120lemma transitive_subset : ∀A.transitive … (subset A).
121#A #l1 elim l1 // #x #xs #IH #l2 #l3 * #H1 #H2 #H3 %
122[ @(subset_def_inv … H3) // | @IH // ]
123qed.
124
125lemma subset_append_h1 : ∀A.∀l1,l2,l3 : list A.l1 ⊆ l3 → l1 ⊆ (l3 @ l2).
126#A #l1 elim l1 // #x #x2 #IH #l2 #l3 * #H1 #H2 % [ @mem_append_l1 // | @IH // ]
127qed.
128
129lemma subset_append_h2 : ∀A.∀l1,l2,l3 : list A.l2 ⊆ l3 → l2 ⊆ (l1 @ l3).
130#A #l1 elim l1 // #x #xs #IH #l2 elim l2 // #y #ys #IH #l3 * #H1 #H2 %
131[ @mem_append_l2 // | @IH // ]
132qed.
133
134(* list of elements with decidable equality *)
135
136let rec eqb_list (D : DeqSet) (l1 : list D) on l1 : list D → bool ≝
137match l1 with
138[ nil ⇒ λl2.match l2 with [nil ⇒ true | _ ⇒ false ]
139| cons x xs ⇒ λl2.match l2 with [ cons y ys ⇒ x == y ∧ eqb_list … xs ys | _ ⇒ false ]
140].
141
142definition DeqSet_List : DeqSet → DeqSet ≝
143λX.mk_DeqSet (list X) (eqb_list …) ?.
144#x elim x [ * /2 by refl, conj/ #y #ys normalize % #EQ destruct] -x
145#x #xs #IH * [ normalize % #EQ destruct] #y #ys normalize % inversion(x == y)
146#EQ normalize nodelta
147[ #H >(proj1 … (IH ys) H) @eq_f2 [2: %] @(proj1 … (eqb_true …)) assumption
148| #EQ destruct
149| #EQ1 destruct @(proj2 … (IH …)) %
150| #EQ1 destruct <EQ @(proj2 … (eqb_true …)) %
151]
152qed.
153
154unification hint  0 ≔ C;
155    X ≟ DeqSet_List C
156(* ---------------------------------------- *) ⊢
157    list C ≡ carr X.
158
159
160unification hint  0 ≔ D,p1,p2;
161    X ≟ DeqSet_List D
162(* ---------------------------------------- *) ⊢
163    eqb_list D p1 p2 ≡ eqb X p1 p2.
164
165lemma mem_list : ∀A : Type[0].
166∀l : list A.∀x : A.mem … x l →
167∃l1,l2.l=l1 @ [x] @ l2.
168#A #l elim l
169[ #x *]
170#x #xs #IH #y *
171[ #EQ destruct %{[]} %{xs} %
172| #H cases(IH … H) #l1 * #l2 #EQ destruct
173  %{(x :: l1)} %{l2} %
174]
175qed.
176
177(* associative list *)
178
179definition associative_list : DeqSet → Type[0] → Type[0] ≝
180λA,B.list (A × (list B)).
181
182let rec update_list (A : DeqSet) (B : Type[0]) (l : associative_list A B)
183   on l : A → list B → associative_list A B ≝
184λa,b.match l with
185    [ nil ⇒ [〈a,b〉]
186    | cons x xs ⇒ if (a == (\fst x)) then 〈a,b〉 :: xs
187                  else x :: (update_list … xs a b) 
188    ].
189
190let rec get_element (A :DeqSet) (B : Type[0]) (l: associative_list A B) on l : A → list B ≝
191λa.match l with [ nil ⇒ nil ?
192                | cons x xs ⇒ if (a == \fst x) then \snd x else get_element … xs a
193                ].
194
195let rec domain_of_associative_list (A :DeqSet) (B : Type[0]) (l: associative_list A B) on l : list A ≝
196 match l with
197  [ nil ⇒ []
198  | cons x xs ⇒ \fst x :: domain_of_associative_list … xs
199  ].
200
201lemma get_element_append_l:
202 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
203  x ∈ domain_of_associative_list … l1 →
204   get_element … (l1@l2) x = get_element … l1 x.
205#A #B #l1 elim l1 normalize [ #l2 #x * ] #hd #tl #IH #l2 #x cases (dec_eq … x (\fst hd))
206#H [ >(\b H) | >(\bf H) ] normalize /2/
207qed.
208
209lemma get_element_append_r:
210 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
211  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l1)) →
212   get_element ?? (l1@l2) x = get_element … l2 x.
213#A #B #l1 elim l1 normalize [ #l2 #x // ] #hd #tl #IH #l2 #x cases (dec_eq … x (\fst hd))
214#H [ >(\b H) | >(\bf H) ] normalize /2 by/ * #K cases (K I)
215qed.
216
217lemma get_element_append_l1 :
218 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
219  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l2)) →
220   get_element ?? (l1@l2) x = get_element … l1 x.
221#A #B #l1 elim l1 normalize [2: #x #xs #IH #l2 #a #H >IH // ]
222#l2 elim l2 // #y #ys #IH #a normalize cases(a == \fst y) normalize
223[ * #H @⊥ @H % ] #H @IH assumption
224qed.
225
226lemma get_element_append_r1 :
227 ∀A,B. ∀l1,l2: associative_list A B. ∀x.
228  ¬ (bool_to_Prop (x ∈ domain_of_associative_list … l1)) →
229   get_element ?? (l1@l2) x = get_element … l2 x.
230#A #B #l1 elim l1 normalize // #x #xs #IH #l2 #a cases (?==?)
231normalize [* #H cases H //] #H >IH normalize //
232qed.
233
234lemma memb_append_l22 : ∀A : DeqSet.∀x : A.∀l1,l2 : list A.
235¬ (x ∈ l1) → x∈ l1 @ l2 = (x ∈ l2).
236#A #x #l1 elim l1 normalize // #y #ys #IH #l2 cases(x==y)
237normalize [*] @IH
238qed.
239
240lemma memb_append_l12 : ∀A : DeqSet.∀x : A.∀l1,l2 : list A.
241¬ (x ∈ l2) → x∈ l1 @ l2 = (x ∈ l1).
242#A #x #l1 elim l1
243[ #l2 #H whd in match (append ???); @not_b_to_eq_false @Prop_notb >H % ]
244#y #ys #IH #l2 #H1 whd in match (memb ???); >IH //
245qed.
246
247lemma foldr_map_append :
248  ∀A,B:Type[0]. ∀l1, l2 : list A.
249   ∀f:A → list B. ∀seed.
250    foldr ?? (λx,acc. (f x) @ acc) seed (l1 @ l2) =
251     append ? (foldr ?? (λx,acc. (f x) @ acc) (nil ?) l1)
252       (foldr  ?? (λx,acc. (f x) @ acc) seed l2).
253#A #B #l1 elim l1 normalize // /3 by eq_f, trans_eq/
254qed.
255
256lemma cons_append : ∀A.∀x : A.∀l.x::l = ([x]@l).
257//
258qed.
259
260lemma domain_of_associative_list_append : ∀A,B.∀l1,l2 : associative_list A B.
261domain_of_associative_list ?? (l1 @ l2) =
262 (domain_of_associative_list ?? l1) @ (domain_of_associative_list ?? l2).
263#A #B #l1 elim l1 // #x #xs #IH #l2 normalize //
264qed.
265
266(*monoids*)
267
268record monoid: Type[1] ≝
269 { carrier :> DeqSet
270 ; op: carrier → carrier → carrier
271 ; e: carrier
272 ; neutral_r : ∀x. op … x e = x
273 ; neutral_l : ∀x. op … e x = x
274 ; is_associative: ∀x,y,z. op … (op … x y) z = op … x (op … y z)
275 }.
276 
277definition is_abelian ≝ λM : monoid.
278∀x,y : M.op … M x y = op … M y x.
279 
280record monoid_action (I : monoid) (M : Type[0]) : Type[0] ≝
281{ act :2> I → M → M
282; act_neutral : ∀x.act (e …) x = x
283; act_op : ∀i,j,x.act (op … i j) x = act j (act i x)
284}.
285
286(* partial order *)
287
288record partial_order (A : Type[0]) : Type[0] ≝
289{ po_rel :2> A → A → Prop
290; refl_po_rel : reflexive … po_rel
291; antisym_po_rel : ∀x,y : A.po_rel … x y → po_rel … y x → x = y
292; trans_po_rel : transitive … po_rel
293}.
294
295(* fold2 *)
296
297let rec foldr2 (A : Type[0]) (B : Type[0]) (C : Type[0]) (a : A) (l1 : list B)
298(l2 : list C) (f : A → B → C → A) on l1 : option A≝
299match l1 with
300[ nil ⇒ match l2 with [ nil ⇒ return a | cons y ys ⇒ None ? ]
301| cons x xs ⇒
302        match l2 with
303        [ nil ⇒ None ?
304        | cons y ys ⇒ ! ih ← (foldr2 … a xs ys f);
305                      return f ih x y
306        ]
307].
308
309(* dependent map*)
310
311let rec dependent_map (A,B : Type[0]) (l : list A) (f : ∀a : A.mem … a l → B) on l : list B ≝
312(match l return λx.l=x → ? with
313[ nil ⇒ λ_.nil ?
314| cons x xs ⇒ λprf.(f x ?) :: dependent_map A B xs (λx,prf1.f x ?)
315])(refl …).
316[ >prf %% | >prf %2 assumption]
317qed.
318
319lemma dependent_map_append : ∀A,B,l1,l2,f.
320dependent_map A B (l1 @ l2) (λa,prf.f a prf) =
321(dependent_map A B l1 (λa,prf.f a ?)) @ (dependent_map A B l2 (λa,prf.f a ?)).
322[2: @hide_prf /2/ | 3: @hide_prf /2/]
323#A #B #l1 elim l1 normalize /2/
324qed.
325
326lemma rewrite_in_dependent_map : ∀A,B,l1,l2,f.
327        ∀EQ:l1 = l2.
328         dependent_map A B l1 (λa,prf.f a prf) =
329         dependent_map A B l2 (λa,prf.f a ?).
330[2: >EQ // | #A #B #l1 #l2 #f #EQ >EQ in f; #f % ]
331qed.
332
333definition applica : ∀A,B : Type[0].∀ l : list A.(∀a : A.mem … a l → B) → ∀a : A.mem … a l → B ≝
334λA,B,l,f,x,prf.f x prf.
335
336lemma proof_irrelevance_temp :  ∀A,B : Type[0].∀l : list A.
337∀f : (∀a : A.mem … a l → B).∀x.∀prf1,prf2.
338applica … f x prf1 = applica … f x prf2.
339//
340qed.
341
342lemma proof_irrelevance_all : ∀A,B : Type[0].∀l : list A.
343∀f : (∀a : A.mem … a l → B).∀x.∀prf1,prf2.
344f x prf1 = f x prf2.
345#A #B #l #f #x #prf1 #prf2 @proof_irrelevance_temp
346qed.
347
348lemma dependent_map_extensional : ∀A,B : Type[0].∀l : list A.
349∀f,g : (∀a.mem … a l → B).(∀a,prf1,prf2.f a prf1 = g a prf2) →
350dependent_map … l f = dependent_map … l g.
351#A #B #l elim l // #x #xs #IH #f #g #H whd in ⊢ (??%%);
352@eq_f2 // @IH //
353qed.
Note: See TracBrowser for help on using the repository browser.