source: LTS/Traces.ma @ 3391

Last change on this file since 3391 was 3391, checked in by piccolo, 6 years ago

Definition of well formed trace is in the operational semantics

File size: 13.0 KB
Line 
1(**************************************************************************)
2(*       ___                                                              *)
3(*      ||M||                                                             *)
4(*      ||A||       A project by Andrea Asperti                           *)
5(*      ||T||                                                             *)
6(*      ||I||       Developers:                                           *)
7(*      ||T||         The HELM team.                                      *)
8(*      ||A||         http://helm.cs.unibo.it                             *)
9(*      \   /                                                             *)
10(*       \ /        This file is distributed under the terms of the       *)
11(*        v         GNU General Public License Version 2                  *)
12(*                                                                        *)
13(**************************************************************************)
14
15include "arithmetics/nat.ma".
16include "basics/types.ma".
17include "basics/deqsets.ma".
18include "../src/ASM/Util.ma".
19
20inductive FunctionName : Type[0] ≝
21 | a_function_id : ℕ → FunctionName.
22 
23inductive CallCostLabel : Type[0] ≝
24 | a_call_label : ℕ → CallCostLabel.
25 
26inductive ReturnPostCostLabel : Type[0] ≝
27 | a_return_cost_label : ℕ → ReturnPostCostLabel.
28 
29inductive NonFunctionalLabel : Type[0] ≝
30 | a_non_functional_label : ℕ → NonFunctionalLabel.
31 
32inductive CostLabel : Type[0] ≝
33 | a_call : CallCostLabel → CostLabel
34 | a_return_post : ReturnPostCostLabel → CostLabel
35 | a_non_functional_label : NonFunctionalLabel → CostLabel.
36
37coercion a_call.
38coercion a_return_post.
39coercion a_non_functional_label.
40
41definition ret_act_label_to_cost_label :
42(ReturnPostCostLabel + NonFunctionalLabel) → CostLabel ≝
43λx.match x with [inl a ⇒ a_return_post a | inr b ⇒ a_non_functional_label b].
44
45coercion ret_act_label_to_cost_label.
46
47definition call_act_label_to_cost_label :
48(CallCostLabel + NonFunctionalLabel) → CostLabel ≝
49λx.match x with [inl a ⇒ a_call a | inr b ⇒ a_non_functional_label b].
50
51coercion call_act_label_to_cost_label.
52
53inductive ActionLabel : Type[0] ≝
54 | call_act : FunctionName → (CallCostLabel + NonFunctionalLabel) → ActionLabel
55 | ret_act : option(ReturnPostCostLabel + NonFunctionalLabel) → ActionLabel
56 | cost_act : option NonFunctionalLabel → ActionLabel
57 | init_act : ActionLabel.
58 
59definition is_cost_label : ActionLabel → Prop ≝
60λact.match act with [ cost_act nf ⇒ True | _ ⇒ False ].
61
62inductive status_class : Type[0] ≝
63 | cl_jump : status_class
64 | cl_io : status_class
65 | cl_other : status_class.
66
67definition is_non_silent_cost_act : ActionLabel → Prop ≝
68λact. ∃l. act = cost_act (Some ? l).
69
70record abstract_status : Type[2] ≝
71 { as_status :> Type[0]
72 ; as_execute : ActionLabel → relation as_status
73 ; as_syntactical_succ : relation as_status
74 ; as_classify : as_status → status_class
75 ; is_call_post_label : as_status → bool
76 ; as_initial : as_status → bool
77 ; as_final : as_status → bool
78 ; is_io_entering : NonFunctionalLabel → bool
79 ; is_io_exiting : NonFunctionalLabel → bool
80 ; jump_emits : ∀s1,s2,l.
81      as_classify … s1 = cl_jump →
82      as_execute l s1 s2 → is_non_silent_cost_act l
83 }.
84 
85definition is_act_io_entering : abstract_status → ActionLabel → bool ≝
86λS,l.match l with
87[ call_act f c ⇒ match c with [ inl _ ⇒ false | inr c' ⇒ is_io_entering S c' ]
88| ret_act x ⇒ match x with [ Some c ⇒ match c with [inl _ ⇒ false
89                                                   | inr c' ⇒ is_io_entering S c']
90                           | None ⇒ false
91                           ]
92| cost_act x ⇒ match x with [ Some c ⇒ is_io_entering S c | None ⇒ false ]
93| init_act ⇒ false
94].
95
96definition is_act_io_exiting : abstract_status → ActionLabel → bool ≝
97λS,l.match l with
98[ call_act f c ⇒ match c with [ inl _ ⇒ false | inr c' ⇒ is_io_exiting S c' ]
99| ret_act x ⇒ match x with [ Some c ⇒ match c with [inl _ ⇒ false
100                                                   | inr c' ⇒ is_io_exiting S c']
101                           | None ⇒ false
102                           ]
103| cost_act x ⇒ match x with [ Some c ⇒ is_io_exiting S c | None ⇒ false ]
104| init_act ⇒ false
105].
106
107
108inductive raw_trace (S : abstract_status) : S → S → Type[0] ≝
109  | t_base : ∀st : S.raw_trace S st st
110  | t_ind : ∀st1,st2,st3 : S.∀l : ActionLabel.
111             as_execute S l st1 st2 → raw_trace S st2 st3 →
112             raw_trace S st1 st3.
113
114definition is_cost_act : ActionLabel → Prop ≝
115λact.∃l.act = cost_act l.
116
117definition is_call_act : ActionLabel → Prop ≝
118λact.∃f,l.act = call_act f l.
119
120definition is_labelled_ret_act : ActionLabel → Prop ≝
121λact.∃l.act = ret_act (Some ? l).
122
123definition is_unlabelled_ret_act : ActionLabel → Prop ≝
124λact.act = ret_act (None ?).
125
126definition is_costlabelled_act : ActionLabel → Prop ≝
127λact.match act with [ call_act _ _ ⇒ True
128                    | ret_act x ⇒ match x with [ Some _ ⇒ True | None ⇒ False ]
129                    | cost_act x ⇒ match x with [ Some _ ⇒ True | None ⇒ False ]
130                    | init_act ⇒ False
131                    ].
132(*
133lemma well_formed_trace_inv :
134∀S : abstract_status.∀st1,st2 : S.∀t : raw_trace S st1 st2.
135well_formed_trace … t →
136(st1 = st2 ∧ t ≃ t_base S st1) ∨
137(∃st1'.∃l.∃prf : as_execute S l st1 st1'.∃tl : raw_trace S st1' st2.
138well_formed_trace … tl ∧ as_classify … st1 ≠ cl_jump ∧
139t ≃ t_ind … prf … tl) ∨
140(∃st1'.∃l.∃ prf : as_execute S l st1 st1'.∃ tl : raw_trace S st1' st2.
141 well_formed_trace … tl ∧ is_non_silent_cost_act l ∧ t ≃ t_ind … prf … tl). (* ∨
142(∃st1'.∃l.∃prf : as_execute S l st1 st1'.∃tl : raw_trace S st1' st2.
143 well_formed_trace … tl ∧ as_classify … st1 = cl_io ∧
144 is_non_silent_cost_act l ∧ t ≃ t_ind … prf … tl).*)
145#S #st1 #st2 #t #H inversion H
146[ #st #EQ1 #EQ2 destruct(EQ1 EQ2) #EQ destruct(EQ) #_ /5 by refl_jmeq, or_introl, conj/
147| #st1' #st2' #st3' #l #prf' #tl' #Htl #Hclass #_ #EQ2 #EQ3 #EQ4 destruct #_
148  %  %2 %{st2'} %{l} %{prf'} %{tl'} /4 by conj/
149| #st1' #st2' #st3' #l #prf #tl #Htl #Hl #_ #EQ2 #EQ3 #EQ4 destruct #_ %2 %{st2'}
150  %{l} %{prf} %{tl} % // % //
151(*| #st1' #st2' #st3' #l #prf #tl #Htl #Hclass #is_non_silent #_ #EQ1 #EQ2 #EQ3
152  destruct #_ %2 %{st2'} %{l} %{prf} %{tl} /5 by conj/ *)
153]
154qed.
155
156*)
157
158let rec append_on_trace (S : abstract_status) (st1 : S) (st2 : S) (st3 : S)
159(t1 : raw_trace S st1 st2) on t1 : raw_trace S st2 st3 → raw_trace S st1 st3 ≝
160match t1
161return λst1,st2,tr.raw_trace S st2 st3 → raw_trace S st1 st3
162with
163[ t_base st ⇒ λt2.t2
164| t_ind st1' st2' st3' l prf tl ⇒ λt2.t_ind … prf … (append_on_trace … tl t2)
165].
166
167interpretation "trace_append" 'append t1 t2 = (append_on_trace ???? t1 t2).
168
169lemma append_associative : ∀S,st1,st2,st3,st4.
170∀t1 : raw_trace S st1 st2.∀t2 : raw_trace S st2 st3.
171∀t3 : raw_trace S st3 st4.(t1 @ t2) @ t3 = t1 @ (t2 @ t3).
172#S #st1 #st2 #st3 #st4 #t1 elim t1 -t1
173[ #st #t2 #t3 %] #st1' #st2' #st3' #l #prf #tl #IH #t2 #t3 whd in ⊢ (??%%); >IH %
174qed.
175
176definition trace_prefix: ∀S : abstract_status.∀st1,st2,st3 : S.raw_trace … st1 st2 →
177raw_trace … st1 st3 → Prop≝
178λS,st1,st2,st3,t1,t2.∃t3 : raw_trace … st2 st3.t2 = t1 @ t3.
179
180definition trace_suffix : ∀S : abstract_status.∀st1,st2,st3 : S.raw_trace … st2 st3 →
181raw_trace … st1 st3 → Prop≝
182λS,st1,st2,st3,t1,t2.∃t3 : raw_trace … st1 st2.t2 = t3 @ t1.
183
184inductive silent_trace (S : abstract_status) :
185∀st1,st2 : S.raw_trace S st1 st2 → Prop ≝
186| silent_empty : ∀st : S.as_classify … st ≠ cl_io → silent_trace … (t_base S st)
187| silent_cons : ∀st1,st2,st3 : S.∀prf : as_execute S (cost_act (None ?)) st1 st2.
188                ∀tl : raw_trace S st2 st3. as_classify … st1 ≠ cl_io → silent_trace … tl →
189                silent_trace … (t_ind … prf … tl).
190
191lemma silent_io : ∀S : abstract_status.
192∀s1,s2 : S. ∀t : raw_trace … s1 s2. silent_trace … t →
193as_classify … s2 ≠ cl_io.
194#S #s1 #s2 #t elim t [ #st #H inversion H // #st1 #st2 #st3 #prf #tl #H1 #sil_tl #_ #EQ1 #EQ2 #EQ3 destruct]
195#st1 #st2 #st3 #l #prf #tl #IH #H inversion H //
196#st1' #st2' #st3' #prf' #tl' #Hclass #silent_tl' #_ #EQ1 #EQ2 destruct
197#EQ destruct #_ @IH assumption
198qed.
199
200definition is_trace_non_empty : ∀S : abstract_status.∀st1,st2.
201raw_trace S st1 st2 → bool ≝
202λS,st1,st2,t.match t with [ t_base _ ⇒ false | _ ⇒ true ].
203(*
204definition silent_trace : ∀S : abstract_status.∀st1,st2 : S.
205raw_trace S st1 st2 → Prop ≝ λS,st1,st2,t.pre_silent_trace … t ∧
206well_formed_trace … t.
207
208lemma silent_is_well_formed : ∀S : abstract_status.∀st1,st2 : S.
209∀t : raw_trace S st1 st2. silent_trace … t → well_formed_trace … t.
210#S #st1 #st2 #t * //
211qed. *)
212(* elim t -t
213[ #st #_ %]
214#st1' #st2' #st3' #l #prf #tl #IH * #H #cl %2
215[2: >cl % #EQ destruct]
216@IH inversion H in ⊢ ?; [ #st #EQ1 #EQ2 #EQ3 destruct]
217#st1'' #st2'' #st3'' #prf' #tl' #H1 #Htl' #_ #EQ1 #EQ2 #EQ3 destruct #_
218% [ assumption | #_ assumption]
219qed.*)
220
221inductive pre_measurable_trace (S : abstract_status) :
222∀st1,st2 : S.raw_trace ? st1 st2 → Prop ≝
223 | pm_empty : ∀st : S. as_classify … st ≠ cl_io → pre_measurable_trace … (t_base ? st)
224 | pm_cons_cost_act : ∀st1,st2,st3 : S.∀l : ActionLabel.
225                      ∀prf : as_execute S l st1 st2.∀tl : raw_trace S st2 st3.
226                      as_classify … st1 ≠ cl_io → is_cost_act l → pre_measurable_trace … tl →
227                      pre_measurable_trace … (t_ind … prf … tl)
228 | pm_cons_lab_ret : ∀st1,st2,st3 : S.∀l : ActionLabel.
229                      as_classify … st1 ≠ cl_io →
230                      ∀prf : as_execute S l st1 st2.∀tl : raw_trace S st2 st3.
231                      is_labelled_ret_act l → pre_measurable_trace … tl →
232                      pre_measurable_trace … (t_ind … prf … tl)
233 | pm_cons_post_call : ∀st1,st2,st3 : S.∀l : ActionLabel.
234                      ∀prf : as_execute S l st1 st2.∀tl : raw_trace S st2 st3.
235                      as_classify … st1 ≠ cl_io → is_call_act l → is_call_post_label … st1 →
236                      pre_measurable_trace … tl →
237                      pre_measurable_trace … (t_ind … prf … tl)
238 | pm_balanced_call : ∀st1,st2,st3,st4,st5.∀l1,l2.
239                      ∀prf : as_execute S l1 st1 st2.∀t1 : raw_trace S st2 st3.
240                      ∀t2 : raw_trace S st4 st5.∀prf' : as_execute S l2 st3 st4.
241                      as_classify … st1 ≠ cl_io → as_classify … st3 ≠ cl_io
242                      →  is_call_act l1 → ¬ is_call_post_label … st1 →
243                      pre_measurable_trace … t1 → pre_measurable_trace … t2 →
244                      as_syntactical_succ S st1 st4 →
245                      is_unlabelled_ret_act l2 →
246                      pre_measurable_trace … (t_ind … prf … (t1 @ (t_ind … prf' … t2))).
247                     
248lemma pre_measurable_trace_inv : ∀S : abstract_status.
249∀st1,st2 : S.∀t : raw_trace … st1 st2. pre_measurable_trace … t →
250(st1 = st2 ∧ as_classify … st1 ≠ cl_io ∧ t ≃ t_base … st1) ∨
251(∃st1' : S.∃l.∃prf : as_execute S l st1 st1'.∃tl.
252 t = t_ind … prf … tl ∧ as_classify … st1 ≠ cl_io ∧ is_cost_act l ∧
253 pre_measurable_trace … tl) ∨
254(∃st1' : S.∃l.∃prf : as_execute S l st1 st1'.∃tl.
255 t = t_ind … prf … tl ∧
256 as_classify … st1 ≠ cl_io ∧ is_labelled_ret_act l ∧ pre_measurable_trace … tl) ∨
257(∃st1' : S .∃l.∃prf : as_execute S l st1 st1'.∃tl.
258 t = t_ind … prf … tl ∧ as_classify … st1 ≠ cl_io ∧ is_call_act l ∧
259 (bool_to_Prop (is_call_post_label … st1)) ∧ pre_measurable_trace … tl) ∨
260(∃st1',st1'',st1''' : S.∃l1,l2.∃prf : as_execute S l1 st1 st1'.
261 ∃t1 : raw_trace S st1' st1''.∃t2 : raw_trace S st1''' st2.
262 ∃prf' : as_execute S l2 st1'' st1'''.
263 t = t_ind … prf … (t1 @ (t_ind … prf' … t2)) ∧ as_classify … st1 ≠cl_io ∧
264 as_classify … st1'' ≠ cl_io ∧ is_call_act l1 ∧
265 bool_to_Prop (¬ is_call_post_label … st1) ∧
266 pre_measurable_trace … t1 ∧ pre_measurable_trace … t2 ∧
267 as_syntactical_succ S st1 st1''' ∧ is_unlabelled_ret_act l2).
268#S #st1 #st2 #t #H inversion H
269[ #st #Hclass #EQ1 #EQ2 destruct #EQ destruct #_ %%%%% // % //
270| #st1' #st2' #st3' #l #prf #tl #Hst1' #Hl #Htl #_ #EQ1 #EQ2 #EQ3 destruct #_
271  %%%%2 %{st2'} %{l} %{prf} %{tl} % // % // % //
272| #st1' #st2' #st3' #l #Hst1 #prf #tl #Hl #Htl #_ #EQ1 #EQ2 #EQ3 destruct #_
273  %%%2 %{st2'} %{l} %{prf} %{tl} % // % // % //
274| #st1' #st2' #st3' #l #prf #tl #Hst1 #Hl #H1st1 #Htl #_ #EQ1 #EQ2 #EQ3 destruct #_
275  % %2 %{st2'} %{l} %{prf} %{tl} % // % // % // % //
276| #st1' #st2' #st3' #st4' #st5' #l1 #l2 #prf #t1 #t2 #prf' #Hst1' #Hst3' #Hl1
277  #H1st1'  #Ht1 #Ht2 #succ #Hl2 #_ #_ #EQ1 #EQ2 #EQ3 destruct #_ %2
278  %{st2'} %{st3'} %{st4'} %{l1} %{(ret_act (None ?))} %{prf} %{t1} %{t2}
279  %{prf'} /12 by conj/
280]
281qed.
282                     
Note: See TracBrowser for help on using the repository browser.