source: Deliverables/D4.1/Matita/Vector.ma @ 340

Last change on this file since 340 was 340, checked in by sacerdot, 9 years ago

::: is now used in place of :: for vectors to reduce ambiguity

File size: 13.7 KB
Line 
1(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
2(* Vector.ma: Fixed length polymorphic vectors, and routine operations on     *)
3(*            them.                                                           *)
4(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
5
6include "Util.ma".
7
8include "Nat.ma".
9include "List.ma".
10include "Cartesian.ma".
11include "Maybe.ma".
12include "Plogic/equality.ma".
13
14(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
15(* The datatype.                                                              *)
16(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
17
18ninductive Vector (A: Type[0]): Nat → Type[0] ≝
19  Empty: Vector A Z
20| Cons: ∀n: Nat. A → Vector A n → Vector A (S n).
21
22(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
23(* Syntax.                                                                    *)
24(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
25
26notation "[[ list0 x sep ; ]]"
27  non associative with precedence 90
28  for ${fold right @'vnil rec acc @{'vcons $x $acc}}.
29
30notation "hvbox(hd break ::: tl)"
31  right associative with precedence 52
32  for @{ 'vcons $hd $tl }.
33
34interpretation "Vector vnil" 'vnil = (Empty ?).
35interpretation "Vector vcons" 'vcons hd tl = (Cons ? ? hd tl).
36
37(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
38(* Lookup.                                                                    *)
39(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
40
41nlet rec get_index (A: Type[0]) (n: Nat)
42                   (v: Vector A n) (m: Nat) (lt: m < n) on m: A ≝
43  (match m with
44    [ Z ⇒
45      match v return λx.λ_. Z < x → A with
46        [ Empty ⇒ λabsd1: Z < Z. ?
47        | Cons p hd tl ⇒ λprf1: Z < S p. hd
48        ]
49    | S o ⇒
50      (match v return λx.λ_. S o < x → A with
51        [ Empty ⇒ λprf: S o < Z. ?
52        | Cons p hd tl ⇒ λprf: S o < S p. get_index A p tl o ?
53        ])
54    ]) lt.
55    ##[ ncases (nothing_less_than_Z Z); #K; ncases (K absd1)
56    ##| ncases (nothing_less_than_Z (S o)); #K; ncases (K prf)
57    ##| napply succ_less_than_injective; nassumption
58    ##]
59nqed.
60
61nlet rec get_index_weak (A: Type[0]) (n: Nat)
62                   (v: Vector A n) (m: Nat) on m ≝
63  match m with
64    [ Z ⇒
65      match v with
66        [ Empty ⇒ Nothing A
67        | Cons p hd tl ⇒ Just A hd
68        ]
69    | S o ⇒
70      match v with
71        [ Empty ⇒ Nothing A
72        | Cons p hd tl ⇒ get_index_weak A p tl o
73        ]
74    ].
75   
76interpretation "Vector get_index" 'get_index v n = (get_index ? ? v n).
77
78nlet rec set_index (A: Type[0]) (n: Nat) (v: Vector A n) (m: Nat) (a: A) (lt: m < n) on m: Vector A n ≝
79  (match m with
80    [ Z ⇒
81      match v return λx.λ_. Z < x → Vector A x with
82        [ Empty ⇒ λabsd1: Z < Z. Empty A
83        | Cons p hd tl ⇒ λprf1: Z < S p. (a ::: tl)
84        ]
85    | S o ⇒
86      (match v return λx.λ_. S o < x → Vector A x with
87        [ Empty ⇒ λprf: S o < Z. Empty A
88        | Cons p hd tl ⇒ λprf: S o < S p. hd ::: (set_index A p tl o a ?)
89        ])
90    ]) lt.
91    napply succ_less_than_injective.
92    nassumption.
93nqed.
94   
95nlet rec set_index_weak (A: Type[0]) (n: Nat)
96                        (v: Vector A n) (m: Nat) (a: A) on m ≝
97  match m with
98    [ Z ⇒
99      match v with
100        [ Empty ⇒ Nothing (Vector A n)
101        | Cons o hd tl ⇒ Just (Vector A n) (? (Cons A o a tl))
102        ]
103    | S o ⇒
104      match v with
105        [ Empty ⇒ Nothing (Vector A n)
106        | Cons p hd tl ⇒
107            let settail ≝ set_index_weak A p tl o a in
108              match settail with
109                [ Nothing ⇒ Nothing (Vector A n)
110                | Just j ⇒ Just (Vector A n) (? (Cons A p hd j))
111                ]
112        ]
113    ].
114    //.
115nqed.
116
117nlet rec drop (A: Type[0]) (n: Nat)
118              (v: Vector A n) (m: Nat) on m ≝
119  match m with
120    [ Z ⇒ Just (Vector A n) v
121    | S o ⇒
122      match v with
123        [ Empty ⇒ Nothing (Vector A n)
124        | Cons p hd tl ⇒ ? (drop A p tl o)
125        ]
126    ].
127    //.
128nqed.
129
130nlet rec split (A: Type[0]) (m,n: Nat) on m
131             : Vector A (m+n) → (Vector A m) × (Vector A n)
132
133 match m return λm. Vector A (m+n) → (Vector A m) × (Vector A n) with
134  [ Z ⇒ λv.〈[[ ]], v〉
135  | S m' ⇒ λv.
136     match v return λl.λ_:Vector A l.l = S (m' + n) → (Vector A (S m')) × (Vector A n) with
137      [ Empty ⇒ λK.⊥
138      | Cons o he tl ⇒ λK.
139         match split A m' n (tl⌈Vector A (m'+n)↦Vector A o⌉) with
140          [ mk_Cartesian v1 v2 ⇒ 〈he:::v1, v2〉 ]] (?: (S (m' + n)) = S (m' + n))].
141//; ndestruct; //.
142nqed.
143
144ndefinition head: ∀A:Type[0]. ∀n. Vector A (S n) → A × (Vector A n)
145≝ λA,n,v.
146 match v return λl.λ_:Vector A l.l = S n → A × (Vector A n) with
147  [ Empty ⇒ λK.⊥
148  | Cons o he tl ⇒ λK. 〈he,(tl⌈Vector A n ↦ Vector A o⌉)〉
149  ] (? : S ? = S ?).
150//; ndestruct; //.
151nqed.
152
153ndefinition from_singl: ∀A:Type[0]. Vector A (S Z) → A ≝
154 λA,v. first … (head … v).
155   
156(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
157(* Folds and builds.                                                          *)
158(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
159   
160nlet rec fold_right (A: Type[0]) (B: Type[0]) (n: Nat)
161                    (f: A → B → B) (x: B) (v: Vector A n) on v ≝
162  match v with
163    [ Empty ⇒ x
164    | Cons n hd tl ⇒ f hd (fold_right A B n f x tl)
165    ].
166
167nlet rec fold_right_i (A: Type[0]) (B: Type[0]) (C: Type[0])
168                      (n: Nat) (f: A → B → C → C) (c: C)
169                      (v: Vector A n) (q: Vector B n) on v ≝
170  (match v return λx.λ_. x = n → C with
171    [ Empty ⇒
172      match q return λx.λ_. Z = x → C with
173        [ Empty ⇒ λprf: Z = Z. c
174        | Cons o hd tl ⇒ λabsd. ?
175        ]
176    | Cons o hd tl ⇒
177      match q return λx.λ_. S o = x → C with
178        [ Empty ⇒ λabsd: S o = Z. ?
179        | Cons p hd' tl' ⇒ λprf: S o = S p.
180            fold_right_i A B C o f (f hd hd' c) tl ?
181        ]
182    ]) (refl ? n).
183    ##[##1,2:
184        ndestruct;
185    ##| ndestruct (prf);
186        napply tl';
187    ##]
188nqed.
189 
190nlet rec fold_left (A: Type[0]) (B: Type[0]) (n: Nat)
191                    (f: A → B → A) (x: A) (v: Vector B n) on v ≝
192  match v with
193    [ Empty ⇒ x
194    | Cons n hd tl ⇒ f (fold_left A B n f x tl) hd
195    ].
196   
197(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
198(* Maps and zips.                                                             *)
199(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
200
201nlet rec map (A: Type[0]) (B: Type[0]) (n: Nat)
202             (f: A → B) (v: Vector A n) on v ≝
203  match v with
204    [ Empty ⇒ Empty B
205    | Cons n hd tl ⇒ (f hd) ::: (map A B n f tl)
206    ].
207
208nlet rec zip_with (A: Type[0]) (B: Type[0]) (C: Type[0]) (n: Nat)
209             (f: A → B → C) (v: Vector A n) (q: Vector B n) on v ≝
210  (match v return (λx.λr. x = n → Vector C x) with
211    [ Empty ⇒ λ_. Empty C
212    | Cons n hd tl ⇒
213      match q return (λy.λr. S n = y → Vector C (S n)) with
214        [ Empty ⇒ ?
215        | Cons m hd' tl' ⇒
216            λe: S n = S m.
217              (f hd hd') ::: (zip_with A B C n f tl ?)
218        ]
219    ])
220    (refl ? n).
221      ##
222        [ #e;
223          ndestruct(e);
224          ##
225        | ndestruct(e);
226          napply tl'
227          ##
228        ]
229nqed.
230
231ndefinition zip ≝
232  λA, B: Type[0].
233  λn: Nat.
234  λv: Vector A n.
235  λq: Vector B n.
236    zip_with A B (Cartesian A B) n (mk_Cartesian A B) v q.
237
238(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
239(* Building vectors from scratch                                              *)
240(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
241
242nlet rec replicate (A: Type[0]) (n: Nat) (h: A) on n ≝
243  match n return λn. Vector A n with
244    [ Z ⇒ Empty A
245    | S m ⇒ h ::: (replicate A m h)
246    ].
247
248nlet rec append (A: Type[0]) (n: Nat) (m: Nat)
249                (v: Vector A n) (q: Vector A m) on v ≝
250  match v return (λn.λv. Vector A (n + m)) with
251    [ Empty ⇒ q
252    | Cons o hd tl ⇒ hd ::: (append A o m tl q)
253    ].
254   
255notation "hvbox(l break @@ r)"
256  right associative with precedence 47
257  for @{ 'vappend $l $r }.
258   
259interpretation "Vector append" 'vappend v1 v2 = (append ??? v1 v2).
260   
261nlet rec scan_left (A: Type[0]) (B: Type[0]) (n: Nat)
262                   (f: A → B → A) (a: A) (v: Vector B n) on v ≝
263  a :::
264    (match v with
265       [ Empty ⇒ Empty A
266       | Cons o hd tl ⇒ scan_left A B o f (f a hd) tl
267       ]).
268
269nlet rec scan_right (A: Type[0]) (B: Type[0]) (n: Nat)
270                    (f: A → B → A) (b: B) (v: Vector A n) on v ≝
271  match v with
272    [ Empty ⇒ ?
273    | Cons o hd tl ⇒ f hd b :: (scan_right A B o f b tl)
274    ].
275    //.
276nqed.
277   
278(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
279(* Other manipulations.                                                       *)
280(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
281   
282nlet rec length (A: Type[0]) (n: Nat) (v: Vector A n) on v ≝
283  match v with
284    [ Empty ⇒ Z
285    | Cons n hd tl ⇒ S $ length A n tl
286    ].
287
288nlet rec reverse (A: Type[0]) (n: Nat)
289                 (v: Vector A n) on v ≝
290  match v return (λm.λv. Vector A m) with
291    [ Empty ⇒ Empty A
292    | Cons o hd tl ⇒ ? (append A o ? (reverse A o tl) (Cons A Z hd (Empty A)))
293    ].
294    nrewrite < (succ_plus ? ?).
295    nrewrite > (plus_zero ?).
296    //.
297nqed.
298
299(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
300(* Conversions to and from lists.                                             *)
301(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
302
303nlet rec list_of_vector (A: Type[0]) (n: Nat)
304                        (v: Vector A n) on v ≝
305  match v return λn.λv. List A with
306    [ Empty ⇒ ? (cic:/matita/ng/List/List.con(0,1,1) A)
307    | Cons o hd tl ⇒ hd :: (list_of_vector A o tl)
308    ].
309    //.
310nqed.
311
312nlet rec vector_of_list (A: Type[0]) (l: List A) on l ≝
313  match l return λl. Vector A (length A l) with
314    [ Empty ⇒ ? (cic:/matita/ng/Vector/Vector.con(0,1,1) A)
315    | Cons hd tl ⇒ ? (hd ::: (vector_of_list A tl))
316    ].
317    nnormalize.
318    //.
319    //.
320nqed.
321
322(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)   
323(* Rotates and shifts.                                                        *)
324(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
325   
326nlet rec rotate_left (A: Type[0]) (n: Nat)
327                     (m: Nat) (v: Vector A n) on m: Vector A n ≝
328  match m with
329    [ Z ⇒ v
330    | S o ⇒
331        match v with
332          [ Empty ⇒ Empty A
333          | Cons p hd tl ⇒
334             rotate_left A (S p) o (? (append A p ? tl (Cons A ? hd (Empty A))))
335          ]
336    ].
337    nrewrite < (succ_plus ? ?).
338    nrewrite > (plus_zero ?).
339    //.
340nqed.
341
342ndefinition rotate_right ≝
343  λA: Type[0].
344  λn, m: Nat.
345  λv: Vector A n.
346    reverse A n (rotate_left A n m (reverse A n v)).
347   
348ndefinition shift_left_1 ≝
349  λA: Type[0].
350  λn: Nat.
351  λv: Vector A n.
352  λa: A.
353    match v with
354      [ Empty ⇒ ?
355      | Cons o hd tl ⇒ reverse A n (? (Cons A o a (reverse A o tl)))
356      ].
357      //.
358nqed.
359
360ndefinition shift_right_1 ≝
361  λA: Type[0].
362  λn: Nat.
363  λv: Vector A n.
364  λa: A.
365    reverse A n (shift_left_1 A n (reverse A n v) a).
366   
367ndefinition shift_left ≝
368  λA: Type[0].
369  λn, m: Nat.
370  λv: Vector A n.
371  λa: A.
372    iterate (Vector A n) (λx. shift_left_1 A n x a) v m.
373   
374ndefinition shift_right ≝
375  λA: Type[0].
376  λn, m: Nat.
377  λv: Vector A n.
378  λa: A.
379    iterate (Vector A n) (λx. shift_right_1 A n x a) v m.
380
381(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
382(* Decidable equality.                                                        *)
383(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
384
385nlet rec eq_v (A: Type[0]) (n: Nat) (f: A → A → Bool) (b: Vector A n) (c: Vector A n) on b ≝
386  (match b return λx.λ_. n = x → Bool with
387    [ Empty ⇒
388      match c return λx.λ_. x = Z → Bool with
389        [ Empty ⇒ λ_. true
390        | Cons p hd tl ⇒ λabsd.?
391        ]
392    | Cons o hd tl ⇒
393        match c return λx.λ_. x = S o → Bool with
394          [ Empty ⇒ λabsd. ?
395          | Cons p hd' tl' ⇒
396            λprf.
397              if (f hd hd') then
398                (eq_v A o f tl ?)
399              else
400                false
401          ]
402    ]) (refl ? n).
403    ##[##1, 3:
404        ndestruct (absd);
405        ndestruct (prf);
406        napply tl';
407    ##|##2:
408        ndestruct (absd);
409    ##]
410nqed.
411   
412(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)
413(* Lemmas.                                                                    *)
414(* -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= *)   
415   
416nlemma map_fusion:
417  ∀A, B, C: Type[0].
418  ∀n: Nat.
419  ∀v: Vector A n.
420  ∀f: A → B.
421  ∀g: B → C.
422    map B C n g (map A B n f v) = map A C n (λx. g (f x)) v.
423  #A B C n v f g.
424  nelim v.
425  nnormalize.
426  @.
427  #N H V H2.
428  nnormalize.
429  nrewrite > H2.
430  @.
431nqed.
432
433nlemma length_correct:
434  ∀A: Type[0].
435  ∀n: Nat.
436  ∀v: Vector A n.
437    length A n v = n.
438  #A n v.
439  nelim v.
440  nnormalize.
441  @.
442  #N H V H2.
443  nnormalize.
444  nrewrite > H2.
445  @.
446nqed.
447
448nlemma map_length:
449  ∀A, B: Type[0].
450  ∀n: Nat.
451  ∀v: Vector A n.
452  ∀f: A → B.
453    length A n v = length B n (map A B n f v).
454  #A B n v f.
455  nelim v.
456  nnormalize.
457  @.
458  #N H V H2.
459  nnormalize.
460  nrewrite > H2.
461  @.
462nqed.
Note: See TracBrowser for help on using the repository browser.