source: Deliverables/D3.1/C-semantics/Cexec.ma @ 485

Last change on this file since 485 was 485, checked in by campbell, 9 years ago

Fix treatment of pointers in initialisation data, a little like later versions
of CompCert?. Remove obsolete Init_pointer.

File size: 32.6 KB
Line 
1
2include "Csem.ma".
3
4include "extralib.ma".
5include "IOMonad.ma".
6
7include "Plogic/russell_support.ma".
8
9ndefinition P_to_P_option_res : ∀A:Type[0].∀P:A → CProp[0].option (res A) → CProp[0] ≝
10  λA,P,a.match a with [ None ⇒ False | Some y ⇒ match y return λ_.CProp[0] with [ Error ⇒ True | OK z ⇒ P z ]].
11
12ndefinition err_inject : ∀A.∀P:A → Prop.∀a:option (res A).∀p:P_to_P_option_res A P a.res (sigma A P) ≝
13  λA.λP:A → Prop.λa:option (res A).λp:P_to_P_option_res A P a.
14  (match a return λa'.a=a' → res (sigma A P) with
15   [ None ⇒ λe1.?
16   | Some b ⇒ λe1.(match b return λb'.b=b' → ? with
17     [ Error ⇒ λ_. Error ?
18     | OK c ⇒ λe2. OK ? (sig_intro A P c ?)
19     ]) (refl ? b)
20   ]) (refl ? a).
21##[ nrewrite > e1 in p; nnormalize; *;
22##| nrewrite > e1 in p; nrewrite > e2; nnormalize; //
23##] nqed.
24
25ndefinition err_eject : ∀A.∀P: A → Prop. res (sigma A P) → res A ≝
26  λA,P,a.match a with [ Error ⇒ Error ? | OK b ⇒
27    match b with [ sig_intro w p ⇒ OK ? w] ].
28
29ndefinition sig_eject : ∀A.∀P: A → Prop. sigma A P → A ≝
30  λA,P,a.match a with [ sig_intro w p ⇒ w].
31
32ncoercion err_inject :
33  ∀A.∀P:A → Prop.∀a.∀p:P_to_P_option_res ? P a.res (sigma A P) ≝ err_inject
34  on a:option (res ?) to res (sigma ? ?).
35ncoercion err_eject : ∀A.∀P:A → Prop.∀c:res (sigma A P).res A ≝ err_eject
36  on _c:res (sigma ? ?) to res ?.
37ncoercion sig_eject : ∀A.∀P:A → Prop.∀c:sigma A P.A ≝ sig_eject
38  on _c:sigma ? ? to ?.
39
40ndefinition P_res: ∀A.∀P:A → Prop.res A → Prop ≝
41  λA,P,a. match a with [ Error ⇒ True | OK v ⇒ P v ].
42
43ndefinition exec_bool_of_val : ∀v:val. ∀ty:type. res bool ≝
44  λv,ty. match v in val with
45  [ Vint i ⇒ match ty with
46    [ Tint _ _ ⇒ OK ? (¬eq i zero)
47    | _ ⇒ Error ?
48    ]
49  | Vfloat f ⇒ match ty with
50    [ Tfloat _ ⇒ OK ? (¬Fcmp Ceq f Fzero)
51    | _ ⇒ Error ?
52    ]
53  | Vptr _ _ _ ⇒ match ty with
54    [ Tpointer _ _ ⇒ OK ? true
55    | _ ⇒ Error ?
56    ]
57  | Vnull _ ⇒ match ty with
58    [ Tpointer _ _ ⇒ OK ? false
59    | _ ⇒ Error ?
60    ]
61  | _ ⇒ Error ?
62  ].
63
64nlemma bool_of_val_complete : ∀v,ty,r. bool_of_val v ty r → ∃b. r = of_bool b ∧ exec_bool_of_val v ty = OK ? b.
65#v ty r H; nelim H; #v t H'; nelim H';
66  ##[ #i is s ne; @ true; @; //; nwhd in ⊢ (??%?); nrewrite > (eq_false … ne); //;
67  ##| #p b i i0 s; @ true; @; //
68  ##| #f s ne; @ true; @; //; nwhd in ⊢ (??%?); nrewrite > (Feq_zero_false … ne); //;
69  ##| #i s; @ false; @; //;
70  ##| #r r' t; @ false; @; //;
71  ##| #s; @ false; @; //; nwhd in ⊢ (??%?); nrewrite > (Feq_zero_true …); //;
72  ##]
73nqed.
74
75(* Prove a few minor results to make proof obligations easy. *)
76
77nlemma bind_OK: ∀A,B,P,e,f.
78  (∀v. e = OK A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
79  match bind A B e f with [ Error ⇒ True | OK v ⇒ P v ].
80#A B P e f; nelim e; /2/; nqed.
81
82nlemma sig_bind_OK: ∀A,B. ∀P:A → Prop. ∀P':B → Prop. ∀e:res (sigma A P). ∀f:sigma A P → res B.
83  (∀v:A. ∀p:P v. match f (sig_intro A P v p) with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
84  match bind (sigma A P) B e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
85#A B P P' e f; nelim e;
86##[ #v0; nelim v0; #v Hv IH; napply IH;
87##| #_; napply I;
88##] nqed.
89
90nlemma bind2_OK: ∀A,B,C,P,e,f.
91  (∀v1,v2. e = OK ? 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P v' ]) →
92  match bind2 A B C e f with [ Error ⇒ True | OK v ⇒ P v ].
93#A B C P e f; nelim e; //; #v; ncases v; /2/; nqed.
94
95nlemma sig_bind2_OK: ∀A,B,C. ∀P:A×B → Prop. ∀P':C → Prop. ∀e:res (sigma (A×B) P). ∀f:A → B → res C.
96  (∀v1:A.∀v2:B. P 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
97  match bind2 A B C e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
98#A B C P P' e f; nelim e; //;
99#v0; nelim v0; #v; nelim v; #v1 v2 Hv IH; napply IH; //; nqed.
100
101nlemma opt_bind_OK: ∀A,B,P,e,f.
102  (∀v. e = Some A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
103  match bind A B (opt_to_res A e) f with [ Error ⇒ True | OK v ⇒ P v ].
104#A B P e f; nelim e; nnormalize; /2/; nqed.
105
106nlemma extract_subset_pair: ∀A,B,C,P. ∀e:{e:A×B | P e}. ∀Q:A→B→res C. ∀R:C→Prop.
107  (∀a,b. eject ?? e = 〈a,b〉 → P 〈a,b〉 → match Q a b with [ OK v ⇒ R v | Error ⇒ True]) →
108  match match eject ?? e with [ mk_pair a b ⇒ Q a b ] with [ OK v ⇒ R v | Error ⇒ True ].
109#A B C P e Q R; ncases e; #e'; ncases e'; nnormalize;
110##[ #H; napply (False_ind … H);
111##| #e''; ncases e''; #a b Pab H; nnormalize; /2/;
112##] nqed.
113
114(*
115nremark err_later: ∀A,B. ∀e:res A. match e with [ Error ⇒ Error B | OK v ⇒ Error B ] = Error B.
116#A B e; ncases e; //; nqed.
117*)
118
119ndefinition try_cast_null : ∀m:mem. ∀i:int. ∀ty:type. ∀ty':type. res val  ≝
120λm:mem. λi:int. λty:type. λty':type.
121match eq i zero with
122[ true ⇒
123  match ty with
124  [ Tint _ _ ⇒
125    match ty' with
126    [ Tpointer r _ ⇒ OK ? (Vnull r)
127    | Tarray r _ _ ⇒ OK ? (Vnull r)
128    | Tfunction _ _ ⇒ OK ? (Vnull Code)
129    | _ ⇒ Error ?
130    ]
131  | _ ⇒ Error ?
132  ]
133| false ⇒ Error ?
134].
135
136ndefinition exec_cast : ∀m:mem. ∀v:val. ∀ty:type. ∀ty':type. res val ≝
137λm:mem. λv:val. λty:type. λty':type.
138match v with
139[ Vint i ⇒
140  match ty with
141  [ Tint sz1 si1 ⇒
142    match ty' with
143    [ Tint sz2 si2 ⇒ OK ? (Vint (cast_int_int sz2 si2 i))
144    | Tfloat sz2 ⇒ OK ? (Vfloat (cast_float_float sz2 (cast_int_float si1 i)))
145    | Tpointer _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
146    | Tarray _ _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
147    | Tfunction _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
148    | _ ⇒ Error ?
149    ]
150  | Tpointer _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
151  | Tarray _ _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
152  | Tfunction _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
153  | _ ⇒ Error ?
154  ]
155| Vfloat f ⇒
156  match ty with
157  [ Tfloat sz ⇒
158    match ty' with
159    [ Tint sz' si' ⇒ OK ? (Vint (cast_int_int sz' si' (cast_float_int si' f)))
160    | Tfloat sz' ⇒ OK ? (Vfloat (cast_float_float sz' f))
161    | _ ⇒ Error ?
162    ]
163  | _ ⇒ Error ?
164  ]
165| Vptr p b ofs ⇒
166    do s ← match ty with [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code | _ ⇒ Error ? ];
167    do u ← match eq_region_dec p s with [ inl _ ⇒ OK ? something | inr _ ⇒ Error ? ];
168    do s' ← match ty' with
169         [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code
170         | _ ⇒ Error ? ];
171    if is_pointer_compat (block_space m b) s'
172    then OK ? (Vptr s' b ofs)
173    else Error ?
174| Vnull r ⇒
175    do s ← match ty with [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code | _ ⇒ Error ? ];
176    do u ← match eq_region_dec r s with [ inl _ ⇒ OK ? something | inr _ ⇒ Error ? ];
177    do s' ← match ty' with
178         [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code
179         | _ ⇒ Error ? ];
180    OK ? (Vnull s')
181| _ ⇒ Error ?
182].
183
184ndefinition load_value_of_type' ≝
185λty,m,l. match l with [ mk_pair pl ofs ⇒ match pl with [ mk_pair psp loc ⇒
186  load_value_of_type ty m psp loc ofs ] ].
187
188(* To make the evaluation of bare lvalue expressions invoke exec_lvalue with
189   a structurally smaller value, we break out the surrounding Expr constructor
190   and use exec_lvalue'. *)
191
192nlet rec exec_expr (ge:genv) (en:env) (m:mem) (e:expr) on e : res (val×trace) ≝
193match e with
194[ Expr e' ty ⇒
195  match e' with
196  [ Econst_int i ⇒ OK ? 〈Vint i, E0〉
197  | Econst_float f ⇒ OK ? 〈Vfloat f, E0〉
198  | Evar _ ⇒
199      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
200      do v ← opt_to_res ? (load_value_of_type' ty m l);
201      OK ? 〈v,tr〉
202  | Ederef _ ⇒
203      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
204      do v ← opt_to_res ? (load_value_of_type' ty m l);
205      OK ? 〈v,tr〉
206  | Efield _ _ ⇒
207      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
208      do v ← opt_to_res ? (load_value_of_type' ty m l);
209      OK ? 〈v,tr〉
210  | Eaddrof a ⇒
211      do 〈plo,tr〉 ← exec_lvalue ge en m a;
212      OK ? 〈match plo with [ mk_pair pl ofs ⇒ match pl with [ mk_pair pcl loc ⇒ Vptr pcl loc ofs ] ], tr〉
213  | Esizeof ty' ⇒ OK ? 〈Vint (repr (sizeof ty')), E0〉
214  | Eunop op a ⇒
215      do 〈v1,tr〉 ← exec_expr ge en m a;
216      do v ← opt_to_res ? (sem_unary_operation op v1 (typeof a));
217      OK ? 〈v,tr〉
218  | Ebinop op a1 a2 ⇒
219      do 〈v1,tr1〉 ← exec_expr ge en m a1;
220      do 〈v2,tr2〉 ← exec_expr ge en m a2;
221      do v ← opt_to_res ? (sem_binary_operation op v1 (typeof a1) v2 (typeof a2) m);
222      OK ? 〈v,tr1⧺tr2〉
223  | Econdition a1 a2 a3 ⇒
224      do 〈v,tr1〉 ← exec_expr ge en m a1;
225      do b ← exec_bool_of_val v (typeof a1);
226      do 〈v',tr2〉 ← match b return λ_.res (val×trace) with
227                 [ true ⇒ (exec_expr ge en m a2)
228                 | false ⇒ (exec_expr ge en m a3) ];
229      OK ? 〈v',tr1⧺tr2〉
230(*      if b then exec_expr ge en m a2 else exec_expr ge en m a3)*)
231  | Eorbool a1 a2 ⇒
232      do 〈v1,tr1〉 ← exec_expr ge en m a1;
233      do b1 ← exec_bool_of_val v1 (typeof a1);
234      match b1 return λ_.res (val×trace) with [ true ⇒ OK ? 〈Vtrue,tr1〉 | false ⇒
235        do 〈v2,tr2〉 ← exec_expr ge en m a2;
236        do b2 ← exec_bool_of_val v2 (typeof a2);
237        OK ? 〈of_bool b2, tr1⧺tr2〉 ]
238  | Eandbool a1 a2 ⇒
239      do 〈v1,tr1〉 ← exec_expr ge en m a1;
240      do b1 ← exec_bool_of_val v1 (typeof a1);
241      match b1 return λ_.res (val×trace) with [ true ⇒
242        do 〈v2,tr2〉 ← exec_expr ge en m a2;
243        do b2 ← exec_bool_of_val v2 (typeof a2);
244        OK ? 〈of_bool b2, tr1⧺tr2〉
245      | false ⇒ OK ? 〈Vfalse,tr1〉 ]
246  | Ecast ty' a ⇒
247      do 〈v,tr〉 ← exec_expr ge en m a;
248      do v' ← exec_cast m v (typeof a) ty';
249      OK ? 〈v',tr〉
250  | Ecost l a ⇒
251      do 〈v,tr〉 ← exec_expr ge en m a;
252      OK ? 〈v,tr⧺(Echarge l)〉
253  ]
254]
255and exec_lvalue' (ge:genv) (en:env) (m:mem) (e':expr_descr) (ty:type) on e' : res (region × block × int × trace) ≝
256  match e' with
257  [ Evar id ⇒
258      match (get … id en) with
259      [ None ⇒ do 〈sp,l〉 ← opt_to_res ? (find_symbol ? ? ge id); OK ? 〈〈〈sp,l〉,zero〉,E0〉 (* global *)
260      | Some loc ⇒ OK ? 〈〈〈Any,loc〉,zero〉,E0〉 (* local *)
261      ]
262  | Ederef a ⇒
263      do 〈v,tr〉 ← exec_expr ge en m a;
264      match v with
265      [ Vptr sp l ofs ⇒ OK ? 〈〈〈sp,l〉,ofs〉,tr〉
266      | _ ⇒ Error ?
267      ]
268  | Efield a i ⇒
269      match (typeof a) with
270      [ Tstruct id fList ⇒
271          do 〈plofs,tr〉 ← exec_lvalue ge en m a;
272          do delta ← field_offset i fList;
273          OK ? 〈〈\fst plofs,add (\snd plofs) (repr delta)〉,tr〉
274      | Tunion id fList ⇒
275          do 〈plofs,tr〉 ← exec_lvalue ge en m a;
276          OK ? 〈plofs,tr〉
277      | _ ⇒ Error ?
278      ]
279  | _ ⇒ Error ?
280  ]
281and exec_lvalue (ge:genv) (en:env) (m:mem) (e:expr) on e : res (region × block × int × trace) ≝
282match e with [ Expr e' ty ⇒ exec_lvalue' ge en m e' ty ].
283
284nlemma P_res_to_P: ∀A,P,e,v.  P_res A P e → e = OK A v → P v.
285#A P e v H1 H2; nrewrite > H2 in H1; nwhd in ⊢ (% → ?); //; nqed.
286
287(* We define a special induction principle tailored to the recursive definition
288   above. *)
289
290ndefinition is_not_lvalue: expr_descr → Prop ≝
291λe. match e with [ Evar _ ⇒ False | Ederef _ ⇒ False | Efield _ _ ⇒ False | _ ⇒ True ].
292
293ndefinition Plvalue ≝ λP:(expr → Prop).λe,ty.
294match e return λ_.Prop with [ Evar _ ⇒ P (Expr e ty) | Ederef _ ⇒ P (Expr e ty) | Efield _ _ ⇒ P (Expr e ty) | _ ⇒ True ].
295
296(* TODO: Can we do this sensibly with a map combinator? *)
297nlet rec exec_exprlist (ge:genv) (e:env) (m:mem) (l:list expr) on l : res (list val×trace) ≝
298match l with
299[ nil ⇒ OK ? 〈nil val, E0〉
300| cons e1 es ⇒
301  do 〈v,tr1〉 ← exec_expr ge e m e1;
302  do 〈vs,tr2〉 ← exec_exprlist ge e m es;
303  OK ? 〈cons val v vs, tr1⧺tr2〉
304].
305
306(* Don't really want to use subset rather than sigma here, but can't be bothered
307   with *another* set of coercions. XXX: why do I have to get the recursive
308   call's property manually? *)
309
310nlet rec exec_alloc_variables (en:env) (m:mem) (l:list (ident × type)) on l : { r:env × mem | alloc_variables en m l (\fst r) (\snd r) } ≝
311match l with
312[ nil ⇒ Some ? 〈en, m〉
313| cons h vars ⇒
314  match h with [ mk_pair id ty ⇒
315    match alloc m 0 (sizeof ty) Any with [ mk_pair m1 b1 ⇒
316      match exec_alloc_variables (set … id b1 en) m1 vars with
317      [ sig_intro r p ⇒ r ]
318]]]. nwhd;
319##[ //;
320##| nelim (exec_alloc_variables (set ident ? ? c3 c7 en) c6 c1);
321    #H; nelim H; //; #H0; nelim H0; nnormalize; #en' m' IH;
322napply (alloc_variables_cons … IH); /2/;
323nqed.
324
325(* TODO: can we establish that length params = length vs in advance? *)
326nlet rec exec_bind_parameters (e:env) (m:mem) (params:list (ident × type)) (vs:list val) on params : res (Σm2:mem. bind_parameters e m params vs m2) ≝
327  match params with
328  [ nil ⇒ match vs with [ nil ⇒ Some ? (OK ? m) | cons _ _ ⇒ Some ? (Error ?) ]
329  | cons idty params' ⇒ match idty with [ mk_pair id ty ⇒
330      match vs with
331      [ nil ⇒ Some ? (Error ?)
332      | cons v1 vl ⇒ Some ? (
333          do b ← opt_to_res ? (get … id e);
334          do m1 ← opt_to_res ? (store_value_of_type ty m Any b zero v1);
335          err_eject ?? (exec_bind_parameters e m1 params' vl)) (* FIXME: don't want to have to eject here *)
336      ]
337  ] ].
338nwhd; //;
339napply opt_bind_OK; #b eb;
340napply opt_bind_OK; #m1 em1;
341napply sig_bind_OK; #m2 Hm2;
342napply (bind_parameters_cons … eb em1 Hm2);
343nqed.
344
345alias id "Tint" = "cic:/matita/c-semantics/Csyntax/type.con(0,2,0)".
346alias id "Tfloat" = "cic:/matita/c-semantics/Csyntax/type.con(0,3,0)".
347ndefinition sz_eq_dec : ∀s1,s2:intsize. (s1 = s2) + (s1 ≠ s2).
348#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
349ndefinition sg_eq_dec : ∀s1,s2:signedness. (s1 = s2) + (s1 ≠ s2).
350#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
351ndefinition fs_eq_dec : ∀s1,s2:floatsize. (s1 = s2) + (s1 ≠ s2).
352#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
353
354nlet rec type_eq_dec (t1,t2:type) : (t1 = t2) + (t1 ≠ t2) ≝
355match t1 return λt'. (t' = t2) + (t' ≠ t2) with
356[ Tvoid ⇒ match t2 return λt'. (Tvoid = t') + (Tvoid ≠ t') with [ Tvoid ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
357| Tint sz sg ⇒ match t2 return λt'. (Tint ?? = t') + (Tint ?? ≠ t')  with [ Tint sz' sg' ⇒
358    match sz_eq_dec sz sz' with [ inl e1 ⇒
359    match sg_eq_dec sg sg' with [ inl e2 ⇒ inl ???
360    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
361    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
362    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
363| Tfloat f ⇒ match t2 return λt'. (Tfloat ? = t') + (Tfloat ? ≠ t')  with [ Tfloat f' ⇒
364    match fs_eq_dec f f' with [ inl e1 ⇒ inl ???
365    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
366    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
367| Tpointer s t ⇒ match t2 return λt'. (Tpointer ?? = t') + (Tpointer ?? ≠ t')  with [ Tpointer s' t' ⇒
368    match eq_region_dec s s' with [ inl e1 ⇒
369      match type_eq_dec t t' with [ inl e2 ⇒ inl ???
370      | inr e2 ⇒ inr ?? (nmk ? (λH.match e2 with [ nmk e' ⇒ e' ? ])) ]
371    | inr e1 ⇒ inr ?? (nmk ? (λH.match e1 with [ nmk e' ⇒ e' ? ])) ] | _ ⇒ inr ?? (nmk ? (λH.?)) ]
372| Tarray s t n ⇒ match t2 return λt'. (Tarray ??? = t') + (Tarray ??? ≠ t')  with [ Tarray s' t' n' ⇒
373    match eq_region_dec s s' with [ inl e1 ⇒
374      match type_eq_dec t t' with [ inl e2 ⇒
375        match decidable_eq_Z_Type n n' with [ inl e3 ⇒ inl ???
376        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
377        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
378        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
379        | _ ⇒ inr ?? (nmk ? (λH.?)) ]
380| Tfunction tl t ⇒ match t2 return λt'. (Tfunction ?? = t') + (Tfunction ?? ≠ t')  with [ Tfunction tl' t' ⇒
381    match typelist_eq_dec tl tl' with [ inl e1 ⇒
382    match type_eq_dec t t' with [ inl e2 ⇒ inl ???
383    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
384    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
385  | _ ⇒ inr ?? (nmk ? (λH.?)) ]
386| Tstruct i fl ⇒
387    match t2 return λt'. (Tstruct ?? = t') + (Tstruct ?? ≠ t')  with [ Tstruct i' fl' ⇒
388    match ident_eq i i' with [ inl e1 ⇒
389    match fieldlist_eq_dec fl fl' with [ inl e2 ⇒ inl ???
390    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
391    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
392    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
393| Tunion i fl ⇒
394    match t2 return λt'. (Tunion ?? = t') + (Tunion ?? ≠ t')  with [ Tunion i' fl' ⇒
395    match ident_eq i i' with [ inl e1 ⇒
396    match fieldlist_eq_dec fl fl' with [ inl e2 ⇒ inl ???
397    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
398    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
399    |  _ ⇒ inr ?? (nmk ? (λH.?)) ]
400| Tcomp_ptr r i ⇒ match t2 return λt'. (Tcomp_ptr ? ? = t') + (Tcomp_ptr ? ? ≠ t')  with [ Tcomp_ptr r' i' ⇒
401    match eq_region_dec r r' with [ inl e1 ⇒
402      match ident_eq i i' with [ inl e2 ⇒ inl ???
403      | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
404    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
405    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
406]
407and typelist_eq_dec (tl1,tl2:typelist) : (tl1 = tl2) + (tl1 ≠ tl2) ≝
408match tl1 return λtl'. (tl' = tl2) + (tl' ≠ tl2) with
409[ Tnil ⇒ match tl2 return λtl'. (Tnil = tl') + (Tnil ≠ tl') with [ Tnil ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
410| Tcons t1 ts1 ⇒ match tl2 return λtl'. (Tcons ?? = tl') + (Tcons ?? ≠ tl') with [ Tnil ⇒ inr ?? (nmk ? (λH.?)) | Tcons t2 ts2 ⇒
411    match type_eq_dec t1 t2 with [ inl e1 ⇒
412    match typelist_eq_dec ts1 ts2 with [ inl e2 ⇒ inl ???
413    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
414    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ] ]
415]
416and fieldlist_eq_dec (fl1,fl2:fieldlist) : (fl1 = fl2) + (fl1 ≠ fl2) ≝
417match fl1 return λfl'. (fl' = fl2) + (fl' ≠ fl2) with
418[ Fnil ⇒ match fl2 return λfl'. (Fnil = fl') + (Fnil ≠ fl') with [ Fnil ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
419| Fcons i1 t1 fs1 ⇒ match fl2 return λfl'. (Fcons ??? = fl') + (Fcons ??? ≠ fl') with [ Fnil ⇒ inr ?? (nmk ? (λH.?)) | Fcons i2 t2 fs2 ⇒
420    match ident_eq i1 i2 with [ inl e1 ⇒
421      match type_eq_dec t1 t2 with [ inl e2 ⇒
422        match fieldlist_eq_dec fs1 fs2 with [ inl e3 ⇒ inl ???
423        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
424        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
425        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ] ]
426]. ndestruct; //; nqed.
427
428ndefinition assert_type_eq : ∀t1,t2:type. res (t1 = t2) ≝
429λt1,t2. match type_eq_dec t1 t2 with [ inl p ⇒ OK ? p | inr _ ⇒ Error ? ].
430
431nlet rec is_is_call_cont (k:cont) : (is_call_cont k) + (¬is_call_cont k) ≝
432match k return λk'.(is_call_cont k') + (¬is_call_cont k') with
433[ Kstop ⇒ ?
434| Kcall _ _ _ _ ⇒ ?
435| _ ⇒ ?
436].
437##[ ##1,8: @1; //
438##| ##*: @2; /2/
439##] nqed.
440
441ndefinition is_Sskip : ∀s:statement. (s = Sskip) + (s ≠ Sskip) ≝
442λs.match s return λs'.(s' = Sskip) + (s' ≠ Sskip) with
443[ Sskip ⇒ inl ?? (refl ??)
444| _ ⇒ inr ?? (nmk ? (λH.?))
445]. ndestruct;
446nqed.
447
448(* Checking types of values given to / received from an external function call. *)
449
450ndefinition eventval_type : ∀ty:typ. Type ≝
451λty. match ty with [ ASTint ⇒ int | ASTfloat ⇒ float ].
452
453ndefinition mk_eventval: ∀ty:typ. eventval_type ty → eventval ≝
454λty:typ. match ty return λty'.eventval_type ty' → eventval with [ ASTint ⇒ λv.EVint v | ASTfloat ⇒ λv.EVfloat v ].
455
456ndefinition mk_val: ∀ty:typ. eventval_type ty → val ≝
457λty:typ. match ty return λty'.eventval_type ty' → val with [ ASTint ⇒ λv.Vint v | ASTfloat ⇒ λv.Vfloat v ].
458
459nlemma mk_val_correct: ∀ty:typ. ∀v:eventval_type ty.
460  eventval_match (mk_eventval ty v) ty (mk_val ty v).
461#ty; ncases ty; nnormalize; //; nqed.
462
463ndefinition convert_eventval : ∀ev:eventval. ∀ty:typ. res (Σv:val. eventval_match ev ty v) ≝
464λev,ty.
465match ty with
466[ ASTint ⇒ match ev with [ EVint i ⇒ Some ? (OK ? (Vint i)) | _ ⇒ Some ? (Error ?) ]
467| ASTfloat ⇒ match ev with [ EVfloat f ⇒ Some ? (OK ? (Vfloat f)) | _ ⇒ Some ? (Error ?) ]
468| _ ⇒ Some ? (Error ?)
469]. nwhd; //; nqed.
470
471ndefinition check_eventval' : ∀v:val. ∀ty:typ. res (Σev:eventval. eventval_match ev ty v) ≝
472λv,ty.
473match ty with
474[ ASTint ⇒ match v with [ Vint i ⇒ Some ? (OK ? (EVint i)) | _ ⇒ Some ? (Error ?) ]
475| ASTfloat ⇒ match v with [ Vfloat f ⇒ Some ? (OK ? (EVfloat f)) | _ ⇒ Some ? (Error ?) ]
476| _ ⇒ Some ? (Error ?)
477]. nwhd; //; nqed.
478
479nlet rec check_eventval_list (vs: list val) (tys: list typ) : res (Σevs:list eventval. eventval_list_match evs tys vs) ≝
480match vs with
481[ nil ⇒ match tys with [ nil ⇒ Some ? (OK ? (nil ?)) | _ ⇒ Some ? (Error ?) ]
482| cons v vt ⇒
483  match tys with
484  [ nil ⇒ Some ? (Error ?)
485  | cons ty tyt ⇒ Some ? (
486    do ev ← check_eventval' v ty;
487    do evt ← check_eventval_list vt tyt;
488    OK ? ((sig_eject ?? ev)::evt))
489  ]
490]. nwhd; //;
491napply sig_bind_OK; #ev Hev;
492napply sig_bind_OK; #evt Hevt;
493nnormalize; /2/;
494nqed.
495
496(* IO monad *)
497
498(* Interactions are function calls that return a value and do not change
499   the rest of the Clight program's state. *)
500nrecord io_out : Type ≝
501{ io_function: ident
502; io_args: list eventval
503; io_in_typ: typ
504}.
505
506ndefinition io_in ≝ λo. eventval_type (io_in_typ o).
507
508ndefinition do_io : ident → list eventval → ∀t:typ. IO io_out io_in (eventval_type t) ≝
509λfn,args,t. Interact ??? (mk_io_out fn args t) (λres. Value ??? res).
510
511ndefinition ret: ∀T. T → (IO io_out io_in T) ≝
512λT,x.(Value ?? T x).
513
514(* execution *)
515
516ndefinition store_value_of_type' ≝
517λty,m,l,v.
518match l with [ mk_pair pl ofs ⇒
519  match pl with [ mk_pair pcl loc ⇒
520    store_value_of_type ty m pcl loc ofs v ] ].
521
522nlet rec exec_step (ge:genv) (st:state) on st : (IO io_out io_in (trace × state)) ≝
523match st with
524[ State f s k e m ⇒
525  match s with
526  [ Sassign a1 a2 ⇒
527    ! 〈l,tr1〉 ← exec_lvalue ge e m a1;
528    ! 〈v2,tr2〉 ← exec_expr ge e m a2;
529    ! m' ← store_value_of_type' (typeof a1) m l v2;
530    ret ? 〈tr1⧺tr2, State f Sskip k e m'〉
531  | Scall lhs a al ⇒
532    ! 〈vf,tr2〉 ← exec_expr ge e m a;
533    ! 〈vargs,tr3〉 ← exec_exprlist ge e m al;
534    ! fd ← find_funct ? ? ge vf;
535    ! p ← err_to_io … (assert_type_eq (type_of_fundef fd) (fun_typeof a));
536(* requires associativity of IOMonad, so rearrange it below
537    ! k' ← match lhs with
538         [ None ⇒ ret ? (Kcall (None ?) f e k)
539         | Some lhs' ⇒
540           ! locofs ← exec_lvalue ge e m lhs';
541           ret ? (Kcall (Some ? 〈sig_eject ?? locofs, typeof lhs'〉) f e k)
542         ];
543    ret ? 〈E0, Callstate fd vargs k' m〉)
544*)
545    match lhs with
546         [ None ⇒ ret ? 〈tr2⧺tr3, Callstate fd vargs (Kcall (None ?) f e k) m〉
547         | Some lhs' ⇒
548           ! 〈locofs,tr1〉 ← exec_lvalue ge e m lhs';
549           ret ? 〈tr1⧺tr2⧺tr3, Callstate fd vargs (Kcall (Some ? 〈locofs, typeof lhs'〉) f e k) m〉
550         ]
551  | Ssequence s1 s2 ⇒ ret ? 〈E0, State f s1 (Kseq s2 k) e m〉
552  | Sskip ⇒
553      match k with
554      [ Kseq s k' ⇒ ret ? 〈E0, State  f s k' e m〉
555      | Kstop ⇒
556          match fn_return f with
557          [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉
558          | _ ⇒ Wrong ???
559          ]
560      | Kcall _ _ _ _ ⇒
561          match fn_return f with
562          [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉
563          | _ ⇒ Wrong ???
564          ]
565      | Kwhile a s' k' ⇒ ret ? 〈E0, State f (Swhile a s') k' e m〉
566      | Kdowhile a s' k' ⇒
567          ! 〈v,tr〉 ← exec_expr ge e m a;
568          ! b ← err_to_io … (exec_bool_of_val v (typeof a));
569          match b with
570          [ true ⇒ ret ? 〈tr, State f (Sdowhile a s') k' e m〉
571          | false ⇒ ret ? 〈tr, State f Sskip k' e m〉
572          ]
573      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉
574      | Kfor3 a2 a3 s' k' ⇒ ret ? 〈E0, State f (Sfor Sskip a2 a3 s') k' e m〉
575      | Kswitch k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
576      | _ ⇒ Wrong ???
577      ]
578  | Scontinue ⇒
579      match k with
580      [ Kseq s' k' ⇒ ret ? 〈E0, State f Scontinue k' e m〉
581      | Kwhile a s' k' ⇒ ret ? 〈E0, State f (Swhile a s') k' e m〉
582      | Kdowhile a s' k' ⇒
583          ! 〈v,tr〉 ← exec_expr ge e m a;
584          ! b ← err_to_io … (exec_bool_of_val v (typeof a));
585          match b with
586          [ true ⇒ ret ? 〈tr, State f (Sdowhile a s') k' e m〉
587          | false ⇒ ret ? 〈tr, State f Sskip k' e m〉
588          ]
589      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉
590      | Kswitch k' ⇒ ret ? 〈E0, State f Scontinue k' e m〉
591      | _ ⇒ Wrong ???
592      ]
593  | Sbreak ⇒
594      match k with
595      [ Kseq s' k' ⇒ ret ? 〈E0, State f Sbreak k' e m〉
596      | Kwhile a s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
597      | Kdowhile a s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
598      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
599      | Kswitch k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
600      | _ ⇒ Wrong ???
601      ]
602  | Sifthenelse a s1 s2 ⇒
603      ! 〈v,tr〉 ← exec_expr ge e m a;
604      ! b ← err_to_io … (exec_bool_of_val v (typeof a));
605      ret ? 〈tr, State f (if b then s1 else s2) k e m〉
606  | Swhile a s' ⇒
607      ! 〈v,tr〉 ← exec_expr ge e m a;
608      ! b ← err_to_io … (exec_bool_of_val v (typeof a));
609      ret ? 〈tr, if b then State f s' (Kwhile a s' k) e m
610                      else State f Sskip k e m〉
611  | Sdowhile a s' ⇒ ret ? 〈E0, State f s' (Kdowhile a s' k) e m〉
612  | Sfor a1 a2 a3 s' ⇒
613      match is_Sskip a1 with
614      [ inl _ ⇒
615          ! 〈v,tr〉 ← exec_expr ge e m a2;
616          ! b ← err_to_io … (exec_bool_of_val v (typeof a2));
617          ret ? 〈tr, State f (if b then s' else Sskip) (if b then (Kfor2 a2 a3 s' k) else k) e m〉
618      | inr _ ⇒ ret ? 〈E0, State f a1 (Kseq (Sfor Sskip a2 a3 s') k) e m〉
619      ]
620  | Sreturn a_opt ⇒
621    match a_opt with
622    [ None ⇒ match fn_return f with
623      [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef (call_cont k) (free_list m (blocks_of_env e))〉
624      | _ ⇒ Wrong ???
625      ]
626    | Some a ⇒
627        match type_eq_dec (fn_return f) Tvoid with
628        [ inl _ ⇒ Wrong ???
629        | inr _ ⇒
630          ! 〈v,tr〉 ← exec_expr ge e m a;
631          ret ? 〈tr, Returnstate v (call_cont k) (free_list m (blocks_of_env e))〉
632        ]
633    ]
634  | Sswitch a sl ⇒
635      ! 〈v,tr〉 ← exec_expr ge e m a;
636      match v with [ Vint n ⇒ ret ? 〈tr, State f (seq_of_labeled_statement (select_switch n sl)) (Kswitch k) e m〉
637                   | _ ⇒ Wrong ??? ]
638  | Slabel lbl s' ⇒ ret ? 〈E0, State f s' k e m〉
639  | Sgoto lbl ⇒
640      match find_label lbl (fn_body f) (call_cont k) with
641      [ Some sk' ⇒ match sk' with [ mk_pair s' k' ⇒ ret ? 〈E0, State f s' k' e m〉 ]
642      | None ⇒ Wrong ???
643      ]
644  | Scost lbl s' ⇒ ret ? 〈Echarge lbl, State f s' k e m〉
645  ]
646| Callstate f0 vargs k m ⇒
647  match f0 with
648  [ Internal f ⇒
649    match exec_alloc_variables empty_env m ((fn_params f) @ (fn_vars f)) with [ mk_pair e m1 ⇒
650      ! m2 ← err_to_io_sig … (exec_bind_parameters e m1 (fn_params f) vargs);
651      ret ? 〈E0, State f (fn_body f) k e m2〉
652    ]
653  | External f argtys retty ⇒
654      ! evargs ← err_to_io_sig … (check_eventval_list vargs (typlist_of_typelist argtys));
655      ! evres ← do_io f evargs (proj_sig_res (signature_of_type argtys retty));
656      ret ? 〈Eextcall f evargs (mk_eventval ? evres), Returnstate (mk_val ? evres) k m〉
657  ]
658| Returnstate res k m ⇒
659  match k with
660  [ Kcall r f e k' ⇒
661    match r with
662    [ None ⇒ ret ? 〈E0, (State f Sskip k' e m)〉
663    | Some r' ⇒
664      match r' with [ mk_pair l ty ⇒
665       
666          ! m' ← store_value_of_type' ty m l res;
667          ret ? 〈E0, (State f Sskip k' e m')〉
668      ]
669    ]
670  | _ ⇒ Wrong ???
671  ]
672].
673
674nlet rec make_initial_state (p:clight_program) : res (genv × state) ≝
675  do ge ← globalenv Genv ?? p;
676  do m0 ← init_mem Genv ?? p;
677  do 〈sp,b〉 ← opt_to_res ? (find_symbol ? ? ge (prog_main ?? p));
678  do u ← opt_to_res ? (match eq_region_dec sp Code with [ inl _ ⇒ Some ? something | inr _ ⇒ None ? ]);
679  do f ← opt_to_res ? (find_funct_ptr ? ? ge b);
680  OK ? 〈ge,Callstate f (nil ?) Kstop m0〉.
681
682ndefinition is_final_state : ∀st:state. (Σr. final_state st r) + (¬∃r. final_state st r).
683#st; nelim st;
684##[ #f s k e m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
685##| #f l k m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
686##| #v k m; ncases k;
687  ##[ ncases v;
688    ##[ ##2: #i; @1; @ i; //;
689    ##| ##1: @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
690    ##| #f; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
691    ##| #r; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
692    ##| #r b of; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
693    ##]
694  ##| #a b; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
695  ##| ##3,4: #a b c; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
696  ##| ##5,6,8: #a b c d; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
697  ##| #a; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
698  ##]
699##] nqed.
700
701nlet rec exec_steps (n:nat) (ge:genv) (s:state) :
702 IO io_out io_in (trace×state) ≝
703match is_final_state s with
704[ inl _ ⇒ ret ? 〈E0, s〉
705| inr _ ⇒
706  match n with
707  [ O ⇒ ret ? 〈E0, s〉
708  | S n' ⇒
709      ! 〈t,s'〉 ← exec_step ge s;
710(*      ! 〈t,s'〉 ← match s with
711                 [ State f s k e m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (State f s k e (mk_mem c n p)) ]
712                 | Callstate fd args k m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (Callstate fd args k (mk_mem c n p)) ]
713                 | Returnstate r k m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (Returnstate r k (mk_mem c n p)) ]
714                 ] ;*)
715      ! 〈t',s''〉 ← match s' with
716                 [ State f s k e m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (State f s k e (mk_mem c n p)) ]
717                 | Callstate fd args k m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (Callstate fd args k (mk_mem c n p)) ]
718                 | Returnstate r k m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (Returnstate r k (mk_mem c n p)) ]
719                 ] ;
720(*      ! 〈t',s''〉 ← exec_steps n' ge s';*)
721      ret ? 〈t ⧺ t',s''〉
722  ]
723].
724
725(* A (possibly non-terminating) execution.   *)
726ncoinductive execution : Type ≝
727| e_stop : trace → int → mem → execution
728| e_step : trace → state → execution → execution
729| e_wrong : execution
730| e_interact : ∀o:io_out. (io_in o → execution) → execution.
731
732ndefinition mem_of_state : state → mem ≝
733λs.match s with [ State f s k e m ⇒ m | Callstate f a k m ⇒ m | Returnstate r k m ⇒ m ].
734
735(* This definition is slightly awkward because of the need to provide resumptions.
736   It records the last trace/state passed in, then recursively processes the next
737   state. *)
738
739nlet corec exec_inf_aux (ge:genv) (s:IO io_out io_in (trace×state)) : execution ≝
740match s with
741[ Wrong ⇒ e_wrong
742| Value v ⇒ match v with [ mk_pair t s' ⇒
743    match is_final_state s' with
744    [ inl r ⇒ e_stop t (sig_eject … r) (mem_of_state s')
745    | inr _ ⇒ e_step t s' (exec_inf_aux ge (exec_step ge s')) ] ]
746| Interact out k' ⇒ e_interact out (λv. exec_inf_aux ge (k' v))
747].
748
749
750ndefinition exec_inf : clight_program → execution ≝
751λp.
752  match make_initial_state p with
753  [ OK gs ⇒ exec_inf_aux (\fst gs) (ret ? 〈E0,\snd gs〉)
754  | _ ⇒ e_wrong
755  ].
756
757nremark execution_cases: ∀e.
758 e = match e with [ e_stop tr r m ⇒ e_stop tr r m | e_step tr s e ⇒ e_step tr s e
759 | e_wrong ⇒ e_wrong | e_interact o k ⇒ e_interact o k ].
760#e; ncases e; //; nqed.
761
762nlemma exec_inf_aux_unfold: ∀ge,s. exec_inf_aux ge s =
763match s with
764[ Wrong ⇒ e_wrong
765| Value v ⇒ match v with [ mk_pair t s' ⇒
766    match is_final_state s' with
767    [ inl r ⇒ e_stop t (sig_eject … r) (mem_of_state s')
768    | inr _ ⇒ e_step t s' (exec_inf_aux ge (exec_step ge s')) ] ]
769| Interact out k' ⇒ e_interact out (λv. exec_inf_aux ge (k' v))
770].
771#ge s; nrewrite > (execution_cases (exec_inf_aux …)); ncases s;
772##[ #o k
773##| #x; ncases x; #tr s'; ncases s';
774  ##[ #fn st k env m
775  ##| #fd args k mem
776  ##| #v k mem; (* for final state check *) ncases k;
777    ##[ ncases v; ##[ ##2,3: #v' ##| ##4: #r ##| ##5: #sp loc off ##]
778    ##| #s' k' ##| ##3,4: #e s' k' ##| ##5,6: #e s' s'' k' ##| #k' ##| #a b c d ##]
779  ##]
780##| ##]
781nwhd in ⊢ (??%%); //;
782nqed.
783
Note: See TracBrowser for help on using the repository browser.