root/Deliverables/D3.1/C-semantics/Cexec.ma @ 457

include "Csem.ma".

include "extralib.ma".
include "IOMonad.ma".

include "Plogic/russell_support.ma".

ndefinition P_to_P_option_res : ∀A:Type[0].∀P:A → CProp[0].option (res A) → CProp[0] ≝
  λA,P,a.match a with [ None ⇒ False | Some y ⇒ match y return λ_.CProp[0] with [ Error ⇒ True | OK z ⇒ P z ]].

ndefinition err_inject : ∀A.∀P:A → Prop.∀a:option (res A).∀p:P_to_P_option_res A P a.res (sigma A P) ≝ 
  λA.λP:A → Prop.λa:option (res A).λp:P_to_P_option_res A P a. 
  (match a return λa'.a=a' → res (sigma A P) with
   [ None ⇒ λe1.?
   | Some b ⇒ λe1.(match b return λb'.b=b' → ? with
     [ Error ⇒ λ_. Error ?
     | OK c ⇒ λe2. OK ? (sig_intro A P c ?)
     ]) (refl ? b)
   ]) (refl ? a).
##[ nrewrite > e1 in p; nnormalize; *;
##| nrewrite > e1 in p; nrewrite > e2; nnormalize; //
##] nqed.

ndefinition err_eject : ∀A.∀P: A → Prop. res (sigma A P) → res A ≝ 
  λA,P,a.match a with [ Error ⇒ Error ? | OK b ⇒
    match b with [ sig_intro w p ⇒ OK ? w] ].

ndefinition sig_eject : ∀A.∀P: A → Prop. sigma A P → A ≝ 
  λA,P,a.match a with [ sig_intro w p ⇒ w].

ncoercion err_inject : 
  ∀A.∀P:A → Prop.∀a.∀p:P_to_P_option_res ? P a.res (sigma A P) ≝ err_inject 
  on a:option (res ?) to res (sigma ? ?).
ncoercion err_eject : ∀A.∀P:A → Prop.∀c:res (sigma A P).res A ≝ err_eject 
  on _c:res (sigma ? ?) to res ?.
ncoercion sig_eject : ∀A.∀P:A → Prop.∀c:sigma A P.A ≝ sig_eject 
  on _c:sigma ? ? to ?.

ndefinition P_res: ∀A.∀P:A → Prop.res A → Prop ≝
  λA,P,a. match a with [ Error ⇒ True | OK v ⇒ P v ].

ndefinition exec_bool_of_val : ∀v:val. ∀ty:type. res bool ≝
  λv,ty. match v in val with
  [ Vint i ⇒ match ty with
    [ Tint _ _ ⇒ OK ? (¬eq i zero)
    | Tpointer _ _ ⇒ OK ? (¬eq i zero)
    | _ ⇒ Error ?
    ]
  | Vfloat f ⇒ match ty with
    [ Tfloat _ ⇒ OK ? (¬Fcmp Ceq f Fzero)
    | _ ⇒ Error ?
    ]
  | Vptr _ _ _ ⇒ match ty with
    [ Tint _ _ ⇒ OK ? true
    | Tpointer _ _ ⇒ OK ? true
    | _ ⇒ Error ?
    ]
  | _ ⇒ Error ?
  ].

nlemma bool_of_val_complete : ∀v,ty,r. bool_of_val v ty r → ∃b. r = of_bool b ∧ exec_bool_of_val v ty = OK ? b.
#v ty r H; nelim H; #v t H'; nelim H';
  ##[ #i is s ne; @ true; @; //; nwhd in ⊢ (??%?); nrewrite > (eq_false … ne); //;
  ##| #p b i i0 s; @ true; @; //
  ##| #i p t ne; @ true; @; //; nwhd in ⊢ (??%?); nrewrite > (eq_false … ne); //;
  ##| #p b i p0 t0; @ true; @; //
  ##| #f s ne; @ true; @; //; nwhd in ⊢ (??%?); nrewrite > (Feq_zero_false … ne); //;
  ##| #i s; @ false; @; //;
  ##| #p t; @ false; @; //;
  ##| #s; @ false; @; //; nwhd in ⊢ (??%?); nrewrite > (Feq_zero_true …); //;
  ##]
nqed.

(* Prove a few minor results to make proof obligations easy. *)

nlemma bind_OK: ∀A,B,P,e,f.
  (∀v. e = OK A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
  match bind A B e f with [ Error ⇒ True | OK v ⇒ P v ].
#A B P e f; nelim e; /2/; nqed.

nlemma sig_bind_OK: ∀A,B. ∀P:A → Prop. ∀P':B → Prop. ∀e:res (sigma A P). ∀f:sigma A P → res B.
  (∀v:A. ∀p:P v. match f (sig_intro A P v p) with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
  match bind (sigma A P) B e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
#A B P P' e f; nelim e;
##[ #v0; nelim v0; #v Hv IH; napply IH;
##| #_; napply I;
##] nqed.

nlemma bind2_OK: ∀A,B,C,P,e,f.
  (∀v1,v2. e = OK ? 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P v' ]) →
  match bind2 A B C e f with [ Error ⇒ True | OK v ⇒ P v ].
#A B C P e f; nelim e; //; #v; ncases v; /2/; nqed.

nlemma sig_bind2_OK: ∀A,B,C. ∀P:A×B → Prop. ∀P':C → Prop. ∀e:res (sigma (A×B) P). ∀f:A → B → res C.
  (∀v1:A.∀v2:B. P 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
  match bind2 A B C e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
#A B C P P' e f; nelim e; //;
#v0; nelim v0; #v; nelim v; #v1 v2 Hv IH; napply IH; //; nqed.

ndefinition opt_to_res ≝ λA.λv:option A. match v with [ None ⇒ Error A | Some v ⇒ OK A v ].
nlemma opt_OK: ∀A,P,e.
  (∀v. e = Some ? v → P v) →
  match opt_to_res A e with [ Error ⇒ True | OK v ⇒ P v ].
#A P e; nelim e; /2/;
nqed.

nlemma opt_bind_OK: ∀A,B,P,e,f.
  (∀v. e = Some A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
  match bind A B (opt_to_res A e) f with [ Error ⇒ True | OK v ⇒ P v ].
#A B P e f; nelim e; nnormalize; /2/; nqed.

nlemma extract_subset_pair: ∀A,B,C,P. ∀e:{e:A×B | P e}. ∀Q:A→B→res C. ∀R:C→Prop.
  (∀a,b. eject ?? e = 〈a,b〉 → P 〈a,b〉 → match Q a b with [ OK v ⇒ R v | Error ⇒ True]) →
  match match eject ?? e with [ mk_pair a b ⇒ Q a b ] with [ OK v ⇒ R v | Error ⇒ True ].
#A B C P e Q R; ncases e; #e'; ncases e'; nnormalize;
##[ #H; napply (False_ind … H);
##| #e''; ncases e''; #a b Pab H; nnormalize; /2/;
##] nqed.

(*
nremark err_later: ∀A,B. ∀e:res A. match e with [ Error ⇒ Error B | OK v ⇒ Error B ] = Error B.
#A B e; ncases e; //; nqed.
*)

ndefinition try_cast_null : ∀m:mem. ∀i:int. ∀ty:type. ∀ty':type. res val  ≝
λm:mem. λi:int. λty:type. λty':type.
match eq i zero with
[ true ⇒
  match ty with
  [ Tint _ _ ⇒
    match ty' with
    [ Tpointer _ _ ⇒ OK ? (Vint i)
    | Tarray _ _ _ ⇒ OK ? (Vint i)
    | Tfunction _ _ ⇒ OK ? (Vint i)
    | _ ⇒ Error ?
    ]
  | Tpointer _ _ ⇒
    match ty' with
    [ Tpointer _ _ ⇒ OK ? (Vint i)
    | Tarray _ _ _ ⇒ OK ? (Vint i)
    | Tfunction _ _ ⇒ OK ? (Vint i)
    | _ ⇒ Error ?
    ]
  | Tarray _ _ _ ⇒
    match ty' with
    [ Tpointer _ _ ⇒ OK ? (Vint i)
    | Tarray _ _ _ ⇒ OK ? (Vint i)
    | Tfunction _ _ ⇒ OK ? (Vint i)
    | _ ⇒ Error ?
    ]
  | Tfunction _ _ ⇒
    match ty' with
    [ Tpointer _ _ ⇒ OK ? (Vint i)
    | Tarray _ _ _ ⇒ OK ? (Vint i)
    | Tfunction _ _ ⇒ OK ? (Vint i)
    | _ ⇒ Error ?
    ]
  | _ ⇒ Error ?
  ]
| false ⇒ Error ?
].

ndefinition ms_eq_dec : ∀s1,s2:memory_space. (s1 = s2) + (s1 ≠ s2).
#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed. 

ndefinition exec_cast : ∀m:mem. ∀v:val. ∀ty:type. ∀ty':type. res val ≝
λm:mem. λv:val. λty:type. λty':type.
match v with
[ Vint i ⇒
  match ty with
  [ Tint sz1 si1 ⇒
    match ty' with
    [ Tint sz2 si2 ⇒ OK ? (Vint (cast_int_int sz2 si2 i))
    | Tfloat sz2 ⇒ OK ? (Vfloat (cast_float_float sz2 (cast_int_float si1 i)))
    | Tpointer _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
    | Tarray _ _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
    | Tfunction _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
    | _ ⇒ Error ?
    ]
  | Tpointer _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
  | Tarray _ _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
  | Tfunction _ _ ⇒ do r ← try_cast_null m i ty ty'; OK val r
  | _ ⇒ Error ?
  ]
| Vfloat f ⇒
  match ty with
  [ Tfloat sz ⇒
    match ty' with
    [ Tint sz' si' ⇒ OK ? (Vint (cast_int_int sz' si' (cast_float_int si' f)))
    | Tfloat sz' ⇒ OK ? (Vfloat (cast_float_float sz' f))
    | _ ⇒ Error ?
    ]
  | _ ⇒ Error ?
  ]
| Vptr p b ofs ⇒
    do s ← match ty with [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code | _ ⇒ Error ? ];
    do u ← match ms_eq_dec p s with [ inl _ ⇒ OK ? something | inr _ ⇒ Error ? ];
    do s' ← match ty' with
         [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code
         | _ ⇒ Error ? ];
    if is_pointer_compat (block_space m b) s'
    then OK ? (Vptr s' b ofs)
    else Error ?
| _ ⇒ Error ?
].

ndefinition load_value_of_type' ≝
λty,m,l. match l with [ mk_pair pl ofs ⇒ match pl with [ mk_pair psp loc ⇒
  load_value_of_type ty m psp loc ofs ] ].

(* To make the evaluation of bare lvalue expressions invoke exec_lvalue with
   a structurally smaller value, we break out the surrounding Expr constructor
   and use exec_lvalue'. *)

nlet rec exec_expr (ge:genv) (en:env) (m:mem) (e:expr) on e : res (val×trace) ≝
match e with
[ Expr e' ty ⇒
  match e' with
  [ Econst_int i ⇒ OK ? 〈Vint i, E0〉
  | Econst_float f ⇒ OK ? 〈Vfloat f, E0〉
  | Evar _ ⇒
      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
      do v ← opt_to_res ? (load_value_of_type' ty m l);
      OK ? 〈v,tr〉
  | Ederef _ ⇒
      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
      do v ← opt_to_res ? (load_value_of_type' ty m l);
      OK ? 〈v,tr〉
  | Efield _ _ ⇒
      do 〈l,tr〉 ← exec_lvalue' ge en m e' ty;
      do v ← opt_to_res ? (load_value_of_type' ty m l);
      OK ? 〈v,tr〉
  | Eaddrof a ⇒
      do 〈plo,tr〉 ← exec_lvalue ge en m a;
      OK ? 〈match plo with [ mk_pair pl ofs ⇒ match pl with [ mk_pair pcl loc ⇒ Vptr pcl loc ofs ] ], tr〉
  | Esizeof ty' ⇒ OK ? 〈Vint (repr (sizeof ty')), E0〉
  | Eunop op a ⇒
      do 〈v1,tr〉 ← exec_expr ge en m a;
      do v ← opt_to_res ? (sem_unary_operation op v1 (typeof a));
      OK ? 〈v,tr〉
  | Ebinop op a1 a2 ⇒
      do 〈v1,tr1〉 ← exec_expr ge en m a1;
      do 〈v2,tr2〉 ← exec_expr ge en m a2;
      do v ← opt_to_res ? (sem_binary_operation op v1 (typeof a1) v2 (typeof a2) m);
      OK ? 〈v,tr1⧺tr2〉
  | Econdition a1 a2 a3 ⇒
      do 〈v,tr1〉 ← exec_expr ge en m a1;
      do b ← exec_bool_of_val v (typeof a1);
      do 〈v',tr2〉 ← match b return λ_.res (val×trace) with
                 [ true ⇒ (exec_expr ge en m a2)
                 | false ⇒ (exec_expr ge en m a3) ];
      OK ? 〈v',tr1⧺tr2〉
(*      if b then exec_expr ge en m a2 else exec_expr ge en m a3)*)
  | Eorbool a1 a2 ⇒
      do 〈v1,tr1〉 ← exec_expr ge en m a1;
      do b1 ← exec_bool_of_val v1 (typeof a1);
      match b1 return λ_.res (val×trace) with [ true ⇒ OK ? 〈Vtrue,tr1〉 | false ⇒
        do 〈v2,tr2〉 ← exec_expr ge en m a2;
        do b2 ← exec_bool_of_val v2 (typeof a2);
        OK ? 〈of_bool b2, tr1⧺tr2〉 ]
  | Eandbool a1 a2 ⇒
      do 〈v1,tr1〉 ← exec_expr ge en m a1;
      do b1 ← exec_bool_of_val v1 (typeof a1);
      match b1 return λ_.res (val×trace) with [ true ⇒
        do 〈v2,tr2〉 ← exec_expr ge en m a2;
        do b2 ← exec_bool_of_val v2 (typeof a2);
        OK ? 〈of_bool b2, tr1⧺tr2〉
      | false ⇒ OK ? 〈Vfalse,tr1〉 ]
  | Ecast ty' a ⇒
      do 〈v,tr〉 ← exec_expr ge en m a;
      do v' ← exec_cast m v (typeof a) ty';
      OK ? 〈v',tr〉
  | Ecost l a ⇒
      do 〈v,tr〉 ← exec_expr ge en m a;
      OK ? 〈v,tr⧺(Echarge l)〉
  ]
]
and exec_lvalue' (ge:genv) (en:env) (m:mem) (e':expr_descr) (ty:type) on e' : res (memory_space × block × int × trace) ≝
  match e' with
  [ Evar id ⇒ 
      match (get … id en) with
      [ None ⇒ do 〈sp,l〉 ← opt_to_res ? (find_symbol ? ? ge id); OK ? 〈〈〈sp,l〉,zero〉,E0〉 (* global *)
      | Some loc ⇒ OK ? 〈〈〈Any,loc〉,zero〉,E0〉 (* local *)
      ]
  | Ederef a ⇒
      do 〈v,tr〉 ← exec_expr ge en m a;
      match v with
      [ Vptr sp l ofs ⇒ OK ? 〈〈〈sp,l〉,ofs〉,tr〉
      | _ ⇒ Error ?
      ]
  | Efield a i ⇒
      match (typeof a) with
      [ Tstruct id fList ⇒
          do 〈plofs,tr〉 ← exec_lvalue ge en m a;
          do delta ← field_offset i fList;
          OK ? 〈〈\fst plofs,add (\snd plofs) (repr delta)〉,tr〉
      | Tunion id fList ⇒
          do 〈plofs,tr〉 ← exec_lvalue ge en m a;
          OK ? 〈plofs,tr〉
      | _ ⇒ Error ?
      ]
  | _ ⇒ Error ?
  ]
and exec_lvalue (ge:genv) (en:env) (m:mem) (e:expr) on e : res (memory_space × block × int × trace) ≝
match e with [ Expr e' ty ⇒ exec_lvalue' ge en m e' ty ].

nlemma P_res_to_P: ∀A,P,e,v.  P_res A P e → e = OK A v → P v.
#A P e v H1 H2; nrewrite > H2 in H1; nwhd in ⊢ (% → ?); //; nqed.

(* We define a special induction principle tailored to the recursive definition
   above. *)

ndefinition is_not_lvalue: expr_descr → Prop ≝
λe. match e with [ Evar _ ⇒ False | Ederef _ ⇒ False | Efield _ _ ⇒ False | _ ⇒ True ].

ndefinition Plvalue ≝ λP:(expr → Prop).λe,ty.
match e return λ_.Prop with [ Evar _ ⇒ P (Expr e ty) | Ederef _ ⇒ P (Expr e ty) | Efield _ _ ⇒ P (Expr e ty) | _ ⇒ True ].

(* TODO: Can we do this sensibly with a map combinator? *)
nlet rec exec_exprlist (ge:genv) (e:env) (m:mem) (l:list expr) on l : res (list val×trace) ≝
match l with
[ nil ⇒ OK ? 〈nil val, E0〉
| cons e1 es ⇒
  do 〈v,tr1〉 ← exec_expr ge e m e1;
  do 〈vs,tr2〉 ← exec_exprlist ge e m es;
  OK ? 〈cons val v vs, tr1⧺tr2〉
].

(* Don't really want to use subset rather than sigma here, but can't be bothered
   with *another* set of coercions. XXX: why do I have to get the recursive
   call's property manually? *)

nlet rec exec_alloc_variables (en:env) (m:mem) (l:list (ident × type)) on l : { r:env × mem | alloc_variables en m l (\fst r) (\snd r) } ≝
match l with
[ nil ⇒ Some ? 〈en, m〉
| cons h vars ⇒
  match h with [ mk_pair id ty ⇒
    match alloc m 0 (sizeof ty) Any with [ mk_pair m1 b1 ⇒
      match exec_alloc_variables (set … id b1 en) m1 vars with
      [ sig_intro r p ⇒ r ]
]]]. nwhd;
##[ //;
##| nelim (exec_alloc_variables (set ident ? ? c3 c7 en) c6 c1);
    #H; nelim H; //; #H0; nelim H0; nnormalize; #en' m' IH;
napply (alloc_variables_cons … IH); /2/;
nqed.

(* TODO: can we establish that length params = length vs in advance? *)
nlet rec exec_bind_parameters (e:env) (m:mem) (params:list (ident × type)) (vs:list val) on params : res (Σm2:mem. bind_parameters e m params vs m2) ≝
  match params with
  [ nil ⇒ match vs with [ nil ⇒ Some ? (OK ? m) | cons _ _ ⇒ Some ? (Error ?) ]
  | cons idty params' ⇒ match idty with [ mk_pair id ty ⇒
      match vs with
      [ nil ⇒ Some ? (Error ?)
      | cons v1 vl ⇒ Some ? (
          do b ← opt_to_res ? (get … id e);
          do m1 ← opt_to_res ? (store_value_of_type ty m Any b zero v1);
          err_eject ?? (exec_bind_parameters e m1 params' vl)) (* FIXME: don't want to have to eject here *)
      ]
  ] ].
nwhd; //;
napply opt_bind_OK; #b eb;
napply opt_bind_OK; #m1 em1;
napply sig_bind_OK; #m2 Hm2;
napply (bind_parameters_cons … eb em1 Hm2);
nqed.

alias id "Tint" = "cic:/matita/c-semantics/Csyntax/type.con(0,2,0)".
alias id "Tfloat" = "cic:/matita/c-semantics/Csyntax/type.con(0,3,0)".
ndefinition sz_eq_dec : ∀s1,s2:intsize. (s1 = s2) + (s1 ≠ s2).
#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
ndefinition sg_eq_dec : ∀s1,s2:signedness. (s1 = s2) + (s1 ≠ s2).
#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
ndefinition fs_eq_dec : ∀s1,s2:floatsize. (s1 = s2) + (s1 ≠ s2).
#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.

nlet rec type_eq_dec (t1,t2:type) : (t1 = t2) + (t1 ≠ t2) ≝
match t1 return λt'. (t' = t2) + (t' ≠ t2) with
[ Tvoid ⇒ match t2 return λt'. (Tvoid = t') + (Tvoid ≠ t') with [ Tvoid ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tint sz sg ⇒ match t2 return λt'. (Tint ?? = t') + (Tint ?? ≠ t')  with [ Tint sz' sg' ⇒
    match sz_eq_dec sz sz' with [ inl e1 ⇒
    match sg_eq_dec sg sg' with [ inl e2 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tfloat f ⇒ match t2 return λt'. (Tfloat ? = t') + (Tfloat ? ≠ t')  with [ Tfloat f' ⇒
    match fs_eq_dec f f' with [ inl e1 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tpointer s t ⇒ match t2 return λt'. (Tpointer ?? = t') + (Tpointer ?? ≠ t')  with [ Tpointer s' t' ⇒
    match ms_eq_dec s s' with [ inl e1 ⇒
      match type_eq_dec t t' with [ inl e2 ⇒ inl ??? 
      | inr e2 ⇒ inr ?? (nmk ? (λH.match e2 with [ nmk e' ⇒ e' ? ])) ] 
    | inr e1 ⇒ inr ?? (nmk ? (λH.match e1 with [ nmk e' ⇒ e' ? ])) ] | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tarray s t n ⇒ match t2 return λt'. (Tarray ??? = t') + (Tarray ??? ≠ t')  with [ Tarray s' t' n' ⇒
    match ms_eq_dec s s' with [ inl e1 ⇒
      match type_eq_dec t t' with [ inl e2 ⇒
        match decidable_eq_Z_Type n n' with [ inl e3 ⇒ inl ???
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
        | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tfunction tl t ⇒ match t2 return λt'. (Tfunction ?? = t') + (Tfunction ?? ≠ t')  with [ Tfunction tl' t' ⇒
    match typelist_eq_dec tl tl' with [ inl e1 ⇒ 
    match type_eq_dec t t' with [ inl e2 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
  | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tstruct i fl ⇒
    match t2 return λt'. (Tstruct ?? = t') + (Tstruct ?? ≠ t')  with [ Tstruct i' fl' ⇒
    match ident_eq i i' with [ inl e1 ⇒
    match fieldlist_eq_dec fl fl' with [ inl e2 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tunion i fl ⇒
    match t2 return λt'. (Tunion ?? = t') + (Tunion ?? ≠ t')  with [ Tunion i' fl' ⇒
    match ident_eq i i' with [ inl e1 ⇒
    match fieldlist_eq_dec fl fl' with [ inl e2 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    |  _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tcomp_ptr i ⇒ match t2 return λt'. (Tcomp_ptr ? = t') + (Tcomp_ptr ? ≠ t')  with [ Tcomp_ptr i' ⇒ 
    match ident_eq i i' with [ inl e1 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | _ ⇒ inr ?? (nmk ? (λH.?)) ]
]
and typelist_eq_dec (tl1,tl2:typelist) : (tl1 = tl2) + (tl1 ≠ tl2) ≝
match tl1 return λtl'. (tl' = tl2) + (tl' ≠ tl2) with
[ Tnil ⇒ match tl2 return λtl'. (Tnil = tl') + (Tnil ≠ tl') with [ Tnil ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Tcons t1 ts1 ⇒ match tl2 return λtl'. (Tcons ?? = tl') + (Tcons ?? ≠ tl') with [ Tnil ⇒ inr ?? (nmk ? (λH.?)) | Tcons t2 ts2 ⇒ 
    match type_eq_dec t1 t2 with [ inl e1 ⇒
    match typelist_eq_dec ts1 ts2 with [ inl e2 ⇒ inl ???
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
    | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ] ]
]
and fieldlist_eq_dec (fl1,fl2:fieldlist) : (fl1 = fl2) + (fl1 ≠ fl2) ≝
match fl1 return λfl'. (fl' = fl2) + (fl' ≠ fl2) with
[ Fnil ⇒ match fl2 return λfl'. (Fnil = fl') + (Fnil ≠ fl') with [ Fnil ⇒ inl ?? (refl ??) | _ ⇒ inr ?? (nmk ? (λH.?)) ]
| Fcons i1 t1 fs1 ⇒ match fl2 return λfl'. (Fcons ??? = fl') + (Fcons ??? ≠ fl') with [ Fnil ⇒ inr ?? (nmk ? (λH.?)) | Fcons i2 t2 fs2 ⇒ 
    match ident_eq i1 i2 with [ inl e1 ⇒
      match type_eq_dec t1 t2 with [ inl e2 ⇒
        match fieldlist_eq_dec fs1 fs2 with [ inl e3 ⇒ inl ???
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ]
        | inr e ⇒ inr ?? (nmk ? (λH.match e with [ nmk e' ⇒ e' ? ])) ] ]
]. ndestruct; //; nqed.

ndefinition assert_type_eq : ∀t1,t2:type. res (t1 = t2) ≝
λt1,t2. match type_eq_dec t1 t2 with [ inl p ⇒ OK ? p | inr _ ⇒ Error ? ].

nlet rec is_is_call_cont (k:cont) : (is_call_cont k) + (¬is_call_cont k) ≝
match k return λk'.(is_call_cont k') + (¬is_call_cont k') with
[ Kstop ⇒ ?
| Kcall _ _ _ _ ⇒ ?
| _ ⇒ ?
]. 
##[ ##1,8: @1; //
##| ##*: @2; /2/
##] nqed.

ndefinition is_Sskip : ∀s:statement. (s = Sskip) + (s ≠ Sskip) ≝
λs.match s return λs'.(s' = Sskip) + (s' ≠ Sskip) with
[ Sskip ⇒ inl ?? (refl ??)
| _ ⇒ inr ?? (nmk ? (λH.?))
]. ndestruct;
nqed.

(* Checking types of values given to / received from an external function call. *)

ndefinition eventval_type : ∀ty:typ. Type ≝
λty. match ty with [ Tint ⇒ int | Tfloat ⇒ float ].

ndefinition mk_eventval: ∀ty:typ. eventval_type ty → eventval ≝
λty:typ. match ty return λty'.eventval_type ty' → eventval with [ Tint ⇒ λv.EVint v | Tfloat ⇒ λv.EVfloat v ].

ndefinition mk_val: ∀ty:typ. eventval_type ty → val ≝
λty:typ. match ty return λty'.eventval_type ty' → val with [ Tint ⇒ λv.Vint v | Tfloat ⇒ λv.Vfloat v ].

nlemma mk_val_correct: ∀ty:typ. ∀v:eventval_type ty.
  eventval_match (mk_eventval ty v) ty (mk_val ty v).
#ty; ncases ty; nnormalize; //; nqed.

ndefinition convert_eventval : ∀ev:eventval. ∀ty:typ. res (Σv:val. eventval_match ev ty v) ≝
λev,ty.
match ty with
[ Tint ⇒ match ev with [ EVint i ⇒ Some ? (OK ? (Vint i)) | _ ⇒ Some ? (Error ?) ]
| Tfloat ⇒ match ev with [ EVfloat f ⇒ Some ? (OK ? (Vfloat f)) | _ ⇒ Some ? (Error ?) ]
| _ ⇒ Some ? (Error ?)
]. nwhd; //; nqed.

ndefinition check_eventval' : ∀v:val. ∀ty:typ. res (Σev:eventval. eventval_match ev ty v) ≝
λv,ty.
match ty with
[ Tint ⇒ match v with [ Vint i ⇒ Some ? (OK ? (EVint i)) | _ ⇒ Some ? (Error ?) ]
| Tfloat ⇒ match v with [ Vfloat f ⇒ Some ? (OK ? (EVfloat f)) | _ ⇒ Some ? (Error ?) ]
| _ ⇒ Some ? (Error ?)
]. nwhd; //; nqed.

nlet rec check_eventval_list (vs: list val) (tys: list typ) : res (Σevs:list eventval. eventval_list_match evs tys vs) ≝
match vs with
[ nil ⇒ match tys with [ nil ⇒ Some ? (OK ? (nil ?)) | _ ⇒ Some ? (Error ?) ]
| cons v vt ⇒
  match tys with
  [ nil ⇒ Some ? (Error ?)
  | cons ty tyt ⇒ Some ? (
    do ev ← check_eventval' v ty;
    do evt ← check_eventval_list vt tyt;
    OK ? ((sig_eject ?? ev)::evt))
  ]
]. nwhd; //;
napply sig_bind_OK; #ev Hev;
napply sig_bind_OK; #evt Hevt;
nnormalize; /2/;
nqed.

(* IO monad *)

(* Interactions are function calls that return a value and do not change
   the rest of the Clight program's state. *)
nrecord io_out : Type ≝
{ io_function: ident
; io_args: list eventval
; io_in_typ: typ
}.

ndefinition io_in ≝ λo. eventval_type (io_in_typ o).

ndefinition do_io : ident → list eventval → ∀t:typ. IO io_out io_in (eventval_type t) ≝
λfn,args,t. Interact ??? (mk_io_out fn args t) (λres. Value ??? res).

ndefinition ret: ∀T. T → (IO io_out io_in T) ≝
λT,x.(Value ?? T x).

(* execution *)

ndefinition store_value_of_type' ≝
λty,m,l,v.
match l with [ mk_pair pl ofs ⇒
  match pl with [ mk_pair pcl loc ⇒
    store_value_of_type ty m pcl loc ofs v ] ].

nlet rec exec_step (ge:genv) (st:state) on st : (IO io_out io_in (trace × state)) ≝
match st with
[ State f s k e m ⇒
  match s with
  [ Sassign a1 a2 ⇒
    ! 〈l,tr1〉 ← exec_lvalue ge e m a1;
    ! 〈v2,tr2〉 ← exec_expr ge e m a2;
    ! m' ← store_value_of_type' (typeof a1) m l v2;
    ret ? 〈tr1⧺tr2, State f Sskip k e m'〉
  | Scall lhs a al ⇒
    ! 〈vf,tr2〉 ← exec_expr ge e m a;
    ! 〈vargs,tr3〉 ← exec_exprlist ge e m al;
    ! fd ← find_funct ? ? ge vf;
    ! p ← err_to_io … (assert_type_eq (type_of_fundef fd) (fun_typeof a));
(* requires associativity of IOMonad, so rearrange it below
    ! k' ← match lhs with
         [ None ⇒ ret ? (Kcall (None ?) f e k)
         | Some lhs' ⇒
           ! locofs ← exec_lvalue ge e m lhs';
           ret ? (Kcall (Some ? 〈sig_eject ?? locofs, typeof lhs'〉) f e k)
         ];
    ret ? 〈E0, Callstate fd vargs k' m〉)
*)
    match lhs with
         [ None ⇒ ret ? 〈tr2⧺tr3, Callstate fd vargs (Kcall (None ?) f e k) m〉
         | Some lhs' ⇒
           ! 〈locofs,tr1〉 ← exec_lvalue ge e m lhs';
           ret ? 〈tr1⧺tr2⧺tr3, Callstate fd vargs (Kcall (Some ? 〈locofs, typeof lhs'〉) f e k) m〉
         ]
  | Ssequence s1 s2 ⇒ ret ? 〈E0, State f s1 (Kseq s2 k) e m〉
  | Sskip ⇒
      match k with
      [ Kseq s k' ⇒ ret ? 〈E0, State  f s k' e m〉
      | Kstop ⇒
          match fn_return f with
          [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉
          | _ ⇒ Wrong ???
          ]
      | Kcall _ _ _ _ ⇒
          match fn_return f with
          [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉
          | _ ⇒ Wrong ???
          ]
      | Kwhile a s' k' ⇒ ret ? 〈E0, State f (Swhile a s') k' e m〉
      | Kdowhile a s' k' ⇒
          ! 〈v,tr〉 ← exec_expr ge e m a;
          ! b ← err_to_io … (exec_bool_of_val v (typeof a));
          match b with
          [ true ⇒ ret ? 〈tr, State f (Sdowhile a s') k' e m〉
          | false ⇒ ret ? 〈tr, State f Sskip k' e m〉
          ]
      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉
      | Kfor3 a2 a3 s' k' ⇒ ret ? 〈E0, State f (Sfor Sskip a2 a3 s') k' e m〉
      | Kswitch k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
      | _ ⇒ Wrong ???
      ]
  | Scontinue ⇒
      match k with
      [ Kseq s' k' ⇒ ret ? 〈E0, State f Scontinue k' e m〉
      | Kwhile a s' k' ⇒ ret ? 〈E0, State f (Swhile a s') k' e m〉
      | Kdowhile a s' k' ⇒ 
          ! 〈v,tr〉 ← exec_expr ge e m a;
          ! b ← err_to_io … (exec_bool_of_val v (typeof a));
          match b with
          [ true ⇒ ret ? 〈tr, State f (Sdowhile a s') k' e m〉
          | false ⇒ ret ? 〈tr, State f Sskip k' e m〉
          ]
      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉
      | Kswitch k' ⇒ ret ? 〈E0, State f Scontinue k' e m〉
      | _ ⇒ Wrong ???
      ]
  | Sbreak ⇒
      match k with
      [ Kseq s' k' ⇒ ret ? 〈E0, State f Sbreak k' e m〉
      | Kwhile a s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
      | Kdowhile a s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
      | Kfor2 a2 a3 s' k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
      | Kswitch k' ⇒ ret ? 〈E0, State f Sskip k' e m〉
      | _ ⇒ Wrong ???
      ]
  | Sifthenelse a s1 s2 ⇒ 
      ! 〈v,tr〉 ← exec_expr ge e m a;
      ! b ← err_to_io … (exec_bool_of_val v (typeof a));
      ret ? 〈tr, State f (if b then s1 else s2) k e m〉
  | Swhile a s' ⇒ 
      ! 〈v,tr〉 ← exec_expr ge e m a;
      ! b ← err_to_io … (exec_bool_of_val v (typeof a));
      ret ? 〈tr, if b then State f s' (Kwhile a s' k) e m
                      else State f Sskip k e m〉
  | Sdowhile a s' ⇒ ret ? 〈E0, State f s' (Kdowhile a s' k) e m〉
  | Sfor a1 a2 a3 s' ⇒
      match is_Sskip a1 with
      [ inl _ ⇒ 
          ! 〈v,tr〉 ← exec_expr ge e m a2;
          ! b ← err_to_io … (exec_bool_of_val v (typeof a2));
          ret ? 〈tr, State f (if b then s' else Sskip) (if b then (Kfor2 a2 a3 s' k) else k) e m〉
      | inr _ ⇒ ret ? 〈E0, State f a1 (Kseq (Sfor Sskip a2 a3 s') k) e m〉
      ]
  | Sreturn a_opt ⇒
    match a_opt with
    [ None ⇒ match fn_return f with
      [ Tvoid ⇒ ret ? 〈E0, Returnstate Vundef (call_cont k) (free_list m (blocks_of_env e))〉
      | _ ⇒ Wrong ???
      ]
    | Some a ⇒ 
        match type_eq_dec (fn_return f) Tvoid with
        [ inl _ ⇒ Wrong ???
        | inr _ ⇒
          ! 〈v,tr〉 ← exec_expr ge e m a;
          ret ? 〈tr, Returnstate v (call_cont k) (free_list m (blocks_of_env e))〉
        ]
    ]
  | Sswitch a sl ⇒ 
      ! 〈v,tr〉 ← exec_expr ge e m a;
      match v with [ Vint n ⇒ ret ? 〈tr, State f (seq_of_labeled_statement (select_switch n sl)) (Kswitch k) e m〉
                   | _ ⇒ Wrong ??? ]
  | Slabel lbl s' ⇒ ret ? 〈E0, State f s' k e m〉
  | Sgoto lbl ⇒
      match find_label lbl (fn_body f) (call_cont k) with
      [ Some sk' ⇒ match sk' with [ mk_pair s' k' ⇒ ret ? 〈E0, State f s' k' e m〉 ]
      | None ⇒ Wrong ???
      ]
  | Scost lbl s' ⇒ ret ? 〈Echarge lbl, State f s' k e m〉
  ]
| Callstate f0 vargs k m ⇒
  match f0 with
  [ Internal f ⇒ 
    match exec_alloc_variables empty_env m ((fn_params f) @ (fn_vars f)) with [ mk_pair e m1 ⇒
      ! m2 ← err_to_io_sig … (exec_bind_parameters e m1 (fn_params f) vargs);
      ret ? 〈E0, State f (fn_body f) k e m2〉
    ]
  | External f argtys retty ⇒ 
      ! evargs ← err_to_io_sig … (check_eventval_list vargs (typlist_of_typelist argtys));
      ! evres ← do_io f evargs (proj_sig_res (signature_of_type argtys retty));
      ret ? 〈Eextcall f evargs (mk_eventval ? evres), Returnstate (mk_val ? evres) k m〉
  ]
| Returnstate res k m ⇒
  match k with
  [ Kcall r f e k' ⇒
    match r with
    [ None ⇒ ret ? 〈E0, (State f Sskip k' e m)〉
    | Some r' ⇒
      match r' with [ mk_pair l ty ⇒
        
          ! m' ← store_value_of_type' ty m l res;
          ret ? 〈E0, (State f Sskip k' e m')〉
      ]
    ]
  | _ ⇒ Wrong ???
  ]
].

nlet rec make_initial_state (p:program) : res state ≝
  let ge ≝ globalenv Genv ?? p in
  let m0 ≝ init_mem Genv ?? p in
    do 〈sp,b〉 ← opt_to_res ? (find_symbol ? ? ge (prog_main ?? p));
    do u ← opt_to_res ? (match ms_eq_dec sp Code with [ inl _ ⇒ Some ? something | inr _ ⇒ None ? ]);
    do f ← opt_to_res ? (find_funct_ptr ? ? ge b);
    OK ? (Callstate f (nil ?) Kstop m0).

ndefinition is_final_state : ∀st:state. (Σr. final_state st r) + (¬∃r. final_state st r).
#st; nelim st;
##[ #f s k e m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
##| #f l k m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
##| #v k m; ncases k; 
  ##[ ncases v;
    ##[ ##2: #i; @1; @ i; //;
    ##| ##1: @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
    ##| #f; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
    ##| #pcl b of; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
    ##]
  ##| #a b; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
  ##| ##3,4: #a b c; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
  ##| ##5,6,8: #a b c d; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
  ##| #a; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
  ##]
##] nqed.

nlet rec exec_steps (n:nat) (ge:genv) (s:state) :
 IO io_out io_in (trace×state) ≝
match is_final_state s with
[ inl _ ⇒ ret ? 〈E0, s〉
| inr _ ⇒
  match n with
  [ O ⇒ ret ? 〈E0, s〉
  | S n' ⇒
      ! 〈t,s'〉 ← exec_step ge s;
(*      ! 〈t,s'〉 ← match s with
                 [ State f s k e m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (State f s k e (mk_mem c n p)) ]
                 | Callstate fd args k m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (Callstate fd args k (mk_mem c n p)) ]
                 | Returnstate r k m ⇒ match m with [ mk_mem c n p ⇒ exec_step ge (Returnstate r k (mk_mem c n p)) ]
                 ] ;*)
      ! 〈t',s''〉 ← match s' with
                 [ State f s k e m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (State f s k e (mk_mem c n p)) ]
                 | Callstate fd args k m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (Callstate fd args k (mk_mem c n p)) ]
                 | Returnstate r k m ⇒ match m with [ mk_mem c n p ⇒ exec_steps n' ge (Returnstate r k (mk_mem c n p)) ]
                 ] ;
(*      ! 〈t',s''〉 ← exec_steps n' ge s';*)
      ret ? 〈t ⧺ t',s''〉
  ]
].

(* A (possibly non-terminating) execution.   *)
ncoinductive execution : Type ≝
| e_stop : trace → int → mem → execution
| e_step : trace → state → execution → execution
| e_wrong : execution
| e_interact : ∀o:io_out. (io_in o → execution) → execution.

ndefinition mem_of_state : state → mem ≝
λs.match s with [ State f s k e m ⇒ m | Callstate f a k m ⇒ m | Returnstate r k m ⇒ m ].

(* This definition is slightly awkward because of the need to provide resumptions.
   It records the last trace/state passed in, then recursively processes the next
   state. *)

nlet corec exec_inf_aux (ge:genv) (s:IO io_out io_in (trace×state)) : execution ≝
match s with
[ Wrong ⇒ e_wrong
| Value v ⇒ match v with [ mk_pair t s' ⇒ 
    match is_final_state s' with
    [ inl r ⇒ e_stop t (sig_eject … r) (mem_of_state s')
    | inr _ ⇒ e_step t s' (exec_inf_aux ge (exec_step ge s')) ] ]
| Interact out k' ⇒ e_interact out (λv. exec_inf_aux ge (k' v))
].


ndefinition exec_inf : program → execution ≝
λp. exec_inf_aux (globalenv Genv ?? p) (! s ← make_initial_state p; ret ? 〈E0,s〉).

nremark execution_cases: ∀e.
 e = match e with [ e_stop tr r m ⇒ e_stop tr r m | e_step tr s e ⇒ e_step tr s e
 | e_wrong ⇒ e_wrong | e_interact o k ⇒ e_interact o k ].
#e; ncases e; //; nqed.

nlemma exec_inf_aux_unfold: ∀ge,s. exec_inf_aux ge s =
match s with
[ Wrong ⇒ e_wrong
| Value v ⇒ match v with [ mk_pair t s' ⇒ 
    match is_final_state s' with
    [ inl r ⇒ e_stop t (sig_eject … r) (mem_of_state s')
    | inr _ ⇒ e_step t s' (exec_inf_aux ge (exec_step ge s')) ] ]
| Interact out k' ⇒ e_interact out (λv. exec_inf_aux ge (k' v))
].
#ge s; nrewrite > (execution_cases (exec_inf_aux …)); ncases s;
##[ #o k
##| #x; ncases x; #tr s'; ncases s';
  ##[ #fn st k env m
  ##| #fd args k mem 
  ##| #v k mem; (* for final state check *) ncases k;
    ##[ ncases v; ##[ ##2,3: #v' ##| ##4: #sp loc off ##]
    ##| #s' k' ##| ##3,4: #e s' k' ##| ##5,6: #e s' s'' k' ##| #k' ##| #a b c d ##]
  ##]
##| ##] 
nwhd in ⊢ (??%%); //;
nqed.