source: Deliverables/D2.3/8051-memoryspaces-branch/src/clight/clightFromC.ml @ 460

Last change on this file since 460 was 460, checked in by campbell, 9 years ago

Port memory spaces changes to latest prototype compiler.

File size: 28.9 KB
Line 
1open Printf
2
3open Cparser
4open Cparser.C
5open Cparser.Env
6
7open Clight
8 
9(** Extract the type part of a type-annotated Clight expression. *)
10
11let typeof e = match e with Expr(_,te) -> te
12
13(** Natural alignment of a type, in bytes. *)
14let rec alignof = function
15  | Tvoid -> 1
16  | Tint (I8,_) -> 1
17  | Tint (I16,_) -> 2
18  | Tint (I32,_) -> 4
19  | Tfloat F32 -> 4
20  | Tfloat F64 -> 8
21  | Tpointer _ -> 4
22  | Tarray (_,t',n) -> alignof t'
23  | Tfunction (_,_) -> 1
24  | Tstruct (_,fld) -> alignof_fields fld
25  | Tunion (_,fld) -> alignof_fields fld
26  | Tcomp_ptr _ -> 4
27and alignof_fields = function
28          | [] -> 1
29          | (id,t)::f' -> max (alignof t) (alignof_fields f')
30
31(** Size of a type, in bytes. *)
32
33let align n amount =
34  ((n + amount - 1) / amount) * amount
35
36let rec sizeof t = 
37  match t with
38    | Tvoid -> 1
39    | Tint (I8,_) -> 1
40    | Tint (I16,_) -> 2
41    | Tint (I32,_) -> 4
42    | Tfloat F32 -> 4
43    | Tfloat F64 -> 8
44    | Tpointer _ -> 4
45    | Tarray (_,t',n) -> sizeof t' * max 1 n
46    | Tfunction (_,_) -> 1
47    | Tstruct (_,fld) -> align (max 1 (sizeof_struct fld 0)) (alignof t)
48    | Tunion (_,fld) -> align (max 1 (sizeof_union fld)) (alignof t)
49    | Tcomp_ptr _ -> 4
50and sizeof_struct fld pos =
51  match fld with
52    | [] -> pos
53    | (id,t)::fld' -> sizeof_struct fld' (align pos (alignof t) + sizeof t)
54and sizeof_union = function
55  | [] -> 0
56  | (id,t)::fld' -> max (sizeof t) (sizeof_union fld')
57
58(** Record the declarations of global variables and associate them
59    with the corresponding atom. *)
60
61let decl_atom : (AST.ident, Env.t * C.decl) Hashtbl.t = Hashtbl.create 103
62
63(** Hooks -- overriden in machine-dependent CPragmas module *)
64
65let process_pragma_hook = ref (fun (s: string) -> false)
66let define_variable_hook = ref (fun (id: AST.ident) (d: C.decl) -> ())
67let define_function_hook = ref (fun (id: AST.ident) (d: C.decl) -> ())
68let define_stringlit_hook = ref (fun (id: AST.ident) -> ())
69
70(** ** Error handling *)
71
72let currentLocation = ref Cutil.no_loc
73
74let updateLoc l = currentLocation := l
75
76let numErrors = ref 0
77
78let error msg =
79  incr numErrors;
80  eprintf "%aError: %s\n" Cutil.printloc !currentLocation msg
81
82let unsupported msg =
83  incr numErrors;
84  eprintf "%aUnsupported feature: %s\n" Cutil.printloc !currentLocation msg
85
86let warning msg =
87  eprintf "%aWarning: %s\n" Cutil.printloc !currentLocation msg
88
89
90(** ** Functions used to handle string literals *)
91
92let stringNum = ref 0   (* number of next global for string literals *)
93let stringTable = Hashtbl.create 47
94
95let name_for_string_literal env s =
96  try
97    Hashtbl.find stringTable s
98  with Not_found ->
99    incr stringNum;
100    let name = Printf.sprintf "__stringlit_%d" !stringNum in
101    let id = name in
102    Hashtbl.add decl_atom id
103      (env, (C.Storage_static,
104             Env.fresh_ident name,
105             C.TPtr(C.Any,C.TInt(C.IChar,[C.AConst]),[]),
106             None));
107    !define_stringlit_hook id;
108    Hashtbl.add stringTable s id;
109    id
110
111let typeStringLiteral s =
112  Tarray(Code, Tint(I8, Unsigned), String.length s + 1)
113
114let global_for_string s id =
115  let init = ref [] in
116  let add_char c =
117    init :=
118       Init_int8(Char.code c)
119       :: !init in
120  add_char '\000';
121  for i = String.length s - 1 downto 0 do add_char s.[i] done;
122  (((id, !init), Code), typeStringLiteral s)
123
124let globals_for_strings globs =
125  Hashtbl.fold
126    (fun s id l -> global_for_string s id :: l)
127    stringTable globs
128
129(** ** Handling of stubs for variadic functions *)
130
131let stub_function_table = Hashtbl.create 47
132
133let register_stub_function name tres targs =
134  let rec letters_of_type = function
135    | [] -> []
136    | Tfloat(_)::tl -> "f" :: letters_of_type tl
137    | _::tl -> "i" :: letters_of_type tl in
138  let stub_name =
139    name ^ "$" ^ String.concat "" (letters_of_type targs) in
140  try
141    (stub_name, Hashtbl.find stub_function_table stub_name)
142  with Not_found ->
143    let rec types_of_types = function
144      | [] -> []
145      | Tfloat(_)::tl -> Tfloat(F64)::(types_of_types tl)
146      | _::tl -> Tpointer(Any,Tvoid)::(types_of_types tl) in
147    let stub_type = Tfunction (types_of_types targs, tres) in
148    Hashtbl.add stub_function_table stub_name stub_type;
149    (stub_name, stub_type)
150
151let declare_stub_function stub_name stub_type =
152  match stub_type with
153  | Tfunction(targs, tres) ->
154      (stub_name,
155                         External(stub_name, targs, tres))
156  | _ -> assert false
157
158let declare_stub_functions k =
159  Hashtbl.fold
160    (fun n i k -> declare_stub_function n i :: k)
161               stub_function_table k
162
163(** ** Translation functions *)
164
165(** Constants *)
166
167let convertInt n = Int64.to_int n
168
169(** Types *)
170
171let convertIkind = function
172  | C.IBool -> unsupported "'_Bool' type"; (Unsigned, I8)
173  | C.IChar -> (Unsigned, I8)
174  | C.ISChar -> (Signed, I8)
175  | C.IUChar -> (Unsigned, I8)
176  | C.IInt -> (Signed, I32)
177  | C.IUInt -> (Unsigned, I32)
178  | C.IShort -> (Signed, I16)
179  | C.IUShort -> (Unsigned, I16)
180  | C.ILong -> (Signed, I32)
181  | C.IULong -> (Unsigned, I32)
182  | C.ILongLong -> 
183      if not !ClightFlags.option_flonglong then unsupported "'long long' type";
184      (Signed, I32)
185  | C.IULongLong ->
186      if not !ClightFlags.option_flonglong then unsupported "'unsigned long long' type";
187      (Unsigned, I32)
188
189let convertFkind = function
190  | C.FFloat -> F32
191  | C.FDouble -> F64
192  | C.FLongDouble ->
193      if not !ClightFlags.option_flonglong then unsupported "'long double' type";
194      F64
195
196let convertSpace = function
197  | C.Any -> Any
198  | C.Data -> Data
199  | C.IData -> IData
200  | C.PData -> PData
201  | C.XData -> XData
202  | C.Code -> Code
203
204let convertTyp env t =
205
206  let rec convertTyp seen t =
207    match Cutil.unroll env t with
208    | C.TVoid a -> Tvoid
209    | C.TInt(ik, a) ->
210        let (sg, sz) = convertIkind ik in Tint(sz, sg)
211    | C.TFloat(fk, a) ->
212        Tfloat(convertFkind fk)
213    | C.TPtr(_,C.TStruct(id, _), _) when List.mem id seen ->
214        Tcomp_ptr("struct " ^ id.name)
215    | C.TPtr(_,C.TUnion(id, _), _) when List.mem id seen ->
216        Tcomp_ptr("union " ^ id.name)
217    | C.TPtr(sp,ty, a) ->
218        Tpointer(convertSpace sp, convertTyp seen ty)
219    | C.TArray(sp, ty, None, a) ->
220        (* Cparser verified that the type ty[] occurs only in
221           contexts that are safe for Clight, so just treat as ty[0]. *)
222        (* warning "array type of unspecified size"; *)
223        Tarray(convertSpace sp, convertTyp seen ty, 0)
224    | C.TArray(sp, ty, Some sz, a) ->
225        Tarray(convertSpace sp, convertTyp seen ty, convertInt sz )
226    | C.TFun(tres, targs, va, a) ->
227        if va then unsupported "variadic function type";
228        if Cutil.is_composite_type env tres then
229          unsupported "return type is a struct or union";
230        Tfunction(begin match targs with
231                  | None -> warning "un-prototyped function type"; []
232                  | Some tl -> convertParams seen tl
233                  end,
234                  convertTyp seen tres)
235    | C.TNamed _ ->
236        assert false
237    | C.TStruct(id, a) ->
238        let flds =
239          try
240            convertFields (id :: seen) (Env.find_struct env id)
241          with Env.Error e ->
242            error (Env.error_message e); [] in
243        Tstruct("struct " ^ id.name, flds)
244    | C.TUnion(id, a) ->
245        let flds =
246          try
247            convertFields (id :: seen) (Env.find_union env id)
248          with Env.Error e ->
249            error (Env.error_message e); [] in
250        Tunion("union " ^ id.name, flds)
251
252  and convertParams seen = function
253    | [] -> []
254    | (id, ty) :: rem ->
255        if Cutil.is_composite_type env ty then
256          unsupported "function parameter of struct or union type";
257        (convertTyp seen ty)::(convertParams seen rem)
258
259  and convertFields seen ci =
260    convertFieldList seen ci.Env.ci_members
261
262  and convertFieldList seen = function
263    | [] -> []
264    | f :: fl ->
265        if f.fld_bitfield <> None then
266          unsupported "bit field in struct or union";
267        (f.fld_name, convertTyp seen f.fld_typ)::(
268              convertFieldList seen fl)
269
270  in convertTyp [] t
271
272let rec convertTypList env = function
273  | [] -> []
274  | t1 :: tl -> (convertTyp env t1 )::( convertTypList env tl)
275
276(** Expressions *)
277
278let ezero = Expr(Econst_int(0), Tint(I32, Signed))
279
280let rec convertExpr env e =
281  let ty = convertTyp env e.etyp in
282  match e.edesc with
283  | C.EConst(C.CInt(i, _, _)) ->
284      Expr(Econst_int( convertInt i), ty)
285  | C.EConst(C.CFloat(f, _, _)) ->
286      Expr(Econst_float f, ty)
287  | C.EConst(C.CStr s) ->
288      Expr(Evar(name_for_string_literal env s), typeStringLiteral s)
289  | C.EConst(C.CWStr s) ->
290      unsupported "wide string literal"; ezero
291  | C.EConst(C.CEnum(id, i)) ->
292      Expr(Econst_int(convertInt i), ty)
293
294  | C.ESizeof ty1 ->
295      Expr(Esizeof(convertTyp env ty1), ty)
296  | C.EVar id ->
297      Expr(Evar(id.name), ty)
298
299  | C.EUnop(C.Oderef, e1) ->
300      Expr(Ederef(convertExpr env e1), ty)
301  | C.EUnop(C.Oaddrof, e1) ->
302      Expr(Eaddrof(convertExpr env e1), ty)
303  | C.EUnop(C.Odot id, e1) ->
304      Expr(Efield(convertExpr env e1, id), ty)
305  | C.EUnop(C.Oarrow id, e1) ->
306      let e1' = convertExpr env e1 in
307      let ty1 =
308        match typeof e1' with
309        | Tpointer (_,t) -> t
310        | _ -> error ("wrong type for ->" ^ id ^ " access"); Tvoid in
311      Expr(Efield(Expr(Ederef(convertExpr env e1), ty1),
312                   id), ty)
313  | C.EUnop(C.Oplus, e1) ->
314      convertExpr env e1
315  | C.EUnop(C.Ominus, e1) ->
316      Expr(Eunop(Oneg, convertExpr env e1), ty)
317  | C.EUnop(C.Olognot, e1) ->
318      Expr(Eunop(Onotbool, convertExpr env e1), ty)
319  | C.EUnop(C.Onot, e1) ->
320      Expr(Eunop(Onotint, convertExpr env e1), ty)
321  | C.EUnop(_, _) ->
322      unsupported "pre/post increment/decrement operator"; ezero
323
324  | C.EBinop(C.Oindex, e1, e2, _) ->
325      Expr(Ederef(Expr(Ebinop(Oadd, convertExpr env e1, convertExpr env e2),
326                       convertTyp env e1.etyp)), ty)
327  | C.EBinop(C.Ologand, e1, e2, _) ->
328      Expr(Eandbool(convertExpr env e1, convertExpr env e2), ty)
329  | C.EBinop(C.Ologor, e1, e2, _) ->
330      Expr(Eorbool(convertExpr env e1, convertExpr env e2), ty)
331  | C.EBinop(op, e1, e2, _) ->
332      let op' =
333        match op with
334        | C.Oadd -> Oadd
335        | C.Osub -> Osub
336        | C.Omul -> Omul
337        | C.Odiv -> Odiv
338        | C.Omod -> Omod
339        | C.Oand -> Oand
340        | C.Oor  -> Oor
341        | C.Oxor -> Oxor
342        | C.Oshl -> Oshl
343        | C.Oshr -> Oshr
344        | C.Oeq  -> Oeq
345        | C.One  -> One
346        | C.Olt  -> Olt
347        | C.Ogt  -> Ogt
348        | C.Ole  -> Ole
349        | C.Oge  -> Oge
350        | C.Ocomma -> unsupported "sequence operator"; Oadd
351        | _ -> unsupported "assignment operator"; Oadd in
352      Expr(Ebinop(op', convertExpr env e1, convertExpr env e2), ty)
353  | C.EConditional(e1, e2, e3) ->
354      Expr(Econdition(convertExpr env e1, convertExpr env e2, convertExpr env e3), ty)
355  | C.ECast(ty1, e1) ->
356      Expr(Ecast(convertTyp env ty1, convertExpr env e1), ty)
357  | C.ECall _ ->
358      unsupported "function call within expression"; ezero
359
360(* Function calls *)
361
362let rec projFunType env ty =
363  match Cutil.unroll env ty with
364  | TFun(res, args, vararg, attr) -> Some(res, vararg)
365  | TPtr(_, ty', attr) -> projFunType env ty'
366  | _ -> None
367
368let convertFuncall env lhs fn args =
369  match projFunType env fn.etyp with
370  | None ->
371      error "wrong type for function part of a call"; Sskip
372  | Some(res, false) ->
373      (* Non-variadic function *)
374      Scall(lhs, convertExpr env fn, List.map (convertExpr env) args)
375  | Some(res, true) ->
376      (* Variadic function: generate a call to a stub function with
377         the appropriate number and types of arguments.  Works only if
378         the function expression e is a global variable. *)
379      let fun_name =
380        match fn with
381        | {edesc = C.EVar id} when !ClightFlags.option_fvararg_calls ->
382            (*warning "emulating call to variadic function"; *)
383            id.name
384        | _ ->
385            unsupported "call to variadic function";
386            "<error>" in
387      let targs = convertTypList env (List.map (fun e -> e.etyp) args) in
388      let tres = convertTyp env res in
389      let (stub_fun_name, stub_fun_typ) =
390        register_stub_function fun_name tres targs in
391      Scall(lhs,
392            Expr(Evar( stub_fun_name), stub_fun_typ),
393            List.map (convertExpr env) args)
394
395(* Handling of volatile *)
396
397let is_volatile_access env e =
398  List.mem C.AVolatile (Cutil.attributes_of_type env e.etyp)
399  && Cutil.is_lvalue env e
400
401let volatile_fun_suffix_type ty =
402  match ty with
403  | Tint(I8, Unsigned) -> ("int8unsigned", ty)
404  | Tint(I8, Signed) -> ("int8signed", ty)
405  | Tint(I16, Unsigned) -> ("int16unsigned", ty)
406  | Tint(I16, Signed) -> ("int16signed", ty)
407  | Tint(I32, _) -> ("int32", Tint(I32, Signed))
408  | Tfloat F32 -> ("float32", ty)
409  | Tfloat F64 -> ("float64", ty)
410  | Tpointer _ | Tarray _ | Tfunction _ | Tcomp_ptr _ ->
411      ("pointer", Tpointer (Any, Tvoid)) (* XXX: what is the pointer is to a different space? *)
412  | _ ->
413      unsupported "operation on volatile struct or union"; ("", Tvoid)
414
415let volatile_read_fun ty =
416  let (suffix, ty') = volatile_fun_suffix_type ty in
417  Expr(Evar( ("__builtin_volatile_read_" ^ suffix)),
418       Tfunction((Tpointer (Any,Tvoid))::[], ty'))
419
420let volatile_write_fun ty =
421  let (suffix, ty') = volatile_fun_suffix_type ty in
422  Expr(Evar( ("__builtin_volatile_write_" ^ suffix)),
423       Tfunction((Tpointer (Any,Tvoid))::(ty'::[]), Tvoid))
424
425(* Toplevel expression, argument of an Sdo *)
426
427let convertTopExpr env e =
428  match e.edesc with
429  | C.EBinop(C.Oassign, lhs, {edesc = C.ECall(fn, args)}, _) ->
430      convertFuncall env (Some (convertExpr env lhs)) fn args
431  | C.EBinop(C.Oassign, lhs, rhs, _) ->
432      if Cutil.is_composite_type env lhs.etyp then
433        unsupported "assignment between structs or between unions";
434      let lhs' = convertExpr env lhs
435      and rhs' = convertExpr env rhs in
436      begin match (is_volatile_access env lhs, is_volatile_access env rhs) with
437      | true, true ->                   (* should not happen *)
438          unsupported "volatile-to-volatile assignment";
439          Sskip
440      | false, true ->                  (* volatile read *)
441          Scall(Some lhs',
442                volatile_read_fun (typeof rhs'),
443                [ Expr (Eaddrof rhs', Tpointer (Any (* XXX ? *), typeof rhs')) ])
444      | true, false ->                  (* volatile write *)
445          Scall(None,
446                volatile_write_fun (typeof lhs'),
447                [ Expr(Eaddrof lhs', Tpointer (Any (* XXX ? *), typeof lhs')); rhs' ])
448      | false, false ->                 (* regular assignment *)
449          Sassign(convertExpr env lhs, convertExpr env rhs)
450      end
451  | C.ECall(fn, args) ->
452      convertFuncall env None fn args
453  | _ ->
454      unsupported "illegal toplevel expression"; Sskip
455
456(* Separate the cases of a switch statement body *)
457
458type switchlabel =
459  | Case of C.exp
460  | Default
461
462type switchbody = 
463  | Label of switchlabel
464  | Stmt of C.stmt
465
466let rec flattenSwitch = function
467  | {sdesc = C.Sseq(s1, s2)} ->
468      flattenSwitch s1 @ flattenSwitch s2
469  | {sdesc = C.Slabeled(C.Scase e, s1)} ->
470      Label(Case e) :: flattenSwitch s1
471  | {sdesc = C.Slabeled(C.Sdefault, s1)} ->
472      Label Default :: flattenSwitch s1
473  | s ->
474      [Stmt s]
475
476let rec groupSwitch = function
477  | [] ->
478      (Cutil.sskip, [])
479  | Label case :: rem ->
480      let (fst, cases) = groupSwitch rem in
481      (Cutil.sskip, (case, fst) :: cases)
482  | Stmt s :: rem ->
483      let (fst, cases) = groupSwitch rem in
484      (Cutil.sseq s.sloc s fst, cases)
485
486(* Statement *)
487
488let rec convertStmt env s =
489  updateLoc s.sloc;
490  match s.sdesc with
491  | C.Sskip ->
492      Sskip
493  | C.Sdo e ->
494      convertTopExpr env e
495  | C.Sseq(s1, s2) ->
496      Ssequence(convertStmt env s1, convertStmt env s2)
497  | C.Sif(e, s1, s2) ->
498      Sifthenelse(convertExpr env e, convertStmt env s1, convertStmt env s2)
499  | C.Swhile(e, s1) ->
500      Swhile(convertExpr env e, convertStmt env s1)
501  | C.Sdowhile(s1, e) ->
502      Sdowhile(convertExpr env e, convertStmt env s1)
503  | C.Sfor(s1, e, s2, s3) ->
504      Sfor(convertStmt env s1, convertExpr env e, convertStmt env s2,
505           convertStmt env s3)
506  | C.Sbreak ->
507      Sbreak
508  | C.Scontinue ->
509      Scontinue
510  | C.Sswitch(e, s1) ->
511      let (init, cases) = groupSwitch (flattenSwitch s1) in
512      if cases = [] then
513        unsupported "ill-formed 'switch' statement";
514      if init.sdesc <> C.Sskip then
515        warning "ignored code at beginning of 'switch'";
516      Sswitch(convertExpr env e, convertSwitch env cases)
517  | C.Slabeled(C.Slabel lbl, s1) ->
518      Slabel( lbl, convertStmt env s1)
519  | C.Slabeled(C.Scase _, _) ->
520      unsupported "'case' outside of 'switch'"; Sskip
521  | C.Slabeled(C.Sdefault, _) ->
522      unsupported "'default' outside of 'switch'"; Sskip
523  | C.Sgoto lbl ->
524      Sgoto( lbl)
525  | C.Sreturn None ->
526      Sreturn None
527  | C.Sreturn(Some e) ->
528      Sreturn(Some(convertExpr env e))
529  | C.Sblock _ ->
530      unsupported "nested blocks"; Sskip
531  | C.Sdecl _ ->
532      unsupported "inner declarations"; Sskip
533
534and convertSwitch env = function
535  | [] ->
536      LSdefault Sskip
537  | [Default, s] ->
538      LSdefault (convertStmt env s)
539  | (Default, s) :: _ ->
540      updateLoc s.sloc;
541      unsupported "'default' case must occur last";
542      LSdefault Sskip
543  | (Case e, s) :: rem ->
544      updateLoc s.sloc;
545      let v =
546        match Ceval.integer_expr env e with
547        | None -> unsupported "'case' label is not a compile-time integer"; 0L
548        | Some v -> v in
549      LScase(convertInt v,
550             convertStmt env s,
551             convertSwitch env rem)
552
553(** Function definitions *)
554
555let convertFundef env fd =
556  if Cutil.is_composite_type env fd.fd_ret then
557    unsupported "function returning a struct or union";
558  let ret =
559    convertTyp env fd.fd_ret in
560  let params =
561    List.map
562      (fun (id, ty) ->
563        if Cutil.is_composite_type env ty then
564          unsupported "function parameter of struct or union type";
565        ( id.name, convertTyp env ty))
566      fd.fd_params in
567  let vars =
568    List.map
569      (fun (sto, id, ty, init) ->
570        if sto = Storage_extern || sto = Storage_static then
571          unsupported "'static' or 'extern' local variable";
572        if init <> None then
573          unsupported "initialized local variable";
574        ( id.name, convertTyp env ty))
575      fd.fd_locals in
576  let body' = convertStmt env fd.fd_body in
577  let id' =  fd.fd_name.name in
578  let decl =
579    (fd.fd_storage, fd.fd_name, Cutil.fundef_typ fd, None) in
580  Hashtbl.add decl_atom id' (env, decl);
581  !define_function_hook id' decl;
582  (id',
583   Internal {fn_return = ret; fn_params = params;
584             fn_vars = vars; fn_body = body'})
585
586(** External function declaration *)
587
588let convertFundecl env (sto, id, ty, optinit) =
589  match convertTyp env ty with
590  | Tfunction(args, res) ->
591      let id' =  id.name in
592      (id', External(id', args, res))
593  | _ ->
594      assert false
595
596(** Initializers *)
597
598let init_data_of_string s =
599  let id = ref [] in
600  let enter_char c =
601    let n = (Char.code c) in
602    id := Init_int8 n :: !id in
603  enter_char '\000';
604  for i = String.length s - 1 downto 0 do enter_char s.[i] done;
605  !id
606
607let convertInit env ty init =
608
609  let k = ref []
610  and pos = ref 0 in
611  let emit size datum =
612    k := datum :: !k;
613    pos := !pos + size in
614  let emit_space size =
615    emit size (Init_space size) in
616  let align size =
617    let n = !pos land (size - 1) in
618    if n > 0 then emit_space (size - n) in
619  let check_align size =
620    assert (!pos land (size - 1) = 0) in
621
622  let rec reduceInitExpr = function
623    | { edesc = C.EVar id; etyp = ty } ->
624        begin match Cutil.unroll env ty with
625        | C.TArray _ | C.TFun _ -> Some id
626        | _ -> None
627        end
628    | {edesc = C.EUnop(C.Oaddrof, {edesc = C.EVar id})} -> Some id
629    | {edesc = C.ECast(ty, e)} -> reduceInitExpr e
630    | _ -> None in
631
632  let rec cvtInit ty = function
633  | Init_single e ->
634      begin match reduceInitExpr e with
635      | Some id ->
636          check_align 4;
637          emit 4 (Init_addrof( id.name, 0))
638      | None ->
639      match Ceval.constant_expr env ty e with
640      | Some(C.CInt(v, ik, _)) ->
641          begin match convertIkind ik with
642          | (_, I8) ->
643              emit 1 (Init_int8(convertInt v))
644          | (_, I16) ->
645              check_align 2;
646              emit 2 (Init_int16(convertInt v))
647          | (_, I32) ->
648              check_align 4;
649              emit 4 (Init_int32(convertInt v))
650          end
651      | Some(C.CFloat(v, fk, _)) ->
652          begin match convertFkind fk with
653          | F32 ->
654              check_align 4;
655              emit 4 (Init_float32 v)
656          | F64 ->
657              check_align 8;
658              emit 8 (Init_float64 v)
659          end
660      | Some(C.CStr s) ->
661          check_align 4;
662          let id = name_for_string_literal env s in
663          emit 4 (Init_addrof(id, 0))
664      | Some(C.CWStr _) ->
665          unsupported "wide character strings"
666      | Some(C.CEnum _) ->
667          error "enum tag after constant folding"
668      | None ->
669          error "initializer is not a compile-time constant"
670      end
671  | Init_array il ->
672      let ty_elt =
673        match Cutil.unroll env ty with
674        | C.TArray(_, t, _, _) -> t
675        | _ -> error "array type expected in initializer"; C.TVoid [] in
676      List.iter (cvtInit ty_elt) il
677  | Init_struct(_, flds) ->
678      cvtPadToSizeof ty (fun () -> List.iter cvtFieldInit flds)
679  | Init_union(_, fld, i) ->
680      cvtPadToSizeof ty (fun () -> cvtFieldInit (fld,i))
681
682  and cvtFieldInit (fld, i) =
683    let ty' = convertTyp env fld.fld_typ in
684    let al = alignof ty' in
685    align al;
686    cvtInit fld.fld_typ i
687
688  and cvtPadToSizeof ty fn =
689    let ty' = convertTyp env ty in
690    let sz = sizeof ty' in
691    let pos0 = !pos in
692    fn();
693    let pos1 = !pos in
694    assert (pos1 <= pos0 + sz);
695    if pos1 < pos0 + sz then emit_space (pos0 + sz - pos1)
696
697  in cvtInit ty init; List.rev !k
698
699(** Global variable *)
700
701let convertGlobvar env space (sto, id, ty, optinit as decl) =
702  let id' =  id.name in
703  let ty' = convertTyp env ty in 
704  let init' =
705    match optinit with
706    | None ->
707        if sto = C.Storage_extern then [] else [Init_space(sizeof ty')]
708    | Some i ->
709        convertInit env ty i in
710  Hashtbl.add decl_atom id' (env, decl);
711  !define_variable_hook id' decl;
712  (((id', init'), convertSpace space), ty')
713
714(** Convert a list of global declarations.
715  Result is a pair [(funs, vars)] where [funs] are
716  the function definitions (internal and external)
717  and [vars] the variable declarations. *)
718
719let rec convertGlobdecls env funs vars gl =
720  match gl with
721  | [] -> (List.rev funs, List.rev vars)
722  | g :: gl' ->
723      updateLoc g.gloc;
724      match g.gdesc with
725      | C.Gdecl(space, ((sto, id, ty, optinit) as d)) ->
726          (* Prototyped functions become external declarations.
727             Variadic functions are skipped.
728             Other types become variable declarations. *)
729          begin match Cutil.unroll env ty with
730          | TFun(_, Some _, false, _) ->
731              convertGlobdecls env (convertFundecl env d :: funs) vars gl'
732          | TFun(_, None, false, _) ->
733              error "function declaration without prototype";
734              convertGlobdecls env funs vars gl'
735          | TFun(_, _, true, _) ->
736              convertGlobdecls env funs vars gl'
737          | _ ->
738              convertGlobdecls env funs (convertGlobvar env space d :: vars) gl'
739          end
740      | C.Gfundef fd ->
741          convertGlobdecls env (convertFundef env fd :: funs) vars gl'
742      | C.Gcompositedecl _ | C.Gcompositedef _
743      | C.Gtypedef _ | C.Genumdef _ ->
744          (* typedefs are unrolled, structs are expanded inline, and
745             enum tags are folded.  So we just skip their declarations. *)
746          convertGlobdecls env funs vars gl'
747      | C.Gpragma s ->
748          if not (!process_pragma_hook s) then
749            warning ("'#pragma " ^ s ^ "' directive ignored");
750          convertGlobdecls env funs vars gl'
751
752(** Build environment of typedefs and structs *)
753
754let rec translEnv env = function
755  | [] -> env
756  | g :: gl ->
757      let env' =
758        match g.gdesc with
759        | C.Gcompositedecl(su, id) ->
760            Env.add_composite env id (Cutil.composite_info_decl env su)
761        | C.Gcompositedef(su, id, fld) ->
762            Env.add_composite env id (Cutil.composite_info_def env su fld)
763        | C.Gtypedef(id, ty) ->
764            Env.add_typedef env id ty
765        | _ ->
766            env in
767      translEnv env' gl
768
769(** Eliminate forward declarations of globals that are defined later. *)
770
771module IdentSet = Set.Make(struct type t = C.ident let compare = compare end)
772
773let cleanupGlobals p =
774 
775  let rec clean defs accu = function
776    | [] -> accu
777    | g :: gl ->
778        updateLoc g.gloc;
779        match g.gdesc with
780        | C.Gdecl(_, (sto, id, ty, None)) ->
781            if IdentSet.mem id defs
782            then clean defs accu gl
783            else clean (IdentSet.add id defs) (g :: accu) gl
784        | C.Gdecl(_, (_, id, ty, _)) ->
785            if IdentSet.mem id defs then
786              error ("multiple definitions of " ^ id.name);
787            clean (IdentSet.add id defs) (g :: accu) gl
788        | C.Gfundef fd ->
789            if IdentSet.mem fd.fd_name defs then
790              error ("multiple definitions of " ^ fd.fd_name.name);
791            clean (IdentSet.add fd.fd_name defs) (g :: accu) gl
792        | _ ->
793            clean defs (g :: accu) gl
794
795  in clean IdentSet.empty [] (List.rev p)
796
797(** Convert a [C.program] into a [Csyntax.program] *)
798
799let convertProgram p =
800  numErrors := 0;
801  stringNum := 0;
802  Hashtbl.clear decl_atom;
803  Hashtbl.clear stringTable;
804  Hashtbl.clear stub_function_table;
805  (* Hack: externals are problematic for Cerco. TODO *)
806  let p = (* Builtins.declarations() @ *) p in
807  try
808    let (funs1, vars1) =
809      convertGlobdecls (translEnv Env.empty p) [] [] (cleanupGlobals p) in
810    let funs2 = declare_stub_functions funs1 in
811    let main = if List.mem_assoc "main" funs2 then Some "main" else None in
812    let vars2 = globals_for_strings vars1 in
813    if !numErrors > 0
814    then None
815    else Some { prog_funct = funs2;
816                prog_vars = vars2;
817                prog_main = main }
818  with Env.Error msg ->
819    error (Env.error_message msg); None
820
821(** ** Extracting information about global variables from their atom *)
822
823let rec type_is_readonly env t =
824  let a = Cutil.attributes_of_type env t in
825  if List.mem C.AVolatile a then false else
826  if List.mem C.AConst a then true else
827  match Cutil.unroll env t with
828  | C.TArray(_, t', _, _) -> type_is_readonly env t'
829  | _ -> false
830
831let atom_is_static a =
832  try
833    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
834    sto = C.Storage_static
835  with Not_found ->
836    false
837
838let atom_is_readonly a =
839  try
840    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
841    type_is_readonly env ty
842  with Not_found ->
843    false
844
845let atom_sizeof a =
846  try
847    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
848    Cutil.sizeof env ty
849  with Not_found ->
850    None
851
852let atom_alignof a =
853  try
854    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
855    Cutil.alignof env ty
856  with Not_found ->
857    None
858
859(** ** The builtin environment *)
860
861open Builtins
862
863let builtins_generic = {
864  typedefs = [
865    (* keeps GCC-specific headers happy, harmless for others *)
866    "__builtin_va_list", C.TPtr(C.Any, C.TVoid [], [])
867  ];
868  functions = [
869    (* The volatile read/volatile write functions *)
870    "__builtin_volatile_read_int8unsigned",
871        (TInt(IUChar, []), [TPtr(C.Any, TVoid [], [])], false);
872    "__builtin_volatile_read_int8signed",
873        (TInt(ISChar, []), [TPtr(C.Any, TVoid [], [])], false);
874    "__builtin_volatile_read_int16unsigned",
875        (TInt(IUShort, []), [TPtr(C.Any, TVoid [], [])], false);
876    "__builtin_volatile_read_int16signed",
877        (TInt(IShort, []), [TPtr(C.Any, TVoid [], [])], false);
878    "__builtin_volatile_read_int32",
879        (TInt(IInt, []), [TPtr(C.Any, TVoid [], [])], false);
880    "__builtin_volatile_read_float32",
881        (TFloat(FFloat, []), [TPtr(C.Any, TVoid [], [])], false);
882    "__builtin_volatile_read_float64",
883         (TFloat(FDouble, []), [TPtr(C.Any, TVoid [], [])], false);
884    "__builtin_volatile_read_pointer",
885         (TPtr(C.Any, TVoid [], []), [TPtr(C.Any, TVoid [], [])], false);
886    "__builtin_volatile_write_int8unsigned",
887        (TVoid [], [TPtr(C.Any, TVoid [], []); TInt(IUChar, [])], false);
888    "__builtin_volatile_write_int8signed",
889        (TVoid [], [TPtr(C.Any, TVoid [], []); TInt(ISChar, [])], false);
890    "__builtin_volatile_write_int16unsigned",
891        (TVoid [], [TPtr(C.Any, TVoid [], []); TInt(IUShort, [])], false);
892    "__builtin_volatile_write_int16signed",
893        (TVoid [], [TPtr(C.Any, TVoid [], []); TInt(IShort, [])], false);
894    "__builtin_volatile_write_int32",
895        (TVoid [], [TPtr(C.Any, TVoid [], []); TInt(IInt, [])], false);
896    "__builtin_volatile_write_float32",
897        (TVoid [], [TPtr(C.Any, TVoid [], []); TFloat(FFloat, [])], false);
898    "__builtin_volatile_write_float64",
899         (TVoid [], [TPtr(C.Any, TVoid [], []); TFloat(FDouble, [])], false);
900    "__builtin_volatile_write_pointer",
901         (TVoid [], [TPtr(C.Any, TVoid [], []); TPtr(C.Any, TVoid [], [])], false)
902  ]
903}
904
905(* Add processor-dependent builtins *)
906
907let builtins =
908  { typedefs = builtins_generic.typedefs @ CBuiltins.builtins.typedefs; 
909    functions = builtins_generic.functions @ CBuiltins.builtins.functions
910  }
Note: See TracBrowser for help on using the repository browser.