source: Deliverables/D2.2/8051/src/common/AST.mli @ 640

(** This file defines some common structures of several languages. *)

type ident = string (* identifiers for variable and function names *)

type immediate = int (* immediate values for assembler constants and offsets *)


(* Comparison between integers or floats *)

type cmp = Cmp_eq | Cmp_ne | Cmp_gt | Cmp_ge | Cmp_lt | Cmp_le

(* Constants in high level languages *)

type cst =
  | Cst_int of int               (* integer constant *)
  | Cst_float of float           (* float constant *)
  | Cst_addrsymbol of ident      (* address of a global symbol *)
  | Cst_stackoffset of immediate (* offset in the stack *)

(* Unary operations *)

type op1 =  
  | Op_cast8unsigned  (**r 8-bit zero extension  *)
  | Op_cast8signed    (**r 8-bit sign extension  *)
  | Op_cast16unsigned (**r 16-bit zero extension  *)
  | Op_cast16signed   (**r 16-bit sign extension *)
  | Op_negint         (**r integer opposite *)
  | Op_notbool        (**r boolean negation  *)
  | Op_notint         (**r bitwise complement  *)
  | Op_negf           (**r float opposite *)
  | Op_absf           (**r float absolute value *)
  | Op_singleoffloat  (**r float truncation *)
  | Op_intoffloat     (**r signed integer to float *)
  | Op_intuoffloat    (**r unsigned integer to float *)
  | Op_floatofint     (**r float to signed integer *)
  | Op_floatofintu    (**r float to unsigned integer *)
  | Op_id             (**r identity *)
  | Op_ptrofint       (**r int to pointer *)
  | Op_intofptr       (**r pointer to int *)

(* Binary operations *)

type op2 =
  | Op_add         (**r integer addition *)
  | Op_sub         (**r integer subtraction *)
  | Op_mul         (**r integer multiplication *)
  | Op_div         (**r integer signed division *)
  | Op_divu        (**r integer unsigned division *)
  | Op_mod         (**r integer signed modulus *)
  | Op_modu        (**r integer unsigned modulus *)
  | Op_and         (**r bitwise ``and'' *)
  | Op_or          (**r bitwise ``or'' *)
  | Op_xor         (**r bitwise ``xor'' *)
  | Op_shl         (**r left shift *)
  | Op_shr         (**r right signed shift *)
  | Op_shru        (**r right unsigned shift *)
  | Op_addf        (**r float addition *)
  | Op_subf        (**r float subtraction *)
  | Op_mulf        (**r float multiplication *)
  | Op_divf        (**r float division *)
  | Op_cmp of cmp  (**r integer signed comparison *)
  | Op_cmpu of cmp (**r integer unsigned comparison *)
  | Op_cmpf of cmp (**r float comparison *)
  | Op_addp        (**r addition for a pointer and an integer *)
  | Op_subp        (**r substraction for a pointer and a integer *)
  | Op_cmpp of cmp (**r pointer comparaison *)

(* Datas are used to initialize the value of variables *)

type data = 
  | Data_reserve of int (* only reserve some space *)
  | Data_int8 of int
  | Data_int16 of int
  | Data_int32 of int
  | Data_float32 of float
  | Data_float64 of float

type data_size = Byte | HalfWord | Word

(* Types and Signatures *)

type sig_type = Sig_int | Sig_float | Sig_ptr

type type_return = Type_ret of sig_type | Type_void

type signature = { args: sig_type list ; res: type_return }

(* External functions. *)

type external_function = { ef_tag: ident ; ef_sig: signature }


(* Traces returned by interpreters: result and cost labels are observed. The
   result is interpreted as an 8 bits integer for coherence between
   languages. *)

type trace = IntValue.int8 * CostLabel.t list