source: Deliverables/D2.2/8051/src/cminor/cminorInterpret.ml @ 1542

Last change on this file since 1542 was 1542, checked in by tranquil, 9 years ago

merge of indexed labels branch

File size: 14.5 KB
Line 
1open AST
2open Cminor
3
4module Mem = Driver.CminorMemory
5module Val = Mem.Value
6module LocalEnv = Map.Make(String)
7type local_env = Val.t LocalEnv.t
8type memory = Cminor.function_def Mem.memory
9
10
11let error_prefix = "Cminor interpret"
12let error s = Error.global_error error_prefix s
13let warning s = Error.warning error_prefix s
14let error_float () = error "float not supported."
15
16
17(* Helpers *)
18
19let value_of_address = List.hd
20let address_of_value v = [v]
21
22
23(* State of execution *)
24
25type indexing = CostLabel.const_indexing
26
27type continuation = 
28    Ct_stop
29  | Ct_cont of statement*continuation
30(*  | Ct_endblock of continuation *)
31  | Ct_returnto of
32      ident option*internal_function*Val.address*local_env*continuation
33
34type state = 
35    State_regular of
36      internal_function*statement*continuation*Val.address*local_env*
37                         (function_def Mem.memory)*indexing list
38  | State_call of function_def*Val.t list*continuation*
39             (function_def Mem.memory)*indexing list
40  | State_return of Val.t*continuation*(function_def Mem.memory)*indexing list
41
42let string_of_local_env lenv =
43  let f x v s = s ^ x ^ " = " ^ (Val.to_string v) ^ "  " in
44  LocalEnv.fold f lenv ""
45
46let string_of_expr = CminorPrinter.print_expression
47
48let string_of_args args =
49  "(" ^ (MiscPottier.string_of_list ", " string_of_expr args) ^ ")"
50
51let rec string_of_statement = function
52  | St_skip -> "skip"
53  | St_assign (x, e) -> x ^ " = " ^ (string_of_expr e)
54  | St_store (q, e1, e2) ->
55    Printf.sprintf "%s[%s] = %s"
56      (Memory.string_of_quantity q) (string_of_expr e1) (string_of_expr e2)
57  | St_call (None, f, args, _)
58  | St_tailcall (f, args, _) -> (string_of_expr f) ^ (string_of_args args)
59  | St_call (Some x, f, args, _) ->
60    x ^ " = " ^ (string_of_expr f) ^ (string_of_args args)
61  | St_seq _ -> "sequence"
62  | St_ifthenelse (e, _, _) -> "if (" ^ (string_of_expr e) ^ ")"
63(*  | St_loop _ -> "loop"
64  | St_block _ -> "block"
65  | St_exit n -> "exit " ^ (string_of_int n) *)
66  | St_switch (e, _, _) -> "switch (" ^ (string_of_expr e) ^ ")"
67  | St_return None -> "return"
68  | St_return (Some e) -> "return (" ^ (string_of_expr e) ^ ")"
69  | St_label (lbl, _) -> "label " ^ lbl
70  | St_goto lbl -> "goto " ^ lbl
71  | St_cost (lbl, _) ->
72    let lbl = CostLabel.string_of_cost_label lbl in
73    "cost " ^ lbl
74  | St_ind_0 (i, _) -> "reset " ^ string_of_int i ^ " to 0"
75  | St_ind_inc (i, _) -> "post-increment " ^ string_of_int i
76
77let print_state = function
78  | State_regular (_, stmt, _, sp, lenv, mem, i) ->
79    Printf.printf "Local environment:\n%s\n\nMemory:%s\nStack pointer: %s\nIndexing:"
80      (string_of_local_env lenv)
81      (Mem.to_string mem)
82      (Val.to_string (value_of_address sp));
83    let ind = CostLabel.curr_const_ind i in
84    CostLabel.const_ind_iter (fun a -> Printf.printf "%d, " a) ind;
85    Printf.printf "\nRegular state: %s\n\n%!"
86      (string_of_statement stmt)
87  | State_call (_, args, _, mem,_) ->
88    Printf.printf "Memory:%s\nCall state\n\nArguments:\n%s\n\n%!"
89      (Mem.to_string mem)
90      (MiscPottier.string_of_list " " Val.to_string args)
91  | State_return (v, _, mem,_) ->
92    Printf.printf "Memory:%s\nReturn state: %s\n\n%!"
93      (Mem.to_string mem)
94      (Val.to_string v)
95
96
97(* Global and local environment management *)
98
99let init_local_env args params vars =
100  let f_param lenv (x, _) v = LocalEnv.add x v lenv in
101  let f_var lenv (x, _) = LocalEnv.add x Val.undef lenv in
102  let lenv = List.fold_left2 f_param LocalEnv.empty params args in
103  List.fold_left f_var lenv vars
104
105let find_fundef f mem =
106  let addr = Mem.find_global mem f in
107  Mem.find_fun_def mem addr
108
109
110(* Expression evaluation *)
111
112module Eval_op (M : Memory.S) = struct
113
114  let concrete_stacksize = M.concrete_size
115
116  let ext_fun_of_sign = function
117    | AST.Signed -> M.Value.sign_ext
118    | AST.Unsigned -> M.Value.zero_ext
119
120  let cast_to_std t v = match t with
121    | AST.Sig_int (size, sign) -> (ext_fun_of_sign sign) v size M.int_size
122    | AST.Sig_float _ -> error_float ()
123    | AST.Sig_offset | AST.Sig_ptr -> v
124
125  let cast_from_std t v = match t with
126    | AST.Sig_int (size, _) -> (ext_fun_of_sign AST.Unsigned) v M.int_size size
127    | AST.Sig_float _ -> error_float ()
128    | AST.Sig_offset | AST.Sig_ptr -> v
129
130  let cst mem sp t = function
131    | Cst_int i -> cast_to_std t (M.Value.of_int i)
132    | Cst_float _ -> error_float ()
133    | Cst_addrsymbol id when M.mem_global mem id ->
134      value_of_address (M.find_global mem id)
135    | Cst_addrsymbol id -> error ("unknown global variable " ^ id ^ ".")
136    | Cst_stack -> value_of_address sp
137    | Cst_offset off -> M.Value.of_int (M.concrete_offset off)
138    | Cst_sizeof t' -> cast_to_std t (M.Value.of_int (M.concrete_size t'))
139
140  let fun_of_op1 = function
141    | Op_cast ((from_size, from_sign), to_size) ->
142      (fun v -> (ext_fun_of_sign from_sign) v from_size to_size)
143    | Op_negint -> M.Value.negint
144    | Op_notbool -> M.Value.notbool
145    | Op_notint -> M.Value.negint
146    | Op_id -> (fun v -> v)
147    | Op_ptrofint
148    | Op_intofptr ->
149      error "conversion between integers and pointers not supported yet."
150
151  let op1 ret_type t op v =
152    cast_from_std ret_type ((fun_of_op1 op) (cast_to_std t v))
153
154  let fun_of_op2 = function
155    | Op_add | Op_addp -> M.Value.add
156    | Op_sub | Op_subp | Op_subpp -> M.Value.sub
157    | Op_mul -> M.Value.mul
158    | Op_div -> M.Value.div
159    | Op_divu -> M.Value.divu
160    | Op_mod -> M.Value.modulo
161    | Op_modu -> M.Value.modulou
162    | Op_and -> M.Value.and_op
163    | Op_or -> M.Value.or_op
164    | Op_xor -> M.Value.xor
165    | Op_shl -> M.Value.shl
166    | Op_shr -> M.Value.shr
167    | Op_shru -> M.Value.shru
168    | Op_cmp Cmp_eq | Op_cmpp Cmp_eq -> M.Value.cmp_eq
169    | Op_cmp Cmp_ne | Op_cmpp Cmp_ne -> M.Value.cmp_ne
170    | Op_cmp Cmp_gt | Op_cmpp Cmp_gt -> M.Value.cmp_gt
171    | Op_cmp Cmp_ge | Op_cmpp Cmp_ge -> M.Value.cmp_ge
172    | Op_cmp Cmp_lt | Op_cmpp Cmp_lt -> M.Value.cmp_lt
173    | Op_cmp Cmp_le | Op_cmpp Cmp_le -> M.Value.cmp_le
174    | Op_cmpu Cmp_eq -> M.Value.cmp_eq_u
175    | Op_cmpu Cmp_ne -> M.Value.cmp_ne_u
176    | Op_cmpu Cmp_gt -> M.Value.cmp_gt_u
177    | Op_cmpu Cmp_ge -> M.Value.cmp_ge_u
178    | Op_cmpu Cmp_lt -> M.Value.cmp_lt_u
179    | Op_cmpu Cmp_le -> M.Value.cmp_le_u
180
181  let op2 ret_type t1 t2 op2 v1 v2 =
182    let v1 = cast_to_std t1 v1 in
183    let v2 = cast_to_std t2 v2 in
184    cast_from_std ret_type ((fun_of_op2 op2) v1 v2)
185end
186
187module Eval = Eval_op (Mem)
188
189let concrete_stacksize = Eval.concrete_stacksize
190let eval_constant = Eval.cst
191let eval_unop = Eval.op1
192let eval_binop = Eval.op2
193
194let type_of_expr (Cminor.Expr (_, t)) = t
195
196let rec eval_expression stack local_env memory (Cminor.Expr (ed, t)) =
197  match ed with
198    | Id x when LocalEnv.mem x local_env -> (LocalEnv.find x local_env,[])
199    | Id x -> error ("unknown local variable " ^ x ^ ".")
200    | Cst(c) -> (eval_constant memory stack t c,[])
201    | Op1(op,arg) -> 
202      let (v,l) = eval_expression stack local_env memory arg in
203      (eval_unop t (type_of_expr arg) op v,l)
204    | Op2(op, arg1, arg2) -> 
205      let (v1,l1) = eval_expression stack local_env memory arg1 in
206      let (v2,l2) = eval_expression stack local_env memory arg2 in
207      (eval_binop t (type_of_expr arg1) (type_of_expr arg2) op v1 v2,l1@l2) 
208    | Mem(q,a) -> 
209      let (v,l) = eval_expression stack local_env memory a in 
210      (Mem.loadq memory q (address_of_value v),l)
211    | Cond(a1,a2,a3) ->
212      let (v1,l1) = eval_expression stack local_env memory a1 in
213      if Val.is_true v1 then
214        let (v2,l2) = eval_expression stack local_env memory a2 in
215        (v2,l1@l2)
216      else
217        if Val.is_false v1 then
218          let (v3,l3) = eval_expression stack local_env memory a3 in
219          (v3,l1@l3)
220        else error "undefined conditional value."
221    | Exp_cost(lbl,e) -> 
222      let (v,l) = eval_expression stack local_env memory e in
223      (v,l@[lbl])
224
225let eval_exprlist sp lenv mem es =
226  let f (vs, cost_lbls) e =
227    let (v, cost_lbls') = eval_expression sp lenv mem e in
228    (vs @ [v], cost_lbls @ cost_lbls') in
229  List.fold_left f ([], []) es
230
231(* State transition *)
232
233let rec callcont = function
234  | Ct_cont(_,k) (*| Ct_endblock k *) -> callcont k
235  | (Ct_stop | Ct_returnto _) as k -> k
236
237let findlabel lbl st k = 
238  let rec fdlbl k = function
239    St_skip                     -> None
240  | St_assign(_,_)              -> None
241  | St_store(_,_,_)             -> None
242  | St_call(_,_,_,_)            -> None
243  | St_tailcall(_,_,_)          -> None 
244  | St_seq(s1,s2)               -> 
245      (match fdlbl (Ct_cont(s2,k)) s1 with
246           None -> fdlbl k s2
247         | Some(v) -> Some(v)
248      )
249  | St_ifthenelse(_,s1,s2)      ->
250      (match fdlbl k s1 with
251           None -> fdlbl k s2
252         | Some(v) -> Some(v)
253      )
254(*  | St_loop(s)                  -> fdlbl (Ct_cont(St_loop(s),k)) s
255  | St_block(s)                 -> fdlbl (Ct_endblock(k)) s
256  | St_exit(_)                  -> None *)
257  | St_switch(_,_,_)            -> None
258  | St_return(_)                -> None
259  | St_label(l,s) when l = lbl  -> Some((s,k))
260  | St_goto(_)                  -> None
261  | St_cost(_,s)  | St_label(_,s)
262  | St_ind_0(_,s) | St_ind_inc(_,s) -> fdlbl k s
263  in match fdlbl k st with
264      None -> assert false (*Wrong label*)
265    | Some(v) -> v
266
267
268let call_state sigma e m i f params cont =
269  let (addr,l1) = eval_expression sigma e m f in
270  let fun_def = Mem.find_fun_def m (address_of_value addr) in
271  let (args,l2) = eval_exprlist sigma e m params in
272  (State_call(fun_def,args,cont,m,i),l1@l2)
273
274let eval_stmt f k sigma e m i s = match s, k with
275  | St_skip,Ct_cont(s,k) -> (State_regular(f, s, k, sigma, e, m, i),[])
276(*  | St_skip,Ct_endblock(k) -> (State_regular(f, St_skip, k, sigma, e, m, i),[]) *)
277  | St_skip, (Ct_returnto _ as k) ->
278    (State_return (Val.undef,k,Mem.free m sigma,i),[])
279  | St_skip,Ct_stop -> 
280    (State_return (Val.undef,Ct_stop,Mem.free m sigma,i),[])
281  | St_assign(x,exp),_ -> 
282    let (v,l) = eval_expression sigma e m exp in
283    let e = LocalEnv.add x v e in
284    (State_regular(f, St_skip, k, sigma, e, m, i),l)
285  | St_store(q,a1,a2),_ ->
286    let (v1,l1) = eval_expression sigma e m a1 in
287    let (v2,l2) = eval_expression sigma e m a2 in
288    let m = Mem.storeq m q (address_of_value v1) v2 in
289    (State_regular(f, St_skip, k, sigma, e, m, i),l1@l2)
290  | St_call(xopt,f',params,_),_ ->
291    call_state sigma e m i f' params (Ct_returnto(xopt,f,sigma,e,k))
292  | St_tailcall(f',params,_),_ -> 
293    call_state sigma e m i f' params (callcont k)
294  | St_seq(s1,s2),_ -> (State_regular(f, s1, Ct_cont(s2, k), sigma, e, m, i),[])
295  | St_ifthenelse(exp,s1,s2),_ ->
296    let (v,l) = eval_expression sigma e m exp in
297    let next_stmt =
298      if Val.is_true v then s1
299      else
300        if Val.is_false v then s2
301        else error "undefined conditional value." in
302      (State_regular(f,next_stmt,k,sigma,e,m,i),l)
303(*  | St_loop(s),_ -> (State_regular(f,s,Ct_cont((St_loop s),k),sigma,e,m,i),[])
304  | St_block(s),_ -> (State_regular(f,s,(Ct_endblock k),sigma,e,m,i),[])
305  | St_exit(n),Ct_cont(s,k) -> (State_regular(f,(St_exit n),k,sigma,e,m,i),[])
306  | St_exit(0),Ct_endblock(k) -> (State_regular(f,St_skip,k,sigma,e,m,i),[])
307  | St_exit(n),Ct_endblock(k) ->
308    (State_regular(f,(St_exit (n-1)),k,sigma,e,m,i),[]) *)
309  | St_label(_,s),_ -> (State_regular(f,s,k,sigma,e,m,i),[])
310  | St_goto(lbl),_ ->
311    let (s2,k2) = findlabel lbl f.f_body (callcont k) in
312    (State_regular(f,s2,k2,sigma,e,m,i),[])
313  | St_switch(exp,lst,def),_ ->
314    let (v,l) = eval_expression sigma e m exp in
315    if Val.is_int v then
316      try
317        let v = Val.to_int v in
318        let lbl =
319          try
320            List.assoc v lst
321          with
322            | Not_found -> def in
323        let (s',k') = findlabel lbl f.f_body (callcont k) in
324        (State_regular(f, s', k', sigma, e, m, i),l)
325      with _ -> error "int value too big."
326    else error "undefined switch value."
327  | St_return(None),_ ->
328    (State_return (Val.undef,callcont k,Mem.free m sigma,i),[])
329  | St_return(Some(a)),_ ->
330      let (v,l) = eval_expression sigma e m a in
331      (State_return (v,callcont k,Mem.free m sigma,i),l)
332  | St_cost(lbl,s),_ ->
333    (* applying current indexing on label *)
334    let lbl = CostLabel.ev_indexing (CostLabel.curr_const_ind i) lbl in
335    (State_regular(f,s,k,sigma,e,m,i),[lbl])
336  | St_ind_0(ind,s),_ ->
337    CostLabel.enter_loop i ind;
338    (State_regular(f,s,k,sigma,e,m,i), [])
339  | St_ind_inc(ind,s),_ ->
340    CostLabel.continue_loop i ind;
341    (State_regular(f,s,k,sigma,e,m,i), [])
342(*  | _ -> error "state malformation." *)
343
344
345module InterpretExternal = Primitive.Interpret (Mem)
346
347let interpret_external k mem i f args =
348  let (mem', v) = match InterpretExternal.t mem f args with
349    | (mem', InterpretExternal.V vs) ->
350      let v = if List.length vs = 0 then Val.undef else List.hd vs in
351      (mem', v)
352    | (mem', InterpretExternal.A addr) -> (mem', value_of_address addr) in
353  State_return (v, k, mem', i)
354
355let step_call vargs k m i = function
356  | F_int f ->
357    let (m, sp) = Mem.alloc m (concrete_stacksize f.f_stacksize) in
358    let lenv = init_local_env vargs f.f_params f.f_vars in
359    let i = CostLabel.new_const_ind i in 
360    State_regular(f,f.f_body,k,sp,lenv,m,i)
361  | F_ext f -> interpret_external k m i f.ef_tag vargs
362
363let step = function
364  | State_regular(f,stmt,k,sp,e,m,i) -> eval_stmt f k sp e m i stmt
365  | State_call(fun_def,vargs,k,m,i) -> (step_call vargs k m i fun_def,[])
366  | State_return(v,Ct_returnto(None,f,sigma,e,k),m,i) ->
367    let i = CostLabel.forget_const_ind i in
368    (State_regular(f,St_skip,k,sigma,e,m,i),[])
369  | State_return(v,Ct_returnto(Some x,f,sigma,e,k),m,i) ->
370    let e = LocalEnv.add x v e in
371    let i = CostLabel.forget_const_ind i in
372    (State_regular(f,St_skip,k,sigma,e,m,i),[])
373  | _ -> error "state malformation."
374
375
376let init_mem prog =
377  let f_var mem (x, size, init_datas) = Mem.add_var mem x size init_datas in
378  let mem = List.fold_left f_var Mem.empty prog.vars in
379  let f_fun_def mem (f, def) = Mem.add_fun_def mem f def in
380  List.fold_left f_fun_def mem prog.functs
381
382let compute_result v =
383  if Val.is_int v then IntValue.Int32.cast (Val.to_int_repr v)
384  else IntValue.Int32.zero
385
386let rec exec debug trace (state, l) =
387  let cost_labels = l @ trace in
388  let print_and_return_result res =
389    if debug then Printf.printf "Result = %s\n%!"
390      (IntValue.Int32.to_string res) ;
391    (res, List.rev cost_labels) in
392  if debug then print_state state ;
393  match state with
394    | State_return(v,Ct_stop,_,_) -> (* Explicit return in main *)
395      print_and_return_result (compute_result v)
396    | State_regular(_,St_skip,Ct_stop,_,_,_,_) -> (* Implicit return in main *)
397      print_and_return_result IntValue.Int32.zero
398    | state -> exec debug cost_labels (step state)
399
400let interpret debug prog =
401  Printf.printf "*** Cminor interpret ***\n%!" ;
402  match prog.main with
403    | None -> (IntValue.Int32.zero, [])
404    | Some main ->
405      let mem = init_mem prog in
406      let main = find_fundef main mem in
407      let first_state = (State_call (main,[],Ct_stop,mem,[]),[]) in
408      exec debug [] first_state
Note: See TracBrowser for help on using the repository browser.