source: Deliverables/D2.2/8051/src/checker.ml @ 2169

let same_traces (traces : ((Languages.ast * AST.trace) list)) =
  let compare_trace trace1 trace2 =
    let occs_trace1 = Misc.ListExt.multi_set_of_list trace1
    and occs_trace2 = Misc.ListExt.multi_set_of_list trace2 in
    Misc.ListExt.assoc_diff occs_trace1 occs_trace2
  in
  let check_trace (_, (res1, trace1)) (_, (res2, trace2)) =
    IntValue.Int32.eq res1 res2 &&
    compare_trace trace1 trace2 = []
  in
  let print_trace lang1 lang2 ds = 
    let string_of_value = function
      | None -> "is not present"
      | Some v -> Printf.sprintf "appears %d times" v
    in 
    let sentence (k, (v1, v2)) =
      let k = CostLabel.string_of_cost_label ~pretty:true k in
      Printf.sprintf "  Label %s %s in language `%s' \
                        whereas it %s in language `%s'."
        k (string_of_value v1) lang1 (string_of_value v2) lang2
    in
    String.concat "\n" (List.map sentence ds) 
  in            
  match Misc.ListExt.transitive_forall2 check_trace traces with
    | None -> ()
    | Some ((ast1, (res1, trace1)), (ast2, (res2, trace2))) ->
      let lang1 = Languages.to_string (Languages.language_of_ast ast1)
      and lang2 = Languages.to_string (Languages.language_of_ast ast2) in
      let diff = compare_trace trace1 trace2 in
      Error.global_error "during trace comparison"
        (Printf.sprintf "%s%s"
           (if res1 != res2 then
               Printf.sprintf
                 "The results of two intermediate programs differ:\n
                  in %s it was %d, in %s it was %d\n"
                 lang1
                 (IntValue.Int32.to_int res1)
                 lang2
                 (IntValue.Int32.to_int res2) else "")
           (Printf.sprintf "The traces of the two intermediate programs:\n%s"
           (print_trace lang1 lang2 diff)))