source: Deliverables/D2.2/8051/src/acc.ml @ 640

open Options

(** Parse the command line. *)
let input_files = OptionsParsing.results ()

(** For each input file of the source language: 

    1. Parse.

    2. Labelize.

    3. Compile to the target language. 
       (And keep track of annotations if required). 
  
    4. Annotate the input program with collected costs. 

    5. Save the annotated input program.

    Optionnally, we can interpret the intermediate programs
    if {!Options.interpretation_requested}. 
*)
let process filename = 
  let _ = Printf.eprintf "Processing %s.\n%!" filename in
  let src_language    = Options.get_source_language () in
  let tgt_language    = Options.get_target_language () in
  let input_ast       = Languages.parse src_language filename in 
  let input_ast       = Languages.labelize input_ast in
  let (exact_output, output_filename) = match Options.get_output_files () with
    | None -> (false, filename)
    | Some filename' -> (true, filename') in
  let save = Languages.save exact_output output_filename in
  let target_asts =
    (** If debugging is enabled, the compilation function returns all
        the intermediate programs. *)
    Languages.compile (Options.is_debug_enabled ()) 
      src_language tgt_language input_ast
  in
  let final_ast, intermediate_asts = Misc.ListExt.cut_last target_asts in
    save final_ast;
    (if Options.annotation_requested () then
       let (annotated_input_ast, cost_id, cost_incr) =
         Languages.annotate input_ast final_ast in
       save annotated_input_ast;
       Languages.save_cost output_filename cost_id cost_incr);
    (if Options.is_debug_enabled () then 
      List.iter save intermediate_asts);
    if Options.interpretation_requested () || Options.is_debug_enabled () then
      begin
        let asts = input_ast :: target_asts in
        let print_result = Options.is_print_result_enabled () in
        let label_traces = List.map (Languages.interpret print_result) asts in
        Printf.eprintf "Checking execution traces...%!";
        Checker.same_traces (List.combine asts label_traces);
        Printf.eprintf "OK.\n%!";
      end

let _ =
  if Options.is_dev_test_enabled () then Dev_test.do_dev_test input_files
  else List.iter process input_files