source: Deliverables/D2.2/8051/src/RTLabs/RTLabsPrinter.ml @ 1580

let n_spaces n = String.make n ' '


let rec print_size = function
  | AST.SQ q -> Memory.string_of_quantity q
  | AST.SProd l -> "struct {" ^ (print_size_list l) ^ "}"
  | AST.SSum l -> "union {" ^ (print_size_list l) ^ "}"
  | AST.SArray (i, se) ->
    (print_size se) ^ "[" ^ (string_of_int i) ^ "]"
and print_size_list l =
  MiscPottier.string_of_list ", " print_size l

let print_global n (x, size) =
  Printf.sprintf "%s\"%s\" { %s }" (n_spaces n) x (print_size size)

let print_globals n globs =
  Printf.sprintf "%sglobals:\n%s"
    (n_spaces n)
    (List.fold_left (fun s g -> s ^ (print_global (n+2) g) ^ "\n") "" globs)


let print_reg = Register.print

let print_oreg = function
  | None -> "_"
  | Some r -> print_reg r

let print_decl (r, t) =
  (Primitive.print_type t) ^ " " ^ (Register.print r)

let print_result = function
  | None -> "_"
  | Some (r, t) -> (Primitive.print_type t) ^ " " ^ (Register.print r)

let print_params r =
  Printf.sprintf "(%s)" (MiscPottier.string_of_list ", " print_decl r)

let print_locals r =
  Printf.sprintf "%s" (MiscPottier.string_of_list ", " print_decl r)


let print_cmp = function
  | AST.Cmp_eq -> "="
  | AST.Cmp_ne -> "!="
  | AST.Cmp_gt -> ">"
  | AST.Cmp_ge -> ">="
  | AST.Cmp_lt -> "<"
  | AST.Cmp_le -> "<="

let rec print_size = function
  | AST.SQ q -> Memory.string_of_quantity q
  | AST.SProd l -> "struct {" ^ (print_size_list l) ^ "}"
  | AST.SSum l -> "union {" ^ (print_size_list l) ^ "}"
  | AST.SArray (i, se) ->
    (print_size se) ^ "[" ^ (string_of_int i) ^ "]"
and print_size_list l =
  MiscPottier.string_of_list ", " print_size l

let print_stacksize = print_size

let print_offset (size, depth) =
  (print_size size) ^ ", " ^ (string_of_int depth)

let print_sizeof = print_size

let print_cst = function
  | AST.Cst_int i -> Printf.sprintf "imm_int %d" i
  | AST.Cst_float f -> Printf.sprintf "imm_float %f" f
  | AST.Cst_addrsymbol id -> Printf.sprintf "imm_addr \"%s\"" id
  | AST.Cst_stack -> "imm_addr STACK"
  | AST.Cst_offset off -> Printf.sprintf "imm_offset { %s }" (print_offset off)
  | AST.Cst_sizeof t -> "imm_sizeof (" ^ (print_size t) ^ ")"

let print_arg = function
  | RTLabs.Reg r -> print_reg r
  | RTLabs.Imm (c, t) ->
    Printf.sprintf "(%s)%s" (Primitive.print_type t) (print_cst c)

let rec print_args args =
  Printf.sprintf "[%s]" (MiscPottier.string_of_list ", " print_arg args)

let string_of_signedness = function
  | AST.Signed -> "s"
  | AST.Unsigned -> "u"

let string_of_int_type (size, sign) =
  Printf.sprintf "%d%s" size (string_of_signedness sign)

let print_op1 op r = Printf.sprintf "%s %s"
  (match op with
  | AST.Op_cast (int_type, dest_size) ->
    Printf.sprintf "int%sto%d" (string_of_int_type int_type) dest_size
  | AST.Op_negint -> "-"
  | AST.Op_notbool -> "!"
  | AST.Op_notint -> "!i"
  | AST.Op_id -> ""
  | AST.Op_ptrofint -> "ptrofint"
  | AST.Op_intofptr -> "intofptr")
        (print_reg r)

let print_op2 op r s = Printf.sprintf "%s %s %s"
  (print_arg r)
  (match op with
  | AST.Op_add -> "+"
  | AST.Op_sub -> "-"
  | AST.Op_mul -> "*"
  | AST.Op_div -> "/"
  | AST.Op_divu -> "/u"
  | AST.Op_mod -> "mod"
  | AST.Op_modu -> "modu"
  | AST.Op_and -> "and"
  | AST.Op_or -> "or"
  | AST.Op_xor -> "xor"
  | AST.Op_shl -> "<<"
  | AST.Op_shr -> ">>"
  | AST.Op_shru -> ">>u"
  | AST.Op_cmp cmp -> print_cmp cmp
  | AST.Op_addp -> "+p"
  | AST.Op_subp -> "-p"
  | AST.Op_subpp -> "-pp"
  | AST.Op_cmpp cmp -> (print_cmp cmp) ^ "p"
  | AST.Op_cmpu cmp -> (print_cmp cmp) ^ "u")
  (print_arg s)


(*
let print_addressing = function
  | RTLabs.Aindexed off -> Printf.sprintf "{ %s }" (print_offset off)
  | RTLabs.Aindexed2 -> "add"
  | RTLabs.Aglobal (id, off) ->
    Printf.sprintf "{ %s }(\"%s\")" (print_offset off) id
  | RTLabs.Abased (id, off) ->
    Printf.sprintf "add, { %s }(\"%s\")" (print_offset off) id
  | RTLabs.Ainstack off -> Printf.sprintf "{ %s }(STACK)" (print_offset off)
*)


let rec print_table = function
  | [] -> ""
  | [lbl] -> lbl
  | lbl :: tbl -> lbl ^ ", " ^ (print_table tbl)


let print_statement = function
  | RTLabs.St_skip lbl -> "--> " ^ lbl
  | RTLabs.St_cost (cost_lbl, lbl) ->
    let cost_lbl = CostLabel.string_of_cost_label ~pretty:true cost_lbl in
    Printf.sprintf "emit %s --> %s" cost_lbl lbl
  | RTLabs.St_ind_0 (i, lbl) ->
    Printf.sprintf "index %d --> %s" i lbl
  | RTLabs.St_ind_inc (i, lbl) ->
    Printf.sprintf "increment %d --> %s" i lbl
  | RTLabs.St_cst (destr, cst, lbl) ->
      Printf.sprintf "%s := %s --> %s"
        (print_reg destr)
        (print_cst cst)
        lbl
  | RTLabs.St_op1 (op1, destr, srcr, lbl) ->
      Printf.sprintf "%s := %s --> %s"
        (print_reg destr)
  (print_op1 op1 srcr)
        lbl
  | RTLabs.St_op2 (op2, destr, srcr1, srcr2, lbl) ->
      Printf.sprintf "%s := %s --> %s"
        (print_reg destr)
  (print_op2 op2 srcr1 srcr2)
        lbl
  | RTLabs.St_load (q, addr, destr, lbl) ->
      Printf.sprintf "%s := (%s) *%s --> %s"
        (print_reg destr)
        (Memory.string_of_quantity q)
        (print_arg addr)
        lbl
  | RTLabs.St_store (q, addr, srcr, lbl) ->
      Printf.sprintf "*%s := (%s)%s --> %s"
        (print_arg addr)
        (Memory.string_of_quantity q)
        (print_arg srcr)
        lbl
  | RTLabs.St_call_id (f, args, Some r, sg, lbl) ->
      Printf.sprintf "%s := \"%s\"(%s) : %s --> %s"
        (print_reg r)
        f
        (print_args args)
        (Primitive.print_sig sg)
        lbl
  | RTLabs.St_call_id (f, args, None, sg, lbl) ->
      Printf.sprintf "\"%s\"(%s) : %s --> %s"
        f
        (print_args args)
        (Primitive.print_sig sg)
        lbl
  | RTLabs.St_call_ptr (f, args, Some r, sg, lbl) ->
      Printf.sprintf "%s := *%s (%s) : %s --> %s"
        (print_reg r)
        (print_reg f)
        (print_args args)
        (Primitive.print_sig sg)
        lbl
  | RTLabs.St_call_ptr (f, args, None, sg, lbl) ->
      Printf.sprintf "*%s (%s) : %s --> %s"
        (print_reg f)
        (print_args args)
        (Primitive.print_sig sg)
        lbl
  | RTLabs.St_tailcall_id (f, args, sg) ->
      Printf.sprintf "tailcall \"%s\" (%s) : %s"
        f
        (print_args args)
        (Primitive.print_sig sg)
  | RTLabs.St_tailcall_ptr (f, args, sg) ->
      Printf.sprintf "tailcall *%s (%s) : %s"
        (print_reg f)
        (print_args args)
        (Primitive.print_sig sg)
  | RTLabs.St_cond (r, lbl_true, lbl_false) ->
      Printf.sprintf "if %s --> %s else --> %s"
        (print_reg r)
        lbl_true
        lbl_false
(*
  | RTLabs.St_condcst (cst, t, lbl_true, lbl_false) ->
      Printf.sprintf "(%s) %s --> %s, %s"
        (Primitive.print_type t)
        (print_cst cst)
        lbl_true
        lbl_false
  | RTLabs.St_cond1 (op1, srcr, lbl_true, lbl_false) ->
      Printf.sprintf "%s %s --> %s, %s"
        (print_op1 op1)
        (print_reg srcr)
        lbl_true
        lbl_false
  | RTLabs.St_cond2 (op2, srcr1, srcr2, lbl_true, lbl_false) ->
      Printf.sprintf "%s %s, %s --> %s, %s"
        (print_op2 op2)
        (print_reg srcr1)
        (print_reg srcr2)
        lbl_true
        lbl_false
*)
  | RTLabs.St_jumptable (r, tbl) ->
      Printf.sprintf "j_tbl %s --> %s"
        (print_reg r)
        (print_table tbl)
  | RTLabs.St_return None -> Printf.sprintf "return"
  | RTLabs.St_return (Some r) -> Printf.sprintf "return %s" (print_arg r)


let print_graph n c entry =
  let f lbl stmt s =
    Printf.sprintf "%s%s: %s\n%s"
      (n_spaces n)
      lbl
      (print_statement stmt)
      s in
  let f' lbl stmt (reach, s) =
    (Label.Set.add lbl reach, f lbl stmt s) in
  let module U = GraphUtilities.Util(RTLabsGraph) in
  let (reachable, str) =
    U.dfs_fold f' c entry (Label.Set.empty, "") in
  let filter lbl _ = not (Label.Set.mem lbl reachable) in
  let c_rest = Label.Map.filter filter c in
  if Label.Map.is_empty c_rest then str else
    let str' = Label.Map.fold f c_rest "" in
    str ^ "DEAD NODES:\n" ^ str'
        
let print_internal_decl n f def =

  Printf.sprintf
    "%s\"%s\"%s\n%slocals: %s\n%sresult: %s\n%sstacksize: %s\n%sentry: %s\n%sexit: %s\n\n%s"
    (n_spaces n)
    f
    (print_params def.RTLabs.f_params)
    (n_spaces (n+2))
    (print_locals def.RTLabs.f_locals)
    (n_spaces (n+2))
    (print_result def.RTLabs.f_result)
    (n_spaces (n+2))
    (print_stacksize def.RTLabs.f_stacksize)
    (n_spaces (n+2))
    def.RTLabs.f_entry
    (n_spaces (n+2))
    def.RTLabs.f_exit
    (print_graph (n+2) def.RTLabs.f_graph def.RTLabs.f_entry)


let print_external_decl n f def =
  Printf.sprintf "%sextern \"%s\": %s\n"
    (n_spaces n)
    f
    (Primitive.print_sig def.AST.ef_sig)


let print_fun_decl n (f, def) = match def with
  | RTLabs.F_int def -> print_internal_decl n f def
  | RTLabs.F_ext def -> print_external_decl n f def

let print_fun_decls n functs =
  List.fold_left (fun s f -> s ^ (print_fun_decl n f) ^ "\n\n") ""
    functs


let print_program p =
  Printf.sprintf "program:\n\n\n%s\n\n%s"
    (print_globals 2 p.RTLabs.vars)
    (print_fun_decls 2 p.RTLabs.functs)