source: Deliverables/D2.2/8051/src/LTL/LTLInterpret.ml @ 1542

Last change on this file since 1542 was 1542, checked in by tranquil, 8 years ago

merge of indexed labels branch

File size: 13.1 KB
Line 
1
2(** This module provides an interpreter for the LTL language. *)
3
4
5let error_prefix = "LTL interpret"
6let error s = Error.global_error error_prefix s
7
8
9module Mem = Driver.LTLMemory
10module Val = Mem.Value
11let chunk = Driver.LTLMemory.int_size
12module Eval = I8051.Eval (Val)
13
14
15(* Memory *)
16
17type memory = LTL.function_def Mem.memory
18
19(* Hardware registers environments. They associate a value to the each hardware
20   register. *)
21
22type hdw_reg_env = Val.t I8051.RegisterMap.t
23
24(* Execution states. *)
25
26type state =
27    { pc     : Val.address ;
28      isp    : Val.address ;
29      exit   : Val.address ;
30      carry  : Val.t ;
31      renv   : hdw_reg_env ;
32      mem    : memory ;
33      inds   : CostLabel.const_indexing list ;
34      trace  : CostLabel.t list }
35
36
37(* Helpers *)
38
39let change_pc st pc = { st with pc = pc }
40let change_isp st isp = { st with isp = isp }
41let change_exit st exit = { st with exit = exit }
42let change_carry st carry = { st with carry = carry }
43let change_renv st renv = { st with renv = renv }
44let change_mem st mem = { st with mem = mem }
45let change_trace st trace = { st with trace = trace }
46let add_trace st cost_lbl = change_trace st (cost_lbl :: st.trace)
47let ev_label st = CostLabel.ev_indexing (CostLabel.curr_const_ind st.inds)
48let new_ind st = { st with inds = CostLabel.new_const_ind st.inds }
49let forget_ind st = { st with inds = CostLabel.forget_const_ind st.inds }
50let enter_loop st = CostLabel.enter_loop st.inds
51let continue_loop st = CostLabel.continue_loop st.inds
52
53let empty_state =
54  { pc     = Val.null ;
55    isp    = Val.null ;
56    exit   = Val.null ;
57    carry  = Val.undef ;
58    renv   = I8051.RegisterMap.empty ;
59    mem    = Mem.empty ;
60    inds   = [] ;
61    trace  = [] }
62
63
64(* Each label of each function is associated a pointer. The base of this pointer
65   is the base of the function in memory. Inside a function, offsets are
66   bijectively associated to labels. *)
67
68module Labels_Offsets = Bijection.Make (Label) (Val.Offset)
69
70let labels_offsets_internal int_fun =
71  let f lbl _ (lbls_offs, i) =
72    (Labels_Offsets.add1 lbl i lbls_offs, Val.Offset.succ i) in
73  Label.Map.fold f int_fun.LTL.f_graph
74
75(* [labels_offsets p] builds a bijection between the labels found in the
76   functions of [p] and some offsets. *)
77
78let labels_offsets p =
79  let f (lbls_offs, i) (_, def) = match def with
80    | LTL.F_int int_fun -> labels_offsets_internal int_fun (lbls_offs, i)
81    | _ -> (lbls_offs, i) in
82  fst (List.fold_left f (Labels_Offsets.empty, Val.Offset.zero) p.LTL.functs)
83
84let fun_def_of_ptr mem ptr = match Mem.find_fun_def mem ptr with
85  | LTL.F_int def -> def
86  | _ -> error "Trying to fetch the definition of an external function."
87
88let fetch_stmt lbls_offs st =
89  let msg =
90    Printf.sprintf "%s does not point to a statement."
91      (Val.string_of_address st.pc) in
92  if Val.is_mem_address st.pc then
93    let off = Val.offset_of_address st.pc in
94    let def = fun_def_of_ptr st.mem st.pc in
95    let lbl = Labels_Offsets.find2 off lbls_offs in
96    Label.Map.find lbl def.LTL.f_graph
97  else error msg
98
99let entry_pc lbls_offs ptr def =
100  Val.change_address_offset ptr (Labels_Offsets.find1 def.LTL.f_entry lbls_offs)
101
102let init_fun_call lbls_offs st ptr def =
103  let pc = entry_pc lbls_offs ptr def in
104  let st = new_ind st in
105  change_pc st pc
106
107let next_pc lbls_offs st lbl =
108  let off = Labels_Offsets.find1 lbl lbls_offs in
109  change_pc st (Val.change_address_offset st.pc off)
110
111let framesize st =
112  if Val.is_mem_address st.pc then
113    let def = fun_def_of_ptr st.mem st.pc in
114    def.LTL.f_stacksize
115  else error "Trying to load the stack size of an external function."
116
117let add_reg r v st =
118  let renv = I8051.RegisterMap.add r v st.renv in
119  change_renv st renv
120
121let get_reg r st =
122  if I8051.RegisterMap.mem r st.renv then I8051.RegisterMap.find r st.renv
123  else error ("Unknown hardware register " ^ (I8051.print_register r) ^ ".")
124
125let push st v =
126  let mem = Mem.store st.mem chunk st.isp v in
127  let isp = Val.add_address st.isp (Val.Offset.of_int chunk) in
128  change_mem (change_isp st isp) mem
129
130let pop st =
131  let isp = Val.add_address st.isp (Val.Offset.of_int (-chunk)) in
132  let st = change_isp st isp in
133  let v = Mem.load st.mem chunk st.isp in
134  (st, v)
135
136let save_ra lbls_offs st lbl =
137  let ra =
138    Val.change_address_offset st.pc (Labels_Offsets.find1 lbl lbls_offs) in
139  let st = push st (List.nth ra 0) in
140  let st = push st (List.nth ra 1) in
141  st
142
143let label_of_pointer lbls_offs ptr =
144(*
145  Printf.printf "Retrieving label of %s\n%!" (Val.to_string ptr) ;
146*)
147  let off = Val.offset_of_address ptr in
148  Labels_Offsets.find2 off lbls_offs
149
150let pointer_of_label lbls_offs ptr lbl =
151  Val.change_address_offset ptr (Labels_Offsets.find1 lbl lbls_offs)
152
153let return_pc st =
154  let (st, pch) = pop st in
155  let (st, pcl) = pop st in
156  (st, [pcl ; pch])
157
158let dptr st = List.map (fun r -> get_reg r st) [I8051.dpl ; I8051.dph]
159
160
161(* State pretty-printing *)
162
163let current_label lbls_offs st =
164  Labels_Offsets.find2 (Val.offset_of_address st.pc) lbls_offs
165
166let print_renv renv =
167  let f r v =
168    if not (Val.eq v Val.undef) then
169    Printf.printf "\n%s = %s%!" (I8051.print_register r) (Val.to_string v) in
170  I8051.RegisterMap.iter f renv
171
172let print_state lbls_offs st =
173  Printf.printf "PC: %s (%s)\n%!"
174    (Val.string_of_address st.pc) (current_label lbls_offs st) ;
175  Printf.printf "SP: %s\n%!"
176    (Val.string_of_address [get_reg I8051.spl st ; get_reg I8051.sph st]) ;
177  Printf.printf "ISP: %s%!" (Val.string_of_address st.isp) ;
178  print_renv st.renv ;
179  Printf.printf "\nC = %s%!" (Val.to_string st.carry) ;
180  Mem.print st.mem ;
181  Printf.printf "\n%!"
182
183
184module InterpretExternal = Primitive.Interpret (Mem)
185
186let interpret_external mem f args = match InterpretExternal.t mem f args with
187  | (mem', InterpretExternal.V vs) -> (mem', vs)
188  | (mem', InterpretExternal.A addr) -> (mem', addr)
189
190let fetch_external_args f st =
191  let size = Mem.size_of_quantity (Primitive.args_byte_size f) in
192  let params = MiscPottier.prefix size I8051.parameters in
193  List.map (fun r -> get_reg r st) params
194
195let set_result st vs =
196  let f st (r, v) = add_reg r v st in
197  List.fold_left f st (MiscPottier.combine I8051.rets vs)
198
199let interpret_external_call st f next_pc =
200  let args = fetch_external_args f st in
201  let (mem, vs) = interpret_external st.mem f args in
202  let st = change_mem st mem in
203  let st = set_result st vs in
204  change_pc st next_pc
205
206let interpret_call lbls_offs st ptr ra =
207  match Mem.find_fun_def st.mem ptr with
208    | LTL.F_int def ->
209      let st = save_ra lbls_offs st ra in
210      init_fun_call lbls_offs st ptr def
211    | LTL.F_ext def ->
212      let next_pc = 
213        Val.change_address_offset st.pc (Labels_Offsets.find1 ra lbls_offs) in
214      interpret_external_call st def.AST.ef_tag next_pc
215
216let interpret_return lbls_offs st =
217  let st = forget_ind st in
218  let (st, pc) = return_pc st in
219  change_pc st pc
220
221
222(* Interpret statements. *)
223
224let interpret_stmt lbls_offs st stmt =
225  let next_pc = next_pc lbls_offs in
226  match stmt with
227
228    | LTL.St_skip lbl ->
229      next_pc st lbl
230
231    | LTL.St_comment (s, lbl) ->
232(*
233      Printf.printf "*** %s ***\n\n%!" s ;
234*)
235      next_pc st lbl
236
237    | LTL.St_cost (cost_lbl, lbl) ->
238      let cost_lbl = ev_label st cost_lbl in
239      let st = add_trace st cost_lbl in
240      next_pc st lbl
241
242    | LTL.St_ind_0 (i, lbl) ->
243      enter_loop st i;
244      next_pc st lbl
245
246    | LTL.St_ind_inc (i, lbl) ->
247      continue_loop st i; 
248      next_pc st lbl
249
250    | LTL.St_int (r, i, lbl) ->
251      let st = add_reg r (Val.of_int i) st in
252      next_pc st lbl
253
254    | LTL.St_pop lbl ->
255      let (st, v) = pop st in
256      let st = add_reg I8051.a v st in
257      next_pc st lbl
258
259    | LTL.St_push lbl ->
260      let v = get_reg I8051.a st in
261      let st = push st v in
262      next_pc st lbl
263
264    | LTL.St_addr (x, lbl) ->
265      let vs = Mem.find_global st.mem x in
266      let st = add_reg I8051.dpl (List.nth vs 0) st in
267      let st = add_reg I8051.dph (List.nth vs 1) st in
268      next_pc st lbl
269
270    | LTL.St_from_acc (destr, lbl) ->
271      let st = add_reg destr (get_reg (I8051.a) st) st in
272      next_pc st lbl
273
274    | LTL.St_to_acc (srcr, lbl) ->
275      let st = add_reg I8051.a (get_reg srcr st) st in
276      next_pc st lbl
277
278    | LTL.St_opaccs (opaccs, lbl) ->
279      let (a, b) =
280        Eval.opaccs opaccs
281          (get_reg I8051.a st)
282          (get_reg I8051.b st) in
283      let st = add_reg I8051.a a st in
284      let st = add_reg I8051.b b st in
285      next_pc st lbl
286
287    | LTL.St_op1 (op1, lbl) ->
288      let v = Eval.op1 op1 (get_reg I8051.a st) in
289      let st = add_reg I8051.a v st in
290      next_pc st lbl
291
292    | LTL.St_op2 (op2, srcr, lbl) ->
293      let (v, carry) =
294        Eval.op2 st.carry op2
295          (get_reg I8051.a st)
296          (get_reg srcr st) in
297      let st = change_carry st carry in
298      let st = add_reg I8051.a v st in
299      next_pc st lbl
300
301    | LTL.St_clear_carry lbl ->
302      let st = change_carry st Val.zero in
303      next_pc st lbl
304
305    | LTL.St_set_carry lbl ->
306      let st = change_carry st (Val.of_int 1) in
307      next_pc st lbl
308
309    | LTL.St_load lbl ->
310      let addr = dptr st in
311      let v = Mem.load st.mem chunk addr in
312      let st = add_reg I8051.a v st in
313      next_pc st lbl
314
315    | LTL.St_store lbl ->
316      let addr = dptr st in
317      let mem = Mem.store st.mem chunk addr (get_reg I8051.a st) in
318      let st = change_mem st mem in
319      next_pc st lbl
320
321    | LTL.St_call_id (f, lbl) ->
322      interpret_call lbls_offs st (Mem.find_global st.mem f) lbl
323
324    | LTL.St_call_ptr lbl ->
325      interpret_call lbls_offs st (dptr st) lbl
326
327    | LTL.St_condacc (lbl_true, lbl_false) ->
328      let v = get_reg I8051.a st in
329      let lbl =
330        if Val.is_true v then lbl_true
331        else
332          if Val.is_false v then lbl_false
333          else error "Undecidable branchment." in
334      next_pc st lbl
335
336    | LTL.St_return ->
337      interpret_return lbls_offs st
338
339
340let compute_result st =
341  let vs = List.map (fun r -> get_reg r st) I8051.rets in
342  let f res v = res && (Val.is_int v) in
343  let is_int vs = (List.length vs > 0) && (List.fold_left f true vs) in
344  if is_int vs then
345    let chunks =
346      List.map (fun v -> IntValue.Int32.cast (Val.to_int_repr v)) vs in
347    IntValue.Int32.merge chunks
348  else IntValue.Int32.zero
349
350let rec iter_small_step debug lbls_offs st =
351  let print_and_return_result (res, cost_labels) =
352    if debug then Printf.printf "Result = %s\n%!"
353      (IntValue.Int32.to_string res) ;
354    (res, cost_labels) in
355  if debug then print_state lbls_offs st ;
356  match fetch_stmt lbls_offs st with
357    | LTL.St_return when Val.eq_address (snd (return_pc st)) st.exit ->
358      print_and_return_result (compute_result st, List.rev st.trace)
359    | stmt ->
360      let st' = interpret_stmt lbls_offs st stmt in
361      iter_small_step debug lbls_offs st'
362
363
364let add_global_vars =
365  List.fold_left
366    (fun mem (id, size) -> Mem.add_var mem id (AST.SQ (AST.QInt size)) None)
367
368let add_fun_defs =
369  List.fold_left (fun mem (f_id, f_def) -> Mem.add_fun_def mem f_id f_def)
370
371let init_prog (st : state) (p : LTL.program) : state =
372  let mem = add_global_vars (add_fun_defs st.mem p.LTL.functs) p.LTL.vars in
373  change_mem st mem
374
375let init_sp st =
376  let (mem, sp) = Mem.alloc st.mem I8051.ext_ram_size in
377  let sp =
378    Val.change_address_offset sp (Val.Offset.of_int I8051.ext_ram_size) in
379  let st = change_mem st mem in
380  (st, sp)
381
382let init_isp st =
383  let (mem, isp) = Mem.alloc st.mem I8051.int_ram_size in
384  let st = change_mem (change_isp st isp) mem in
385  let (mem, exit) = Mem.alloc st.mem 1 in
386  let st = change_exit st exit in
387  let st = push st (List.nth exit 0) in
388  let st = push st (List.nth exit 1) in
389  st 
390
391let init_renv st sp =
392  let f r st = add_reg r Val.undef st in
393  let st = I8051.RegisterSet.fold f I8051.registers st in
394  let spl = List.nth sp 0 in
395  let sph = List.nth sp 1 in
396  let st = add_reg I8051.spl spl st in
397  let st = add_reg I8051.sph sph st in
398  st
399
400let init_main_call lbls_offs st main =
401  let ptr = Mem.find_global st.mem main in
402  match Mem.find_fun_def st.mem ptr with
403    | LTL.F_int def ->
404      init_fun_call lbls_offs st ptr def
405    | _ -> error ("Cannot execute the main (\"" ^ main ^ "\"): it is external.")
406
407
408(* Before interpreting, the environment is initialized:
409   - Build a bijection between the labels in the program and some values (taken
410     amongst the offsets).
411   - Add function definitions to the memory and reserve space for the globals.
412   - Allocate memory to emulate the external stack and initialize the external
413     stack pointer.
414   - Allocate memory to emulate the internal stack and initialize the internal
415     stack pointer.
416   - Initialiaze the physical register environment. All are set to 0, except for
417     the stack pointer registers that take the high and low bits of the external
418     stack pointer.
419   - Initialize a call to the main (set the current program counter to the
420     beginning of the function).
421   - Initialize the carry flag to 0. *)
422
423let interpret debug p =
424  Printf.printf "*** LTL interpret ***\n%!" ;
425  match p.LTL.main with
426    | None -> (IntValue.Int8.zero, [])
427    | Some main ->
428      let lbls_offs = labels_offsets p in
429      let st = empty_state in
430      let st = init_prog st p in
431      let (st, sp) = init_sp st in
432      let st = init_isp st in
433      let st = init_renv st sp in
434      let st = init_main_call lbls_offs st main in
435      let st = change_carry st Val.zero in
436      iter_small_step debug lbls_offs st
Note: See TracBrowser for help on using the repository browser.