source: Deliverables/D2.2/8051/src/ERTL/liveness.ml @ 1572

Last change on this file since 1572 was 1572, checked in by tranquil, 8 years ago
  • corrected previous bug
  • finished propagating immediates
File size: 9.5 KB
Line 
1(* Pasted from Pottier's PP compiler *)
2
3open ERTL
4
5(* In the following, a ``variable'' means a pseudo-register or an
6   allocatable hardware register. *)
7
8(* These functions allow turning an [ERTL] control flow graph into an
9   explicit graph, that is, making successor edges explicit. This is
10   useful in itself and facilitates the computation of predecessor
11   edges. *)
12
13let statement_successors (stmt : statement) =
14  match stmt with
15  | St_return _ ->
16    Label.Set.empty
17  | St_skip l
18  | St_comment (_, l)
19  | St_cost (_, l)
20  | St_ind_0 (_, l)
21  | St_ind_inc (_, l)
22  | St_set_hdw (_, _, l)
23  | St_get_hdw (_, _, l)
24  | St_hdw_to_hdw (_, _, l)
25  | St_newframe l
26  | St_delframe l
27  | St_framesize (_, l)
28  | St_push (_, l)
29  | St_pop (_, l)
30  | St_addrH (_, _, l)
31  | St_addrL (_, _, l)
32  (* | St_int (_, _, l) *)
33  | St_move (_, _, l)
34  | St_opaccsA (_, _, _, _, l)
35  | St_opaccsB (_, _, _, _, l)
36  | St_op1 (_, _, _, l)
37  | St_op2 (_, _, _, _, l)
38  | St_clear_carry l
39  | St_set_carry l
40  | St_load (_, _, _, l)
41  | St_store (_, _, _, l)
42  | St_call_id (_, _, l)
43  | St_call_ptr (_, _, _, l) ->
44    Label.Set.singleton l
45  | St_cond (_, l1, l2) ->
46    Label.Set.add l1 (Label.Set.singleton l2)
47
48(* The analysis uses the lattice of sets of variables. The lattice's
49   join operation is pointwise set union, which reflects the fact that
50   a variable is deemed live at a program point if and only if it is
51   live at any of the successors of that program point. *)
52
53module L = struct
54
55  (* A set of variable is represented as a pair of a set of
56     pseudo-registers and a set of hardware registers. *)
57
58  type t =
59      Register.Set.t * I8051.RegisterSet.t
60
61  type property =
62      t
63
64  let bottom =
65    Register.Set.empty, I8051.RegisterSet.empty
66
67  let psingleton r =
68    Register.Set.singleton r, I8051.RegisterSet.empty
69
70  let hsingleton hwr =
71    Register.Set.empty, I8051.RegisterSet.singleton hwr
72
73  let join (rset1, hwrset1) (rset2, hwrset2) =
74    (Register.Set.union rset1 rset2, I8051.RegisterSet.union hwrset1 hwrset2)
75
76  let diff (rset1, hwrset1) (rset2, hwrset2) =
77    (Register.Set.diff rset1 rset2, I8051.RegisterSet.diff hwrset1 hwrset2)
78
79  let equal (rset1, hwrset1) (rset2, hwrset2) =
80    Register.Set.equal rset1 rset2 && I8051.RegisterSet.equal hwrset1 hwrset2
81
82  let is_maximal _ =
83    false
84
85end
86
87module F = Fix.Make (Label.ImpMap) (L)
88
89(* These are the sets of variables defined at (written by) a statement. *)
90
91let defined (stmt : statement) : L.t =
92  match stmt with
93  | St_skip _
94  | St_comment _
95  | St_cost _
96  | St_ind_0 _
97  | St_ind_inc _
98  | St_push _
99  | St_store _
100  | St_cond _
101  | St_return _ ->
102    L.bottom
103  | St_clear_carry _
104  | St_set_carry _ ->
105    Register.Set.empty, I8051.RegisterSet.singleton I8051.carry
106  | St_op2 (I8051.Add, r, _, _, _)
107  | St_op2 (I8051.Addc, r, _, _, _)
108  | St_op2 (I8051.Sub, r, _, _, _) ->
109    L.join (L.hsingleton I8051.carry) (L.psingleton r)
110  | St_op1 (I8051.Inc, r, _, _)
111  | St_get_hdw (r, _, _)
112  | St_framesize (r, _)
113  | St_pop (r, _)
114  (* | St_int (r, _, _) *)
115  | St_addrH (r, _, _)
116  | St_addrL (r, _, _)
117  | St_move (r, _, _)
118  | St_opaccsA (_, r, _, _, _)
119  | St_opaccsB (_, r, _, _, _)
120  | St_op1 (_, r, _, _)
121  | St_op2 (_, r, _, _, _)
122  | St_load (r, _, _, _) ->
123    L.psingleton r
124  | St_set_hdw (r, _, _)
125  | St_hdw_to_hdw (r, _, _) ->
126    L.hsingleton r
127  | St_call_id _ | St_call_ptr _  ->
128      (* Potentially destroys all caller-save hardware registers. *)
129    Register.Set.empty, I8051.caller_saved
130  | St_newframe _
131  | St_delframe _ ->
132    L.join (L.hsingleton I8051.spl) (L.hsingleton I8051.sph)
133
134let set_of_list rl =
135  List.fold_right I8051.RegisterSet.add rl I8051.RegisterSet.empty
136
137(* This is the set of variables used at (read by) a statement. *)
138
139let set_of_list =
140  let f set r = I8051.RegisterSet.add r set in
141  List.fold_left f I8051.RegisterSet.empty
142
143let ret_regs = set_of_list I8051.rets
144
145let add_arg : RTL.argument -> L.property -> L.property = function
146  | RTL.Reg r -> L.join (L.psingleton r)
147  | RTL.Imm _ -> fun x -> x
148
149let used (stmt : statement) : L.t =
150  match stmt with
151  | St_skip _
152  | St_comment _
153  | St_cost _
154  | St_ind_0 _
155  | St_ind_inc _
156  | St_framesize _
157  | St_pop _
158  | St_addrH _
159  | St_addrL _
160  (* | St_int _ *)
161  | St_clear_carry _
162  | St_set_carry _ ->
163    L.bottom
164  | St_call_id (_, nparams, _) ->
165    (* Reads the hardware registers that are used to pass parameters. *)
166    Register.Set.empty,
167    set_of_list (MiscPottier.prefix nparams I8051.parameters)
168  | St_call_ptr (r1, r2, nparams, _) ->
169    (* Reads the hardware registers that are used to pass parameters. *)
170    Register.Set.of_list [r1 ; r2],
171    set_of_list (MiscPottier.prefix nparams I8051.parameters)
172  | St_get_hdw (_, r, _)
173  | St_hdw_to_hdw (_, r, _) ->
174    L.hsingleton r
175  | St_op1 (_, _, r, _)
176  | St_cond (r, _, _) ->
177    L.psingleton r
178  | St_set_hdw (_, a, _)
179  | St_push (a, _)
180  | St_move (_, a, _) ->
181    add_arg a L.bottom
182  | St_op2 ((I8051.Addc | I8051.Sub), _, a1, a2, _) ->
183    add_arg a1 (add_arg a2 (L.hsingleton I8051.carry))
184  | St_opaccsA (_, _, a1, a2, _)
185  | St_opaccsB (_, _, a1, a2, _)
186  | St_op2 (_, _, a1, a2, _)
187  | St_load (_, a1, a2, _) ->
188    add_arg a1 (add_arg a2 L.bottom)
189  | St_store (a1, a2, a3, _) ->
190    add_arg a1 (add_arg a2 (add_arg a3 L.bottom))
191  | St_newframe _
192  | St_delframe _ ->
193    L.join (L.hsingleton I8051.spl) (L.hsingleton I8051.sph)
194  | St_return _ ->
195    Register.Set.empty, I8051.RegisterSet.union I8051.callee_saved ret_regs
196
197(* A statement is considered pure if it has no side effect, that is, if
198   its only effect is to write a value to its destination variable.
199
200   A pure statement whose destination is dead after the statement will
201   be eliminated during the translation of [ERTL] to [LTL]. This is done by
202   replacing the statement with an [St_skip] statement.
203
204   [eliminable liveafter stmt] returns [Some l], where [l] is [stmt]'s single
205   successor, if statement [stmt] is eliminable. Otherwise, it returns
206   [None]. The parameter [liveafter] is the set of variables that are live
207   after the statement. *)
208
209let eliminable ((pliveafter, hliveafter) : L.t) (stmt : statement) =
210  match stmt with
211  | St_skip _
212  | St_comment _
213  | St_cost _
214  | St_ind_0 _
215  | St_ind_inc _
216  | St_newframe _
217  | St_delframe _
218  | St_pop _
219  | St_push _
220  | St_clear_carry _
221  | St_set_carry _
222  | St_store _
223  | St_call_id _
224  | St_call_ptr _
225  | St_cond _
226  | St_return _ ->
227    None
228  | St_get_hdw (r, _, l)
229  | St_framesize (r, l)
230  (* | St_int (r, _, l) *)
231  | St_addrH (r, _, l)
232  | St_addrL (r, _, l)
233  | St_move (r, _, l)
234  | St_opaccsA (_, r, _, _, l)
235  | St_opaccsB (_, r, _, _, l)
236  | St_op1 (_, r, _, l)
237  | St_op2 (_, r, _, _, l)
238  | St_load (r, _, _, l) ->
239    if (Register.Set.mem r pliveafter) ||
240       (I8051.RegisterSet.mem I8051.carry hliveafter) then None else Some l
241  | St_set_hdw (r, _, l)
242  | St_hdw_to_hdw (r, _, l) ->
243    if I8051.RegisterSet.mem r hliveafter then None else Some l
244
245(* This is the abstract semantics of instructions. It defines the
246   variables that are live before the instruction in terms of
247   those that are live after the instruction. *)
248
249(* The standard definition is: a variable is considered live
250   before the instruction if either (1) it is used by the instruction,
251   or (2) it is live after the instruction and not defined by the
252   instruction.
253
254   As an exception to this rule, if the instruction is eliminable,
255   then a variable is considered live before the instruction
256   if and only if it is live after the instruction. This anticipates
257   on the instruction's elimination.
258
259   This exception means that the source variables of a pure
260   instruction need not be considered live if the instruction's result
261   is unused. This allows a sequence of pure instructions whose end
262   result is dead to be considered entirely dead.
263
264   It is a simple, but not entirely trivial, exercise to check that
265   this transfer function is monotone. *)
266
267let statement_semantics (stmt : statement) (liveafter : L.t) : L.t =
268  match eliminable liveafter stmt with
269  | None ->
270      L.join (L.diff liveafter (defined stmt)) (used stmt)
271  | Some _ ->
272      liveafter
273
274(* A valuation is a function that maps a program point (a control flow
275   graph label) to the set of variables that are live after that
276   point. *)
277
278type valuation =
279    Label.t -> L.t
280
281(* This is how we turn an [ERTL] procedure into a liveness analysis
282   problem and solve it. *)
283
284let analyze (int_fun : internal_function) : valuation =
285
286  (* Formulate the problem. Construct a system (recursive) equations
287     that describe the live variables before and after each
288     instruction. *)
289
290  (* The following two functions, [livebefore] and [liveafter],
291     define these equations. Both use an oracle, a valuation --
292     also called [liveafter] -- which is supposed to tell us
293     which variables are live after each label. *)
294
295  (* The live variables before an instruction are computed, using the
296     instruction's semantics, in terms of the live variables after the
297     instruction -- which are given by the oracle. *)
298
299  let livebefore label (liveafter : valuation) : L.t =
300    let stmt : statement = Label.Map.find label int_fun.f_graph in
301    statement_semantics stmt (liveafter label)
302  in
303
304  (* The live variables after an instruction are the union of the live
305     variables before each of the instruction's successors. *)
306
307  let liveafter label (liveafter : valuation) : L.t =
308    let stmt : statement = Label.Map.find label int_fun.f_graph in
309    Label.Set.fold (fun successor accu ->
310      L.join (livebefore successor liveafter) accu
311    ) (statement_successors stmt) L.bottom
312  in
313
314  (* Compute the least fixed point of these recursive equations. *)
315
316  F.lfp liveafter
Note: See TracBrowser for help on using the repository browser.