source: Deliverables/D2.2/8051/src/ERTL/liveness.ml @ 1542

Last change on this file since 1542 was 1542, checked in by tranquil, 8 years ago

merge of indexed labels branch

File size: 9.4 KB
Line 
1(* Pasted from Pottier's PP compiler *)
2
3open ERTL
4
5(* In the following, a ``variable'' means a pseudo-register or an
6   allocatable hardware register. *)
7
8(* These functions allow turning an [ERTL] control flow graph into an
9   explicit graph, that is, making successor edges explicit. This is
10   useful in itself and facilitates the computation of predecessor
11   edges. *)
12
13let statement_successors (stmt : statement) =
14  match stmt with
15  | St_return _ ->
16    Label.Set.empty
17  | St_skip l
18  | St_comment (_, l)
19  | St_cost (_, l)
20  | St_ind_0 (_, l)
21  | St_ind_inc (_, l)
22  | St_set_hdw (_, _, l)
23  | St_get_hdw (_, _, l)
24  | St_hdw_to_hdw (_, _, l)
25  | St_newframe l
26  | St_delframe l
27  | St_framesize (_, l)
28  | St_push (_, l)
29  | St_pop (_, l)
30  | St_addrH (_, _, l)
31  | St_addrL (_, _, l)
32  | St_int (_, _, l)
33  | St_move (_, _, l)
34  | St_opaccsA (_, _, _, _, l)
35  | St_opaccsB (_, _, _, _, l)
36  | St_op1 (_, _, _, l)
37  | St_op2 (_, _, _, _, l)
38  | St_clear_carry l
39  | St_set_carry l
40  | St_load (_, _, _, l)
41  | St_store (_, _, _, l)
42  | St_call_id (_, _, l)
43  | St_call_ptr (_, _, _, l) ->
44    Label.Set.singleton l
45  | St_cond (_, l1, l2) ->
46    Label.Set.add l1 (Label.Set.singleton l2)
47
48(* The analysis uses the lattice of sets of variables. The lattice's
49   join operation is pointwise set union, which reflects the fact that
50   a variable is deemed live at a program point if and only if it is
51   live at any of the successors of that program point. *)
52
53module L = struct
54
55  (* A set of variable is represented as a pair of a set of
56     pseudo-registers and a set of hardware registers. *)
57
58  type t =
59      Register.Set.t * I8051.RegisterSet.t
60
61  type property =
62      t
63
64  let bottom =
65    Register.Set.empty, I8051.RegisterSet.empty
66
67  let psingleton r =
68    Register.Set.singleton r, I8051.RegisterSet.empty
69
70  let hsingleton hwr =
71    Register.Set.empty, I8051.RegisterSet.singleton hwr
72
73  let join (rset1, hwrset1) (rset2, hwrset2) =
74    (Register.Set.union rset1 rset2, I8051.RegisterSet.union hwrset1 hwrset2)
75
76  let diff (rset1, hwrset1) (rset2, hwrset2) =
77    (Register.Set.diff rset1 rset2, I8051.RegisterSet.diff hwrset1 hwrset2)
78
79  let equal (rset1, hwrset1) (rset2, hwrset2) =
80    Register.Set.equal rset1 rset2 && I8051.RegisterSet.equal hwrset1 hwrset2
81
82  let is_maximal _ =
83    false
84
85end
86
87module F = Fix.Make (Label.ImpMap) (L)
88
89(* These are the sets of variables defined at (written by) a statement. *)
90
91let defined (stmt : statement) : L.t =
92  match stmt with
93  | St_skip _
94  | St_comment _
95  | St_cost _
96  | St_ind_0 _
97  | St_ind_inc _
98  | St_push _
99  | St_store _
100  | St_cond _
101  | St_return _ ->
102    L.bottom
103  | St_clear_carry _
104  | St_set_carry _ ->
105    Register.Set.empty, I8051.RegisterSet.singleton I8051.carry
106  | St_op2 (I8051.Add, r, _, _, _)
107  | St_op2 (I8051.Addc, r, _, _, _)
108  | St_op2 (I8051.Sub, r, _, _, _) ->
109    L.join (L.hsingleton I8051.carry) (L.psingleton r)
110  | St_op1 (I8051.Inc, r, _, _)
111  | St_get_hdw (r, _, _)
112  | St_framesize (r, _)
113  | St_pop (r, _)
114  | St_int (r, _, _)
115  | St_addrH (r, _, _)
116  | St_addrL (r, _, _)
117  | St_move (r, _, _)
118  | St_opaccsA (_, r, _, _, _)
119  | St_opaccsB (_, r, _, _, _)
120  | St_op1 (_, r, _, _)
121  | St_op2 (_, r, _, _, _)
122  | St_load (r, _, _, _) ->
123    L.psingleton r
124  | St_set_hdw (r, _, _)
125  | St_hdw_to_hdw (r, _, _) ->
126    L.hsingleton r
127  | St_call_id _ | St_call_ptr _  ->
128      (* Potentially destroys all caller-save hardware registers. *)
129    Register.Set.empty, I8051.caller_saved
130  | St_newframe _
131  | St_delframe _ ->
132    L.join (L.hsingleton I8051.spl) (L.hsingleton I8051.sph)
133
134let set_of_list rl =
135  List.fold_right I8051.RegisterSet.add rl I8051.RegisterSet.empty
136
137(* This is the set of variables used at (read by) a statement. *)
138
139let set_of_list =
140  let f set r = I8051.RegisterSet.add r set in
141  List.fold_left f I8051.RegisterSet.empty
142
143let ret_regs = set_of_list I8051.rets
144
145let used (stmt : statement) : L.t =
146  match stmt with
147  | St_skip _
148  | St_comment _
149  | St_cost _
150  | St_ind_0 _
151  | St_ind_inc _
152  | St_framesize _
153  | St_pop _
154  | St_addrH _
155  | St_addrL _
156  | St_int _
157  | St_clear_carry _
158  | St_set_carry _ ->
159    L.bottom
160  | St_call_id (_, nparams, _) ->
161    (* Reads the hardware registers that are used to pass parameters. *)
162    Register.Set.empty,
163    set_of_list (MiscPottier.prefix nparams I8051.parameters)
164  | St_call_ptr (r1, r2, nparams, _) ->
165    (* Reads the hardware registers that are used to pass parameters. *)
166    Register.Set.of_list [r1 ; r2],
167    set_of_list (MiscPottier.prefix nparams I8051.parameters)
168  | St_get_hdw (_, r, _)
169  | St_hdw_to_hdw (_, r, _) ->
170    L.hsingleton r
171  | St_set_hdw (_, r, _)
172  | St_push (r, _)
173  | St_move (_, r, _)
174  | St_op1 (_, _, r, _)
175  | St_cond (r, _, _) ->
176    L.psingleton r
177  | St_op2 (I8051.Addc, _, r1, r2, _) ->
178    L.join (L.join (L.psingleton r1) (L.psingleton r2))
179      (L.hsingleton I8051.carry)
180  | St_opaccsA (_, _, r1, r2, _)
181  | St_opaccsB (_, _, r1, r2, _)
182  | St_op2 (_, _, r1, r2, _)
183  | St_load (_, r1, r2, _) ->
184    L.join (L.psingleton r1) (L.psingleton r2)
185  | St_store (r1, r2, r3, _) ->
186    L.join (L.join (L.psingleton r1) (L.psingleton r2)) (L.psingleton r3)
187  | St_newframe _
188  | St_delframe _ ->
189    L.join (L.hsingleton I8051.spl) (L.hsingleton I8051.sph)   
190  | St_return _ ->
191    Register.Set.empty, I8051.RegisterSet.union I8051.callee_saved ret_regs
192
193(* A statement is considered pure if it has no side effect, that is, if
194   its only effect is to write a value to its destination variable.
195
196   A pure statement whose destination is dead after the statement will
197   be eliminated during the translation of [ERTL] to [LTL]. This is done by
198   replacing the statement with an [St_skip] statement.
199
200   [eliminable liveafter stmt] returns [Some l], where [l] is [stmt]'s single
201   successor, if statement [stmt] is eliminable. Otherwise, it returns
202   [None]. The parameter [liveafter] is the set of variables that are live
203   after the statement. *)
204
205let eliminable ((pliveafter, hliveafter) : L.t) (stmt : statement) =
206  match stmt with
207  | St_skip _
208  | St_comment _
209  | St_cost _
210  | St_ind_0 _
211  | St_ind_inc _
212  | St_newframe _
213  | St_delframe _
214  | St_pop _
215  | St_push _
216  | St_clear_carry _
217  | St_set_carry _
218  | St_store _
219  | St_call_id _
220  | St_call_ptr _
221  | St_cond _
222  | St_return _ ->
223    None
224  | St_get_hdw (r, _, l)
225  | St_framesize (r, l)
226  | St_int (r, _, l)
227  | St_addrH (r, _, l)
228  | St_addrL (r, _, l)
229  | St_move (r, _, l)
230  | St_opaccsA (_, r, _, _, l)
231  | St_opaccsB (_, r, _, _, l)
232  | St_op1 (_, r, _, l)
233  | St_op2 (_, r, _, _, l)
234  | St_load (r, _, _, l) ->
235    if (Register.Set.mem r pliveafter) ||
236       (I8051.RegisterSet.mem I8051.carry hliveafter) then None else Some l
237  | St_set_hdw (r, _, l)
238  | St_hdw_to_hdw (r, _, l) ->
239    if I8051.RegisterSet.mem r hliveafter then None else Some l
240
241(* This is the abstract semantics of instructions. It defines the
242   variables that are live before the instruction in terms of
243   those that are live after the instruction. *)
244
245(* The standard definition is: a variable is considered live
246   before the instruction if either (1) it is used by the instruction,
247   or (2) it is live after the instruction and not defined by the
248   instruction.
249
250   As an exception to this rule, if the instruction is eliminable,
251   then a variable is considered live before the instruction
252   if and only if it is live after the instruction. This anticipates
253   on the instruction's elimination.
254
255   This exception means that the source variables of a pure
256   instruction need not be considered live if the instruction's result
257   is unused. This allows a sequence of pure instructions whose end
258   result is dead to be considered entirely dead.
259
260   It is a simple, but not entirely trivial, exercise to check that
261   this transfer function is monotone. *)
262
263let statement_semantics (stmt : statement) (liveafter : L.t) : L.t =
264  match eliminable liveafter stmt with
265  | None ->
266      L.join (L.diff liveafter (defined stmt)) (used stmt)
267  | Some _ ->
268      liveafter
269
270(* A valuation is a function that maps a program point (a control flow
271   graph label) to the set of variables that are live after that
272   point. *)
273
274type valuation =
275    Label.t -> L.t
276
277(* This is how we turn an [ERTL] procedure into a liveness analysis
278   problem and solve it. *)
279
280let analyze (int_fun : internal_function) : valuation =
281
282  (* Formulate the problem. Construct a system (recursive) equations
283     that describe the live variables before and after each
284     instruction. *)
285
286  (* The following two functions, [livebefore] and [liveafter],
287     define these equations. Both use an oracle, a valuation --
288     also called [liveafter] -- which is supposed to tell us
289     which variables are live after each label. *)
290
291  (* The live variables before an instruction are computed, using the
292     instruction's semantics, in terms of the live variables after the
293     instruction -- which are given by the oracle. *)
294
295  let livebefore label (liveafter : valuation) : L.t =
296    let stmt : statement = Label.Map.find label int_fun.f_graph in
297    statement_semantics stmt (liveafter label)
298  in
299
300  (* The live variables after an instruction are the union of the live
301     variables before each of the instruction's successors. *)
302
303  let liveafter label (liveafter : valuation) : L.t =
304    let stmt : statement = Label.Map.find label int_fun.f_graph in
305    Label.Set.fold (fun successor accu ->
306      L.join (livebefore successor liveafter) accu
307    ) (statement_successors stmt) L.bottom
308  in
309
310  (* Compute the least fixed point of these recursive equations. *)
311
312  F.lfp liveafter
Note: See TracBrowser for help on using the repository browser.