source: Deliverables/D2.2/8051-matita-out/src/clight/clightFromC.ml @ 2383

Last change on this file since 2383 was 2383, checked in by campbell, 8 years ago

Branch prototype so that there's a version with the matita output patch
preinstalled.

File size: 28.6 KB
Line 
1open Printf
2
3open Cparser
4open Cparser.C
5open Cparser.Env
6
7open Clight
8 
9(** Extract the type part of a type-annotated Clight expression. *)
10
11let typeof e = match e with Expr(_,te) -> te
12
13(** Natural alignment of a type, in bytes. *)
14let rec alignof = function
15  | Tvoid -> 1
16  | Tint (I8,_) -> 1
17  | Tint (I16,_) -> 2
18  | Tint (I32,_) -> 4
19  | Tfloat F32 -> 4
20  | Tfloat F64 -> 8
21  | Tpointer _ -> 4
22  | Tarray (t',n) -> alignof t'
23  | Tfunction (_,_) -> 1
24  | Tstruct (_,fld) -> alignof_fields fld
25  | Tunion (_,fld) -> alignof_fields fld
26  | Tcomp_ptr _ -> 4
27and alignof_fields = function
28          | [] -> 1
29          | (id,t)::f' -> max (alignof t) (alignof_fields f')
30
31(** Size of a type, in bytes. *)
32
33let align n amount =
34  ((n + amount - 1) / amount) * amount
35
36let rec sizeof t = 
37  match t with
38    | Tvoid -> 1
39    | Tint (I8,_) -> 1
40    | Tint (I16,_) -> 2
41    | Tint (I32,_) -> 4
42    | Tfloat F32 -> 4
43    | Tfloat F64 -> 8
44    | Tpointer _ -> 4
45    | Tarray (t',n) -> sizeof t' * max 1 n
46    | Tfunction (_,_) -> 1
47    | Tstruct (_,fld) -> align (max 1 (sizeof_struct fld 0)) (alignof t)
48    | Tunion (_,fld) -> align (max 1 (sizeof_union fld)) (alignof t)
49    | Tcomp_ptr _ -> 4
50and sizeof_struct fld pos =
51  match fld with
52    | [] -> pos
53    | (id,t)::fld' -> sizeof_struct fld' (align pos (alignof t) + sizeof t)
54and sizeof_union = function
55  | [] -> 0
56  | (id,t)::fld' -> max (sizeof t) (sizeof_union fld')
57
58(** Record the declarations of global variables and associate them
59    with the corresponding atom. *)
60
61let decl_atom : (AST.ident, Env.t * C.decl) Hashtbl.t = Hashtbl.create 103
62
63(** Hooks -- overriden in machine-dependent CPragmas module *)
64
65let process_pragma_hook = ref (fun (s: string) -> false)
66let define_variable_hook = ref (fun (id: AST.ident) (d: C.decl) -> ())
67let define_function_hook = ref (fun (id: AST.ident) (d: C.decl) -> ())
68let define_stringlit_hook = ref (fun (id: AST.ident) -> ())
69
70(** ** Error handling *)
71
72let currentLocation = ref Cutil.no_loc
73
74let updateLoc l = currentLocation := l
75
76let numErrors = ref 0
77
78let error msg =
79  incr numErrors;
80  eprintf "%aError: %s\n" Cutil.printloc !currentLocation msg
81
82let unsupported msg =
83  incr numErrors;
84  eprintf "%aUnsupported feature: %s\n" Cutil.printloc !currentLocation msg
85
86let warning msg =
87  eprintf "%aWarning: %s\n" Cutil.printloc !currentLocation msg
88
89
90(** ** Functions used to handle string literals *)
91
92let stringNum = ref 0   (* number of next global for string literals *)
93let stringTable = Hashtbl.create 47
94
95let name_for_string_literal env s =
96  try
97    Hashtbl.find stringTable s
98  with Not_found ->
99    incr stringNum;
100    let name = Printf.sprintf "__stringlit_%d" !stringNum in
101    let id = name in
102    Hashtbl.add decl_atom id
103      (env, (C.Storage_static,
104             Env.fresh_ident name,
105             C.TPtr(C.TInt(C.IChar,[C.AConst]),[]),
106             None));
107    !define_stringlit_hook id;
108    Hashtbl.add stringTable s id;
109    id
110
111let typeStringLiteral s =
112  Tarray(Tint(I8, AST.Unsigned), String.length s + 1)
113
114let global_for_string s id =
115  let init = ref [] in
116  let add_char c =
117    init :=
118       Init_int8(Char.code c)
119       :: !init in
120  add_char '\000';
121  for i = String.length s - 1 downto 0 do add_char s.[i] done;
122  ((id, !init), typeStringLiteral s)
123
124let globals_for_strings globs =
125  Hashtbl.fold
126    (fun s id l -> global_for_string s id :: l)
127    stringTable globs
128
129(** ** Handling of stubs for variadic functions *)
130
131let stub_function_table = Hashtbl.create 47
132
133let register_stub_function name tres targs =
134  let rec letters_of_type = function
135    | [] -> []
136    | Tfloat(_)::tl -> "f" :: letters_of_type tl
137    | _::tl -> "i" :: letters_of_type tl in
138  let stub_name =
139    name ^ "$" ^ String.concat "" (letters_of_type targs) in
140  try
141    (stub_name, Hashtbl.find stub_function_table stub_name)
142  with Not_found ->
143    let rec types_of_types = function
144      | [] -> []
145      | Tfloat(_)::tl -> Tfloat(F64)::(types_of_types tl)
146      | _::tl -> Tpointer(Tvoid)::(types_of_types tl) in
147    let stub_type = Tfunction (types_of_types targs, tres) in
148    Hashtbl.add stub_function_table stub_name stub_type;
149    (stub_name, stub_type)
150
151let declare_stub_function stub_name stub_type =
152  match stub_type with
153  | Tfunction(targs, tres) ->
154      (stub_name,
155                         External(stub_name, targs, tres))
156  | _ -> assert false
157
158let declare_stub_functions k =
159  Hashtbl.fold
160    (fun n i k -> declare_stub_function n i :: k)
161               stub_function_table k
162
163(** ** Translation functions *)
164
165(** Constants *)
166
167let convertInt n = Int64.to_int n
168
169(** Types *)
170
171let convertIkind = function
172  | C.IBool -> unsupported "'_Bool' type"; (AST.Unsigned, I8)
173  | C.IChar -> (AST.Unsigned, I8)
174  | C.ISChar -> (AST.Signed, I8)
175  | C.IUChar -> (AST.Unsigned, I8)
176  | C.IInt -> (AST.Signed, I32)
177  | C.IUInt -> (AST.Unsigned, I32)
178  | C.IShort -> (AST.Signed, I16)
179  | C.IUShort -> (AST.Unsigned, I16)
180  | C.ILong -> (AST.Signed, I32)
181  | C.IULong -> (AST.Unsigned, I32)
182  | C.ILongLong -> 
183      if not !ClightFlags.option_flonglong then unsupported "'long long' type";
184      (AST.Signed, I32)
185  | C.IULongLong ->
186      if not !ClightFlags.option_flonglong then unsupported "'unsigned long long' type";
187      (AST.Unsigned, I32)
188
189let convertFkind = function
190  | C.FFloat -> F32
191  | C.FDouble -> F64
192  | C.FLongDouble ->
193      if not !ClightFlags.option_flonglong then unsupported "'long double' type";
194      F64
195
196let convertTyp env t =
197
198  let rec convertTyp seen t =
199    match Cutil.unroll env t with
200    | C.TVoid a -> Tvoid
201    | C.TInt(ik, a) ->
202        let (sg, sz) = convertIkind ik in Tint(sz, sg)
203    | C.TFloat(fk, a) ->
204        Tfloat(convertFkind fk)
205    | C.TPtr(C.TStruct(id, _), _) when List.mem id seen ->
206        Tcomp_ptr("struct " ^ id.name)
207    | C.TPtr(C.TUnion(id, _), _) when List.mem id seen ->
208        Tcomp_ptr("union " ^ id.name)
209    | C.TPtr(ty, a) ->
210        Tpointer(convertTyp seen ty)
211    | C.TArray(ty, None, a) ->
212        (* Cparser verified that the type ty[] occurs only in
213           contexts that are safe for Clight, so just treat as ty[0]. *)
214        (* warning "array type of unspecified size"; *)
215        Tarray(convertTyp seen ty, 0)
216    | C.TArray(ty, Some sz, a) ->
217        Tarray(convertTyp seen ty, convertInt sz )
218    | C.TFun(tres, targs, va, a) ->
219        if va then unsupported "variadic function type";
220        if Cutil.is_composite_type env tres then
221          unsupported "return type is a struct or union";
222        Tfunction(begin match targs with
223                  | None -> warning "un-prototyped function type"; []
224                  | Some tl -> convertParams seen tl
225                  end,
226                  convertTyp seen tres)
227    | C.TNamed _ ->
228        assert false
229    | C.TStruct(id, a) ->
230        let flds =
231          try
232            convertFields (id :: seen) (Env.find_struct env id)
233          with Env.Error e ->
234            error (Env.error_message e); [] in
235        Tstruct("struct " ^ id.name, flds)
236    | C.TUnion(id, a) ->
237        let flds =
238          try
239            convertFields (id :: seen) (Env.find_union env id)
240          with Env.Error e ->
241            error (Env.error_message e); [] in
242        Tunion("union " ^ id.name, flds)
243
244  and convertParams seen = function
245    | [] -> []
246    | (id, ty) :: rem ->
247        if Cutil.is_composite_type env ty then
248          unsupported "function parameter of struct or union type";
249        (convertTyp seen ty)::(convertParams seen rem)
250
251  and convertFields seen ci =
252    convertFieldList seen ci.Env.ci_members
253
254  and convertFieldList seen = function
255    | [] -> []
256    | f :: fl ->
257        if f.fld_bitfield <> None then
258          unsupported "bit field in struct or union";
259        (f.fld_name, convertTyp seen f.fld_typ)::(
260              convertFieldList seen fl)
261
262  in convertTyp [] t
263
264let rec convertTypList env = function
265  | [] -> []
266  | t1 :: tl -> (convertTyp env t1 )::( convertTypList env tl)
267
268(** Expressions *)
269
270let ezero = Expr(Econst_int(0), Tint(I32, AST.Signed))
271
272let rec convertExpr env e =
273  let ty = convertTyp env e.etyp in
274  match e.edesc with
275  | C.EConst(C.CInt(i, _, _)) when i = Int64.zero && ty = Tpointer Tvoid ->
276      Expr(Ecast (ty, Expr (Econst_int 0, Tint (I8, AST.Unsigned))), ty)
277  | C.EConst(C.CInt(i, _, _)) ->
278      Expr(Econst_int( convertInt i), ty)
279  | C.EConst(C.CFloat(f, _, _)) ->
280      Expr(Econst_float f, ty)
281  | C.EConst(C.CStr s) ->
282      Expr(Evar(name_for_string_literal env s), typeStringLiteral s)
283  | C.EConst(C.CWStr s) ->
284      unsupported "wide string literal"; ezero
285  | C.EConst(C.CEnum(id, i)) ->
286      Expr(Econst_int(convertInt i), ty)
287
288  | C.ESizeof ty1 ->
289      Expr(Esizeof(convertTyp env ty1), ty)
290  | C.EVar id ->
291      Expr(Evar(id.name), ty)
292
293  | C.EUnop(C.Oderef, e1) ->
294      Expr(Ederef(convertExpr env e1), ty)
295  | C.EUnop(C.Oaddrof, e1) ->
296      Expr(Eaddrof(convertExpr env e1), ty)
297  | C.EUnop(C.Odot id, e1) ->
298      Expr(Efield(convertExpr env e1, id), ty)
299  | C.EUnop(C.Oarrow id, e1) ->
300      let e1' = convertExpr env e1 in
301      let ty1 =
302        match typeof e1' with
303        | Tpointer t -> t
304        | _ -> error ("wrong type for ->" ^ id ^ " access"); Tvoid in
305      Expr(Efield(Expr(Ederef(convertExpr env e1), ty1),
306                   id), ty)
307  | C.EUnop(C.Oplus, e1) ->
308      convertExpr env e1
309  | C.EUnop(C.Ominus, e1) ->
310      Expr(Eunop(Oneg, convertExpr env e1), ty)
311  | C.EUnop(C.Olognot, e1) ->
312      Expr(Eunop(Onotbool, convertExpr env e1), ty)
313  | C.EUnop(C.Onot, e1) ->
314      Expr(Eunop(Onotint, convertExpr env e1), ty)
315  | C.EUnop(_, _) ->
316      unsupported "pre/post increment/decrement operator"; ezero
317
318  | C.EBinop(C.Oindex, e1, e2, _) ->
319      Expr(Ederef(Expr(Ebinop(Oadd, convertExpr env e1, convertExpr env e2),
320                       Tpointer ty)), ty)
321  | C.EBinop(C.Ologand, e1, e2, _) ->
322      Expr(Eandbool(convertExpr env e1, convertExpr env e2), ty)
323  | C.EBinop(C.Ologor, e1, e2, _) ->
324      Expr(Eorbool(convertExpr env e1, convertExpr env e2), ty)
325  | C.EBinop(op, e1, e2, _) ->
326      let op' =
327        match op with
328        | C.Oadd -> Oadd
329        | C.Osub -> Osub
330        | C.Omul -> Omul
331        | C.Odiv -> Odiv
332        | C.Omod -> Omod
333        | C.Oand -> Oand
334        | C.Oor  -> Oor
335        | C.Oxor -> Oxor
336        | C.Oshl -> Oshl
337        | C.Oshr -> Oshr
338        | C.Oeq  -> Oeq
339        | C.One  -> One
340        | C.Olt  -> Olt
341        | C.Ogt  -> Ogt
342        | C.Ole  -> Ole
343        | C.Oge  -> Oge
344        | C.Ocomma -> unsupported "sequence operator"; Oadd
345        | _ -> unsupported "assignment operator"; Oadd in
346      Expr(Ebinop(op', convertExpr env e1, convertExpr env e2), ty)
347  | C.EConditional(e1, e2, e3) ->
348      Expr(Econdition(convertExpr env e1, convertExpr env e2, convertExpr env e3), ty)
349  | C.ECast(ty1, e1) ->
350      Expr(Ecast(convertTyp env ty1, convertExpr env e1), ty)
351  | C.ECall _ ->
352      unsupported "function call within expression"; ezero
353
354(* Function calls *)
355
356let rec projFunType env ty =
357  match Cutil.unroll env ty with
358  | TFun(res, args, vararg, attr) -> Some(res, vararg)
359  | TPtr(ty', attr) -> projFunType env ty'
360  | _ -> None
361
362let convertFuncall env lhs fn args =
363  match projFunType env fn.etyp with
364  | None ->
365      error "wrong type for function part of a call"; Sskip
366  | Some(res, false) ->
367      (* Non-variadic function *)
368      Scall(lhs, convertExpr env fn, List.map (convertExpr env) args)
369  | Some(res, true) ->
370      (* Variadic function: generate a call to a stub function with
371         the appropriate number and types of arguments.  Works only if
372         the function expression e is a global variable. *)
373      let fun_name =
374        match fn with
375        | {edesc = C.EVar id} when !ClightFlags.option_fvararg_calls ->
376            (*warning "emulating call to variadic function"; *)
377            id.name
378        | _ ->
379            unsupported "call to variadic function";
380            "<error>" in
381      let targs = convertTypList env (List.map (fun e -> e.etyp) args) in
382      let tres = convertTyp env res in
383      let (stub_fun_name, stub_fun_typ) =
384        register_stub_function fun_name tres targs in
385      Scall(lhs,
386            Expr(Evar( stub_fun_name), stub_fun_typ),
387            List.map (convertExpr env) args)
388
389(* Handling of volatile *)
390
391let is_volatile_access env e =
392  List.mem C.AVolatile (Cutil.attributes_of_type env e.etyp)
393  && Cutil.is_lvalue env e
394
395let volatile_fun_suffix_type ty =
396  match ty with
397  | Tint(I8, AST.Unsigned) -> ("int8unsigned", ty)
398  | Tint(I8, AST.Signed) -> ("int8signed", ty)
399  | Tint(I16, AST.Unsigned) -> ("int16unsigned", ty)
400  | Tint(I16, AST.Signed) -> ("int16signed", ty)
401  | Tint(I32, _) -> ("int32", Tint(I32, AST.Signed))
402  | Tfloat F32 -> ("float32", ty)
403  | Tfloat F64 -> ("float64", ty)
404  | Tpointer _ | Tarray _ | Tfunction _ | Tcomp_ptr _ ->
405      ("pointer", Tpointer Tvoid)
406  | _ ->
407      unsupported "operation on volatile struct or union"; ("", Tvoid)
408
409let volatile_read_fun ty =
410  let (suffix, ty') = volatile_fun_suffix_type ty in
411  Expr(Evar( ("__builtin_volatile_read_" ^ suffix)),
412       Tfunction((Tpointer Tvoid)::[], ty'))
413
414let volatile_write_fun ty =
415  let (suffix, ty') = volatile_fun_suffix_type ty in
416  Expr(Evar( ("__builtin_volatile_write_" ^ suffix)),
417       Tfunction((Tpointer Tvoid)::(ty'::[]), Tvoid))
418
419(* Toplevel expression, argument of an Sdo *)
420
421let convertTopExpr env e =
422  match e.edesc with
423  | C.EBinop(C.Oassign, lhs, {edesc = C.ECall(fn, args)}, _) ->
424      convertFuncall env (Some (convertExpr env lhs)) fn args
425  | C.EBinop(C.Oassign, lhs, rhs, _) ->
426      if Cutil.is_composite_type env lhs.etyp then
427        unsupported "assignment between structs or between unions";
428      let lhs' = convertExpr env lhs
429      and rhs' = convertExpr env rhs in
430      begin match (is_volatile_access env lhs, is_volatile_access env rhs) with
431      | true, true ->                   (* should not happen *)
432          unsupported "volatile-to-volatile assignment";
433          Sskip
434      | false, true ->                  (* volatile read *)
435          Scall(Some lhs',
436                volatile_read_fun (typeof rhs'),
437                [ Expr (Eaddrof rhs', Tpointer (typeof rhs')) ])
438      | true, false ->                  (* volatile write *)
439          Scall(None,
440                volatile_write_fun (typeof lhs'),
441                [ Expr(Eaddrof lhs', Tpointer (typeof lhs')); rhs' ])
442      | false, false ->                 (* regular assignment *)
443          Sassign(convertExpr env lhs, convertExpr env rhs)
444      end
445  | C.ECall(fn, args) ->
446      convertFuncall env None fn args
447  | _ ->
448      unsupported "illegal toplevel expression"; Sskip
449
450(* Separate the cases of a switch statement body *)
451
452type switchlabel =
453  | Case of C.exp
454  | Default
455
456type switchbody = 
457  | Label of switchlabel
458  | Stmt of C.stmt
459
460let rec flattenSwitch = function
461  | {sdesc = C.Sseq(s1, s2)} ->
462      flattenSwitch s1 @ flattenSwitch s2
463  | {sdesc = C.Slabeled(C.Scase e, s1)} ->
464      Label(Case e) :: flattenSwitch s1
465  | {sdesc = C.Slabeled(C.Sdefault, s1)} ->
466      Label Default :: flattenSwitch s1
467  | s ->
468      [Stmt s]
469
470let rec groupSwitch = function
471  | [] ->
472      (Cutil.sskip, [])
473  | Label case :: rem ->
474      let (fst, cases) = groupSwitch rem in
475      (Cutil.sskip, (case, fst) :: cases)
476  | Stmt s :: rem ->
477      let (fst, cases) = groupSwitch rem in
478      (Cutil.sseq s.sloc s fst, cases)
479
480(* Statement *)
481
482let rec convertStmt env s =
483  updateLoc s.sloc;
484  match s.sdesc with
485  | C.Sskip ->
486      Sskip
487  | C.Sdo e ->
488      convertTopExpr env e
489  | C.Sseq(s1, s2) ->
490      Ssequence(convertStmt env s1, convertStmt env s2)
491  | C.Sif(e, s1, s2) ->
492      Sifthenelse(convertExpr env e, convertStmt env s1, convertStmt env s2)
493  | C.Swhile(e, s1) ->
494      Swhile(None, convertExpr env e, convertStmt env s1)
495  | C.Sdowhile(s1, e) ->
496      Sdowhile(None, convertExpr env e, convertStmt env s1)
497  | C.Sfor(s1, e, s2, s3) ->
498      Sfor(None, convertStmt env s1, convertExpr env e, convertStmt env s2,
499           convertStmt env s3)
500  | C.Sbreak ->
501      Sbreak
502  | C.Scontinue ->
503      Scontinue
504  | C.Sswitch(e, s1) ->
505      let (init, cases) = groupSwitch (flattenSwitch s1) in
506      if cases = [] then
507        unsupported "ill-formed 'switch' statement";
508      if init.sdesc <> C.Sskip then
509        warning "ignored code at beginning of 'switch'";
510      Sswitch(convertExpr env e, convertSwitch env cases)
511  | C.Slabeled(C.Slabel lbl, s1) ->
512      Slabel( lbl, convertStmt env s1)
513  | C.Slabeled(C.Scase _, _) ->
514      unsupported "'case' outside of 'switch'"; Sskip
515  | C.Slabeled(C.Sdefault, _) ->
516      unsupported "'default' outside of 'switch'"; Sskip
517  | C.Sgoto lbl ->
518      Sgoto( lbl)
519  | C.Sreturn None ->
520      Sreturn None
521  | C.Sreturn(Some e) ->
522      Sreturn(Some(convertExpr env e))
523  | C.Sblock _ ->
524      unsupported "nested blocks"; Sskip
525  | C.Sdecl _ ->
526      unsupported "inner declarations"; Sskip
527
528and convertSwitch env = function
529  | [] ->
530      LSdefault Sskip
531  | [Default, s] ->
532      LSdefault (convertStmt env s)
533  | (Default, s) :: _ ->
534      updateLoc s.sloc;
535      unsupported "'default' case must occur last";
536      LSdefault Sskip
537  | (Case e, s) :: rem ->
538      updateLoc s.sloc;
539      let v =
540        match Ceval.integer_expr env e with
541        | None -> unsupported "'case' label is not a compile-time integer"; 0L
542        | Some v -> v in
543      LScase(convertInt v,
544             convertStmt env s,
545             convertSwitch env rem)
546
547(** Function definitions *)
548
549let convertFundef env fd =
550  if Cutil.is_composite_type env fd.fd_ret then
551    unsupported "function returning a struct or union";
552  let ret =
553    convertTyp env fd.fd_ret in
554  let params =
555    List.map
556      (fun (id, ty) ->
557        if Cutil.is_composite_type env ty then
558          unsupported "function parameter of struct or union type";
559        ( id.name, convertTyp env ty))
560      fd.fd_params in
561  let vars =
562    List.map
563      (fun (sto, id, ty, init) ->
564        if sto = Storage_extern || sto = Storage_static then
565          unsupported "'static' or 'extern' local variable";
566        if init <> None then
567          unsupported "initialized local variable";
568        ( id.name, convertTyp env ty))
569      fd.fd_locals in
570  let body' = convertStmt env fd.fd_body in
571  let id' =  fd.fd_name.name in
572  let decl =
573    (fd.fd_storage, fd.fd_name, Cutil.fundef_typ fd, None) in
574  Hashtbl.add decl_atom id' (env, decl);
575  !define_function_hook id' decl;
576  (id',
577   Internal {fn_return = ret; fn_params = params;
578             fn_vars = vars; fn_body = body'})
579
580(** External function declaration *)
581
582let convertFundecl env (sto, id, ty, optinit) =
583  match convertTyp env ty with
584  | Tfunction(args, res) ->
585      let id' =  id.name in
586      (id', External(id', args, res))
587  | _ ->
588      assert false
589
590(** Initializers *)
591
592let init_data_of_string s =
593  let id = ref [] in
594  let enter_char c =
595    let n = (Char.code c) in
596    id := Init_int8 n :: !id in
597  enter_char '\000';
598  for i = String.length s - 1 downto 0 do enter_char s.[i] done;
599  !id
600
601let convertInit env ty init =
602
603  let k = ref []
604  and pos = ref 0 in
605  let emit size datum =
606    k := datum :: !k;
607    pos := !pos + size in
608  let emit_space size =
609    emit size (Init_space size) in
610  let align size =
611    let n = !pos land (size - 1) in
612    if n > 0 then emit_space (size - n) in
613  let check_align size =
614    assert (!pos land (size - 1) = 0) in
615
616  let rec reduceInitExpr = function
617    | { edesc = C.EVar id; etyp = ty } ->
618        begin match Cutil.unroll env ty with
619        | C.TArray _ | C.TFun _ -> Some id
620        | _ -> None
621        end
622    | {edesc = C.EUnop(C.Oaddrof, {edesc = C.EVar id})} -> Some id
623    | {edesc = C.ECast(ty, e)} -> reduceInitExpr e
624    | _ -> None in
625
626  let rec cvtInit ty = function
627  | Init_single e ->
628      begin match reduceInitExpr e with
629      | Some id ->
630          check_align 4;
631          emit 4 (Init_addrof( id.name, 0))
632      | None ->
633      match Ceval.constant_expr env ty e with
634      | Some(C.CInt(v, ik, _)) ->
635          begin match convertIkind ik with
636          | (_, I8) ->
637              emit 1 (Init_int8(convertInt v))
638          | (_, I16) ->
639              check_align 2;
640              emit 2 (Init_int16(convertInt v))
641          | (_, I32) ->
642              check_align 4;
643              emit 4 (Init_int32(convertInt v))
644          end
645      | Some(C.CFloat(v, fk, _)) ->
646          begin match convertFkind fk with
647          | F32 ->
648              check_align 4;
649              emit 4 (Init_float32 v)
650          | F64 ->
651              check_align 8;
652              emit 8 (Init_float64 v)
653          end
654      | Some(C.CStr s) ->
655          check_align 4;
656          let id = name_for_string_literal env s in
657          emit 4 (Init_addrof(id, 0))
658      | Some(C.CWStr _) ->
659          unsupported "wide character strings"
660      | Some(C.CEnum _) ->
661          error "enum tag after constant folding"
662      | None ->
663          error "initializer is not a compile-time constant"
664      end
665  | Init_array il ->
666      let ty_elt =
667        match Cutil.unroll env ty with
668        | C.TArray(t, _, _) -> t
669        | _ -> error "array type expected in initializer"; C.TVoid [] in
670      List.iter (cvtInit ty_elt) il
671  | Init_struct(_, flds) ->
672      cvtPadToSizeof ty (fun () -> List.iter cvtFieldInit flds)
673  | Init_union(_, fld, i) ->
674      cvtPadToSizeof ty (fun () -> cvtFieldInit (fld,i))
675
676  and cvtFieldInit (fld, i) =
677    let ty' = convertTyp env fld.fld_typ in
678    let al = alignof ty' in
679    align al;
680    cvtInit fld.fld_typ i
681
682  and cvtPadToSizeof ty fn =
683    let ty' = convertTyp env ty in
684    let sz = sizeof ty' in
685    let pos0 = !pos in
686    fn();
687    let pos1 = !pos in
688    assert (pos1 <= pos0 + sz);
689    if pos1 < pos0 + sz then emit_space (pos0 + sz - pos1)
690
691  in cvtInit ty init; List.rev !k
692
693(** Global variable *)
694
695let convertGlobvar env (sto, id, ty, optinit as decl) =
696  let id' =  id.name in
697  let ty' = convertTyp env ty in 
698  let init' =
699    match optinit with
700    | None ->
701        if sto = C.Storage_extern then [] else [Init_space(sizeof ty')]
702    | Some i ->
703        convertInit env ty i in
704  Hashtbl.add decl_atom id' (env, decl);
705  !define_variable_hook id' decl;
706  ((id', init'), ty')
707
708(** Convert a list of global declarations.
709  Result is a pair [(funs, vars)] where [funs] are
710  the function definitions (internal and external)
711  and [vars] the variable declarations. *)
712
713let rec convertGlobdecls env funs vars gl =
714  match gl with
715  | [] -> (List.rev funs, List.rev vars)
716  | g :: gl' ->
717      updateLoc g.gloc;
718      match g.gdesc with
719      | C.Gdecl((sto, id, ty, optinit) as d) ->
720          (* Prototyped functions become external declarations.
721             Variadic functions are skipped.
722             Other types become variable declarations. *)
723          begin match Cutil.unroll env ty with
724          | TFun(_, Some _, false, _) ->
725              convertGlobdecls env (convertFundecl env d :: funs) vars gl'
726          | TFun(_, None, false, _) ->
727              error "function declaration without prototype";
728              convertGlobdecls env funs vars gl'
729          | TFun(_, _, true, _) ->
730              convertGlobdecls env funs vars gl'
731          | _ ->
732              convertGlobdecls env funs (convertGlobvar env d :: vars) gl'
733          end
734      | C.Gfundef fd ->
735          convertGlobdecls env (convertFundef env fd :: funs) vars gl'
736      | C.Gcompositedecl _ | C.Gcompositedef _
737      | C.Gtypedef _ | C.Genumdef _ ->
738          (* typedefs are unrolled, structs are expanded inline, and
739             enum tags are folded.  So we just skip their declarations. *)
740          convertGlobdecls env funs vars gl'
741      | C.Gpragma s ->
742          if not (!process_pragma_hook s) then
743            warning ("'#pragma " ^ s ^ "' directive ignored");
744          convertGlobdecls env funs vars gl'
745
746(** Build environment of typedefs and structs *)
747
748let rec translEnv env = function
749  | [] -> env
750  | g :: gl ->
751      let env' =
752        match g.gdesc with
753        | C.Gcompositedecl(su, id) ->
754            Env.add_composite env id (Cutil.composite_info_decl env su)
755        | C.Gcompositedef(su, id, fld) ->
756            Env.add_composite env id (Cutil.composite_info_def env su fld)
757        | C.Gtypedef(id, ty) ->
758            Env.add_typedef env id ty
759        | _ ->
760            env in
761      translEnv env' gl
762
763(** Eliminate forward declarations of globals that are defined later. *)
764
765module IdentSet = Set.Make(struct type t = C.ident let compare = compare end)
766
767let cleanupGlobals p =
768 
769  let rec clean defs accu = function
770    | [] -> accu
771    | g :: gl ->
772        updateLoc g.gloc;
773        match g.gdesc with
774        | C.Gdecl(sto, id, ty, None) ->
775            if IdentSet.mem id defs
776            then clean defs accu gl
777            else clean (IdentSet.add id defs) (g :: accu) gl
778        | C.Gdecl(_, id, ty, _) ->
779            if IdentSet.mem id defs then
780              error ("multiple definitions of " ^ id.name);
781            clean (IdentSet.add id defs) (g :: accu) gl
782        | C.Gfundef fd ->
783            if IdentSet.mem fd.fd_name defs then
784              error ("multiple definitions of " ^ fd.fd_name.name);
785            clean (IdentSet.add fd.fd_name defs) (g :: accu) gl
786        | _ ->
787            clean defs (g :: accu) gl
788
789  in clean IdentSet.empty [] (List.rev p)
790
791(** Convert a [C.program] into a [Csyntax.program] *)
792
793let convertProgram p =
794  numErrors := 0;
795  stringNum := 0;
796  Hashtbl.clear decl_atom;
797  Hashtbl.clear stringTable;
798  Hashtbl.clear stub_function_table;
799  (* Hack: externals are problematic for Cerco. TODO *)
800  let p = (* Builtins.declarations() @ *) p in
801  try
802    let (funs1, vars1) =
803      convertGlobdecls (translEnv Env.empty p) [] [] (cleanupGlobals p) in
804    let funs2 = declare_stub_functions funs1 in
805    let main = if List.mem_assoc "main" funs2 then Some "main" else None in
806    let vars2 = globals_for_strings vars1 in
807    if !numErrors > 0
808    then None
809    else Some { prog_funct = funs2;
810                prog_vars = vars2;
811                prog_main = main }
812  with Env.Error msg ->
813    error (Env.error_message msg); None
814
815(** ** Extracting information about global variables from their atom *)
816
817let rec type_is_readonly env t =
818  let a = Cutil.attributes_of_type env t in
819  if List.mem C.AVolatile a then false else
820  if List.mem C.AConst a then true else
821  match Cutil.unroll env t with
822  | C.TArray(t', _, _) -> type_is_readonly env t'
823  | _ -> false
824
825let atom_is_static a =
826  try
827    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
828    sto = C.Storage_static
829  with Not_found ->
830    false
831
832let atom_is_readonly a =
833  try
834    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
835    type_is_readonly env ty
836  with Not_found ->
837    false
838
839let atom_sizeof a =
840  try
841    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
842    Cutil.sizeof env ty
843  with Not_found ->
844    None
845
846let atom_alignof a =
847  try
848    let (env, (sto, id, ty, init)) = Hashtbl.find decl_atom a in
849    Cutil.alignof env ty
850  with Not_found ->
851    None
852
853(** ** The builtin environment *)
854
855open Builtins
856
857let builtins_generic = {
858  typedefs = [
859    (* keeps GCC-specific headers happy, harmless for others *)
860    "__builtin_va_list", C.TPtr(C.TVoid [], [])
861  ];
862  functions = [
863    (* The volatile read/volatile write functions *)
864    "__builtin_volatile_read_int8unsigned",
865        (TInt(IUChar, []), [TPtr(TVoid [], [])], false);
866    "__builtin_volatile_read_int8signed",
867        (TInt(ISChar, []), [TPtr(TVoid [], [])], false);
868    "__builtin_volatile_read_int16unsigned",
869        (TInt(IUShort, []), [TPtr(TVoid [], [])], false);
870    "__builtin_volatile_read_int16signed",
871        (TInt(IShort, []), [TPtr(TVoid [], [])], false);
872    "__builtin_volatile_read_int32",
873        (TInt(IInt, []), [TPtr(TVoid [], [])], false);
874    "__builtin_volatile_read_float32",
875        (TFloat(FFloat, []), [TPtr(TVoid [], [])], false);
876    "__builtin_volatile_read_float64",
877         (TFloat(FDouble, []), [TPtr(TVoid [], [])], false);
878    "__builtin_volatile_read_pointer",
879         (TPtr(TVoid [], []), [TPtr(TVoid [], [])], false);
880    "__builtin_volatile_write_int8unsigned",
881        (TVoid [], [TPtr(TVoid [], []); TInt(IUChar, [])], false);
882    "__builtin_volatile_write_int8signed",
883        (TVoid [], [TPtr(TVoid [], []); TInt(ISChar, [])], false);
884    "__builtin_volatile_write_int16unsigned",
885        (TVoid [], [TPtr(TVoid [], []); TInt(IUShort, [])], false);
886    "__builtin_volatile_write_int16signed",
887        (TVoid [], [TPtr(TVoid [], []); TInt(IShort, [])], false);
888    "__builtin_volatile_write_int32",
889        (TVoid [], [TPtr(TVoid [], []); TInt(IInt, [])], false);
890    "__builtin_volatile_write_float32",
891        (TVoid [], [TPtr(TVoid [], []); TFloat(FFloat, [])], false);
892    "__builtin_volatile_write_float64",
893         (TVoid [], [TPtr(TVoid [], []); TFloat(FDouble, [])], false);
894    "__builtin_volatile_write_pointer",
895         (TVoid [], [TPtr(TVoid [], []); TPtr(TVoid [], [])], false)
896  ]
897}
898
899(* Add processor-dependent builtins *)
900
901let builtins =
902  { typedefs = builtins_generic.typedefs @ CBuiltins.builtins.typedefs; 
903    functions = builtins_generic.functions @ CBuiltins.builtins.functions
904  }
Note: See TracBrowser for help on using the repository browser.