source: Deliverables/D2.2/8051-indexed-labels-branch/src/cminor/cminorInterpret.ml @ 1291

Last change on this file since 1291 was 1291, checked in by tranquil, 8 years ago

Started branch of untrusted compiler with indexed labels

  • added indexing structure to CostLabel?
  • propagated changes to other modules
  • added indexing as parameter to labelling
  • loop indexes not implemented yet, so behaviour is still the same
File size: 13.6 KB
Line 
1open AST
2open Cminor
3
4module Mem = Driver.CminorMemory
5module Val = Mem.Value
6module LocalEnv = Map.Make(String)
7type local_env = Val.t LocalEnv.t
8type memory = Cminor.function_def Mem.memory
9
10
11let error_prefix = "Cminor interpret"
12let error s = Error.global_error error_prefix s
13let warning s = Error.warning error_prefix s
14let error_float () = error "float not supported."
15
16
17(* Helpers *)
18
19let value_of_address = List.hd
20let address_of_value v = [v]
21
22
23(* State of execution *)
24
25type continuation = 
26    Ct_stop
27  | Ct_cont of statement*continuation
28  | Ct_endblock of continuation
29  | Ct_returnto of
30      ident option*internal_function*Val.address*local_env*continuation
31
32type state = 
33    State_regular of
34      internal_function*statement*continuation*Val.address*local_env*(function_def Mem.memory)
35  | State_call of function_def*Val.t list*continuation*(function_def Mem.memory)
36  | State_return of Val.t*continuation*(function_def Mem.memory)
37
38let string_of_local_env lenv =
39  let f x v s = s ^ x ^ " = " ^ (Val.to_string v) ^ "  " in
40  LocalEnv.fold f lenv ""
41
42let string_of_expr = CminorPrinter.print_expression
43
44let string_of_args args =
45  "(" ^ (MiscPottier.string_of_list ", " string_of_expr args) ^ ")"
46
47let rec string_of_statement = function
48  | St_skip -> "skip"
49  | St_assign (x, e) -> x ^ " = " ^ (string_of_expr e)
50  | St_store (q, e1, e2) ->
51    Printf.sprintf "%s[%s] = %s"
52      (Memory.string_of_quantity q) (string_of_expr e1) (string_of_expr e2)
53  | St_call (None, f, args, _)
54  | St_tailcall (f, args, _) -> (string_of_expr f) ^ (string_of_args args)
55  | St_call (Some x, f, args, _) ->
56    x ^ " = " ^ (string_of_expr f) ^ (string_of_args args)
57  | St_seq _ -> "sequence"
58  | St_ifthenelse (e, _, _) -> "if (" ^ (string_of_expr e) ^ ")"
59  | St_loop _ -> "loop"
60  | St_block _ -> "block"
61  | St_exit n -> "exit " ^ (string_of_int n)
62  | St_switch (e, _, _) -> "switch (" ^ (string_of_expr e) ^ ")"
63  | St_return None -> "return"
64  | St_return (Some e) -> "return (" ^ (string_of_expr e) ^ ")"
65  | St_label (lbl, _) -> "label " ^ lbl
66  | St_goto lbl -> "goto " ^ lbl
67  | St_cost (lbl, _) ->
68                let lbl = CostLabel.string_of_cost_label lbl in
69                "cost " ^ lbl
70
71let print_state = function
72  | State_regular (_, stmt, _, sp, lenv, mem) ->
73    Printf.printf "Local environment:\n%s\n\nMemory:%s\nStack pointer: %s\n\nRegular state: %s\n\n%!"
74      (string_of_local_env lenv)
75      (Mem.to_string mem)
76      (Val.to_string (value_of_address sp))
77      (string_of_statement stmt)
78  | State_call (_, args, _, mem) ->
79    Printf.printf "Memory:%s\nCall state\n\nArguments:\n%s\n\n%!"
80      (Mem.to_string mem)
81      (MiscPottier.string_of_list " " Val.to_string args)
82  | State_return (v, _, mem) ->
83    Printf.printf "Memory:%s\nReturn state: %s\n\n%!"
84      (Mem.to_string mem)
85      (Val.to_string v)
86
87
88(* Global and local environment management *)
89
90let init_local_env args params vars =
91  let f_param lenv (x, _) v = LocalEnv.add x v lenv in
92  let f_var lenv (x, _) = LocalEnv.add x Val.undef lenv in
93  let lenv = List.fold_left2 f_param LocalEnv.empty params args in
94  List.fold_left f_var lenv vars
95
96let find_fundef f mem =
97  let addr = Mem.find_global mem f in
98  Mem.find_fun_def mem addr
99
100
101(* Expression evaluation *)
102
103module Eval_op (M : Memory.S) = struct
104
105  let concrete_stacksize = M.concrete_size
106
107  let ext_fun_of_sign = function
108    | AST.Signed -> M.Value.sign_ext
109    | AST.Unsigned -> M.Value.zero_ext
110
111  let cast_to_std t v = match t with
112    | AST.Sig_int (size, sign) -> (ext_fun_of_sign sign) v size M.int_size
113    | AST.Sig_float _ -> error_float ()
114    | AST.Sig_offset | AST.Sig_ptr -> v
115
116  let cast_from_std t v = match t with
117    | AST.Sig_int (size, _) -> (ext_fun_of_sign AST.Unsigned) v M.int_size size
118    | AST.Sig_float _ -> error_float ()
119    | AST.Sig_offset | AST.Sig_ptr -> v
120
121  let cst mem sp t = function
122    | Cst_int i -> cast_to_std t (M.Value.of_int i)
123    | Cst_float _ -> error_float ()
124    | Cst_addrsymbol id when M.mem_global mem id ->
125      value_of_address (M.find_global mem id)
126    | Cst_addrsymbol id -> error ("unknown global variable " ^ id ^ ".")
127    | Cst_stack -> value_of_address sp
128    | Cst_offset off -> M.Value.of_int (M.concrete_offset off)
129    | Cst_sizeof t' -> cast_to_std t (M.Value.of_int (M.concrete_size t'))
130
131  let fun_of_op1 = function
132    | Op_cast ((from_size, from_sign), to_size) ->
133      (fun v -> (ext_fun_of_sign from_sign) v from_size to_size)
134    | Op_negint -> M.Value.negint
135    | Op_notbool -> M.Value.notbool
136    | Op_notint -> M.Value.negint
137    | Op_id -> (fun v -> v)
138    | Op_ptrofint
139    | Op_intofptr ->
140      error "conversion between integers and pointers not supported yet."
141
142  let op1 ret_type t op v =
143    cast_from_std ret_type ((fun_of_op1 op) (cast_to_std t v))
144
145  let fun_of_op2 = function
146    | Op_add | Op_addp -> M.Value.add
147    | Op_sub | Op_subp | Op_subpp -> M.Value.sub
148    | Op_mul -> M.Value.mul
149    | Op_div -> M.Value.div
150    | Op_divu -> M.Value.divu
151    | Op_mod -> M.Value.modulo
152    | Op_modu -> M.Value.modulou
153    | Op_and -> M.Value.and_op
154    | Op_or -> M.Value.or_op
155    | Op_xor -> M.Value.xor
156    | Op_shl -> M.Value.shl
157    | Op_shr -> M.Value.shr
158    | Op_shru -> M.Value.shru
159    | Op_cmp Cmp_eq | Op_cmpp Cmp_eq -> M.Value.cmp_eq
160    | Op_cmp Cmp_ne | Op_cmpp Cmp_ne -> M.Value.cmp_ne
161    | Op_cmp Cmp_gt | Op_cmpp Cmp_gt -> M.Value.cmp_gt
162    | Op_cmp Cmp_ge | Op_cmpp Cmp_ge -> M.Value.cmp_ge
163    | Op_cmp Cmp_lt | Op_cmpp Cmp_lt -> M.Value.cmp_lt
164    | Op_cmp Cmp_le | Op_cmpp Cmp_le -> M.Value.cmp_le
165    | Op_cmpu Cmp_eq -> M.Value.cmp_eq_u
166    | Op_cmpu Cmp_ne -> M.Value.cmp_ne_u
167    | Op_cmpu Cmp_gt -> M.Value.cmp_gt_u
168    | Op_cmpu Cmp_ge -> M.Value.cmp_ge_u
169    | Op_cmpu Cmp_lt -> M.Value.cmp_lt_u
170    | Op_cmpu Cmp_le -> M.Value.cmp_le_u
171
172  let op2 ret_type t1 t2 op2 v1 v2 =
173    let v1 = cast_to_std t1 v1 in
174    let v2 = cast_to_std t2 v2 in
175    cast_from_std ret_type ((fun_of_op2 op2) v1 v2)
176end
177
178module Eval = Eval_op (Mem)
179
180let concrete_stacksize = Eval.concrete_stacksize
181let eval_constant = Eval.cst
182let eval_unop = Eval.op1
183let eval_binop = Eval.op2
184
185let type_of_expr (Cminor.Expr (_, t)) = t
186
187let rec eval_expression stack local_env memory (Cminor.Expr (ed, t)) =
188  match ed with
189    | Id x when LocalEnv.mem x local_env -> (LocalEnv.find x local_env,[])
190    | Id x -> error ("unknown local variable " ^ x ^ ".")
191    | Cst(c) -> (eval_constant memory stack t c,[])
192    | Op1(op,arg) -> 
193      let (v,l) = eval_expression stack local_env memory arg in
194      (eval_unop t (type_of_expr arg) op v,l)
195    | Op2(op, arg1, arg2) -> 
196      let (v1,l1) = eval_expression stack local_env memory arg1 in
197      let (v2,l2) = eval_expression stack local_env memory arg2 in
198      (eval_binop t (type_of_expr arg1) (type_of_expr arg2) op v1 v2,l1@l2) 
199    | Mem(q,a) -> 
200      let (v,l) = eval_expression stack local_env memory a in 
201      (Mem.loadq memory q (address_of_value v),l)
202    | Cond(a1,a2,a3) ->
203      let (v1,l1) = eval_expression stack local_env memory a1 in
204      if Val.is_true v1 then
205        let (v2,l2) = eval_expression stack local_env memory a2 in
206        (v2,l1@l2)
207      else
208        if Val.is_false v1 then
209          let (v3,l3) = eval_expression stack local_env memory a3 in
210          (v3,l1@l3)
211        else error "undefined conditional value."
212    | Exp_cost(lbl,e) -> 
213      let (v,l) = eval_expression stack local_env memory e in
214      (v,l@[lbl])
215
216let eval_exprlist sp lenv mem es =
217  let f (vs, cost_lbls) e =
218    let (v, cost_lbls') = eval_expression sp lenv mem e in
219    (vs @ [v], cost_lbls @ cost_lbls') in
220  List.fold_left f ([], []) es
221
222(* State transition *)
223
224let rec callcont = function
225    Ct_stop                     -> Ct_stop
226  | Ct_cont(_,k)                -> callcont k
227  | Ct_endblock(k)              -> callcont k
228  | Ct_returnto(a,b,c,d,e)      -> Ct_returnto(a,b,c,d,e)
229
230let findlabel lbl st k = 
231  let rec fdlbl k = function
232    St_skip                     -> None
233  | St_assign(_,_)              -> None
234  | St_store(_,_,_)             -> None
235  | St_call(_,_,_,_)            -> None
236  | St_tailcall(_,_,_)          -> None 
237  | St_seq(s1,s2)               -> 
238      (match fdlbl (Ct_cont(s2,k)) s1 with
239           None -> fdlbl k s2
240         | Some(v) -> Some(v)
241      )
242  | St_ifthenelse(_,s1,s2)      ->
243      (match fdlbl k s1 with
244           None -> fdlbl k s2
245         | Some(v) -> Some(v)
246      )
247  | St_loop(s)                  -> fdlbl (Ct_cont(St_loop(s),k)) s
248  | St_block(s)                 -> fdlbl (Ct_endblock(k)) s
249  | St_exit(_)                  -> None
250  | St_switch(_,_,_)            -> None
251  | St_return(_)                -> None
252  | St_label(l,s)               -> if l=lbl then Some((s,k)) else None 
253  | St_goto(_)                  -> None
254  | St_cost (_,s)               -> fdlbl k s
255  in match fdlbl k st with
256      None -> assert false (*Wrong label*)
257    | Some(v) -> v
258
259
260let call_state sigma e m f params cont =
261  let (addr,l1) = eval_expression sigma e m f in
262  let fun_def = Mem.find_fun_def m (address_of_value addr) in
263  let (args,l2) = eval_exprlist sigma e m params in
264  (State_call(fun_def,args,cont,m),l1@l2)
265
266let eval_stmt f k sigma e m s = match s, k with
267  | St_skip,Ct_cont(s,k) -> (State_regular(f, s, k, sigma, e, m),[])
268  | St_skip,Ct_endblock(k) -> (State_regular(f, St_skip, k, sigma, e, m),[])
269  | St_skip, (Ct_returnto _ as k) ->
270    (State_return (Val.undef,k,Mem.free m sigma),[])
271  | St_skip,Ct_stop -> 
272    (State_return (Val.undef,Ct_stop,Mem.free m sigma),[])
273  | St_assign(x,exp),_ -> 
274    let (v,l) = eval_expression sigma e m exp in
275    let e = LocalEnv.add x v e in
276    (State_regular(f, St_skip, k, sigma, e, m),l)
277  | St_store(q,a1,a2),_ ->
278    let (v1,l1) = eval_expression sigma e m a1 in
279    let (v2,l2) = eval_expression sigma e m a2 in
280    let m = Mem.storeq m q (address_of_value v1) v2 in
281    (State_regular(f, St_skip, k, sigma, e, m),l1@l2)
282  | St_call(xopt,f',params,_),_ ->
283    call_state sigma e m f' params (Ct_returnto(xopt,f,sigma,e,k))
284  | St_tailcall(f',params,_),_ -> 
285    call_state sigma e m f' params (callcont k)
286  | St_seq(s1,s2),_ -> (State_regular(f, s1, Ct_cont(s2, k), sigma, e, m),[])
287  | St_ifthenelse(exp,s1,s2),_ ->
288    let (v,l) = eval_expression sigma e m exp in
289    let next_stmt =
290      if Val.is_true v then s1
291      else
292        if Val.is_false v then s2
293        else error "undefined conditional value." in
294      (State_regular(f,next_stmt,k,sigma,e,m),l)
295  | St_loop(s),_ -> (State_regular(f,s,Ct_cont((St_loop s),k),sigma,e,m),[])
296  | St_block(s),_ -> (State_regular(f,s,(Ct_endblock k),sigma,e,m),[])
297  | St_exit(n),Ct_cont(s,k) -> (State_regular(f,(St_exit n),k,sigma,e,m),[])
298  | St_exit(0),Ct_endblock(k) -> (State_regular(f,St_skip,k,sigma,e,m),[])
299  | St_exit(n),Ct_endblock(k) ->
300    (State_regular(f,(St_exit (n-1)),k,sigma,e,m),[])
301  | St_label(_,s),_ -> (State_regular(f,s,k,sigma,e,m),[])
302  | St_goto(lbl),_ -> 
303    let (s2,k2) = findlabel lbl f.f_body (callcont k) in
304    (State_regular(f,s2,k2,sigma,e,m),[])
305  | St_switch(exp,lst,def),_ ->
306    let (v,l) = eval_expression sigma e m exp in
307    if Val.is_int v then
308      try
309        let i = Val.to_int v in
310        let nb_exit =
311          if List.mem_assoc i lst then List.assoc i lst
312          else def in
313        (State_regular(f, St_exit nb_exit,k, sigma, e, m),l)
314      with _ -> error "int value too big."
315    else error "undefined switch value."
316  | St_return(None),_ ->
317    (State_return (Val.undef,callcont k,Mem.free m sigma),[])
318  | St_return(Some(a)),_ ->
319      let (v,l) = eval_expression sigma e m a in
320      (State_return (v,callcont k,Mem.free m sigma),l)
321  | St_cost(lbl,s),_ -> (State_regular(f,s,k,sigma,e,m),[lbl])
322  | _ -> error "state malformation."
323
324
325module InterpretExternal = Primitive.Interpret (Mem)
326
327let interpret_external k mem f args =
328  let (mem', v) = match InterpretExternal.t mem f args with
329    | (mem', InterpretExternal.V vs) ->
330      let v = if List.length vs = 0 then Val.undef else List.hd vs in
331      (mem', v)
332    | (mem', InterpretExternal.A addr) -> (mem', value_of_address addr) in
333  State_return (v, k, mem')
334
335let step_call vargs k m = function
336  | F_int f ->
337    let (m, sp) = Mem.alloc m (concrete_stacksize f.f_stacksize) in
338    let lenv = init_local_env vargs f.f_params f.f_vars in
339    State_regular(f,f.f_body,k,sp,lenv,m)
340  | F_ext f -> interpret_external k m f.ef_tag vargs
341
342let step = function
343  | State_regular(f,stmt,k,sp,e,m) -> eval_stmt f k sp e m stmt
344  | State_call(fun_def,vargs,k,m) -> (step_call vargs k m fun_def,[])
345  | State_return(v,Ct_returnto(None,f,sigma,e,k),m) ->
346    (State_regular(f,St_skip,k,sigma,e,m),[])
347  | State_return(v,Ct_returnto(Some x,f,sigma,e,k),m) ->
348    let e = LocalEnv.add x v e in
349    (State_regular(f,St_skip,k,sigma,e,m),[])
350  | _ -> error "state malformation."
351
352
353let init_mem prog =
354  let f_var mem (x, size, init_datas) = Mem.add_var mem x size init_datas in
355  let mem = List.fold_left f_var Mem.empty prog.vars in
356  let f_fun_def mem (f, def) = Mem.add_fun_def mem f def in
357  List.fold_left f_fun_def mem prog.functs
358
359let compute_result v =
360  if Val.is_int v then IntValue.Int32.cast (Val.to_int_repr v)
361  else IntValue.Int32.zero
362
363let rec exec debug trace (state, l) =
364  let cost_labels = l @ trace in
365  let print_and_return_result res =
366    if debug then Printf.printf "Result = %s\n%!"
367      (IntValue.Int32.to_string res) ;
368    (res, cost_labels) in
369  if debug then print_state state ;
370  match state with
371    | State_return(v,Ct_stop,_) -> (* Explicit return in main *)
372      print_and_return_result (compute_result v)
373    | State_regular(_,St_skip,Ct_stop,_,_,_) -> (* Implicit return in main *)
374      print_and_return_result IntValue.Int32.zero
375    | state -> exec debug cost_labels (step state)
376
377let interpret debug prog =
378  Printf.printf "*** Cminor interpret ***\n%!" ;
379  match prog.main with
380    | None -> (IntValue.Int32.zero, [])
381    | Some main ->
382      let mem = init_mem prog in
383      let first_state = (State_call (find_fundef main mem,[],Ct_stop,mem),[]) in
384      exec debug [] first_state
Note: See TracBrowser for help on using the repository browser.